4af0907d48231e38ce8a9ed4ea40227fad8d210f
[occt.git] / CMakeLists.txt
1 cmake_minimum_required (VERSION 2.8.12 FATAL_ERROR)
2
3 set (CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/adm/cmake")
4
5 set (CMAKE_SUPPRESS_REGENERATION TRUE)
6
7 set (CMAKE_CONFIGURATION_TYPES Release Debug RelWithDebInfo CACHE INTERNAL "" FORCE)
8
9 # macro: include patched file if it exists
10 macro (OCCT_INCLUDE_CMAKE_FILE BEING_INCLUDED_FILE)
11   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake")
12     include (${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake)
13   else()
14     include (${CMAKE_SOURCE_DIR}/${BEING_INCLUDED_FILE}.cmake)
15   endif()
16 endmacro()
17
18 # include variable description
19 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vardescr")
20
21 # set type of OCCT libraries
22 if (NOT BUILD_LIBRARY_TYPE)
23   set (BUILD_LIBRARY_TYPE "Shared" CACHE STRING "${BUILD_LIBRARY_TYPE_DESCR}" FORCE)
24   SET_PROPERTY(CACHE BUILD_LIBRARY_TYPE PROPERTY STRINGS Shared Static)
25 endif()
26
27 if ("${BUILD_LIBRARY_TYPE}" STREQUAL "Shared")
28   set (BUILD_SHARED_LIBS ON)
29
30   if (NOT DEFINED BUILD_SHARED_LIBRARY_NAME_POSTFIX)
31     set (BUILD_SHARED_LIBRARY_NAME_POSTFIX "" CACHE STRING "${BUILD_SHARED_LIBRARY_NAME_POSTFIX_DESCR}" FORCE)
32   endif()
33 else()
34   unset (BUILD_SHARED_LIBS)
35   unset (BUILD_SHARED_LIBRARY_NAME_POSTFIX)
36 endif()
37
38 # the name of the project
39 project (OCCT)
40
41 if (WIN32)
42   add_definitions(-DUNICODE)
43   add_definitions(-D_UNICODE)
44 endif()
45
46 # include occt macros
47 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_macros")
48
49 # Solution folder property
50 set_property (GLOBAL PROPERTY USE_FOLDERS ON)
51
52 # get current OCCT version
53 OCC_VERSION (OCC_VERSION_MAJOR OCC_VERSION_MINOR OCC_VERSION_MAINTENANCE OCC_VERSION_DEVELOPMENT OCC_VERSION_STRING_EXT)
54
55 set_property (GLOBAL PROPERTY OCC_VERSION_MAJOR ${OCC_VERSION_MAJOR})
56 set_property (GLOBAL PROPERTY OCC_VERSION_MINOR ${OCC_VERSION_MINOR})
57 set_property (GLOBAL PROPERTY OCC_VERSION_MAINTENANCE ${OCC_VERSION_MAINTENANCE})
58
59 set (INSTALL_TEST_CASES OFF CACHE BOOL "${INSTALL_TEST_CASES_DESCR}")
60
61 # Regeneration of OCCT resource files
62 set (BUILD_RESOURCES OFF CACHE BOOL "${BUILD_RESOURCES_DESCR}")
63
64 # single-configuration generator
65 set (SINGLE_GENERATOR OFF)
66 if (DEFINED CMAKE_BUILD_TYPE)
67   set (SINGLE_GENERATOR ON)
68 endif()
69
70 # a single-configuration generator like the Makefile generator defines CMAKE_BUILD_TYPE variable
71 # check this variable and set if it's required
72 if (DEFINED CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE) # single-configuration generator.
73   set (CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel." FORCE)
74 endif()
75
76 # enable extended messages of many OCCT algorithms
77 if (((SINGLE_GENERATOR AND "${CMAKE_BUILD_TYPE}" STREQUAL "Debug") OR NOT SINGLE_GENERATOR) AND (NOT "${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore"))
78   if (NOT BUILD_WITH_DEBUG)
79     set (BUILD_WITH_DEBUG OFF CACHE BOOL "${BUILD_WITH_DEBUG_DESCR}")
80   endif()
81 else()
82   OCCT_CHECK_AND_UNSET (BUILD_WITH_DEBUG)
83 endif()
84
85 if (BUILD_WITH_DEBUG)
86   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:DEBUG>:OCCT_DEBUG>)
87 endif()
88
89 # option disabling OCCT exceptions in Release builds (No_Exception)
90 if (NOT DEFINED BUILD_RELEASE_DISABLE_EXCEPTIONS)
91   set (BUILD_RELEASE_DISABLE_EXCEPTIONS ON CACHE BOOL "${BUILD_RELEASE_DISABLE_EXCEPTIONS_DESCR}")
92 endif()
93
94 # option to enable or disable use of precompiled headers
95 if (NOT DEFINED BUILD_USE_PCH)
96   set (BUILD_USE_PCH OFF CACHE BOOL "${BUILD_USE_PCH_DESCR}")
97 endif()
98
99 if (BUILD_USE_PCH)
100
101   # Load Cotire tool for accelerating build procedure
102   include(cotire)
103
104   # Set Cotire to ignore lxx, pxx, gxx
105   set (COTIRE_ADDITIONAL_PREFIX_HEADER_IGNORE_EXTENSIONS "lxx;pxx;gxx" CACHE STRING "Set Cotire to ignore OCCT specific files that can be #included" FORCE)
106
107   # Set priority for inclusion of system headers in PCH to reduce problems
108   # due to incomplete inclusion or wrong order.
109   if (WIN32)
110     # on Windows, assume that SDK (windows.h) is in default location
111     set(ProgramFilesX86 "ProgramFiles(x86)")
112     file(TO_CMAKE_PATH "$ENV{${ProgramFilesX86}}" ProgramFilesX86)
113     set_property (DIRECTORY PROPERTY COTIRE_PREFIX_HEADER_INCLUDE_PRIORITY_PATH "${ProgramFilesX86}")
114     unset(ProgramFilesX86)
115   endif()
116
117 endif()
118
119 # copy samples to install directory
120 set (INSTALL_SAMPLES OFF CACHE BOOL "${INSTALL_SAMPLES_DESCR}")
121
122 # install dir of the project
123 if (NOT DEFINED INSTALL_DIR)
124   # set default install directory for Windows
125   if (WIN32 AND NOT DEFINED CMAKE_INSTALL_PREFIX)
126     set (CMAKE_INSTALL_PREFIX "C:/opencascade-${OCC_VERSION_STRING_EXT}")
127   endif()
128   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}")
129 else()
130   file (TO_CMAKE_PATH "${INSTALL_DIR}" INSTALL_DIR)
131   set (INSTALL_DIR "${INSTALL_DIR}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
132 endif()
133
134 # choose a variant of the layout of the install paths
135 if (NOT INSTALL_DIR_LAYOUT)
136   if (WIN32)
137     set (INSTALL_DIR_LAYOUT "Windows" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
138   else()
139     set (INSTALL_DIR_LAYOUT "Unix" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
140   endif()
141   SET_PROPERTY(CACHE INSTALL_DIR_LAYOUT PROPERTY STRINGS Windows Unix)
142 endif()
143
144 # check INSTALL_DIR_LAYOUT changes and update INSTALL_DIR_* paths if necessary
145 if (NOT DEFINED INSTALL_DIR_LAYOUT_PREV)
146   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
147 elseif (NOT "${INSTALL_DIR_LAYOUT_PREV}" STREQUAL "${INSTALL_DIR_LAYOUT}")
148   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
149   # The structure of install folder should be reset due to changed layout
150   OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
151
152   # Unset INSTALL_DIR_WITH_VERSION on windows
153   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
154     OCCT_CHECK_AND_UNSET (INSTALL_DIR_WITH_VERSION)
155   else()
156     if (NOT DEFINED INSTALL_DIR_WITH_VERSION)
157       set (INSTALL_DIR_WITH_VERSION OFF CACHE BOOL "${INSTALL_DIR_WITH_VERSION_DESCR}")
158     endif()
159   endif()
160 endif()
161
162 # check CMAKE_INSTALL_PREFIX changes and update INSTALL_DIR if necessary
163 if (NOT DEFINED CMAKE_INSTALL_PREFIX_PREV)
164   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
165 elseif (NOT "${CMAKE_INSTALL_PREFIX_PREV}" STREQUAL "${CMAKE_INSTALL_PREFIX}")
166   # CMAKE_INSTALL_PREFIX has been changed at previous step
167   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
168
169   # INSTALL_DIR is required to be updated
170   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
171 endif()
172
173 # check INSTALL_DIR changes and update CMAKE_INSTALL_PREFIX if necessary
174 if (NOT DEFINED INSTALL_DIR_PREV)
175   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
176 elseif (NOT "${INSTALL_DIR_PREV}" STREQUAL "${INSTALL_DIR}")
177   # INSTALL_DIR has been changed at previous step
178   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
179
180   # sync CMAKE_INSTALL_PREFIX with INSTALL_DIR
181   set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
182
183   # set CMAKE_INSTALL_PREFIX_PREV to avoid the reset of structure of the install folder
184   set (CMAKE_INSTALL_PREFIX_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
185 endif()
186
187 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
188   if (NOT DEFINED INSTALL_DIR_WITH_VERSION_PREV)
189     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
190   elseif (NOT "${INSTALL_DIR_WITH_VERSION_PREV}" STREQUAL "${INSTALL_DIR_WITH_VERSION}")
191     # INSTALL_DIR_WITH_VERSION has been changed at previous step
192     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
193
194     OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
195   endif()
196 endif()
197
198 # hide CMAKE_INSTALL_PREFIX from a user
199 set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
200
201 set (BIN_LETTER "")
202 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
203   set (BIN_LETTER "d")
204 elseif ("${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo")
205   set (BIN_LETTER "i")
206 endif()
207
208 # Get all used variables: OS_WITH_BIT, COMPILER
209 OCCT_MAKE_OS_WITH_BITNESS()
210 OCCT_MAKE_COMPILER_SHORT_NAME()
211
212 # do not define INSTALL_DIR_BIN for win.
213 # Leave library structure for win: <prefix>/win64/vc10/bin(d)
214 if (NOT DEFINED INSTALL_DIR_BIN)
215   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
216     set (INSTALL_DIR_BIN "bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
217   else()
218     set (INSTALL_DIR_BIN "${OS_WITH_BIT}/${COMPILER}/bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
219   endif()
220 endif()
221
222 # define folder containing all shell/batch scripts
223 if (NOT DEFINED INSTALL_DIR_SCRIPT)
224   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
225     set (INSTALL_DIR_SCRIPT "${INSTALL_DIR_BIN}" CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
226   else()
227     set (INSTALL_DIR_SCRIPT "." CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
228   endif()
229 endif()
230
231 # place the libraries to <prefix>/lib folder for unix and leave old structure for windows
232 if (NOT DEFINED INSTALL_DIR_LIB)
233   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
234     set (INSTALL_DIR_LIB "lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
235   else()
236     set (INSTALL_DIR_LIB "${OS_WITH_BIT}/${COMPILER}/lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
237   endif()
238 endif()
239
240 # OCCT headers: <prefix>/inc for windows,
241 #               <prefix>/include/opencascade-7.0.0 for unix
242 if (NOT DEFINED INSTALL_DIR_INCLUDE)
243   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
244     set (INSTALL_DIR_INCLUDE "include/opencascade" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
245     if (INSTALL_DIR_WITH_VERSION)
246       set (INSTALL_DIR_INCLUDE "include/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}" FORCE)
247     endif()
248   else()
249     set (INSTALL_DIR_INCLUDE "inc" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
250   endif()
251 endif()
252
253 # OCCT resources: <prefix>/src for windows,
254 #                 <prefix>/share/opencascade-7.0.0/resources for unix
255 if (NOT DEFINED INSTALL_DIR_RESOURCE)
256   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
257     set (INSTALL_DIR_RESOURCE "share/opencascade/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
258     if (INSTALL_DIR_WITH_VERSION)
259       set (INSTALL_DIR_RESOURCE "share/opencascade-${OCC_VERSION_STRING_EXT}/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}" FORCE)
260     endif()
261   else()
262     set (INSTALL_DIR_RESOURCE "src" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
263   endif()
264 endif()
265
266 # OCCT data
267 if (NOT DEFINED INSTALL_DIR_DATA)
268   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
269     set (INSTALL_DIR_DATA "share/opencascade/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
270     if (INSTALL_DIR_WITH_VERSION)
271       set (INSTALL_DIR_DATA "share/opencascade-${OCC_VERSION_STRING_EXT}/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}" FORCE)
272     endif()
273   else()
274     set (INSTALL_DIR_DATA "data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
275   endif()
276 endif()
277
278 # OCCT samples
279 if (NOT DEFINED INSTALL_DIR_SAMPLES)
280   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
281     set (INSTALL_DIR_SAMPLES "share/opencascade/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
282     if (INSTALL_DIR_WITH_VERSION)
283       set (INSTALL_DIR_SAMPLES "share/opencascade-${OCC_VERSION_STRING_EXT}/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}" FORCE)
284     endif()
285   else()
286     set (INSTALL_DIR_SAMPLES "samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
287   endif()
288 endif()
289
290 # OCCT tests
291 if (NOT DEFINED INSTALL_DIR_TESTS)
292   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
293     set (INSTALL_DIR_TESTS "share/opencascade/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
294     if (INSTALL_DIR_WITH_VERSION)
295       set (INSTALL_DIR_TESTS "share/opencascade-${OCC_VERSION_STRING_EXT}/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}" FORCE)
296     endif()
297   else()
298     set (INSTALL_DIR_TESTS "tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
299   endif()
300 endif()
301
302 # OCCT doc
303 if (NOT DEFINED INSTALL_DIR_DOC)
304   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
305     set (INSTALL_DIR_DOC "share/doc/opencascade" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
306     if (INSTALL_DIR_WITH_VERSION)
307       set (INSTALL_DIR_DOC "share/doc/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_DOC_DESCR}" FORCE)
308     endif()
309   else()
310     set (INSTALL_DIR_DOC "doc" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
311   endif()
312 endif()
313
314 # define folder containing CMake configuration files
315 if (NOT DEFINED INSTALL_DIR_CMAKE)
316   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
317     if (INSTALL_DIR_WITH_VERSION)
318       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
319     else()
320       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
321     endif()
322   else()
323     set (INSTALL_DIR_CMAKE "cmake" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
324   endif()
325 endif()
326
327 # include occt macros
328 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_resources")
329
330 # install LICENSE_LGPL_21.txt and OCCT_LGPL_EXCEPTION.txt files
331 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
332   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" "${INSTALL_DIR_DOC}")
333   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" "${INSTALL_DIR_DOC}")
334 else()
335   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" ".")
336   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" ".")
337 endif()
338
339 if(APPLE)
340   set (INSTALL_NAME_DIR "" CACHE STRING "install_name library suffix on OS X (e.g. @executable_path/../Frameworks)")
341 endif()
342
343 # a directory recognized as a 'patch' for OCCT
344 set (BUILD_PATCH "" CACHE PATH "${BUILD_PATCH_DESCR}")
345
346 # the list of being built toolkits
347 set (BUILD_ADDITIONAL_TOOLKITS "" CACHE STRING "${BUILD_ADDITIONAL_TOOLKITS_DESCR}")
348 separate_arguments (BUILD_ADDITIONAL_TOOLKITS)
349
350 if (MSVC)
351   set (BUILD_SAMPLES_MFC OFF CACHE BOOL "${BUILD_SAMPLES_MFC_DESCR}")
352 endif()
353 set (BUILD_SAMPLES_QT OFF CACHE BOOL "${BUILD_SAMPLES_QT_DESCR}")
354
355 set (BUILD_Inspector OFF CACHE BOOL "${BUILD_Inspector_DESCR}")
356
357 # uwp sample
358 if (MSVC)
359   if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
360     set (BUILD_MODULE_UwpSample OFF CACHE BOOL "${BUILD_MODULE_UwpSample_DESCR}")
361   else()
362     unset (BUILD_MODULE_UwpSample)
363   endif()
364 endif()
365
366 # whether use optional 3rdparty or not
367 set (USE_TK        ON  CACHE BOOL "${USE_TK_DESCR}")
368 set (USE_FREETYPE  ON  CACHE BOOL "${USE_FREETYPE_DESCR}")
369 set (USE_FREEIMAGE OFF CACHE BOOL "${USE_FREEIMAGE_DESCR}")
370 set (USE_FFMPEG    OFF CACHE BOOL "${USE_FFMPEG_DESCR}")
371 set (USE_OPENVR    OFF CACHE BOOL "${USE_OPENVR_DESCR}")
372 set (USE_RAPIDJSON OFF CACHE BOOL "${USE_RAPIDJSON_DESCR}")
373 set (USE_TBB       OFF CACHE BOOL "${USE_TBB_DESCR}")
374 set (USE_EIGEN     OFF CACHE BOOL "${USE_EIGEN_DESCR}")
375
376 if (APPLE)
377   set (USE_GLX OFF CACHE BOOL "${USE_GLX_DESCR}")
378 else()
379   set (USE_GLX OFF)
380 endif()
381
382 if (WIN32)
383   set (USE_D3D OFF CACHE BOOL "${USE_D3D_DESCR}")
384 else()
385   set (USE_D3D OFF)
386 endif()
387
388 # Enable/Disable the floating point exceptions (FPE) during runtime.
389 if (NOT BUILD_ENABLE_FPE_SIGNAL_HANDLER)
390   set (BUILD_ENABLE_FPE_SIGNAL_HANDLER OFF CACHE BOOL "${BUILD_ENABLE_FPE_SIGNAL_HANDLER_DESCR}" FORCE)
391 endif()
392
393 if (BUILD_ENABLE_FPE_SIGNAL_HANDLER)
394   set (BUILD_ENABLE_FPE_SIGNAL_HANDLER 1)
395 else()
396   set (BUILD_ENABLE_FPE_SIGNAL_HANDLER 0)
397 endif()
398
399 # OpenGL
400 if (ANDROID OR IOS OR EMSCRIPTEN OR "${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
401   set (USE_OPENGL OFF)
402   set (USE_GLES2 ON)
403 else()
404   set (USE_OPENGL ON CACHE BOOL "${USE_OPENGL_DESCR}")
405   set (USE_GLES2 OFF CACHE BOOL "${USE_GLES2_DESCR}")
406 endif()
407
408 # include the patched or original list of modules
409 # list <MODULENAME>_TOOLKITS is created foreach module and contains its toolkits
410 # list <OCCT_MODULES> will contain all modules
411 OCCT_MODULES_AND_TOOLKITS (MODULES "TOOLKITS" OCCT_MODULES)
412
413 foreach (OCCT_MODULE ${OCCT_MODULES})
414   BUILD_MODULE (${OCCT_MODULE})
415 endforeach()
416
417 if (ANDROID AND BUILD_MODULE_Draw)
418   message (STATUS "Info. Draw module is turned off due to it is not supported on Android")
419   set (BUILD_MODULE_Draw OFF CACHE BOOL "${BUILD_MODULE_Draw_DESCR}" FORCE)
420 endif()
421 if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore" AND BUILD_MODULE_Draw)
422   message (STATUS "Info. Draw module is turned off due to it is not supported on UWP")
423   set (BUILD_MODULE_Draw OFF CACHE BOOL "${BUILD_MODULE_Draw_DESCR}" FORCE)
424 endif()
425
426 # Overview
427 if (NOT DEFINED BUILD_DOC_Overview)
428   set (DO_ONLY_CHECK_FOR_DOXYGEN ON)
429   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
430   set (DO_ONLY_CHECK_FOR_DOXYGEN OFF)
431
432   if (CAN_DOXYGEN_BE_USED)
433     message (STATUS "Info. Overview building is turned on")
434   endif()
435
436   set (BUILD_DOC_Overview ${CAN_DOXYGEN_BE_USED} CACHE BOOL "${BUILD_DOC_Overview_DESCR}")
437 endif()
438
439 # accumulate used toolkits (first level) in BUILD_TOOLKITS variable
440 list (APPEND BUILD_TOOLKITS ${BUILD_ADDITIONAL_TOOLKITS})
441
442 foreach (OCCT_MODULE ${OCCT_MODULES})
443   if (BUILD_MODULE_${OCCT_MODULE})
444     list (APPEND BUILD_TOOLKITS ${${OCCT_MODULE}_TOOLKITS})
445   endif()
446 endforeach()
447
448 # DRAWEXE excluded when library build is static
449 if (NOT BUILD_SHARED_LIBS)
450   list (REMOVE_ITEM BUILD_TOOLKITS DRAWEXE)
451   message (STATUS "Info: DRAWEXE is not included due to ${BUILD_LIBRARY_TYPE} build library type")
452 endif()
453
454 # accumulate all used toolkits
455 list (REMOVE_DUPLICATES BUILD_TOOLKITS)
456 set (RAW_BUILD_TOOLKITS)
457 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
458   OCCT_TOOLKIT_FULL_DEP (${BUILD_TOOLKIT} TOOLKIT_FULL_DEPS)
459   list (APPEND RAW_BUILD_TOOLKITS ${BUILD_TOOLKIT} ${TOOLKIT_FULL_DEPS})
460 endforeach()
461
462 list (REMOVE_DUPLICATES RAW_BUILD_TOOLKITS)
463 set (BUILD_TOOLKITS ${RAW_BUILD_TOOLKITS})
464
465 # include the patched or original list of definitions and flags
466 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_defs_flags")
467
468 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/3rdparty_macro")
469
470 # search for TKIVtk and TKIVtkDraw in BUILD_TOOLKITS
471 list (FIND BUILD_TOOLKITS TKIVtk CAN_USE_VTK)
472 if (CAN_USE_VTK EQUAL -1)
473   list (FIND BUILD_TOOLKITS TKIVtkDraw CAN_USE_VTK)
474 endif()
475
476 if (NOT CAN_USE_VTK EQUAL -1)
477   if (NOT DEFINED USE_VTK)
478     set (USE_VTK OFF CACHE BOOL "${USE_VTK_DESCR}")
479   endif()
480 else()
481   OCCT_CHECK_AND_UNSET (USE_VTK)
482 endif()
483
484 # Rebuild *.yacc and *.lex files that are contained by TKMath toolkit
485 list (FIND BUILD_TOOLKITS TKMath   CAN_REBUILD_PDC_FOR_TKMATH)
486 list (FIND BUILD_TOOLKITS StepFile CAN_REBUILD_PDC_FOR_STEPFILE)
487
488 if (NOT ${CAN_REBUILD_PDC_FOR_TKMATH} EQUAL -1 OR NOT ${CAN_REBUILD_PDC_FOR_STEPFILE} EQUAL -1)
489   set (BUILD_YACCLEX OFF CACHE BOOL "${BUILD_YACCLEX_DESCR}")
490 else()
491   OCCT_CHECK_AND_UNSET (BUILD_YACCLEX)
492 endif()
493
494 if (NOT DEFINED 3RDPARTY_DIR)
495   set (3RDPARTY_DIR "" CACHE PATH ${3RDPARTY_DIR_DESCR})
496   get_filename_component (3RDPARTY_DIR "${3RDPARTY_DIR}" ABSOLUTE)
497 else()
498   file (TO_CMAKE_PATH "${3RDPARTY_DIR}" 3RDPARTY_DIR)
499   set (3RDPARTY_DIR "${3RDPARTY_DIR}" CACHE PATH "${3RDPARTY_DIR_DESCR}" FORCE)
500 endif()
501
502 # search for CSF variable in EXTERNLIB of each being used toolkit
503 OCCT_IS_PRODUCT_REQUIRED (CSF_FreeImagePlus CAN_USE_FREEIMAGE)
504 OCCT_IS_PRODUCT_REQUIRED (CSF_TclLibs USE_TCL)
505 OCCT_IS_PRODUCT_REQUIRED (CSF_TclTkLibs CAN_USE_TK)
506 OCCT_IS_PRODUCT_REQUIRED (CSF_FREETYPE CAN_USE_FREETYPE)
507 OCCT_IS_PRODUCT_REQUIRED (CSF_OpenGlLibs CAN_USE_OPENGL)
508 OCCT_IS_PRODUCT_REQUIRED (CSF_OpenGlesLibs CAN_USE_GLES2)
509 OCCT_IS_PRODUCT_REQUIRED (CSF_TBB CAN_USE_TBB)
510 OCCT_IS_PRODUCT_REQUIRED (CSF_EIGEN CAN_USE_EIGEN)
511
512 # define CSF variable
513 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_csf")
514
515 # Tcl (mandatory for Draw Harness)
516 if (USE_TCL)
517   message (STATUS "Info: TCL is used by OCCT")
518   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tcl")
519 else()
520   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TCL")
521   OCCT_CHECK_AND_UNSET ("INSTALL_TCL")
522 endif()
523
524 # Tk (optional for Draw Harness)
525 if (CAN_USE_TK)
526   if (USE_TK)
527     message (STATUS "Info: TK is used by OCCT")
528     add_definitions (-DHAVE_TK)
529     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tk")
530   else()
531     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TK")
532     OCCT_CHECK_AND_UNSET ("INSTALL_TK")
533   endif()
534 else()
535   OCCT_CHECK_AND_UNSET ("USE_TK")
536   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TK")
537   OCCT_CHECK_AND_UNSET ("INSTALL_TK")
538 endif()
539
540 # FreeType
541 if (CAN_USE_FREETYPE)
542   if (USE_FREETYPE)
543     message (STATUS "Info: FreeType is used by OCCT")
544     add_definitions (-DHAVE_FREETYPE)
545     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freetype")
546   else()
547     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREETYPE")
548     OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2")
549     OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build")
550     OCCT_CHECK_AND_UNSET ("INSTALL_FREETYPE")
551   endif()
552 else()
553   OCCT_CHECK_AND_UNSET ("USE_FREETYPE")
554   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREETYPE")
555   OCCT_CHECK_AND_UNSET ("INSTALL_FREETYPE")
556 endif()
557
558 # VTK
559 if (USE_VTK)
560   add_definitions (-DHAVE_VTK)
561   set (OCCT_VTK_USED_TARGETS "" CACHE INTERNAL "" FORCE)
562   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vtk")
563 else()
564   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_VTK")
565
566   if (NOT CAN_USE_VTK EQUAL -1)
567     message (STATUS "Info: TKIVtk and TKIVtkDraw toolkits excluded due to VTK usage is disabled")
568
569     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtk)
570     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtkDraw)
571   endif()
572 endif()
573
574 # GLX
575 if (USE_GLX)
576   add_definitions (-DMACOSX_USE_GLX)
577   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/glx")
578 endif()
579
580 # FREEIMAGE
581 if (CAN_USE_FREEIMAGE)
582   if (USE_FREEIMAGE)
583     add_definitions (-DHAVE_FREEIMAGE)
584     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimage")
585   else()
586     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
587     OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
588   endif()
589 else()
590   OCCT_CHECK_AND_UNSET ("USE_FREEIMAGE")
591
592   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
593   OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
594 endif()
595
596 # OpenVR
597 # search for CSF_OpenVR variable in EXTERNLIB of each being used toolkit
598 OCCT_IS_PRODUCT_REQUIRED (CSF_OpenVR CAN_USE_OPENVR)
599 if (CAN_USE_OPENVR)
600   if (USE_OPENVR)
601     add_definitions (-DHAVE_OPENVR)
602     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/openvr")
603   else()
604     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_OPENVR")
605     OCCT_CHECK_AND_UNSET ("INSTALL_OPENVR")
606   endif()
607 else()
608   OCCT_CHECK_AND_UNSET ("USE_OPENVR")
609
610   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_OPENVR")
611   OCCT_CHECK_AND_UNSET ("INSTALL_OPENVR")
612 endif()
613
614 # FFmpeg
615 # search for CSF_FFmpeg variable in EXTERNLIB of each being used toolkit
616 OCCT_IS_PRODUCT_REQUIRED (CSF_FFmpeg CAN_USE_FFMPEG)
617
618 if (CAN_USE_FFMPEG)
619   if (USE_FFMPEG)
620     add_definitions (-DHAVE_FFMPEG)
621     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/ffmpeg")
622   else()
623     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FFMPEG")
624     OCCT_CHECK_AND_UNSET ("INSTALL_FFMPEG")
625   endif()
626 else()
627   OCCT_CHECK_AND_UNSET ("USE_FFMPEG")
628
629   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FFMPEG")
630   OCCT_CHECK_AND_UNSET ("INSTALL_FFMPEG")
631 endif()
632
633 # OpenGL
634 if (CAN_USE_OPENGL)
635   if (USE_OPENGL)
636     add_definitions (-DHAVE_OPENGL_EXT)
637   else()
638     list (REMOVE_ITEM BUILD_TOOLKITS TKOpenGl)
639     list (REMOVE_ITEM BUILD_TOOLKITS TKOpenGlTest)
640   endif()
641 else()
642   OCCT_CHECK_AND_UNSET ("USE_OPENGL")
643 endif()
644
645 # OpenGL ES 2.0
646 if (CAN_USE_GLES2)
647   if (USE_GLES2)
648     add_definitions (-DHAVE_GLES2_EXT)
649     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/egl")
650     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gles2")
651   else()
652     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EGL")
653     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GLES2")
654     OCCT_CHECK_AND_UNSET ("INSTALL_EGL")
655     OCCT_CHECK_AND_UNSET ("INSTALL_GLES2")
656     list (REMOVE_ITEM BUILD_TOOLKITS TKOpenGles)
657     list (REMOVE_ITEM BUILD_TOOLKITS TKOpenGlesTest)
658   endif()
659 else()
660   OCCT_CHECK_AND_UNSET ("USE_GLES2")
661
662   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EGL")
663   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GLES2")
664   OCCT_CHECK_AND_UNSET ("INSTALL_EGL")
665   OCCT_CHECK_AND_UNSET ("INSTALL_GLES2")
666 endif()
667
668 # D3D
669 if (USE_D3D)
670   add_definitions (-DHAVE_D3D)
671   #if(MSVC_VERSION LESS 1700)
672   #OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/d3d")
673   #endif()
674 else()
675   list (REMOVE_ITEM BUILD_TOOLKITS TKD3DHost)
676   list (REMOVE_ITEM BUILD_TOOLKITS TKD3DHostTest)
677 endif()
678
679 # TBB
680 if (NOT DEFINED ANDROID AND CAN_USE_TBB)
681   if (USE_TBB)
682     add_definitions (-DHAVE_TBB)
683     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tbb")
684   else()
685     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
686     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
687     OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
688   endif()
689 else()
690   OCCT_CHECK_AND_UNSET ("USE_TBB")
691
692   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
693   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
694   OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
695 endif()
696
697 # RapidJSON
698 # search for CSF_RapidJSON variable in EXTERNLIB of each being used toolkit
699 OCCT_IS_PRODUCT_REQUIRED (CSF_RapidJSON CAN_USE_RAPIDJSON)
700 if (CAN_USE_RAPIDJSON)
701   if (USE_RAPIDJSON)
702     add_definitions (-DHAVE_RAPIDJSON)
703     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/rapidjson")
704   else()
705     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_RAPIDJSON")
706     OCCT_CHECK_AND_UNSET ("INSTALL_RAPIDJSON")
707   endif()
708 else()
709   OCCT_CHECK_AND_UNSET ("USE_RAPIDJSON")
710
711   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_RAPIDJSON")
712   OCCT_CHECK_AND_UNSET ("INSTALL_RAPIDJSON")
713 endif()
714
715 # EIGEN
716 if (CAN_USE_EIGEN)
717   if (USE_EIGEN)
718     add_definitions (-DHAVE_EIGEN)
719     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/eigen")
720   else()
721     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EIGEN")
722     OCCT_CHECK_AND_UNSET ("INSTALL_EIGEN")
723   endif()
724 else()
725   OCCT_CHECK_AND_UNSET ("USE_EIGEN")
726
727   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EIGEN")
728   OCCT_CHECK_AND_UNSET ("INSTALL_EIGEN")
729 endif()
730
731 # Doxygen
732 if (BUILD_DOC_Overview)
733   if (NOT DEFINED INSTALL_DOC_Overview)
734     set (INSTALL_DOC_Overview OFF CACHE BOOL "${INSTALL_DOC_Overview_DESCR}")
735   endif()
736
737   if (INSTALL_DOC_Overview)
738     install (DIRECTORY "${CMAKE_BINARY_DIR}/doc/overview" DESTINATION  "${INSTALL_DIR_DOC}")
739
740     # create overview.html only for windows
741     if (WIN32 AND "${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
742       OCCT_INSTALL_FILE_OR_DIR ("dox/resources/overview.html" "${INSTALL_DIR_DOC}/..")
743     endif()
744   endif()
745
746   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
747 else()
748   OCCT_CHECK_AND_UNSET ("INSTALL_DOC_Overview")
749
750   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOXYGEN_EXECUTABLE")
751   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOT_EXECUTABLE")
752 endif()
753
754 # bison
755 if (BUILD_YACCLEX)
756   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/bison")
757 else()
758   OCCT_CHECK_AND_UNSET ("3RDPARTY_BISON_EXECUTABLE")
759 endif()
760
761 # flex
762 if (BUILD_YACCLEX)
763   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/flex")
764 else()
765   OCCT_CHECK_AND_UNSET ("3RDPARTY_FLEX_EXECUTABLE")
766 endif()
767
768 # qt for inspector and samples
769 if (BUILD_Inspector OR BUILD_SAMPLES_QT)
770   # check qt 3rdparty path
771   add_definitions (-DHAVE_QT)
772   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/qt")
773   message (STATUS "Info: Qt is used by OCCT")
774 else()
775   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_QT")
776   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TQTMALLOC")
777   OCCT_CHECK_AND_UNSET ("INSTALL_QT")
778 endif()
779
780 # check all 3rdparty include paths
781 string (REGEX REPLACE ";" " " 3RDPARTY_NOT_INCLUDED "${3RDPARTY_NOT_INCLUDED}")
782 if (3RDPARTY_NOT_INCLUDED)
783   message (FATAL_ERROR "Could not find headers of used third-party products: ${3RDPARTY_NOT_INCLUDED}" )
784 endif()
785
786 if (3RDPARTY_INCLUDE_DIRS)
787   list (REMOVE_DUPLICATES 3RDPARTY_INCLUDE_DIRS)
788   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_INCLUDE_DIRS_WITH_ENDS "${3RDPARTY_INCLUDE_DIRS}")
789   message (STATUS "Info: The directories of 3rdparty headers: \n\t${3RDPARTY_INCLUDE_DIRS_WITH_ENDS}")
790   include_directories (${3RDPARTY_INCLUDE_DIRS})
791 endif()
792
793 # include <cmake binary folder>/inc
794 include_directories (${CMAKE_BINARY_DIR}/${INSTALL_DIR_INCLUDE})
795
796 # check all 3rdparty library paths
797 string (REGEX REPLACE ";" " " 3RDPARTY_NO_LIBS "${3RDPARTY_NO_LIBS}")
798 if (3RDPARTY_NO_LIBS)
799   if (BUILD_SHARED_LIBS)
800     message (SEND_ERROR "Could not find libraries of used third-party products: ${3RDPARTY_NO_LIBS}" )
801   else()
802     message (WARNING "Could not find libraries of used third-party products: ${3RDPARTY_NO_LIBS}" )
803   endif()
804 endif()
805 if (3RDPARTY_LIBRARY_DIRS)
806   list (REMOVE_DUPLICATES 3RDPARTY_LIBRARY_DIRS)
807   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_LIBRARY_DIRS_WITH_ENDS "${3RDPARTY_LIBRARY_DIRS}")
808   message (STATUS "Info: The directories of 3rdparty libraries: \n\t${3RDPARTY_LIBRARY_DIRS_WITH_ENDS}")
809   link_directories (${3RDPARTY_LIBRARY_DIRS})
810 endif()
811
812 # report not found 3rdparty dll paths
813 string (REGEX REPLACE ";" " " 3RDPARTY_NO_DLLS "${3RDPARTY_NO_DLLS}")
814 if (3RDPARTY_NO_DLLS)
815   message (WARNING "Could not find DLLs of used third-party products: ${3RDPARTY_NO_DLLS}" )
816 endif()
817
818 # build directories
819 if (SINGLE_GENERATOR)
820   set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
821   set (CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
822   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
823   if (WIN32)
824     set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
825   endif()
826 endif()
827
828 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
829 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
830 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
831
832 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
833 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
834 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
835
836 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
837 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
838 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
839
840 if (WIN32)
841   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE        "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
842   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
843   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG          "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
844 endif()
845
846 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
847 message (STATUS "\nInfo: \(${CURRENT_TIME}\) Start collecting all OCCT header files into ${CMAKE_BINARY_DIR}/inc ...")
848
849 # collect all the headers to <binary dir>/inc folder
850 COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}" "${BUILD_TOOLKITS}" "${CMAKE_SOURCE_DIR}/src" "${INSTALL_DIR_INCLUDE}")
851
852 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
853 message (STATUS "Info: \(${CURRENT_TIME}\) End the collecting")
854
855 list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
856 if (${DRAWEXE_INDEX} GREATER -1)
857   OCCT_INSTALL_FILE_OR_DIR ("data/" "${INSTALL_DIR_DATA}")
858   OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR_SAMPLES}")
859 endif()
860
861 if (WIN32)
862   set (SCRIPT_EXT bat)
863 else()
864   set (SCRIPT_EXT sh)
865 endif()
866
867 # OCCT tools
868 # include the patched or original list of tools
869 # list <TOOLNAME>_TOOLKITS is created foreach tool and contains its toolkits
870 # list <OCCT_TOOLS> will contain all tools
871 if (BUILD_Inspector)
872   add_definitions (-DHAVE_Inspector)
873
874   OCCT_MODULES_AND_TOOLKITS (TOOLS "TOOL_TOOLKITS" OCCT_TOOLS)
875   foreach (OCCT_TOOL ${OCCT_TOOLS})
876     list (APPEND BUILD_TOOL_TOOLKITS ${${OCCT_TOOL}_TOOL_TOOLKITS})
877   endforeach()
878
879   # collect all the headers to <binary dir>/inc/inspector folder
880   string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
881   message (STATUS "\nInfo: \(${CURRENT_TIME}\) Start collecting all OCCT tool header files into ${CMAKE_BINARY_DIR}/inc/inspector ...")
882   COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}" "${BUILD_TOOL_TOOLKITS}" "${CMAKE_SOURCE_DIR}/tools" "${INSTALL_DIR_INCLUDE}/inspector")
883 endif()
884
885 # OCCT samples
886 # get absolute path from INSTALL_DIR
887 set (INSTALL_DIR_ABSOLUTE "${INSTALL_DIR}")
888 if(NOT IS_ABSOLUTE "${INSTALL_DIR_ABSOLUTE}")
889   get_filename_component(INSTALL_DIR_ABSOLUTE "${CMAKE_BINARY_DIR}/${INSTALL_DIR}" ABSOLUTE)
890 endif()
891
892 if (INSTALL_SAMPLES)
893   OCCT_CONFIGURE ("adm/templates/env.samples.${SCRIPT_EXT}.in" "env.samples.${SCRIPT_EXT}")
894   if (WIN32)
895     OCCT_INSTALL_FILE_OR_DIR ("samples/CSharp" "${INSTALL_DIR_SAMPLES}")
896     OCCT_INSTALL_FILE_OR_DIR ("samples/mfc" "${INSTALL_DIR_SAMPLES}")
897
898     if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
899       OCCT_INSTALL_FILE_OR_DIR ("samples/xaml" "${INSTALL_DIR_SAMPLES}")
900     endif()
901
902     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/CSharp" RENAME "env.${SCRIPT_EXT}")
903     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/mfc/standard" RENAME "env.${SCRIPT_EXT}")
904   endif()
905
906   OCCT_INSTALL_FILE_OR_DIR ("samples/java" "${INSTALL_DIR_SAMPLES}")
907   OCCT_INSTALL_FILE_OR_DIR ("samples/ocafsamples" "${INSTALL_DIR_SAMPLES}")
908   OCCT_INSTALL_FILE_OR_DIR ("samples/qt" "${INSTALL_DIR_SAMPLES}")
909   OCCT_INSTALL_FILE_OR_DIR ("samples/OCCTOverview/code" "${INSTALL_DIR_SAMPLES}/OCCTOverview")
910
911   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/FuncDemo" RENAME "env.${SCRIPT_EXT}")
912   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/IESample" RENAME "env.${SCRIPT_EXT}")
913   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/OCCTOverview" RENAME "env.${SCRIPT_EXT}")
914   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/Tutorial" RENAME "env.${SCRIPT_EXT}")
915 endif()
916
917 if (INSTALL_TEST_CASES)
918   OCCT_INSTALL_FILE_OR_DIR ("tests/" "${INSTALL_DIR_TESTS}")
919 endif()
920
921 list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
922 if (${DRAWEXE_INDEX} GREATER -1)
923   # copy data and samples/tcl folders to install script folder
924   OCCT_INSTALL_FILE_OR_DIR ("data/" "${INSTALL_DIR_DATA}")
925   OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR_SAMPLES}")
926
927   # copy draw script to install script folder
928   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}")
929     install (FILES "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
930             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
931   else()
932     install (FILES "${CMAKE_SOURCE_DIR}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
933             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
934   endif()
935
936   # copy draw script to CMake binary folder
937   OCCT_COPY_FILE_OR_DIR ("adm/templates/draw.${SCRIPT_EXT}" "${CMAKE_BINARY_DIR}")
938 endif()
939
940 set (SUB_CUSTOM_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.${SCRIPT_EXT}")
941
942 if (WIN32)
943   set (ADDITIONAL_CUSTOM_CONTENT "\nif exist \"%~dp0${SUB_CUSTOM_NAME}\" (\n  call \"%~dp0${SUB_CUSTOM_NAME}\" %1 %2 %3 \n)")
944 else()
945   set (ADDITIONAL_CUSTOM_CONTENT "\nif [ -e \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" ]; then\n  source \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" \"\$1\" \"\$2\" \nfi")
946 endif()
947
948  # change custom.bat/sh
949 if (EXISTS "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}")
950   file (READ "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" CUSTOM_CONTENT)
951
952   set (CUSTOM_CONTENT "${CUSTOM_CONTENT} ${ADDITIONAL_CUSTOM_CONTENT}")
953
954   file (WRITE "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" "${CUSTOM_CONTENT}")
955 else()
956   OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.${SCRIPT_EXT}.main" "custom.${SCRIPT_EXT}" "custom.${SCRIPT_EXT}" "${INSTALL_DIR_SCRIPT}")
957 endif()
958
959 if (WIN32)
960   set (THIRDPARTY_DIR_REPLACE "%THIRDPARTY_DIR%")
961 else()
962   set (THIRDPARTY_DIR_REPLACE "\${THIRDPARTY_DIR}")
963 endif()
964 get_cmake_property(USED_3RDPARTY_CACHE_VARIABLES VARIABLES)
965 string (REGEX MATCHALL "(^|;)USED_3RDPARTY_[^;]+_DIR[^;]*" USED_3RDPARTY_CACHE_VARIABLES "${USED_3RDPARTY_CACHE_VARIABLES}")
966 file (TO_CMAKE_PATH "${3RDPARTY_DIR}" 3RDPARTY_DIR)
967 foreach (USED_3RDPARTY_CACHE_VARIABLE ${USED_3RDPARTY_CACHE_VARIABLES})
968    file (TO_CMAKE_PATH "${${USED_3RDPARTY_CACHE_VARIABLE}}" ${USED_3RDPARTY_CACHE_VARIABLE})
969    string (REPLACE "${3RDPARTY_DIR}" "${THIRDPARTY_DIR_REPLACE}" ${USED_3RDPARTY_CACHE_VARIABLE} "${${USED_3RDPARTY_CACHE_VARIABLE}}")
970    if (NOT WIN32)
971      string (REGEX REPLACE ";" ":" ${USED_3RDPARTY_CACHE_VARIABLE} "${${USED_3RDPARTY_CACHE_VARIABLE}}")
972    endif()
973 endforeach()
974
975 # write current custom.bat/sh (for install directory)
976 set (SUB_CUSTOM_BUILD_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.install.${SCRIPT_EXT}")
977 OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.install.${SCRIPT_EXT}.in" "${SUB_CUSTOM_BUILD_NAME}" "${SUB_CUSTOM_NAME}" "${INSTALL_DIR_SCRIPT}")
978
979 # write current custom.bat/sh (for build directory)
980 OCCT_CONFIGURE ("adm/templates/custom.build.${SCRIPT_EXT}.in" "${SUB_CUSTOM_NAME}")
981
982 if (BUILD_SAMPLES_MFC OR BUILD_SAMPLES_QT)
983   OCCT_INSTALL_FILE_OR_DIR ("adm/templates/sample.${SCRIPT_EXT}" "${INSTALL_DIR_SCRIPT}")
984   OCCT_COPY_FILE_OR_DIR    ("adm/templates/sample.${SCRIPT_EXT}" "${CMAKE_BINARY_DIR}")
985 endif()
986
987 if (WIN32)
988   # env script for draw in building environment
989   OCCT_CONFIGURE ("adm/templates/env.${SCRIPT_EXT}.in" "env.${SCRIPT_EXT}")
990   # install env script
991   install (FILES "${CMAKE_BINARY_DIR}/env.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SCRIPT}")
992   # copy build.bat and install.bat scripts to CMake binary folder
993   OCCT_COPY_FILE_OR_DIR ("adm/templates/build.bat" "${CMAKE_BINARY_DIR}")
994   OCCT_COPY_FILE_OR_DIR ("adm/templates/install.bat" "${CMAKE_BINARY_DIR}")
995 else()
996   set (SUB_ENV_NAME "env.${SCRIPT_EXT}")
997   set (SUB_ENV_BUILD_NAME "env.install.${SCRIPT_EXT}")
998   # install env script
999   OCCT_CONFIGURE_AND_INSTALL ("adm/templates/env.install.${SCRIPT_EXT}.in" "${SUB_ENV_BUILD_NAME}" "${SUB_ENV_NAME}" "${INSTALL_DIR_SCRIPT}")
1000   # env script for draw in building environment
1001   OCCT_CONFIGURE ("adm/templates/env.build.${SCRIPT_EXT}.in" "env.${SCRIPT_EXT}")
1002 endif()
1003
1004 # copy DrawAppliInit from OCCT source to build directory
1005 if (NOT EXISTS "${CMAKE_BINARY_DIR}/DrawAppliInit")
1006   OCCT_COPY_FILE_OR_DIR (DrawAppliInit "${CMAKE_BINARY_DIR}")
1007 endif()
1008
1009 # RESOURCES
1010 FILE_TO_LIST ("adm/RESOURCES" RESOURCES)
1011 foreach(RESOURCE ${RESOURCES})
1012   get_filename_component(RESOURCE_FOLDER ${RESOURCE} DIRECTORY)
1013   if(NOT "${RESOURCE_FOLDER}" STREQUAL "")
1014     get_filename_component(RESOURCE_FOLDER ${RESOURCE_FOLDER} NAME)
1015     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR_RESOURCE}/${RESOURCE_FOLDER}")
1016   else()
1017     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR_RESOURCE}")
1018   endif()
1019 endforeach()
1020
1021 if (BUILD_SAMPLES_QT)
1022   FILE_TO_LIST ("adm/SAMPLES_RESOURCES" SAMPLES_RESOURCES)
1023   foreach(RESOURCE ${SAMPLES_RESOURCES})
1024     OCCT_INSTALL_FILE_OR_DIR ("samples/${RESOURCE}" "${INSTALL_DIR_RESOURCE}/samples")
1025     #message("Copy Sample resources: samples/${RESOURCE} into ${INSTALL_DIR_RESOURCE}/samples")
1026   endforeach()
1027
1028   ## Copy sources of OCCTOverview for using in the sample
1029   OCCT_INSTALL_FILE_OR_DIR ("samples/OCCTOverview/code/DataExchangeSamples.cxx" "${INSTALL_DIR_SAMPLES}/OCCTOverview/code")
1030   OCCT_INSTALL_FILE_OR_DIR ("samples/OCCTOverview/code/OcafSamples.cxx" "${INSTALL_DIR_SAMPLES}/OCCTOverview/code")
1031   OCCT_INSTALL_FILE_OR_DIR ("samples/OCCTOverview/code/GeometrySamples.cxx" "${INSTALL_DIR_SAMPLES}/OCCTOverview/code")
1032   OCCT_INSTALL_FILE_OR_DIR ("samples/OCCTOverview/code/TopologySamples.cxx" "${INSTALL_DIR_SAMPLES}/OCCTOverview/code")
1033   OCCT_INSTALL_FILE_OR_DIR ("samples/OCCTOverview/code/TriangulationSamples.cxx" "${INSTALL_DIR_SAMPLES}/OCCTOverview/code")
1034   OCCT_INSTALL_FILE_OR_DIR ("samples/OCCTOverview/code/Viewer2dSamples.cxx" "${INSTALL_DIR_SAMPLES}/OCCTOverview/code")
1035   OCCT_INSTALL_FILE_OR_DIR ("samples/OCCTOverview/code/Viewer3dSamples.cxx" "${INSTALL_DIR_SAMPLES}/OCCTOverview/code")
1036 endif()
1037
1038
1039 # patch installed DrawDefault file if BUILD_SHARED_LIBRARY_NAME_POSTFIX is changed
1040 if (NOT "${BUILD_SHARED_LIBRARY_NAME_POSTFIX}" STREQUAL "")
1041   OCCT_UPDATE_DRAW_DEFAULT_FILE()
1042 endif()
1043
1044 # include patched toolkit projects or original ones
1045 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
1046   OCCT_ADD_SUBDIRECTORY ("src/${BUILD_TOOLKIT}")
1047 endforeach()
1048
1049 if (BUILD_DOC_Overview)
1050   OCCT_ADD_SUBDIRECTORY (dox)
1051 endif()
1052
1053 # patch DRAWEXE
1054 if (MSVC AND 3RDPARTY_DLL_DIRS)
1055   list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
1056   if (${DRAWEXE_INDEX} GREATER -1)
1057     list (REMOVE_DUPLICATES 3RDPARTY_DLL_DIRS)
1058     set (3RDPARTY_DLL_DIRS_FOR_PATH "")
1059
1060     foreach (3RDPARTY_DLL_DIR ${3RDPARTY_DLL_DIRS})
1061       set (3RDPARTY_DLL_DIRS_FOR_PATH "${3RDPARTY_DLL_DIRS_FOR_PATH};${3RDPARTY_DLL_DIR}")
1062     endforeach()
1063
1064     OCCT_MAKE_COMPILER_BITNESS()
1065     set (X_COMPILER_BITNESS "x64")
1066     if ("${COMPILER_BITNESS}" STREQUAL "32")
1067       set (X_COMPILER_BITNESS "Win32")
1068     endif()
1069
1070     OCCT_CONFIGURE ("adm/templates/DRAWEXE.vcxproj.user.in" "${CMAKE_BINARY_DIR}/src/DRAWEXE/DRAWEXE.vcxproj.user")
1071   endif()
1072 endif()
1073
1074 # include patched toolkit projects or original ones
1075 if (BUILD_TOOL_TOOLKITS)
1076   foreach (BUILD_TOOL_TOOLKIT ${BUILD_TOOL_TOOLKITS})
1077     OCCT_ADD_SUBDIRECTORY ("tools/${BUILD_TOOL_TOOLKIT}")
1078   endforeach()
1079 endif()
1080
1081 message (STATUS "Info: \(${CURRENT_TIME}\) OCCT toolkits processed")
1082 # samples do not support patch usage
1083 if (BUILD_SAMPLES_MFC OR BUILD_SAMPLES_QT)
1084   set (OCCT_ROOT ${CMAKE_SOURCE_DIR})
1085 endif()
1086
1087 if (BUILD_SAMPLES_MFC)
1088   set (MFC_STANDARD_SAMPLES_DIR ${OCCT_ROOT}/samples/mfc/standard)
1089   set (COMMON_WINMAIN_FILE      ${MFC_STANDARD_SAMPLES_DIR}/Common/Winmain.cpp)
1090
1091   add_subdirectory(samples/mfc/standard/mfcsample)
1092   add_subdirectory(samples/mfc/standard/01_Geometry)
1093   add_subdirectory(samples/mfc/standard/02_Modeling)
1094   add_subdirectory(samples/mfc/standard/03_Viewer2d)
1095   add_subdirectory(samples/mfc/standard/04_Viewer3d)
1096   add_subdirectory(samples/mfc/standard/05_ImportExport)
1097   add_subdirectory(samples/mfc/standard/06_Ocaf)
1098   add_subdirectory(samples/mfc/standard/07_Triangulation)
1099   add_subdirectory(samples/mfc/standard/08_HLR)
1100   add_subdirectory(samples/mfc/standard/09_Animation)
1101   add_subdirectory(samples/mfc/standard/10_Convert)
1102
1103   message (STATUS "Info: \(${CURRENT_TIME}\) MFC Sample projects added")
1104 endif()
1105
1106 OCCT_MODULES_AND_TOOLKITS (SAMPLES "SAMPLES_TOOLKITS" OCCT_SAMPLES)
1107
1108 if (BUILD_Inspector OR BUILD_SAMPLES_QT)
1109   if (BUILD_SAMPLES_QT)
1110     if (NOT Qt5_FOUND OR "${Qt5Gui_EGL_INCLUDE_DIRS}" STREQUAL "" OR NOT WIN32)
1111       list (REMOVE_ITEM qt_SAMPLES_TOOLKITS AndroidQt)
1112       message (STATUS "Info: AndroidQt sample excluded due to OS is not Windows or Qt is configured without ANGLE")
1113     endif()
1114   else()
1115     list (REMOVE_ITEM OCCT_SAMPLES qt)
1116     message (STATUS "Info: qt samples excluded due to BUILD_SAMPLES_QT is disabled")
1117   endif()
1118
1119   foreach (OCCT_SAMPLE ${OCCT_SAMPLES})
1120     list (APPEND BUILD_SAMPLE_TOOLKITS ${${OCCT_SAMPLE}_SAMPLES_TOOLKITS})
1121
1122     # collect all the headers to <binary dir>/inc/samples folder
1123     string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
1124     message (STATUS "Info: \(${CURRENT_TIME}\) ${OCCT_SAMPLE} Sample projects added")
1125
1126     # include patched toolkit projects or original ones
1127     foreach (BUILD_SAMPLE_TOOLKIT ${${OCCT_SAMPLE}_SAMPLES_TOOLKITS})
1128       OCCT_ADD_SUBDIRECTORY ("samples/${OCCT_SAMPLE}/${BUILD_SAMPLE_TOOLKIT}")
1129     endforeach()
1130   endforeach()
1131 endif()
1132
1133 if (BUILD_MODULE_UwpSample)
1134   add_subdirectory(samples/xaml)
1135 endif()
1136
1137 if (BUILD_TOOL_TOOLKITS)
1138   # copy tinspector script to install script folder
1139   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/adm/templates/inspector.${SCRIPT_EXT}")
1140     install (FILES "${BUILD_PATCH}/adm/templates/inspector.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
1141             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
1142   else()
1143     install (FILES "${CMAKE_SOURCE_DIR}/adm/templates/inspector.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
1144             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
1145   endif()
1146
1147   set (OpenCASCADE_BINARY_DIR "${INSTALL_DIR}/${INSTALL_DIR_BIN}")
1148   # patch TInspectorEXE
1149   OCCT_CONFIGURE ("adm/templates/TInspectorEXE.vcxproj.user.in" "${CMAKE_BINARY_DIR}/tools/TInspectorEXE/TInspectorEXE.vcxproj.user")
1150 endif()
1151
1152 # Prepare variables for configuration of OpenCASCADE cmake config file
1153 set (OCCT_MODULES_ENABLED)
1154 set (OCCT_LIBRARIES)
1155 set (SET_OpenCASCADE_MODULES_TOOLKITS "\n# List of available OpenCASCADE libraries for each module\n")
1156 set (OCCT_COMPILE_DEFINITIONS)
1157
1158 foreach (OCCT_TOOLKIT ${BUILD_TOOLKITS})
1159   if (TARGET ${OCCT_TOOLKIT})
1160
1161     # get all libraries
1162     get_target_property (${OCCT_TOOLKIT}_TYPE ${OCCT_TOOLKIT} "TYPE")
1163     if ("${${OCCT_TOOLKIT}_TYPE}" STREQUAL "STATIC_LIBRARY" OR "${${OCCT_TOOLKIT}_TYPE}" STREQUAL "SHARED_LIBRARY" )
1164       list (APPEND OCCT_LIBRARIES ${OCCT_TOOLKIT})
1165
1166       # get all modules
1167       get_target_property (${OCCT_TOOLKIT}_MODULE ${OCCT_TOOLKIT} "MODULE")
1168       list (APPEND OCCT_MODULES_ENABLED ${${OCCT_TOOLKIT}_MODULE})
1169       list (APPEND OpenCASCADE_${${OCCT_TOOLKIT}_MODULE}_TOOLKITS ${OCCT_TOOLKIT})
1170
1171       # get compile definitions of target directory
1172       get_directory_property (COMPILE_DEFINITIONS DIRECTORY "${${OCCT_TOOLKIT}_SOURCE_DIR}" "COMPILE_DEFINITIONS")
1173       list (APPEND OCCT_COMPILE_DEFINITIONS ${COMPILE_DEFINITIONS})
1174     endif()
1175   endif()
1176 endforeach()
1177 list (REMOVE_DUPLICATES OCCT_MODULES_ENABLED)
1178 list (REMOVE_DUPLICATES OCCT_COMPILE_DEFINITIONS)
1179 # these macros are defined for specific tookits, not globalwise
1180 list (REMOVE_ITEM OCCT_COMPILE_DEFINITIONS HAVE_OPENGL)
1181 list (REMOVE_ITEM OCCT_COMPILE_DEFINITIONS HAVE_GLES2)
1182
1183 # export compile definitions and C/C++ flags for each configuration to OpenCASCADE config files
1184 foreach (OCCT_CONFIGURATION ${CMAKE_CONFIGURATION_TYPES})
1185   set (SET_OpenCASCADE_COMPILE_DEFINITIONS)
1186   string (TOUPPER "${OCCT_CONFIGURATION}" OCCT_CONFIGURATION_UPPER)
1187   string (TOLOWER "${OCCT_CONFIGURATION}" OCCT_CONFIGURATION_LOWER)
1188   foreach(COMPILE_DEFINITION ${OCCT_COMPILE_DEFINITIONS})
1189     string(REPLACE "(" "\\(" COMPILE_DEFINITION "${COMPILE_DEFINITION}")
1190     string(REPLACE ")" "\\)" COMPILE_DEFINITION "${COMPILE_DEFINITION}")
1191     set (SET_OpenCASCADE_COMPILE_DEFINITIONS "${SET_OpenCASCADE_COMPILE_DEFINITIONS}set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:${OCCT_CONFIGURATION}>:${COMPILE_DEFINITION}>)\n")
1192   endforeach()
1193   set (SET_OpenCASCADE_CMAKE_C_FLAGS "${CMAKE_C_FLAGS_${OCCT_CONFIGURATION_UPPER}}")
1194   set (SET_OpenCASCADE_CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS_${OCCT_CONFIGURATION_UPPER}}")
1195   configure_file("${CMAKE_SOURCE_DIR}/adm/templates/OpenCASCADECompileDefinitionsAndFlags.cmake.in" "OpenCASCADECompileDefinitionsAndFlags-${OCCT_CONFIGURATION_LOWER}.cmake" @ONLY)
1196 endforeach()
1197 # install OpenCASCADE config file with compile definitions and C/C++ flags ONLY for current configuration
1198 install (CODE "string (TOLOWER \"\${CMAKE_INSTALL_CONFIG_NAME}\" CMAKE_INSTALL_CONFIG_NAME_LOWER)")
1199 install (CODE "configure_file(\"${CMAKE_BINARY_DIR}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" \"${INSTALL_DIR}/${INSTALL_DIR_CMAKE}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" COPYONLY)")
1200
1201 foreach (OCCT_MODULE ${OCCT_MODULES})
1202   if (BUILD_MODULE_${OCCT_MODULE})
1203     set (SET_OpenCASCADE_MODULES_TOOLKITS "${SET_OpenCASCADE_MODULES_TOOLKITS}set (OpenCASCADE_${OCCT_MODULE}_LIBRARIES ${OpenCASCADE_${OCCT_MODULE}_TOOLKITS})\n")
1204   endif()
1205
1206   # sort enabled modules for correct work of OpenCASCADE config file
1207   list(FIND OCCT_MODULES_ENABLED "${OCCT_MODULE}" OCCT_MODULE_INDEX)
1208   if (NOT ${OCCT_MODULE_INDEX} EQUAL -1)
1209     list (APPEND OCCT_MODULES_ENABLED_SORTED ${OCCT_MODULE})
1210   endif()
1211 endforeach()
1212 set (OCCT_MODULES_ENABLED ${OCCT_MODULES_ENABLED_SORTED})
1213
1214 # Add all targets to the build-tree export set
1215 export (TARGETS ${OCCT_LIBRARIES} FILE "${CMAKE_BINARY_DIR}/OpenCASCADETargets.cmake")
1216
1217 # Export the package for use from the build-tree
1218 # (this registers the build-tree with a global CMake-registry)
1219 export(PACKAGE OpenCASCADE)
1220
1221 if (CMAKE_BUILD_TYPE)
1222   set (SET_OpenCASCADE_BUILD_TYPE "set (OpenCASCADE_BUILD_TYPE        \"${CMAKE_BUILD_TYPE}\")")
1223 endif()
1224
1225 if (BUILD_SHARED_LIBS)
1226   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_SHARED_LINKER_FLAGS}\")")
1227 else()
1228   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_STATIC_LINKER_FLAGS}\")")
1229 endif()
1230
1231 if (WIN32)
1232   set (SET_OpenCASCADE_WITH_D3D "set (OpenCASCADE_WITH_D3D       ${USE_D3D})")
1233 endif()
1234 if (APPLE)
1235   set (SET_OpenCASCADE_WITH_GLX "set (OpenCASCADE_WITH_GLX       ${USE_GLX})")
1236 endif()
1237
1238 # Configure and install cmake config file
1239 configure_file("${CMAKE_SOURCE_DIR}/adm/templates/OpenCASCADEConfig.cmake.in" "OpenCASCADEConfig.cmake" @ONLY)
1240 install(FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfig.cmake" DESTINATION  "${INSTALL_DIR_CMAKE}")
1241
1242 # Configure cmake version file
1243 include(CMakePackageConfigHelpers)
1244 write_basic_package_version_file( ${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake
1245                                   VERSION ${OCC_VERSION_MAJOR}.${OCC_VERSION_MINOR}.${OCC_VERSION_MAINTENANCE}
1246                                   COMPATIBILITY ExactVersion )
1247
1248 # Install cmake version file
1249 install (FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake" DESTINATION "${INSTALL_DIR_CMAKE}")
1250
1251 # Install the export set for use with the install-tree for each configuration
1252 foreach (OCCT_MODULE ${OCCT_MODULES_ENABLED})
1253   install(EXPORT OpenCASCADE${OCCT_MODULE}Targets DESTINATION "${INSTALL_DIR_CMAKE}")
1254 endforeach()
1255
1256 # Update generated OpenCASCADETargets-*.cmake files
1257 # to have correct paths to libraries depending on the configuration
1258 OCCT_UPDATE_TARGET_FILE ()
1259
1260 message (STATUS "Info: \(${CURRENT_TIME}\) OCCT configuration files prepared")