samples/qt/Tutorial/Tutorial.pro

   1 TEMPLATE = app
   2 CONFIG += debug_and_release qt
   3
   4 TARGET = Tutorial
   5
   6 SAMPLESROOT = $$quote($$(CASROOT)/samples/qt)
   7
   8 HEADERS   = src/*.h \
   9             $${SAMPLESROOT}/Common/src/*.h \
  10             $${SAMPLESROOT}/Interface/src/*.h
  11
  12 SOURCES   = src/*.cxx \
  13             $${SAMPLESROOT}/Common/src/*.cxx \
  14             $${SAMPLESROOT}/Interface/src/*.cxx
  15
  16 TS_FILES  = $${SAMPLESROOT}/Common/src/Common-icon.ts \
  17             $${SAMPLESROOT}/Common/src/Common-string.ts \
  18             ./src/Tutorial-icon.ts \
  19             ./src/Tutorial-string.ts
  20
  21 RES_FILES = $${SAMPLESROOT}/Common/res/* \
  22             ./res/*
  23
  24 RES_DIR   = $$quote($$(RES_DIR))
  25
  26 INCLUDEPATH += $$quote($${SAMPLESROOT}/Common/src)
  27 INCLUDEPATH += $$quote($${SAMPLESROOT}/Interface/src)
  28 INCLUDEPATH += $$quote($$(CASROOT)/inc)
  29
  30 OCCT_DEFINES = $$(CSF_DEFINES)
  31
  32 DEFINES = $$split(OCCT_DEFINES, ;)
  33
  34 unix {
  35     UNAME = $$system(uname -s)
  36     LIBLIST = $$(LD_LIBRARY_PATH)
  37     LIBPATHS = $$split(LIBLIST,":")
  38     for(lib, LIBPATHS):LIBS += -L$${lib}
  39
  40     CONFIG(debug, debug|release) {
  41         DESTDIR = ./$$UNAME/bind
  42         OBJECTS_DIR = ./$$UNAME/objd
  43         MOC_DIR = ./$$UNAME/mocd
  44     } else {
  45         DESTDIR = ./$$UNAME/bin
  46         OBJECTS_DIR = ./$$UNAME/obj
  47         MOC_DIR = ./$$UNAME/moc
  48     }
  49
  50     MACOSX_USE_GLX = $$(MACOSX_USE_GLX)
  51
  52     !macx | equals(MACOSX_USE_GLX, true): INCLUDEPATH += $$QMAKE_INCDIR_X11 $$QMAKE_INCDIR_OPENGL $$QMAKE_INCDIR_THREAD
  53     !macx | equals(MACOSX_USE_GLX, true): DEFINES += LIN LININTEL
  54     equals(MACOSX_USE_GLX, true): DEFINES += MACOSX_USE_GLX
  55     DEFINES += OCC_CONVERT_SIGNALS QT_NO_STL
  56     !macx | equals(MACOSX_USE_GLX, true): LIBS += -L$$QMAKE_LIBDIR_X11 $$QMAKE_LIBS_X11 -L$$QMAKE_LIBDIR_OPENGL $$QMAKE_LIBS_OPENGL $$QMAKE_LIBS_THREAD
  57     LIBS += -lfreeimageplus
  58     LIBS += -ltbb -ltbbmalloc
  59     QMAKE_CXXFLAGS += -std=gnu++11
  60 }
  61
  62 win32 {
  63     CONFIG(debug, debug|release) {
  64         DEFINES += _DEBUG
  65         DESTDIR = ./win$(ARCH)/$(VCVER)/bind
  66         OBJECTS_DIR = ./win$(ARCH)/$(VCVER)/objd
  67         MOC_DIR = ./win$(ARCH)/$(VCVER)/mocd
  68         LIBS = -L$$(QT_DIR)/lib;$$(CASROOT)/win$$(ARCH)/$$(VCVER)/libd
  69     } else {
  70         DEFINES += NDEBUG
  71         DESTDIR = ./win$(ARCH)/$(VCVER)/bin
  72         OBJECTS_DIR = ./win$(ARCH)/$(VCVER)/obj
  73         MOC_DIR = ./win$(ARCH)/$(VCVER)/moc
  74         LIBS = -L$$(QT_DIR)/lib;$$(CASROOT)/win$$(ARCH)/$$(VCVER)/lib
  75     }
  76     DEFINES +=WNT WIN32 NO_COMMONSAMPLE_EXPORTS NO_IESAMPLE_EXPORTS
  77 }
  78
  79 LIBS += -lTKernel -lTKMath -lTKService -lTKV3d -lTKOpenGl \
  80         -lTKBRep -lTKIGES -lTKSTL -lTKVRML -lTKSTEP -lTKSTEPAttr -lTKSTEP209 \
  81         -lTKSTEPBase -lTKGeomBase -lTKGeomAlgo -lTKG3d -lTKG2d \
  82         -lTKXSBase -lTKShHealing -lTKHLR -lTKTopAlgo -lTKMesh -lTKPrim \
  83         -lTKCDF -lTKBool -lTKBO -lTKFillet -lTKOffset \
  84
  85 !exists($${RES_DIR}) {
  86     win32 {
  87         system(mkdir $${RES_DIR})
  88     } else {
  89         system(mkdir -p $${RES_DIR})
  90     }
  91 }
  92
  93 lrelease.name = LRELEASE ${QMAKE_FILE_IN}
  94 lrelease.commands = lrelease ${QMAKE_FILE_IN} -qm $${RES_DIR}/${QMAKE_FILE_BASE}.qm
  95 lrelease.output = ${QMAKE_FILE_BASE}.qm
  96 lrelease.input = TS_FILES
  97 lrelease.clean = $${RES_DIR}/${QMAKE_FILE_BASE}.qm
  98 lrelease.CONFIG += no_link target_predeps
  99 QMAKE_EXTRA_COMPILERS += lrelease
 100
 101 copy_res.name = Copy resource ${QMAKE_FILE_IN}
 102 copy_res.output = ${QMAKE_FILE_BASE}${QMAKE_FILE_EXT}
 103 copy_res.clean = $${RES_DIR}/${QMAKE_FILE_BASE}${QMAKE_FILE_EXT}
 104 copy_res.input = RES_FILES
 105 copy_res.CONFIG += no_link target_predeps
 106 win32: copy_res.commands = type ${QMAKE_FILE_IN} > $${RES_DIR}/${QMAKE_FILE_BASE}${QMAKE_FILE_EXT}
 107 unix:  copy_res.commands = cp -f ${QMAKE_FILE_IN} $${RES_DIR}
 108 QMAKE_EXTRA_COMPILERS += copy_res
 109 #QMAKE_CXXFLAGS += /wd4996
 110
 111 greaterThan(QT_MAJOR_VERSION, 4) {
 112     QT += widgets
 113 }