CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.12 FATAL_ERROR)
   2
   3 set (CMAKE_SUPPRESS_REGENERATION TRUE)
   4
   5 set (CMAKE_CONFIGURATION_TYPES Release Debug RelWithDebInfo CACHE INTERNAL "" FORCE)
   6
   7 # macro: include patched file if it exists
   8 macro (OCCT_INCLUDE_CMAKE_FILE BEING_INCLUDED_FILE)
   9   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake")
  10     include (${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake)
  11   else()
  12     include (${CMAKE_SOURCE_DIR}/${BEING_INCLUDED_FILE}.cmake)
  13   endif()
  14 endmacro()
  15
  16 # include variable description
  17 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vardescr")
  18
  19 # set type of OCCT libraries
  20 if (NOT BUILD_LIBRARY_TYPE)
  21   set (BUILD_LIBRARY_TYPE "Shared" CACHE STRING "${BUILD_LIBRARY_TYPE_DESCR}" FORCE)
  22   SET_PROPERTY(CACHE BUILD_LIBRARY_TYPE PROPERTY STRINGS Shared Static)
  23 endif()
  24
  25 if ("${BUILD_LIBRARY_TYPE}" STREQUAL "Shared")
  26   set (BUILD_SHARED_LIBS ON)
  27
  28   if (NOT DEFINED BUILD_SHARED_LIBRARY_NAME_POSTFIX)
  29     set (BUILD_SHARED_LIBRARY_NAME_POSTFIX "" CACHE STRING "${BUILD_SHARED_LIBRARY_NAME_POSTFIX_DESCR}" FORCE)
  30   endif()
  31 else()
  32   unset (BUILD_SHARED_LIBS)
  33   message (STATUS "Info: Only 3rdparty's header files are used for building of static OCCT libraries")
  34   unset (BUILD_SHARED_LIBRARY_NAME_POSTFIX)
  35 endif()
  36
  37 # the name of the project
  38 project (OCCT)
  39
  40 if (WIN32)
  41   add_definitions(-DUNICODE)
  42   add_definitions(-D_UNICODE)
  43 endif()
  44
  45 # include occt macros
  46 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_macros")
  47
  48 # Solution folder property
  49 set_property (GLOBAL PROPERTY USE_FOLDERS ON)
  50
  51 # get current OCCT version
  52 OCC_VERSION (OCC_VERSION_MAJOR OCC_VERSION_MINOR OCC_VERSION_MAINTENANCE OCC_VERSION_DEVELOPMENT OCC_VERSION_STRING_EXT)
  53
  54 set_property (GLOBAL PROPERTY OCC_VERSION_MAJOR ${OCC_VERSION_MAJOR})
  55 set_property (GLOBAL PROPERTY OCC_VERSION_MINOR ${OCC_VERSION_MINOR})
  56 set_property (GLOBAL PROPERTY OCC_VERSION_MAINTENANCE ${OCC_VERSION_MAINTENANCE})
  57
  58 set (INSTALL_TEST_CASES OFF CACHE BOOL "${INSTALL_TEST_CASES_DESCR}")
  59
  60 # Regeneration of OCCT resource files
  61 set (BUILD_RESOURCES OFF CACHE BOOL "${BUILD_RESOURCES_DESCR}")
  62
  63 # single-configuration generator
  64 set (SINGLE_GENERATOR OFF)
  65 if (CMAKE_BUILD_TYPE)
  66   set (SINGLE_GENERATOR ON)
  67 endif()
  68
  69 # a single-configuration generator like the Makefile generator defines CMAKE_BUILD_TYPE variable
  70 # check this variable and set if it's required
  71 if (DEFINED CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE) # single-configuration generator.
  72   set (CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel." FORCE)
  73 endif()
  74
  75 # enable extended messages of many OCCT algorithms
  76 if (((SINGLE_GENERATOR AND "${CMAKE_BUILD_TYPE}" STREQUAL "Debug") OR NOT SINGLE_GENERATOR) AND (NOT "${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore"))
  77   if (NOT BUILD_WITH_DEBUG)
  78     set (BUILD_WITH_DEBUG OFF CACHE BOOL "${BUILD_WITH_DEBUG_DESCR}")
  79   endif()
  80 else()
  81   OCCT_CHECK_AND_UNSET (BUILD_WITH_DEBUG)
  82 endif()
  83
  84 if (BUILD_WITH_DEBUG)
  85   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:DEBUG>:OCCT_DEBUG>)
  86 endif()
  87
  88 # copy samples to install directory
  89 set (INSTALL_SAMPLES OFF CACHE BOOL "${INSTALL_SAMPLES_DESCR}")
  90
  91 # install dir of the project
  92 if (NOT DEFINED INSTALL_DIR)
  93   # set default install directory for Windows
  94   if (WIN32 AND NOT DEFINED CMAKE_INSTALL_PREFIX)
  95     set (CMAKE_INSTALL_PREFIX "C:/opencascade-${OCC_VERSION_STRING_EXT}")
  96   endif()
  97   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}")
  98 else()
  99   file (TO_CMAKE_PATH "${INSTALL_DIR}" INSTALL_DIR)
 100   set (INSTALL_DIR "${INSTALL_DIR}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
 101 endif()
 102
 103 # choose a variant of the layout of the install paths
 104 if (NOT INSTALL_DIR_LAYOUT)
 105   if (WIN32)
 106     set (INSTALL_DIR_LAYOUT "Windows" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
 107   else()
 108     set (INSTALL_DIR_LAYOUT "Unix" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
 109   endif()
 110   SET_PROPERTY(CACHE INSTALL_DIR_LAYOUT PROPERTY STRINGS Windows Unix)
 111 endif()
 112
 113 # check INSTALL_DIR_LAYOUT changes and update INSTALL_DIR_* paths if necessary
 114 if (NOT DEFINED INSTALL_DIR_LAYOUT_PREV)
 115   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
 116 elseif (NOT "${INSTALL_DIR_LAYOUT_PREV}" STREQUAL "${INSTALL_DIR_LAYOUT}")
 117   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
 118   # The structure of install folder should be reset due to changed layout
 119   OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
 120
 121   # Unset INSTALL_DIR_WITH_VERSION on windows
 122   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
 123     OCCT_CHECK_AND_UNSET (INSTALL_DIR_WITH_VERSION)
 124   else()
 125     if (NOT DEFINED INSTALL_DIR_WITH_VERSION)
 126       set (INSTALL_DIR_WITH_VERSION OFF CACHE BOOL "${INSTALL_DIR_WITH_VERSION_DESCR}")
 127     endif()
 128   endif()
 129 endif()
 130
 131 # check CMAKE_INSTALL_PREFIX changes and update INSTALL_DIR if necessary
 132 if (NOT DEFINED CMAKE_INSTALL_PREFIX_PREV)
 133   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
 134 elseif (NOT "${CMAKE_INSTALL_PREFIX_PREV}" STREQUAL "${CMAKE_INSTALL_PREFIX}")
 135   # CMAKE_INSTALL_PREFIX has been changed at previous step
 136   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
 137
 138   # INSTALL_DIR is required to be updated
 139   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
 140 endif()
 141
 142 # check INSTALL_DIR changes and update CMAKE_INSTALL_PREFIX if necessary
 143 if (NOT DEFINED INSTALL_DIR_PREV)
 144   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 145 elseif (NOT "${INSTALL_DIR_PREV}" STREQUAL "${INSTALL_DIR}")
 146   # INSTALL_DIR has been changed at previous step
 147   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 148
 149   # sync CMAKE_INSTALL_PREFIX with INSTALL_DIR
 150   set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 151
 152   # set CMAKE_INSTALL_PREFIX_PREV to avoid the reset of structure of the install folder
 153   set (CMAKE_INSTALL_PREFIX_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 154 endif()
 155
 156 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 157   if (NOT DEFINED INSTALL_DIR_WITH_VERSION_PREV)
 158     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
 159   elseif (NOT "${INSTALL_DIR_WITH_VERSION_PREV}" STREQUAL "${INSTALL_DIR_WITH_VERSION}")
 160     # INSTALL_DIR_WITH_VERSION has been changed at previous step
 161     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
 162
 163     OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
 164   endif()
 165 endif()
 166
 167 # hide CMAKE_INSTALL_PREFIX from a user
 168 set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 169
 170 set (BIN_LETTER "")
 171 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
 172   set (BIN_LETTER "d")
 173 elseif ("${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo")
 174   set (BIN_LETTER "i")
 175 endif()
 176
 177 # Get all used variables: OS_WITH_BIT, COMPILER
 178 OCCT_MAKE_OS_WITH_BITNESS()
 179 OCCT_MAKE_COMPILER_SHORT_NAME()
 180
 181 # do not define INSTALL_DIR_BIN for win.
 182 # Leave library structure for win: <prefix>/win64/vc10/bin(d)
 183 if (NOT DEFINED INSTALL_DIR_BIN)
 184   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 185     set (INSTALL_DIR_BIN "bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
 186   else()
 187     set (INSTALL_DIR_BIN "${OS_WITH_BIT}/${COMPILER}/bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
 188   endif()
 189 endif()
 190
 191 # define folder contaning all shell/batch scripts
 192 if (NOT DEFINED INSTALL_DIR_SCRIPT)
 193   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 194     set (INSTALL_DIR_SCRIPT "${INSTALL_DIR_BIN}" CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
 195   else()
 196     set (INSTALL_DIR_SCRIPT "." CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
 197   endif()
 198 endif()
 199
 200 # place the libraries to <prefix>/lib folder for unix and leave old structure for windows
 201 if (NOT DEFINED INSTALL_DIR_LIB)
 202   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 203     set (INSTALL_DIR_LIB "lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
 204   else()
 205     set (INSTALL_DIR_LIB "${OS_WITH_BIT}/${COMPILER}/lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
 206   endif()
 207 endif()
 208
 209 # OCCT headers: <prefix>/inc for windows,
 210 #               <prefix>/include/opencascade-7.0.0 for unix
 211 if (NOT DEFINED INSTALL_DIR_INCLUDE)
 212   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 213     set (INSTALL_DIR_INCLUDE "include/opencascade" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
 214     if (INSTALL_DIR_WITH_VERSION)
 215       set (INSTALL_DIR_INCLUDE "include/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}" FORCE)
 216     endif()
 217   else()
 218     set (INSTALL_DIR_INCLUDE "inc" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
 219   endif()
 220 endif()
 221
 222 # OCCT resources: <prefix>/src for windows,
 223 #                 <prefix>/share/opencascade-7.0.0/resources for unix
 224 if (NOT DEFINED INSTALL_DIR_RESOURCE)
 225   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 226     set (INSTALL_DIR_RESOURCE "share/opencascade/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
 227     if (INSTALL_DIR_WITH_VERSION)
 228       set (INSTALL_DIR_RESOURCE "share/opencascade-${OCC_VERSION_STRING_EXT}/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}" FORCE)
 229     endif()
 230   else()
 231     set (INSTALL_DIR_RESOURCE "src" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
 232   endif()
 233 endif()
 234
 235 # OCCT data
 236 if (NOT DEFINED INSTALL_DIR_DATA)
 237   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 238     set (INSTALL_DIR_DATA "share/opencascade/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
 239     if (INSTALL_DIR_WITH_VERSION)
 240       set (INSTALL_DIR_DATA "share/opencascade-${OCC_VERSION_STRING_EXT}/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}" FORCE)
 241     endif()
 242   else()
 243     set (INSTALL_DIR_DATA "data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
 244   endif()
 245 endif()
 246
 247 # OCCT samples
 248 if (NOT DEFINED INSTALL_DIR_SAMPLES)
 249   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 250     set (INSTALL_DIR_SAMPLES "share/opencascade/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
 251     if (INSTALL_DIR_WITH_VERSION)
 252       set (INSTALL_DIR_SAMPLES "share/opencascade-${OCC_VERSION_STRING_EXT}/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}" FORCE)
 253     endif()
 254   else()
 255     set (INSTALL_DIR_SAMPLES "samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
 256   endif()
 257 endif()
 258
 259 # OCCT tests
 260 if (NOT DEFINED INSTALL_DIR_TESTS)
 261   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 262     set (INSTALL_DIR_TESTS "share/opencascade/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
 263     if (INSTALL_DIR_WITH_VERSION)
 264       set (INSTALL_DIR_TESTS "share/opencascade-${OCC_VERSION_STRING_EXT}/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}" FORCE)
 265     endif()
 266   else()
 267     set (INSTALL_DIR_TESTS "tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
 268   endif()
 269 endif()
 270
 271 # OCCT doc
 272 if (NOT DEFINED INSTALL_DIR_DOC)
 273   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 274     set (INSTALL_DIR_DOC "share/doc/opencascade" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
 275     if (INSTALL_DIR_WITH_VERSION)
 276       set (INSTALL_DIR_DOC "share/doc/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_DOC_DESCR}" FORCE)
 277     endif()
 278   else()
 279     set (INSTALL_DIR_DOC "doc" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
 280   endif()
 281 endif()
 282
 283 # define folder contaning CMake configuration files
 284 if (NOT DEFINED INSTALL_DIR_CMAKE)
 285   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 286     if (INSTALL_DIR_WITH_VERSION)
 287       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
 288     else()
 289       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
 290     endif()
 291   else()
 292     set (INSTALL_DIR_CMAKE "cmake" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
 293   endif()
 294 endif()
 295
 296 # include occt macros
 297 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_resources")
 298
 299 # install LICENSE_LGPL_21.txt and OCCT_LGPL_EXCEPTION.txt files
 300 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 301   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" "${INSTALL_DIR_DOC}")
 302   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" "${INSTALL_DIR_DOC}")
 303 else()
 304   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" ".")
 305   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" ".")
 306 endif()
 307
 308 if(APPLE)
 309   set (INSTALL_NAME_DIR "" CACHE STRING "install_name library suffix on OS X (e.g. @executable_path/../Frameworks)")
 310 endif()
 311
 312 # a directory recognized as a 'patch' for OCCT
 313 set (BUILD_PATCH "" CACHE PATH "${BUILD_PATCH_DESCR}")
 314
 315 # the list of being built toolkits
 316 set (BUILD_ADDITIONAL_TOOLKITS "" CACHE STRING "${BUILD_ADDITIONAL_TOOLKITS_DESCR}")
 317 separate_arguments (BUILD_ADDITIONAL_TOOLKITS)
 318
 319 if (MSVC)
 320   set (BUILD_MODULE_MfcSamples OFF CACHE BOOL "${BUILD_MODULE_MfcSamples_DESCR}")
 321 endif()
 322
 323 # uwp sample
 324 if (MSVC)
 325   if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
 326     set (BUILD_MODULE_UwpSample OFF CACHE BOOL "${BUILD_MODULE_UwpSample_DESCR}")
 327   else()
 328     unset (BUILD_MODULE_UwpSample)
 329   endif()
 330 endif()
 331
 332 # whether use optional 3rdparty or not
 333 if (APPLE)
 334   set (USE_GLX OFF CACHE BOOL "${USE_GLX_DESCR}")
 335 endif()
 336
 337 if (WIN32)
 338   set (USE_D3D OFF CACHE BOOL "${USE_D3D_DESCR}")
 339 endif()
 340
 341 # Enable/Disable the floating point exceptions (FPE) during runtime.
 342 if (NOT BUILD_ENABLE_FPE_SIGNAL_HANDLER)
 343   set (BUILD_ENABLE_FPE_SIGNAL_HANDLER OFF CACHE BOOL "${BUILD_ENABLE_FPE_SIGNAL_HANDLER_DESCR}" FORCE)
 344 endif()
 345
 346 if (BUILD_ENABLE_FPE_SIGNAL_HANDLER)
 347   set (BUILD_ENABLE_FPE_SIGNAL_HANDLER 1)
 348 else()
 349   set (BUILD_ENABLE_FPE_SIGNAL_HANDLER 0)
 350 endif()
 351
 352 # include the patched or original list of modules
 353 # list <MODULENAME>_TOOLKITS is created foreach module and contains its toolkits
 354 # list <OCCT_MODULES> will contain all modules
 355 OCCT_MODULES_AND_TOOLKITS (OCCT_MODULES)
 356
 357 foreach (OCCT_MODULE ${OCCT_MODULES})
 358   BUILD_MODULE (${OCCT_MODULE})
 359 endforeach()
 360
 361 if (ANDROID AND BUILD_MODULE_Draw)
 362   message (STATUS "Info. Draw module is turned off due to it is not supported on Android")
 363   set (BUILD_MODULE_Draw OFF CACHE BOOL "${BUILD_MODULE_Draw_DESCR}" FORCE)
 364 endif()
 365 if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore" AND BUILD_MODULE_Draw)
 366   message (STATUS "Info. Draw module is turned off due to it is not supported on UWP")
 367   set (BUILD_MODULE_Draw OFF CACHE BOOL "${BUILD_MODULE_Draw_DESCR}" FORCE)
 368 endif()
 369
 370 # Overview
 371 if (NOT DEFINED BUILD_DOC_Overview)
 372   set (DO_ONLY_CHECK_FOR_DOXYGEN ON)
 373   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
 374   set (DO_ONLY_CHECK_FOR_DOXYGEN OFF)
 375
 376   if (CAN_DOXYGEN_BE_USED)
 377     message (STATUS "Info. Overview building is turned on")
 378   endif()
 379
 380   set (BUILD_DOC_Overview ${CAN_DOXYGEN_BE_USED} CACHE BOOL "${BUILD_DOC_Overview_DESCR}")
 381 endif()
 382
 383 if (NOT USE_D3D)
 384   list (REMOVE_ITEM Visualization_TOOLKITS TKD3DHost)
 385 endif()
 386
 387 # accumulate used toolkits (first level) in BUILD_TOOLKITS variable
 388 list (APPEND BUILD_TOOLKITS ${BUILD_ADDITIONAL_TOOLKITS})
 389
 390 foreach (OCCT_MODULE ${OCCT_MODULES})
 391   if (BUILD_MODULE_${OCCT_MODULE})
 392     list (APPEND BUILD_TOOLKITS ${${OCCT_MODULE}_TOOLKITS})
 393   endif()
 394 endforeach()
 395
 396 # DRAWEXE excluded when library build is static
 397 if (NOT BUILD_SHARED_LIBS)
 398   list (REMOVE_ITEM BUILD_TOOLKITS DRAWEXE)
 399   message (STATUS "Info: DRAWEXE is not included due to ${BUILD_LIBRARY_TYPE} build library type")
 400 endif()
 401
 402 # accumulate all used toolkits
 403 list (REMOVE_DUPLICATES BUILD_TOOLKITS)
 404 set (RAW_BUILD_TOOLKITS)
 405 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
 406   OCCT_TOOLKIT_FULL_DEP (${BUILD_TOOLKIT} TOOLKIT_FULL_DEPS)
 407   list (APPEND RAW_BUILD_TOOLKITS ${BUILD_TOOLKIT} ${TOOLKIT_FULL_DEPS})
 408 endforeach()
 409
 410 list (REMOVE_DUPLICATES RAW_BUILD_TOOLKITS)
 411 set (BUILD_TOOLKITS ${RAW_BUILD_TOOLKITS})
 412
 413 # include the patched or original list of definitions and flags
 414 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_defs_flags")
 415
 416 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/3rdparty_macro")
 417
 418 # search for TKIVtk and TKIVtkDraw in BUILD_TOOLKITS
 419 list (FIND BUILD_TOOLKITS TKIVtk CAN_USE_VTK)
 420 if (CAN_USE_VTK EQUAL -1)
 421   list (FIND BUILD_TOOLKITS TKIVtkDraw CAN_USE_VTK)
 422 endif()
 423
 424 if (NOT CAN_USE_VTK EQUAL -1)
 425   if (NOT DEFINED USE_VTK)
 426     set (USE_VTK OFF CACHE BOOL "${USE_VTK_DESCR}")
 427   endif()
 428 else()
 429   OCCT_CHECK_AND_UNSET (USE_VTK)
 430 endif()
 431
 432 # Rebuild *.yacc and *.lex files that are contained by TKMath toolkit
 433 list (FIND BUILD_TOOLKITS TKMath   CAN_REBUILD_PDC_FOR_TKMATH)
 434 list (FIND BUILD_TOOLKITS StepFile CAN_REBUILD_PDC_FOR_STEPFILE)
 435
 436 if (NOT ${CAN_REBUILD_PDC_FOR_TKMATH} EQUAL -1 OR NOT ${CAN_REBUILD_PDC_FOR_STEPFILE} EQUAL -1)
 437   set (BUILD_YACCLEX OFF CACHE BOOL "${BUILD_YACCLEX_DESCR}")
 438 else()
 439   OCCT_CHECK_AND_UNSET (BUILD_YACCLEX)
 440 endif()
 441
 442 if (NOT DEFINED 3RDPARTY_DIR)
 443   set (3RDPARTY_DIR "" CACHE PATH ${3RDPARTY_DIR_DESCR})
 444   get_filename_component (3RDPARTY_DIR "${3RDPARTY_DIR}" ABSOLUTE)
 445 else()
 446   file (TO_CMAKE_PATH "${3RDPARTY_DIR}" 3RDPARTY_DIR)
 447   set (3RDPARTY_DIR "${3RDPARTY_DIR}" CACHE PATH "${3RDPARTY_DIR_DESCR}" FORCE)
 448 endif()
 449
 450 # search for CSF variable in EXTERNLIB of each being used toolkit
 451 OCCT_IS_PRODUCT_REQUIRED (CSF_FreeImagePlus CAN_USE_FREEIMAGE)
 452 OCCT_IS_PRODUCT_REQUIRED (CSF_TclLibs USE_TCL)
 453 OCCT_IS_PRODUCT_REQUIRED (CSF_FREETYPE USE_FREETYPE)
 454 OCCT_IS_PRODUCT_REQUIRED (CSF_OpenGlLibs CAN_USE_GLES2)
 455 OCCT_IS_PRODUCT_REQUIRED (CSF_GL2PS CAN_USE_GL2PS)
 456 OCCT_IS_PRODUCT_REQUIRED (CSF_TBB CAN_USE_TBB)
 457 OCCT_IS_PRODUCT_REQUIRED (CSF_EIGEN CAN_USE_EIGEN)
 458
 459 # define CSF variable
 460 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_csf")
 461
 462 if (USE_TCL)
 463   message (STATUS "Info: TCL is used by OCCT")
 464   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tcl")
 465
 466   message (STATUS "Info: TK is used by OCCT")
 467   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tk")
 468 else()
 469   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TCL")
 470   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TK")
 471
 472   OCCT_CHECK_AND_UNSET ("INSTALL_TCL")
 473   OCCT_CHECK_AND_UNSET ("INSTALL_TK")
 474 endif()
 475
 476 if (USE_FREETYPE)
 477   message (STATUS "Info: Freetype is used by OCCT")
 478   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freetype")
 479 else()
 480   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREETYPE")
 481   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2")
 482   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build")
 483   OCCT_CHECK_AND_UNSET ("INSTALL_FREETYPE")
 484 endif()
 485
 486 # VTK
 487 if (USE_VTK)
 488   add_definitions (-DHAVE_VTK)
 489   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vtk")
 490 else()
 491   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_VTK")
 492
 493   if (NOT CAN_USE_VTK EQUAL -1)
 494     message (STATUS "Info: TKIVtk and TKIVtkDraw toolkits excluded due to VTK usage is disabled")
 495
 496     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtk)
 497     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtkDraw)
 498   endif()
 499 endif()
 500
 501 # D3D
 502 if (USE_D3D)
 503   add_definitions (-DHAVE_D3D)
 504   #if(MSVC_VERSION LESS 1700)
 505   #OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/d3d")
 506   #endif()
 507 endif()
 508
 509 # GLX
 510 if (USE_GLX)
 511   add_definitions (-DMACOSX_USE_GLX)
 512   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/glx")
 513 endif()
 514
 515 # FREEIMAGE
 516
 517 if (CAN_USE_FREEIMAGE)
 518   set (USE_FREEIMAGE OFF CACHE BOOL "${USE_FREEIMAGE_DESCR}")
 519
 520   if (USE_FREEIMAGE)
 521     add_definitions (-DHAVE_FREEIMAGE)
 522     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimage")
 523   else()
 524     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
 525     OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
 526   endif()
 527 else()
 528   OCCT_CHECK_AND_UNSET ("USE_FREEIMAGE")
 529
 530   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
 531   OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
 532 endif()
 533
 534 # OpenGL ES 2.0
 535 if (WIN32 AND CAN_USE_GLES2)
 536   if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
 537     set (USE_GLES2 ON)
 538   else()
 539     set (USE_GLES2 OFF CACHE BOOL "${USE_GLES2_DESCR}")
 540   endif()
 541
 542   if (USE_GLES2)
 543     add_definitions (-DHAVE_GLES2)
 544     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/egl")
 545         OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gles2")
 546   else()
 547     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EGL")
 548     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GLES2")
 549     OCCT_CHECK_AND_UNSET ("INSTALL_EGL")
 550     OCCT_CHECK_AND_UNSET ("INSTALL_GLES2")
 551   endif()
 552 else()
 553   OCCT_CHECK_AND_UNSET ("USE_GLES2")
 554
 555   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EGL")
 556   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GLES2")
 557   OCCT_CHECK_AND_UNSET ("INSTALL_EGL")
 558   OCCT_CHECK_AND_UNSET ("INSTALL_GLES2")
 559 endif()
 560
 561 # GL2PS
 562 if (NOT DEFINED ANDROID AND CAN_USE_GL2PS)
 563   set (USE_GL2PS OFF CACHE BOOL "${USE_GL2PS_DESCR}")
 564
 565   if (USE_GL2PS)
 566     add_definitions (-DHAVE_GL2PS)
 567     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gl2ps")
 568   else()
 569     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
 570     OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
 571   endif()
 572 else()
 573   OCCT_CHECK_AND_UNSET ("USE_GL2PS")
 574
 575   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
 576   OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
 577 endif()
 578
 579 # TBB
 580 if (NOT DEFINED ANDROID AND CAN_USE_TBB)
 581   set (USE_TBB OFF CACHE BOOL "${USE_TBB_DESCR}")
 582
 583   if (USE_TBB)
 584     add_definitions (-DHAVE_TBB)
 585     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tbb")
 586   else()
 587     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
 588     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
 589     OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
 590   endif()
 591 else()
 592   OCCT_CHECK_AND_UNSET ("USE_TBB")
 593
 594   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
 595   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
 596   OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
 597 endif()
 598
 599 # EIGEN
 600 if (CAN_USE_EIGEN)
 601   set (USE_EIGEN OFF CACHE BOOL "${USE_EIGEN_DESCR}")
 602
 603   if (USE_EIGEN)
 604     add_definitions (-DHAVE_EIGEN)
 605     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/eigen")
 606   else()
 607     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EIGEN")
 608   endif()
 609 else()
 610   OCCT_CHECK_AND_UNSET ("USE_EIGEN")
 611
 612   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EIGEN")
 613 endif()
 614
 615 # Doxygen
 616 if (BUILD_DOC_Overview)
 617   if (NOT DEFINED INSTALL_DOC_Overview)
 618     set (INSTALL_DOC_Overview OFF CACHE BOOL "${INSTALL_DOC_Overview_DESCR}")
 619   endif()
 620
 621   if (INSTALL_DOC_Overview)
 622     install (DIRECTORY "${CMAKE_BINARY_DIR}/doc/overview" DESTINATION  "${INSTALL_DIR_DOC}")
 623
 624     # create overview.html only for windows
 625     if (WIN32 AND "${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
 626       OCCT_INSTALL_FILE_OR_DIR ("dox/resources/overview.html" "${INSTALL_DIR_DOC}/..")
 627     endif()
 628   endif()
 629
 630   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
 631 else()
 632   OCCT_CHECK_AND_UNSET ("INSTALL_DOC_Overview")
 633
 634   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOXYGEN_EXECUTABLE")
 635   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOT_EXECUTABLE")
 636 endif()
 637
 638 # bison
 639 if (BUILD_YACCLEX)
 640   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/bison")
 641 else()
 642   OCCT_CHECK_AND_UNSET ("3RDPARTY_BISON_EXECUTABLE")
 643 endif()
 644
 645 # flex
 646 if (BUILD_YACCLEX)
 647   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/flex")
 648 else()
 649   OCCT_CHECK_AND_UNSET ("3RDPARTY_FLEX_EXECUTABLE")
 650 endif()
 651
 652 string (REGEX REPLACE ";" " " 3RDPARTY_NOT_INCLUDED "${3RDPARTY_NOT_INCLUDED}")
 653
 654 # check all 3rdparty paths
 655 if (3RDPARTY_NOT_INCLUDED)
 656   message (FATAL_ERROR "NOT FOUND: ${3RDPARTY_NOT_INCLUDED}" )
 657 endif()
 658
 659 if (3RDPARTY_INCLUDE_DIRS)
 660   list (REMOVE_DUPLICATES 3RDPARTY_INCLUDE_DIRS)
 661   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_INCLUDE_DIRS_WITH_ENDS "${3RDPARTY_INCLUDE_DIRS}")
 662   message (STATUS "Info: The directories of 3rdparty headers: \n\t${3RDPARTY_INCLUDE_DIRS_WITH_ENDS}")
 663   include_directories (${3RDPARTY_INCLUDE_DIRS})
 664 endif()
 665
 666 # include <cmake binary folder>/inc
 667 include_directories (${CMAKE_BINARY_DIR}/inc)
 668
 669 if (3RDPARTY_LIBRARY_DIRS AND BUILD_SHARED_LIBS)
 670   list (REMOVE_DUPLICATES 3RDPARTY_LIBRARY_DIRS)
 671   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_LIBRARY_DIRS_WITH_ENDS "${3RDPARTY_LIBRARY_DIRS}")
 672   message (STATUS "Info: The directories of 3rdparty libraries: \n\t${3RDPARTY_LIBRARY_DIRS_WITH_ENDS}")
 673   link_directories (${3RDPARTY_LIBRARY_DIRS})
 674 endif()
 675
 676 # build directories
 677 if (SINGLE_GENERATOR)
 678   set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
 679   set (CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
 680   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
 681   if (WIN32)
 682     set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
 683   endif()
 684 endif()
 685
 686 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
 687 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
 688 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
 689
 690 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
 691 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
 692 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
 693
 694 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
 695 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
 696 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
 697
 698 if (WIN32)
 699   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE        "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
 700   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
 701   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG          "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
 702 endif()
 703
 704 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
 705 message (STATUS "\nInfo: \(${CURRENT_TIME}\) Start collecting all OCCT header files into ${CMAKE_BINARY_DIR}/inc ...")
 706
 707 # collect all the headers to <binary dir>/inc folder
 708 COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}" "${BUILD_TOOLKITS}")
 709
 710 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
 711 message (STATUS "Info: \(${CURRENT_TIME}\) End the collecting")
 712
 713 list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
 714 if (${DRAWEXE_INDEX} GREATER -1)
 715   OCCT_INSTALL_FILE_OR_DIR ("data/" "${INSTALL_DIR_DATA}")
 716   OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR_SAMPLES}")
 717 endif()
 718
 719 if (WIN32)
 720   set (SCRIPT_EXT bat)
 721 else()
 722   set (SCRIPT_EXT sh)
 723 endif()
 724
 725 # OCCT samples
 726 # get absolute path from INSTALL_DIR
 727 set (INSTALL_DIR_ABSOLUTE "${INSTALL_DIR}")
 728 if(NOT IS_ABSOLUTE "${INSTALL_DIR_ABSOLUTE}")
 729   get_filename_component(INSTALL_DIR_ABSOLUTE "${CMAKE_BINARY_DIR}/${INSTALL_DIR}" ABSOLUTE)
 730 endif()
 731
 732 if (INSTALL_SAMPLES)
 733   OCCT_CONFIGURE ("adm/templates/env.samples.${SCRIPT_EXT}.in" "env.samples.${SCRIPT_EXT}")
 734   if (WIN32)
 735     OCCT_INSTALL_FILE_OR_DIR ("samples/CSharp" "${INSTALL_DIR_SAMPLES}")
 736     OCCT_INSTALL_FILE_OR_DIR ("samples/mfc" "${INSTALL_DIR_SAMPLES}")
 737
 738     if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
 739       OCCT_INSTALL_FILE_OR_DIR ("samples/xaml" "${INSTALL_DIR_SAMPLES}")
 740     endif()
 741
 742     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/CSharp" RENAME "env.${SCRIPT_EXT}")
 743     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/mfc/standard" RENAME "env.${SCRIPT_EXT}")
 744   endif()
 745
 746   OCCT_INSTALL_FILE_OR_DIR ("samples/java" "${INSTALL_DIR_SAMPLES}")
 747   OCCT_INSTALL_FILE_OR_DIR ("samples/ocafsamples" "${INSTALL_DIR_SAMPLES}")
 748   OCCT_INSTALL_FILE_OR_DIR ("samples/qt" "${INSTALL_DIR_SAMPLES}")
 749
 750   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/FuncDemo" RENAME "env.${SCRIPT_EXT}")
 751   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/IESample" RENAME "env.${SCRIPT_EXT}")
 752   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/Tutorial" RENAME "env.${SCRIPT_EXT}")
 753 endif()
 754
 755 if (INSTALL_TEST_CASES)
 756   OCCT_INSTALL_FILE_OR_DIR ("tests/" "${INSTALL_DIR_TESTS}")
 757 endif()
 758
 759 list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
 760 if (${DRAWEXE_INDEX} GREATER -1)
 761   # copy data and samples/tcl folders to install script folder
 762   OCCT_INSTALL_FILE_OR_DIR ("data/" "${INSTALL_DIR_DATA}")
 763   OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR_SAMPLES}")
 764
 765   # copy draw script to install script folder
 766   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}")
 767     install (FILES "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
 768             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
 769   else()
 770     install (FILES "${CMAKE_SOURCE_DIR}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
 771             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
 772   endif()
 773
 774   # copy draw script to CMake binary folder
 775   OCCT_COPY_FILE_OR_DIR ("adm/templates/draw.${SCRIPT_EXT}" "${CMAKE_BINARY_DIR}")
 776 endif()
 777
 778 set (SUB_CUSTOM_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.${SCRIPT_EXT}")
 779
 780 if (WIN32)
 781   set (ADDITIONAL_CUSTOM_CONTENT "\nif exist \"%~dp0${SUB_CUSTOM_NAME}\" (\n  call \"%~dp0${SUB_CUSTOM_NAME}\" %1 %2 %3 \n)")
 782 else()
 783   set (ADDITIONAL_CUSTOM_CONTENT "\nif [ -e \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" ]; then\n  source \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" \"\$1\" \"\$2\" \nfi")
 784 endif()
 785
 786  # change custom.bat/sh
 787 if (EXISTS "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}")
 788   file (READ "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" CUSTOM_CONTENT)
 789
 790   set (CUSTOM_CONTENT "${CUSTOM_CONTENT} ${ADDITIONAL_CUSTOM_CONTENT}")
 791
 792   file (WRITE "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" "${CUSTOM_CONTENT}")
 793 else()
 794   OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.${SCRIPT_EXT}.main" "custom.${SCRIPT_EXT}" "custom.${SCRIPT_EXT}" "${INSTALL_DIR_SCRIPT}")
 795 endif()
 796
 797 # write current custom.bat/sh (for install directory)
 798 set (SUB_CUSTOM_BUILD_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.install.${SCRIPT_EXT}")
 799 OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.install.${SCRIPT_EXT}.in" "${SUB_CUSTOM_BUILD_NAME}" "${SUB_CUSTOM_NAME}" "${INSTALL_DIR_SCRIPT}")
 800
 801 # write current custom.bat/sh (for build directory)
 802 OCCT_CONFIGURE ("adm/templates/custom.build.${SCRIPT_EXT}.in" "${SUB_CUSTOM_NAME}")
 803
 804 if (BUILD_MODULE_MfcSamples)
 805   OCCT_INSTALL_FILE_OR_DIR ("adm/templates/sample.bat" "${INSTALL_DIR_SCRIPT}")
 806   OCCT_COPY_FILE_OR_DIR    ("adm/templates/sample.bat" "${CMAKE_BINARY_DIR}")
 807 endif()
 808
 809 # env script for draw in building environment
 810 OCCT_CONFIGURE ("adm/templates/env.${SCRIPT_EXT}.in" "env.${SCRIPT_EXT}")
 811
 812 # install env script
 813 install (FILES "${CMAKE_BINARY_DIR}/env.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SCRIPT}")
 814
 815 # copy DrawAppliInit from OCCT source to build directory
 816 if (NOT EXISTS "${CMAKE_BINARY_DIR}/DrawAppliInit")
 817   OCCT_COPY_FILE_OR_DIR (DrawAppliInit "${CMAKE_BINARY_DIR}")
 818 endif()
 819
 820 # RESOURCES
 821 FILE_TO_LIST ("adm/RESOURCES" RESOURCES)
 822 foreach(RESOURCE ${RESOURCES})
 823   get_filename_component(RESOURCE_FOLDER ${RESOURCE} DIRECTORY)
 824   if(NOT "${RESOURCE_FOLDER}" STREQUAL "")
 825     get_filename_component(RESOURCE_FOLDER ${RESOURCE_FOLDER} NAME)
 826     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR_RESOURCE}/${RESOURCE_FOLDER}")
 827   else()
 828     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR_RESOURCE}")
 829   endif()
 830 endforeach()
 831
 832 # patch installed DrawDefault file if BUILD_SHARED_LIBRARY_NAME_POSTFIX is changed
 833 if (NOT "${BUILD_SHARED_LIBRARY_NAME_POSTFIX}" STREQUAL "")
 834   OCCT_UPDATE_DRAW_DEFAULT_FILE()
 835 endif()
 836
 837 # include patched toolkit projects or original ones
 838 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
 839   OCCT_ADD_SUBDIRECTORY ("src/${BUILD_TOOLKIT}")
 840 endforeach()
 841
 842 if (BUILD_DOC_Overview)
 843   OCCT_ADD_SUBDIRECTORY (dox)
 844 endif()
 845
 846 # patch DRAWEXE
 847 if (MSVC AND 3RDPARTY_DLL_DIRS)
 848   list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
 849   if (${DRAWEXE_INDEX} GREATER -1)
 850     list (REMOVE_DUPLICATES 3RDPARTY_DLL_DIRS)
 851     set (3RDPARTY_DLL_DIRS_FOR_PATH "")
 852
 853     foreach (3RDPARTY_DLL_DIR ${3RDPARTY_DLL_DIRS})
 854       set (3RDPARTY_DLL_DIRS_FOR_PATH "${3RDPARTY_DLL_DIRS_FOR_PATH};${3RDPARTY_DLL_DIR}")
 855     endforeach()
 856
 857     OCCT_MAKE_COMPILER_BITNESS()
 858     set (X_COMPILER_BITNESS "x64")
 859     if ("${COMPILER_BITNESS}" STREQUAL "32")
 860       set (X_COMPILER_BITNESS "Win32")
 861     endif()
 862
 863     OCCT_CONFIGURE ("adm/templates/DRAWEXE.vcxproj.user.in" "${CMAKE_BINARY_DIR}/src/DRAWEXE/DRAWEXE.vcxproj.user")
 864   endif()
 865 endif()
 866
 867 # samples do not support patch usage
 868 if (BUILD_MODULE_MfcSamples)
 869   set (OCCT_ROOT ${CMAKE_SOURCE_DIR})
 870
 871   set (MFC_STANDARD_SAMPLES_DIR ${OCCT_ROOT}/samples/mfc/standard)
 872   set (COMMON_WINMAIN_FILE      ${MFC_STANDARD_SAMPLES_DIR}/Common/Winmain.cpp)
 873
 874   add_subdirectory(samples/mfc/standard/mfcsample)
 875   add_subdirectory(samples/mfc/standard/01_Geometry)
 876   add_subdirectory(samples/mfc/standard/02_Modeling)
 877   add_subdirectory(samples/mfc/standard/03_Viewer2d)
 878   add_subdirectory(samples/mfc/standard/04_Viewer3d)
 879   add_subdirectory(samples/mfc/standard/05_ImportExport)
 880   add_subdirectory(samples/mfc/standard/06_Ocaf)
 881   add_subdirectory(samples/mfc/standard/07_Triangulation)
 882   add_subdirectory(samples/mfc/standard/08_HLR)
 883   add_subdirectory(samples/mfc/standard/09_Animation)
 884   add_subdirectory(samples/mfc/standard/10_Convert)
 885 endif()
 886
 887 if (BUILD_MODULE_UwpSample)
 888   add_subdirectory(samples/xaml)
 889 endif()
 890
 891 # Prepare variables for configuration of OpenCASCADE cmake config file
 892 set (OCCT_MODULES_ENABLED)
 893 set (OCCT_LIBRARIES)
 894 set (SET_OpenCASCADE_MODULES_TOOLKITS "\n# List of available OpenCASCADE libraries for each module\n")
 895 set (OCCT_COMPILE_DEFINITIONS)
 896
 897 foreach (OCCT_TOOLKIT ${BUILD_TOOLKITS})
 898   if (TARGET ${OCCT_TOOLKIT})
 899
 900     # get all libraries
 901     get_target_property (${OCCT_TOOLKIT}_TYPE ${OCCT_TOOLKIT} "TYPE")
 902     if ("${${OCCT_TOOLKIT}_TYPE}" STREQUAL "STATIC_LIBRARY" OR "${${OCCT_TOOLKIT}_TYPE}" STREQUAL "SHARED_LIBRARY" )
 903       list (APPEND OCCT_LIBRARIES ${OCCT_TOOLKIT})
 904
 905       # get all modules
 906       get_target_property (${OCCT_TOOLKIT}_MODULE ${OCCT_TOOLKIT} "MODULE")
 907       list (APPEND OCCT_MODULES_ENABLED ${${OCCT_TOOLKIT}_MODULE})
 908       list (APPEND OpenCASCADE_${${OCCT_TOOLKIT}_MODULE}_TOOLKITS ${OCCT_TOOLKIT})
 909
 910       # get compile definitions of target directory
 911       get_directory_property (COMPILE_DEFINITIONS DIRECTORY "${${OCCT_TOOLKIT}_SOURCE_DIR}" "COMPILE_DEFINITIONS")
 912       list (APPEND OCCT_COMPILE_DEFINITIONS ${COMPILE_DEFINITIONS})
 913     endif()
 914   endif()
 915 endforeach()
 916 list (REMOVE_DUPLICATES OCCT_MODULES_ENABLED)
 917 list (REMOVE_DUPLICATES OCCT_COMPILE_DEFINITIONS)
 918
 919 # export compile definitions and C/C++ flags for each configuration to OpenCASCADE config files
 920 foreach (OCCT_CONFIGURATION ${CMAKE_CONFIGURATION_TYPES})
 921   set (SET_OpenCASCADE_COMPILE_DEFINITIONS)
 922   string (TOUPPER "${OCCT_CONFIGURATION}" OCCT_CONFIGURATION_UPPER)
 923   string (TOLOWER "${OCCT_CONFIGURATION}" OCCT_CONFIGURATION_LOWER)
 924   foreach(COMPILE_DEFINITION ${OCCT_COMPILE_DEFINITIONS})
 925     string(REPLACE "(" "\\(" COMPILE_DEFINITION "${COMPILE_DEFINITION}")
 926     string(REPLACE ")" "\\)" COMPILE_DEFINITION "${COMPILE_DEFINITION}")
 927     set (SET_OpenCASCADE_COMPILE_DEFINITIONS "${SET_OpenCASCADE_COMPILE_DEFINITIONS}set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:${OCCT_CONFIGURATION}>:${COMPILE_DEFINITION}>)\n")
 928   endforeach()
 929   set (SET_OpenCASCADE_CMAKE_C_FLAGS "${CMAKE_C_FLAGS_${OCCT_CONFIGURATION_UPPER}}")
 930   set (SET_OpenCASCADE_CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS_${OCCT_CONFIGURATION_UPPER}}")
 931   configure_file("${CMAKE_SOURCE_DIR}/adm/templates/OpenCASCADECompileDefinitionsAndFlags.cmake.in" "OpenCASCADECompileDefinitionsAndFlags-${OCCT_CONFIGURATION_LOWER}.cmake" @ONLY)
 932 endforeach()
 933 # install OpenCASCADE config file with compile definitions and C/C++ flags ONLY for current configuration
 934 install (CODE "string (TOLOWER \"\${CMAKE_INSTALL_CONFIG_NAME}\" CMAKE_INSTALL_CONFIG_NAME_LOWER)")
 935 install (CODE "configure_file(\"${CMAKE_BINARY_DIR}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" \"${INSTALL_DIR}/${INSTALL_DIR_CMAKE}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" COPYONLY)")
 936
 937 foreach (OCCT_MODULE ${OCCT_MODULES})
 938   if (BUILD_MODULE_${OCCT_MODULE})
 939     set (SET_OpenCASCADE_MODULES_TOOLKITS "${SET_OpenCASCADE_MODULES_TOOLKITS}set (OpenCASCADE_${OCCT_MODULE}_LIBRARIES ${OpenCASCADE_${OCCT_MODULE}_TOOLKITS})\n")
 940   endif()
 941
 942   # sort enabled modules for correct work of OpenCASCADE config file
 943   list(FIND OCCT_MODULES_ENABLED "${OCCT_MODULE}" OCCT_MODULE_INDEX)
 944   if (NOT ${OCCT_MODULE_INDEX} EQUAL -1)
 945     list (APPEND OCCT_MODULES_ENABLED_SORTED ${OCCT_MODULE})
 946   endif()
 947 endforeach()
 948 set (OCCT_MODULES_ENABLED ${OCCT_MODULES_ENABLED_SORTED})
 949
 950 # Add all targets to the build-tree export set
 951 export (TARGETS ${OCCT_LIBRARIES} FILE "${CMAKE_BINARY_DIR}/OpenCASCADETargets.cmake")
 952
 953 # Export the package for use from the build-tree
 954 # (this registers the build-tree with a global CMake-registry)
 955 export(PACKAGE OpenCASCADE)
 956
 957 if (CMAKE_BUILD_TYPE)
 958   set (SET_OpenCASCADE_BUILD_TYPE "set (OpenCASCADE_BUILD_TYPE        \"${CMAKE_BUILD_TYPE}\")")
 959 endif()
 960
 961 if (BUILD_SHARED_LIBS)
 962   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_SHARED_LINKER_FLAGS}\")")
 963 else()
 964   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_STATIC_LINKER_FLAGS}\")")
 965 endif()
 966
 967 if (WIN32)
 968   set (SET_OpenCASCADE_WITH_D3D "set (OpenCASCADE_WITH_D3D       ${USE_D3D})")
 969 endif()
 970 if (APPLE)
 971   set (SET_OpenCASCADE_WITH_GLX "set (OpenCASCADE_WITH_GLX       ${USE_GLX})")
 972 endif()
 973
 974 if (NOT SINGLE_GENERATOR)
 975   OCCT_INSERT_CODE_FOR_TARGET()
 976 endif()
 977
 978 # Configure and install cmake config file
 979 configure_file("${CMAKE_SOURCE_DIR}/adm/templates/OpenCASCADEConfig.cmake.in" "OpenCASCADEConfig.cmake" @ONLY)
 980 install(FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfig.cmake" DESTINATION  "${INSTALL_DIR_CMAKE}")
 981
 982 # Configure cmake version file
 983 include(CMakePackageConfigHelpers)
 984 write_basic_package_version_file( ${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake
 985                                   VERSION ${OCC_VERSION_MAJOR}.${OCC_VERSION_MINOR}.${OCC_VERSION_MAINTENANCE}
 986                                   COMPATIBILITY ExactVersion )
 987
 988 # Install cmake version file
 989 install (FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake" DESTINATION "${INSTALL_DIR_CMAKE}")
 990
 991 # Install the export set for use with the install-tree for each configuration
 992 foreach (OCCT_MODULE ${OCCT_MODULES_ENABLED})
 993   install(EXPORT OpenCASCADE${OCCT_MODULE}Targets DESTINATION "${INSTALL_DIR_CMAKE}")
 994 endforeach()
 995
 996 # Update generated OpenCASCADETargets-*.cmake files
 997 # to have correct paths to libraries depending on the configuration
 998 OCCT_UPDATE_TARGET_FILE ()