e5c56715492bace70ef6bf7b7c3425ab7821d43c
[occt.git] / adm / qmake / OccToolkit.pri
1 # This is a project template file defining an OCCT Toolkit.
2 # This project should be included with predefined OCC_TOOLKIT_NAME variable.
3
4 TEMPLATE = lib
5 !exists(../../src/$$OCC_TOOLKIT_NAME/PACKAGES) {
6   TEMPLATE = app
7   CONFIG += console
8 }
9 win32 {
10   # do not append version to DLL name
11   CONFIG += skip_target_version_ext
12 }
13
14 include(OccCppConfig.pri)
15
16 aSrcRoot = $$OccGitRoot/src
17 aHxxRoot = $$OccGitRoot/inc
18 INCLUDEPATH += $$aHxxRoot
19
20 # CSF variables
21 HAVE_FREETYPE  { CSF_FREETYPE = -lfreetype }
22 CSF_TclLibs   = -ltcl8.6
23 CSF_TclTkLibs = -ltk8.6
24 HAVE_FREEIMAGE { CSF_FreeImagePlus = -lfreeimage } else:win32 { CSF_FreeImagePlus = -lwindowscodecs -lole32 }
25 HAVE_FFMPEG    { CSF_FFmpeg = -lavcodec -lavformat -lswscale -lavutil }
26 HAVE_TBB       { CSF_TBB = -ltbb -ltbbmalloc }
27 HAVE_ZLIB      { CSF_ZLIB = -lzlib }
28 HAVE_LIBLZMA   { CSF_LIBLZMA = -lliblzma }
29 win32 {
30   CSF_kernel32   = -lkernel32
31   CSF_advapi32   = -ladvapi32
32   CSF_gdi32      = -lgdi32
33   CSF_user32     = -luser32 -lcomdlg32
34   CSF_shell32    = -lShell32
35   CSF_opengl32   = -lopengl32
36   CSF_wsock32    = -lwsock32
37   CSF_netapi32   = -lnetapi32
38   CSF_OpenGlLibs = -lopengl32
39   CSF_OpenGlesLibs = -llibEGL -llibGLESv2
40   CSF_psapi      = -lPsapi
41   CSF_winmm      = -lwinmm
42   CSF_d3d9       = -ld3d9
43   CSF_TclLibs    = -ltcl86
44   CSF_TclTkLibs  = -ltk86
45   CSF_TBB =
46 } else:mac {
47   CSF_dl         = -ldl
48   CSF_objc       = -lobjc
49   CSF_OpenGlLibs = -framework OpenGL
50   CSF_OpenGlesLibs = -framework OpenGLES
51   iphoneos {
52     CSF_Appkit     = -framework UIKit
53   } else {
54     CSF_Appkit     = -framework AppKit
55   }
56   CSF_IOKit      = -framework IOKit
57   CSF_TclLibs    = -framework Tcl
58   CSF_TclTkLibs  = -framework Tk
59 } else {
60   CSF_dl = -ldl
61   CSF_ThreadLibs = -lpthread -lrt
62   CSF_OpenGlLibs = -lGL
63   CSF_OpenGlesLibs = -lEGL -lGLESv2
64   CSF_TclTkLibs  = -lX11 -ltk8.6
65   CSF_XwLibs     = -lX11 -lXext -lXmu -lXi
66   CSF_MotifLibs  = -lX11
67   HAVE_FREETYPE  { CSF_fontconfig = -lfontconfig }
68 }
69
70 for (aCfgIter, CONFIG) {
71   aRes = $$find(aCfgIter, "^HAVE_")
72   !equals(aCfgIter, "HAVE_GLES2") {
73     count(aRes, 1) {
74       DEFINES += $$aCfgIter
75     }
76   }
77 }
78
79 # Define the list of standard OCCT file extensions
80 aHxxRegex = ^.*\.(hxx|h|lxx|gxx)$
81 aPxxRegex = ^.*\.(pxx)$
82 aCxxRegex = ^.*\.(cxx|cpp|c)$
83 mac { aCxxRegex = ^.*\.(cxx|cpp|c|m|mm)$ }
84
85 # Auxiliary function for probing file extension
86 defineTest (occCheckExtension) {
87   aProbe = $$find(1, "$$2")
88   count(aProbe, 1) { return(true) } else { return(false) }
89 }
90
91 # Auxiliary function for probing compilable files
92 defineTest (occIsCxxFile) { occCheckExtension ($$1, $$aCxxRegex) { return(true) } else { return(false) } }
93
94 # Auxiliary function for probing header files
95 defineTest (occIsHxxFile) { occCheckExtension ($$1, $$aHxxRegex) { return(true) } else { return(false) } }
96
97 aTkFiles     = $$cat($$aSrcRoot/$$OCC_TOOLKIT_NAME/FILES,     lines)
98 aTkFiles += CMakeLists.txt
99 aPackages    = $$cat($$aSrcRoot/$$OCC_TOOLKIT_NAME/PACKAGES,  lines)
100 anExternLibs = $$cat($$aSrcRoot/$$OCC_TOOLKIT_NAME/EXTERNLIB, lines)
101
102 for (aTkFileIter, aTkFiles) { OTHER_FILES += $$aSrcRoot/$$OCC_TOOLKIT_NAME/$$aTkFileIter }
103 for (anExternLib, anExternLibs) {
104   hasCsf = $$find(anExternLib, CSF_)
105   count(hasCsf, 1) {
106     aList = $$split($$anExternLib, "\n")
107     LIBS += $$aList
108     equals(anExternLib, "CSF_OpenGlLibs") {
109       DEFINES += "HAVE_OPENGL"
110     }
111     equals(anExternLib, "CSF_OpenGlesLibs") {
112       DEFINES += "HAVE_GLES2"
113     }
114   } else {
115     LIBS += -l$$anExternLib
116   }
117 }
118
119 # Iterate over Packages and add compilable files into this project
120 isEmpty (aPackages) { aPackages = $$OCC_TOOLKIT_NAME }
121 for (aPackage, aPackages) {
122   aPackageFolder = $$aSrcRoot/$$OCC_TOOLKIT_NAME/$$aPackage
123   aPackageFiles = $$cat($$aSrcRoot/$$aPackage/FILES, lines)
124   for (aFileIter, aPackageFiles) {
125     occIsCxxFile($$aFileIter) {
126       SOURCES += $$aSrcRoot/$$aPackage/$$aFileIter
127     }
128   }
129 }
130
131 # extend clean with versioned .so files
132 !win32 {
133   aVerList = $$split(VERSION, ".")
134   aVerMaj = $$member(aVerList, 0)
135   aVerMin = $$member(aVerList, 1)
136   aVerMic = $$member(aVerList, 2)
137   equals(TEMPLATE, app) {
138     QMAKE_CLEAN += $$DESTDIR/$${TARGET}
139   } else {
140     mac {
141       QMAKE_CLEAN += $$DESTDIR/lib$${TARGET}.dylib
142       QMAKE_CLEAN += $$DESTDIR/lib$${TARGET}.$${aVerMaj}.dylib
143       QMAKE_CLEAN += $$DESTDIR/lib$${TARGET}.$${aVerMaj}.$${aVerMin}.dylib
144       QMAKE_CLEAN += $$DESTDIR/lib$${TARGET}.$${aVerMaj}.$${aVerMin}.$${aVerMic}.dylib
145     } else {
146       QMAKE_CLEAN += $$DESTDIR/lib$${TARGET}.so
147       QMAKE_CLEAN += $$DESTDIR/lib$${TARGET}.so.$${aVerMaj}
148       QMAKE_CLEAN += $$DESTDIR/lib$${TARGET}.so.$${aVerMaj}.$${aVerMin}
149       QMAKE_CLEAN += $$DESTDIR/lib$${TARGET}.so.$${aVerMaj}.$${aVerMin}.$${aVerMic}
150     }
151   }
152 }