samples/qt/IESample/IESample.pro

   1 TEMPLATE = app
   2 CONFIG += debug_and_release qt
   3
   4 TARGET = IESample
   5
   6 HEADERS = src/*.h
   7 SOURCES = src/*.cxx
   8
   9 INCLUDEPATH = $(CASROOT) $(CASROOT)/inc $(CASROOT)/src/WOKTclLib $(QTDIR)/include/QtCore \
  10               $(QTDIR)/include/QtGui $(QTDIR)/include
  11
  12 TRANSLATIONS += ./src/Common-icon.ts \
  13                 ./src/Common-string.ts \
  14                 ./src/Interface-string.ts
  15
  16
  17 DEFINES = CSFDB
  18
  19 unix {
  20     CONFIG(debug, debug|release) {
  21         DESTDIR = ./Linux/bind
  22         OBJECTS_DIR = ./Linux/objd
  23         MOC_DIR = ./Linux/srcd
  24     } else {
  25         DESTDIR = ./Linux/bin
  26         OBJECTS_DIR = ./Linux/obj
  27         MOC_DIR = ./Linux/src
  28     }
  29     INCLUDEPATH += $$QMAKE_INCDIR_X11 $$QMAKE_INCDIR_OPENGL $$QMAKE_INCDIR_THREAD
  30     DEFINES += LIN LININTEL OCC_CONVERT_SIGNALS HAVE_CONFIG_H HAVE_WOK_CONFIG_H QT_NO_STL
  31     LIBS = -L$(CASROOT)/Linux/lib -L$$QMAKE_LIBDIR_X11 $$QMAKE_LIBS_X11 -L$$QMAKE_LIBDIR_OPENGL $$QMAKE_LIBS_OPENGL $$QMAKE_LIBS_THREAD
  32 }
  33
  34 win32 {
  35     CONFIG(debug, debug|release) {
  36         DEFINES += _DEBUG
  37         DESTDIR = ./win32/bind
  38         OBJECTS_DIR = ./win32/objd
  39         MOC_DIR = ./win32/srcd
  40         LIBS = -L$(CASROOT)/win32/libd
  41     } else {
  42         DEFINES += NDEBUG
  43         DESTDIR = ./win32/bin
  44         OBJECTS_DIR = ./win32/obj
  45         MOC_DIR = ./win32/src
  46         LIBS = -L$(CASROOT)/win32/lib
  47     }
  48     DEFINES +=WNT WIN32 NO_COMMONSAMPLE_EXPORTS NO_IESAMPLE_EXPORTS
  49 }
  50
  51 LIBS += -lTKernel -lPTKernel -lTKMath -lTKService -lTKV3d -lTKV2d \
  52         -lTKBRep -lTKIGES -lTKSTL -lTKVRML -lTKSTEP -lTKSTEPAttr -lTKSTEP209 \
  53         -lTKSTEPBase -lTKShapeSchema -lTKGeomBase -lTKGeomAlgo -lTKG3d -lTKG2d \
  54         -lTKXSBase -lTKPShape -lTKShHealing -lTKHLR -lTKTopAlgo -lTKMesh -lTKPrim \
  55         -lTKCDF -lTKBool -lTKBO -lTKFillet -lTKOffset \
  56         -L$(QTDIR)/lib -lQtCore -lQtGui
  57
  58 lrelease.name = LRELASE ${QMAKE_FILE_IN}
  59 lrelease.commands = $(QTDIR)/bin/lrelease ${QMAKE_FILE_IN} -qm ./res/${QMAKE_FILE_BASE}.qm
  60 lrelease.output = ./res/${QMAKE_FILE_BASE}.qm
  61 lrelease.input = TRANSLATIONS
  62 lrelease.clean = ./res/${QMAKE_FILE_BASE}.qm
  63 lrelease.CONFIG += no_link target_predeps
  64 QMAKE_EXTRA_COMPILERS += lrelease