CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.12 FATAL_ERROR)
   2
   3 set (CMAKE_SUPPRESS_REGENERATION TRUE)
   4
   5 set (CMAKE_CONFIGURATION_TYPES Release Debug RelWithDebInfo CACHE INTERNAL "" FORCE)
   6
   7 # macro: include patched file if it exists
   8 macro (OCCT_INCLUDE_CMAKE_FILE BEING_INCLUDED_FILE)
   9   if (APPLY_OCCT_PATCH_DIR AND EXISTS "${APPLY_OCCT_PATCH_DIR}/${BEING_INCLUDED_FILE}.cmake")
  10     include (${APPLY_OCCT_PATCH_DIR}/${BEING_INCLUDED_FILE}.cmake)
  11   else()
  12     include (${CMAKE_SOURCE_DIR}/${BEING_INCLUDED_FILE}.cmake)
  13   endif()
  14 endmacro()
  15
  16 # include variable description
  17 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vardescr")
  18
  19 # set type of OCCT libraries
  20 if (NOT BUILD_LIBRARY_TYPE)
  21   set (BUILD_LIBRARY_TYPE "Shared" CACHE STRING "${BUILD_LIBRARY_TYPE_DESCR}" FORCE)
  22   SET_PROPERTY(CACHE BUILD_LIBRARY_TYPE PROPERTY STRINGS Shared Static)
  23 endif()
  24
  25 if ("${BUILD_LIBRARY_TYPE}" STREQUAL "Shared")
  26   set (BUILD_SHARED_LIBS ON)
  27 else()
  28   unset (BUILD_SHARED_LIBS)
  29 endif()
  30
  31 # the name of the project
  32 project (OCCT)
  33
  34 # Solution folder property
  35 set_property (GLOBAL PROPERTY USE_FOLDERS ON)
  36
  37 set (INSTALL_TEST_CASES OFF CACHE BOOL "${INSTALL_TEST_CASES_DESCR}")
  38 # a single-configuration generator like the Makefile generator defines CMAKE_BUILD_TYPE variable
  39 # check this variable and set if it's required
  40 if (DEFINED CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE) # single-configuration generator.
  41   set (CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel." FORCE)
  42 endif()
  43
  44 # enable extended messages of many OCCT algorithms
  45 set (OCCT_ALGO_EXTENDED_OUTPUT OFF CACHE BOOL "${OCCT_ALGO_EXTENDED_OUTPUT_DESCR}")
  46 if (OCCT_ALGO_EXTENDED_OUTPUT)
  47   add_definitions (-DOCCT_DEBUG)
  48 endif()
  49
  50 # copy samples to install directory
  51 set (INSTALL_SAMPLES OFF CACHE BOOL "${INSTALL_SAMPLES_DESCR}")
  52
  53 # install dir of the built project
  54 set (INSTALL_DIR "" CACHE PATH "${INSTALL_DIR_DESCR}" )
  55 set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE )
  56
  57 set (APPLY_OCCT_PATCH_DIR "" CACHE PATH "${APPLY_OCCT_PATCH_DIR_DESCR}")
  58
  59 # the list of being built toolkits
  60 set (BUILD_ADDITIONAL_TOOLKITS "" CACHE STRING "${BUILD_ADDITIONAL_TOOLKITS_DESCR}")
  61 separate_arguments (BUILD_ADDITIONAL_TOOLKITS)
  62
  63 if (MSVC)
  64   set (BUILD_MODULE_OcctMfcSamples OFF CACHE BOOL "${BUILD_MODULE_OcctMfcSamples_DESCR}")
  65 endif()
  66
  67 # whether use optional 3rdparty or not
  68 if (APPLE)
  69   set (USE_GLX OFF CACHE BOOL "${USE_GLX_DESCR}")
  70 endif()
  71 if (WIN32)
  72   set (USE_D3D OFF CACHE BOOL "${USE_D3D_DESCR}")
  73 endif()
  74
  75 set (USE_VTK OFF CACHE BOOL "${USE_VTK_DESCR}")
  76
  77 # include occt macros
  78 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_macros")
  79
  80 # include the patched or original list of modules
  81 # list <MODULENAME>_TOOLKITS is created foreach module and contains its toolkits
  82 # list <OCCT_MODULES> will contain all modules
  83 OCCT_MODULES_AND_TOOLKITS (OCCT_MODULES)
  84
  85 foreach (OCCT_MODULE ${OCCT_MODULES})
  86   BUILD_MODULE (${OCCT_MODULE})
  87 endforeach()
  88
  89 if (ANDROID AND BUILD_MODULE_Draw)
  90   message (STATUS "Info. Draw module is turned off due to it is not supported on Android")
  91   set (BUILD_MODULE_Draw OFF CACHE BOOL "${BUILD_MODULE_Draw_DESCR}" FORCE)
  92 endif()
  93
  94 # Overview
  95 set (BUILD_DOC_OcctOverview OFF CACHE BOOL "${BUILD_DOC_OcctOverview_DESCR}")
  96
  97 if (NOT USE_VTK)
  98   list (REMOVE_ITEM Visualization_TOOLKITS TKIVtk)
  99   list (REMOVE_ITEM Draw_TOOLKITS TKIVtkDraw)
 100 endif()
 101
 102 if (NOT USE_D3D)
 103   list (REMOVE_ITEM Visualization_TOOLKITS TKD3DHost)
 104 endif()
 105
 106 # accumulate used toolkits (first level) in BUILD_TOOLKITS variable
 107 list (APPEND BUILD_TOOLKITS ${BUILD_ADDITIONAL_TOOLKITS})
 108
 109 foreach (OCCT_MODULE ${OCCT_MODULES})
 110   if (BUILD_MODULE_${OCCT_MODULE})
 111     list (APPEND BUILD_TOOLKITS ${${OCCT_MODULE}_TOOLKITS})
 112   endif()
 113 endforeach()
 114
 115 # DRAWEXE excluded when library build is static
 116 if (NOT BUILD_SHARED_LIBS)
 117   list (REMOVE_ITEM BUILD_TOOLKITS DRAWEXE)
 118   message (STATUS "Info: DRAWEXE is not included due to ${BUILD_LIBRARY_TYPE} build library type")
 119 endif()
 120
 121 # accumulate all used toolkits
 122 list (REMOVE_DUPLICATES BUILD_TOOLKITS)
 123 set (RAW_BUILD_TOOLKITS)
 124 foreach(BUILD_TOOLKIT ${BUILD_TOOLKITS})
 125   OCCT_TOOLKIT_FULL_DEP (${BUILD_TOOLKIT} TOOLKIT_FULL_DEPS)
 126   list (APPEND RAW_BUILD_TOOLKITS ${BUILD_TOOLKIT} ${TOOLKIT_FULL_DEPS})
 127 endforeach()
 128
 129 list (REMOVE_DUPLICATES RAW_BUILD_TOOLKITS)
 130 set (BUILD_TOOLKITS ${RAW_BUILD_TOOLKITS})
 131
 132 # include the patched or original list of definitions and flags
 133 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_defs_flags")
 134
 135 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/3rdparty_macro")
 136
 137 # Rebuild *.yacc and *.lex files that are contained by TKMath toolkit
 138 list (FIND BUILD_TOOLKITS TKMath   CAN_REBUILD_PDC_FOR_TKMATH)
 139 list (FIND BUILD_TOOLKITS StepFile CAN_REBUILD_PDC_FOR_STEPFILE)
 140
 141 if (NOT ${CAN_REBUILD_PDC_FOR_TKMATH} EQUAL -1 OR NOT ${CAN_REBUILD_PDC_FOR_STEPFILE} EQUAL -1)
 142   set (REBUILD_PLATFORM_DEPENDENT_CODE OFF CACHE BOOL "${REBUILD_PLATFORM_DEPENDENT_CODE_DESCR}")
 143 else()
 144   OCCT_CHECK_AND_UNSET (REBUILD_PLATFORM_DEPENDENT_CODE)
 145 endif()
 146
 147 if (NOT DEFINED 3RDPARTY_DIR)
 148   set (3RDPARTY_DIR "" CACHE PATH ${3RDPARTY_DIR_DESCR})
 149   get_filename_component (3RDPARTY_DIR "${3RDPARTY_DIR}" ABSOLUTE)
 150 endif()
 151
 152 # search for CSF_TclLibs variable in EXTERNLIB of each being used toolkit
 153 OCCT_IS_PRODUCT_REQUIRED (CSF_TclLibs USE_TCL)
 154
 155 if (USE_TCL)
 156   message (STATUS "Info: TCL is used by OCCT")
 157   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tcl")
 158
 159   message (STATUS "Info: TK is used by OCCT")
 160   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tk")
 161 else()
 162   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TCL")
 163   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TK")
 164
 165   OCCT_CHECK_AND_UNSET ("INSTALL_TCL")
 166   OCCT_CHECK_AND_UNSET ("INSTALL_TK")
 167 endif()
 168
 169 # search for CSF_FREETYPE variable in EXTERNLIB of each being used toolkit
 170 OCCT_IS_PRODUCT_REQUIRED (CSF_FREETYPE USE_FREETYPE)
 171
 172 if (USE_FREETYPE)
 173   message (STATUS "Info: Freetype is used by OCCT")
 174   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freetype")
 175 else()
 176   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREETYPE")
 177   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2")
 178   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build")
 179   OCCT_CHECK_AND_UNSET ("INSTALL_FREETYPE")
 180 endif()
 181
 182 # VTK
 183 if (USE_VTK)
 184   add_definitions (-DHAVE_VTK)
 185   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vtk")
 186 else()
 187   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_VTK")
 188   #OCCT_CHECK_AND_UNSET ("INSTALL_VTK")
 189 endif()
 190
 191 # D3D
 192 if (USE_D3D)
 193   add_definitions (-DHAVE_D3D)
 194   #if(MSVC_VERSION LESS 1700)
 195   #OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/d3d")
 196   #endif()
 197 endif()
 198
 199 # GLX
 200 if (USE_GLX)
 201   add_definitions (-DMACOSX_USE_GLX)
 202   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/glx")
 203 endif()
 204
 205 # FREEIMAGE
 206 # search for CSF_FREEIMAGE variable in EXTERNLIB of each being used toolkit
 207 OCCT_IS_PRODUCT_REQUIRED (CSF_FREEIMAGE     CAN_USE_FREEIMAGE)
 208 OCCT_IS_PRODUCT_REQUIRED (CSF_FreeImagePlus CAN_USE_FREEIMAGEPLUS)
 209
 210 if (CAN_USE_FREEIMAGE OR CAN_USE_FREEIMAGEPLUS)
 211   set (USE_FREEIMAGE OFF CACHE BOOL "${USE_FREEIMAGE_DESCR}")
 212
 213   if (USE_FREEIMAGE)
 214     add_definitions (-DHAVE_FREEIMAGE)
 215     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimage")
 216     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimageplus")
 217   else()
 218     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
 219     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGEPLUS")
 220     OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
 221     OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGEPLUS")
 222   endif()
 223 else()
 224   OCCT_CHECK_AND_UNSET ("USE_FREEIMAGE")
 225
 226   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
 227   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGEPLUS")
 228   OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
 229   OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGEPLUS")
 230 endif()
 231
 232 # GL2PS
 233 # search for CSF_GL2PS variable in EXTERNLIB of each being used toolkit
 234 OCCT_IS_PRODUCT_REQUIRED (CSF_GL2PS CAN_USE_GL2PS)
 235
 236 if (NOT DEFINED ANDROID AND CAN_USE_GL2PS)
 237   set (USE_GL2PS OFF CACHE BOOL "${USE_GL2PS_DESCR}")
 238
 239   if (USE_GL2PS)
 240     add_definitions (-DHAVE_GL2PS)
 241     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gl2ps")
 242   else()
 243     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
 244     OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
 245   endif()
 246 else()
 247   OCCT_CHECK_AND_UNSET ("USE_GL2PS")
 248
 249   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
 250   OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
 251 endif()
 252
 253 # TBB
 254 # search for CSF_TBB variable in EXTERNLIB of each being used toolkit
 255 OCCT_IS_PRODUCT_REQUIRED (CSF_TBB CAN_USE_TBB)
 256
 257 if (NOT DEFINED ANDROID AND CAN_USE_TBB)
 258   set (USE_TBB OFF CACHE BOOL "${USE_TBB_DESCR}")
 259
 260   if (USE_TBB)
 261     add_definitions (-DHAVE_TBB)
 262     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tbb")
 263   else()
 264     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
 265     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
 266     OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
 267   endif()
 268 else()
 269   OCCT_CHECK_AND_UNSET ("USE_TBB")
 270
 271   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
 272   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
 273   OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
 274 endif()
 275
 276 # Doxygen
 277 if (BUILD_DOC_OcctOverview)
 278   if (NOT DEFINED INSTALL_DOC_OcctOverview)
 279     set (INSTALL_DOC_OcctOverview OFF CACHE BOOL "${INSTALL_DOC_OcctOverview_DESCR}")
 280   endif()
 281
 282   if (INSTALL_DOC_OcctOverview)
 283     install (DIRECTORY "${CMAKE_BINARY_DIR}/doc/overview" DESTINATION  "${INSTALL_DIR}/doc")
 284
 285     OCCT_INSTALL_FILE_OR_DIR ("dox/resources/overview.html" "${INSTALL_DIR}")
 286   endif()
 287
 288   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
 289 else()
 290   OCCT_CHECK_AND_UNSET ("INSTALL_DOC_OcctOverview")
 291
 292   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOXYGEN_EXECUTABLE")
 293   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOXYGEN_DOT_EXECUTABLE")
 294 endif()
 295
 296 # bison
 297 if (REBUILD_PLATFORM_DEPENDENT_CODE)
 298   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/bison")
 299 else()
 300   OCCT_CHECK_AND_UNSET ("3RDPARTY_BISON_EXECUTABLE")
 301 endif()
 302
 303 # flex
 304 if (REBUILD_PLATFORM_DEPENDENT_CODE)
 305   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/flex")
 306 else()
 307   OCCT_CHECK_AND_UNSET ("3RDPARTY_FLEX_EXECUTABLE")
 308 endif()
 309
 310 string (REGEX REPLACE ";" " " 3RDPARTY_NOT_INCLUDED "${3RDPARTY_NOT_INCLUDED}")
 311
 312 # check all 3rdparty paths
 313 if (3RDPARTY_NOT_INCLUDED)
 314   message (FATAL_ERROR "NOT FOUND: ${3RDPARTY_NOT_INCLUDED}" )
 315 endif()
 316
 317 if (3RDPARTY_INCLUDE_DIRS)
 318   list (REMOVE_DUPLICATES 3RDPARTY_INCLUDE_DIRS)
 319   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_INCLUDE_DIRS_WITH_ENDS "${3RDPARTY_INCLUDE_DIRS}")
 320   message (STATUS "The directories containing 3rdparty headers: ${3RDPARTY_INCLUDE_DIRS_WITH_ENDS}")
 321   include_directories (${3RDPARTY_INCLUDE_DIRS})
 322 endif()
 323
 324 # include <cmake binary folder>/inc
 325 include_directories (${CMAKE_BINARY_DIR}/inc)
 326
 327 if (3RDPARTY_LIBRARY_DIRS)
 328   list (REMOVE_DUPLICATES 3RDPARTY_LIBRARY_DIRS)
 329   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_LIBRARY_DIRS_WITH_ENDS "${3RDPARTY_LIBRARY_DIRS}")
 330   message (STATUS "The directories containing 3rdparty libraries: ${3RDPARTY_LIBRARY_DIRS_WITH_ENDS}")
 331   link_directories (${3RDPARTY_LIBRARY_DIRS})
 332 endif()
 333
 334 # Get all used variables: OS_WITH_BIT, COMPILER
 335 OCCT_MAKE_OS_WITH_BITNESS()
 336 OCCT_MAKE_COMPILER_SHORT_NAME()
 337
 338 # build directories
 339 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
 340 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
 341 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
 342
 343 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
 344 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
 345 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
 346
 347 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
 348 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
 349 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
 350
 351 if (WIN32)
 352   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE        "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
 353   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
 354   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG          "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
 355 endif()
 356
 357 if ("${INSTALL_DIR}" STREQUAL "")
 358   get_filename_component (CMAKE_BINARY_DIR_PARENT ${CMAKE_BINARY_DIR} DIRECTORY)
 359
 360   set (INSTALL_DIR "${CMAKE_BINARY_DIR_PARENT}/install" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
 361   set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE )
 362
 363   message (STATUS "Info: INSTALL_DIR has been set as ${INSTALL_DIR}")
 364 endif()
 365
 366 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
 367 message (STATUS "\nInfo: \(${CURRENT_TIME}\) Start collecting all OCCT header files into ${CMAKE_BINARY_DIR}/inc ...")
 368
 369 # collect all the headers to <binary dir>/inc folder
 370 COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}" "${BUILD_TOOLKITS}")
 371
 372 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
 373 message (STATUS "Info: \(${CURRENT_TIME}\) End the collecting")
 374
 375 OCCT_INSTALL_FILE_OR_DIR ("data" "${INSTALL_DIR}")
 376 OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR}/samples")
 377
 378 if (INSTALL_SAMPLES)
 379   OCCT_INSTALL_FILE_OR_DIR ("samples" "${INSTALL_DIR}")
 380 endif()
 381
 382 if (INSTALL_TEST_CASES)
 383   OCCT_INSTALL_FILE_OR_DIR ("tests" "${INSTALL_DIR}")
 384 endif()
 385
 386 if (WIN32)
 387   set (SCRIPT_EXT bat)
 388 else()
 389   set (SCRIPT_EXT sh)
 390 endif()
 391
 392 # DRAW.BAT or DRAW.SH
 393 if (APPLY_OCCT_PATCH_DIR AND EXISTS "${APPLY_OCCT_PATCH_DIR}/adm/templates/draw.${SCRIPT_EXT}")
 394   install (FILES "${APPLY_OCCT_PATCH_DIR}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR}" PERMISSIONS
 395           OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
 396 else()
 397   install (FILES "${CMAKE_SOURCE_DIR}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR}" PERMISSIONS
 398           OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
 399 endif()
 400 OCCT_COPY_FILE_OR_DIR ("adm/templates/draw.${SCRIPT_EXT}" "${CMAKE_BINARY_DIR}")
 401
 402 set (SUB_CUSTOM_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.${SCRIPT_EXT}")
 403
 404 if (WIN32)
 405   set (ADDITIONAL_CUSTOM_CONTENT "\nif exist \"%~dp0${SUB_CUSTOM_NAME}\" (\n  call \"%~dp0${SUB_CUSTOM_NAME}\" %VCVER% %ARCH% %CASDEB% \n)")
 406 else()
 407   set (ADDITIONAL_CUSTOM_CONTENT "\nif [ -e \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" ]; then\n  source \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" \"\${COMPILER}\" \"\${WOKSTATION}\${ARCH}\" \"\${CASDEB}\" \nfi")
 408 endif()
 409
 410  # change custom.bat/sh
 411 if (EXISTS "${INSTALL_DIR}/custom.${SCRIPT_EXT}")
 412   file (READ "${INSTALL_DIR}/custom.${SCRIPT_EXT}" CUSTOM_CONTENT)
 413
 414   set (CUSTOM_CONTENT "${CUSTOM_CONTENT} ${ADDITIONAL_CUSTOM_CONTENT}")
 415
 416   file (WRITE "${INSTALL_DIR}/custom.${SCRIPT_EXT}" "${CUSTOM_CONTENT}")
 417 else()
 418   OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.${SCRIPT_EXT}.main" "custom.${SCRIPT_EXT}" "custom.${SCRIPT_EXT}" "${INSTALL_DIR}")
 419 endif()
 420
 421 # write current custom.bat/sh (for install directory)
 422 set (SUB_CUSTOM_BUILD_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.install.${SCRIPT_EXT}")
 423 OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.install.${SCRIPT_EXT}.in" "${SUB_CUSTOM_BUILD_NAME}" "${SUB_CUSTOM_NAME}" "${INSTALL_DIR}")
 424
 425 # write current custom.bat/sh (for build directory)
 426 OCCT_CONFIGURE ("adm/templates/custom.build.${SCRIPT_EXT}.in" "${SUB_CUSTOM_NAME}")
 427
 428 if (BUILD_MODULE_OcctMfcSamples)
 429   OCCT_INSTALL_FILE_OR_DIR ("adm/templates/sample.bat" "${INSTALL_DIR}")
 430   OCCT_COPY_FILE_OR_DIR    ("adm/templates/sample.bat" "${CMAKE_BINARY_DIR}")
 431 endif()
 432
 433 # env script for draw in building environment
 434 OCCT_CONFIGURE ("adm/templates/env.build.${SCRIPT_EXT}.in" "env.${SCRIPT_EXT}")
 435
 436 # end script for draw in standalone environment
 437 # release version
 438 set (BUILD_LETTER "")
 439 OCCT_CONFIGURE ("adm/templates/env.install.${SCRIPT_EXT}.in" "env.install.release.${SCRIPT_EXT}")
 440 install (FILES "${CMAKE_BINARY_DIR}/env.install.release.${SCRIPT_EXT}"
 441          CONFIGURATIONS Release
 442          DESTINATION  "${INSTALL_DIR}"
 443          RENAME "env.${SCRIPT_EXT}")
 444
 445 # debug version
 446 set (BUILD_LETTER "d")
 447 OCCT_CONFIGURE ("adm/templates/env.install.${SCRIPT_EXT}.in" "env.install.debug.${SCRIPT_EXT}")
 448 install (FILES "${CMAKE_BINARY_DIR}/env.install.debug.${SCRIPT_EXT}"
 449          CONFIGURATIONS Debug
 450          DESTINATION  "${INSTALL_DIR}"
 451          RENAME "env.${SCRIPT_EXT}")
 452
 453 # release with debug info version
 454 set (BUILD_LETTER "i")
 455 OCCT_CONFIGURE ("adm/templates/env.install.${SCRIPT_EXT}.in" "env.install.relwithdebinfo.${SCRIPT_EXT}")
 456 install (FILES "${CMAKE_BINARY_DIR}/env.install.relwithdebinfo.${SCRIPT_EXT}"
 457          CONFIGURATIONS RelWithDebInfo
 458          DESTINATION  "${INSTALL_DIR}"
 459          RENAME "env.${SCRIPT_EXT}")
 460
 461 # copy DrawAppliInit from OCCT source to build directory
 462 if (NOT EXISTS "${CMAKE_BINARY_DIR}/DrawAppliInit")
 463   OCCT_COPY_FILE_OR_DIR (DrawAppliInit "${CMAKE_BINARY_DIR}")
 464 endif()
 465
 466 # RESOURCES
 467 FILE_TO_LIST ("adm/RESOURCES" RESOURCES)
 468 foreach(RESOURCE ${RESOURCES})
 469   get_filename_component(RESOURCE_FOLDER ${RESOURCE} DIRECTORY)
 470   if(NOT "${RESOURCE_FOLDER}" STREQUAL "")
 471     get_filename_component(RESOURCE_FOLDER ${RESOURCE_FOLDER} NAME)
 472     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR}/src/${RESOURCE_FOLDER}")
 473   else()
 474     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR}/src")
 475   endif()
 476 endforeach()
 477
 478 # define CSF variable
 479 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_csf")
 480
 481 # include patched toolkit projects or original ones
 482 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
 483   OCCT_ADD_SUBDIRECTORY ("src/${BUILD_TOOLKIT}")
 484 endforeach()
 485
 486 if (BUILD_DOC_OcctOverview)
 487   OCCT_ADD_SUBDIRECTORY (dox)
 488 endif()
 489
 490 # patch DRAWEXE
 491 if (MSVC AND 3RDPARTY_DLL_DIRS)
 492   list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
 493   if (${DRAWEXE_INDEX} GREATER -1)
 494     list (REMOVE_DUPLICATES 3RDPARTY_DLL_DIRS)
 495     set (3RDPARTY_DLL_DIRS_FOR_PATH "")
 496
 497     foreach (3RDPARTY_DLL_DIR ${3RDPARTY_DLL_DIRS})
 498       set (3RDPARTY_DLL_DIRS_FOR_PATH "${3RDPARTY_DLL_DIRS_FOR_PATH};${3RDPARTY_DLL_DIR}")
 499     endforeach()
 500
 501     OCCT_MAKE_COMPILER_BITNESS()
 502     set (X_COMPILER_BITNESS "x64")
 503     if ("${COMPILER_BITNESS}" STREQUAL "32")
 504       set (X_COMPILER_BITNESS "Win32")
 505     endif()
 506
 507     OCCT_CONFIGURE ("adm/templates/DRAWEXE.vcxproj.user.in" "${CMAKE_BINARY_DIR}/src/DRAWEXE/DRAWEXE.vcxproj.user")
 508   endif()
 509 endif()
 510
 511 # samples do not support patch usage
 512 if (BUILD_MODULE_OcctMfcSamples)
 513   set (OCCT_ROOT ${CMAKE_SOURCE_DIR})
 514
 515   set (MFC_STANDARD_SAMPLES_DIR ${OCCT_ROOT}/samples/mfc/standard)
 516   set (COMMON_WINMAIN_FILE      ${MFC_STANDARD_SAMPLES_DIR}/Common/Winmain.cpp)
 517
 518   add_subdirectory(samples/mfc/standard/mfcsample)
 519   add_subdirectory(samples/mfc/standard/01_Geometry)
 520   add_subdirectory(samples/mfc/standard/02_Modeling)
 521   add_subdirectory(samples/mfc/standard/03_Viewer2d)
 522   add_subdirectory(samples/mfc/standard/04_Viewer3d)
 523   add_subdirectory(samples/mfc/standard/05_ImportExport)
 524   add_subdirectory(samples/mfc/standard/06_Ocaf)
 525   add_subdirectory(samples/mfc/standard/07_Triangulation)
 526   add_subdirectory(samples/mfc/standard/08_HLR)
 527   add_subdirectory(samples/mfc/standard/09_Animation)
 528   add_subdirectory(samples/mfc/standard/10_Convert)
 529 endif()