0032323: Configuration - drop unused dependency from Xmu
[occt.git] / adm / qmake / OccToolkit.pri
1 # This is a project template file defining an OCCT Toolkit.
2 # This project should be included with predefined OCC_TOOLKIT_NAME variable.
3
4 TEMPLATE = lib
5 !exists(../../src/$$OCC_TOOLKIT_NAME/PACKAGES) {
6   TEMPLATE = app
7   CONFIG += console
8 }
9 win32 {
10   # do not append version to DLL name
11   CONFIG += skip_target_version_ext
12 }
13
14 include(OccCppConfig.pri)
15
16 aSrcRoot = $$OccGitRoot/src
17 aHxxRoot = $$OccGitRoot/inc
18 INCLUDEPATH += $$aHxxRoot
19
20 # CSF variables
21 HAVE_FREETYPE  { CSF_FREETYPE = -lfreetype }
22 CSF_TclLibs   = -ltcl8.6
23 CSF_TclTkLibs = -ltk8.6
24 HAVE_FREEIMAGE { CSF_FreeImagePlus = -lfreeimage } else:win32 { CSF_FreeImagePlus = -lwindowscodecs -lole32 }
25 HAVE_FFMPEG    { CSF_FFmpeg = -lavcodec -lavformat -lswscale -lavutil }
26 HAVE_TBB       { CSF_TBB = -ltbb -ltbbmalloc }
27 HAVE_ZLIB      { CSF_ZLIB = -lzlib }
28 HAVE_LIBLZMA   { CSF_LIBLZMA = -lliblzma }
29 win32 {
30   CSF_kernel32   = -lkernel32
31   CSF_advapi32   = -ladvapi32
32   CSF_gdi32      = -lgdi32
33   CSF_user32     = -luser32 -lcomdlg32
34   CSF_shell32    = -lShell32
35   CSF_opengl32   = -lopengl32
36   CSF_wsock32    = -lwsock32
37   CSF_netapi32   = -lnetapi32
38   CSF_OpenGlLibs = -lopengl32
39   CSF_OpenGlesLibs = -llibEGL -llibGLESv2
40   CSF_psapi      = -lPsapi
41   CSF_winmm      = -lwinmm
42   CSF_d3d9       = -ld3d9
43   CSF_TclLibs    = -ltcl86
44   CSF_TclTkLibs  = -ltk86
45   CSF_TBB =
46 } else:mac {
47   CSF_dl         = -ldl
48   CSF_objc       = -lobjc
49   CSF_OpenGlLibs = -framework OpenGL
50   CSF_OpenGlesLibs = -framework OpenGLES
51   iphoneos {
52     CSF_Appkit     = -framework UIKit
53   } else {
54     CSF_Appkit     = -framework AppKit
55   }
56   CSF_IOKit      = -framework IOKit
57   CSF_TclLibs    = -framework Tcl
58   CSF_TclTkLibs  = -framework Tk
59 } else {
60   CSF_dl = -ldl
61   CSF_ThreadLibs = -lpthread -lrt
62   CSF_OpenGlesLibs = -lEGL -lGLESv2
63   CSF_TclTkLibs  = -ltk8.6
64   HAVE_XLIB {
65     CSF_OpenGlLibs = -lGL
66     CSF_XwLibs     = -lX11
67   } else {
68     CSF_OpenGlLibs = -lGL -lEGL
69   }
70   HAVE_FREETYPE  { CSF_fontconfig = -lfontconfig }
71 }
72
73 for (aCfgIter, CONFIG) {
74   aRes = $$find(aCfgIter, "^HAVE_")
75   !equals(aCfgIter, "HAVE_GLES2") {
76     count(aRes, 1) {
77       DEFINES += $$aCfgIter
78     }
79   }
80 }
81
82 # Define the list of standard OCCT file extensions
83 aHxxRegex = ^.*\.(hxx|h|lxx|gxx)$
84 aPxxRegex = ^.*\.(pxx)$
85 aCxxRegex = ^.*\.(cxx|cpp|c)$
86 mac { aCxxRegex = ^.*\.(cxx|cpp|c|m|mm)$ }
87
88 # Auxiliary function for probing file extension
89 defineTest (occCheckExtension) {
90   aProbe = $$find(1, "$$2")
91   count(aProbe, 1) { return(true) } else { return(false) }
92 }
93
94 # Auxiliary function for probing compilable files
95 defineTest (occIsCxxFile) { occCheckExtension ($$1, $$aCxxRegex) { return(true) } else { return(false) } }
96
97 # Auxiliary function for probing header files
98 defineTest (occIsHxxFile) { occCheckExtension ($$1, $$aHxxRegex) { return(true) } else { return(false) } }
99
100 aTkFiles     = $$cat($$aSrcRoot/$$OCC_TOOLKIT_NAME/FILES,     lines)
101 aTkFiles += CMakeLists.txt
102 aPackages    = $$cat($$aSrcRoot/$$OCC_TOOLKIT_NAME/PACKAGES,  lines)
103 anExternLibs = $$cat($$aSrcRoot/$$OCC_TOOLKIT_NAME/EXTERNLIB, lines)
104
105 for (aTkFileIter, aTkFiles) { OTHER_FILES += $$aSrcRoot/$$OCC_TOOLKIT_NAME/$$aTkFileIter }
106 for (anExternLib, anExternLibs) {
107   hasCsf = $$find(anExternLib, CSF_)
108   count(hasCsf, 1) {
109     aList = $$split($$anExternLib, "\n")
110     LIBS += $$aList
111     equals(anExternLib, "CSF_OpenGlLibs") {
112       DEFINES += "HAVE_OPENGL"
113     }
114     equals(anExternLib, "CSF_OpenGlesLibs") {
115       DEFINES += "HAVE_GLES2"
116     }
117   } else {
118     LIBS += -l$$anExternLib
119   }
120 }
121
122 # Iterate over Packages and add compilable files into this project
123 isEmpty (aPackages) { aPackages = $$OCC_TOOLKIT_NAME }
124 for (aPackage, aPackages) {
125   aPackageFolder = $$aSrcRoot/$$OCC_TOOLKIT_NAME/$$aPackage
126   aPackageFiles = $$cat($$aSrcRoot/$$aPackage/FILES, lines)
127   for (aFileIter, aPackageFiles) {
128     occIsCxxFile($$aFileIter) {
129       SOURCES += $$aSrcRoot/$$aPackage/$$aFileIter
130     }
131   }
132 }
133
134 # extend clean with versioned .so files
135 !win32 {
136   aVerList = $$split(VERSION, ".")
137   aVerMaj = $$member(aVerList, 0)
138   aVerMin = $$member(aVerList, 1)
139   aVerMic = $$member(aVerList, 2)
140   equals(TEMPLATE, app) {
141     QMAKE_CLEAN += $$DESTDIR/$${TARGET}
142   } else {
143     mac {
144       QMAKE_CLEAN += $$DESTDIR/lib$${TARGET}.dylib
145       QMAKE_CLEAN += $$DESTDIR/lib$${TARGET}.$${aVerMaj}.dylib
146       QMAKE_CLEAN += $$DESTDIR/lib$${TARGET}.$${aVerMaj}.$${aVerMin}.dylib
147       QMAKE_CLEAN += $$DESTDIR/lib$${TARGET}.$${aVerMaj}.$${aVerMin}.$${aVerMic}.dylib
148     } else {
149       QMAKE_CLEAN += $$DESTDIR/lib$${TARGET}.so
150       QMAKE_CLEAN += $$DESTDIR/lib$${TARGET}.so.$${aVerMaj}
151       QMAKE_CLEAN += $$DESTDIR/lib$${TARGET}.so.$${aVerMaj}.$${aVerMin}
152       QMAKE_CLEAN += $$DESTDIR/lib$${TARGET}.so.$${aVerMaj}.$${aVerMin}.$${aVerMic}
153     }
154   }
155 }