tools/CMakeLists.txt

   1 # Caution! Be careful, when increase minimal cmake version:
   2 # using of newer version may leads (by default) to applying
   3 # of some new policies. It may break compilation.
   4 # For canceling of applying new policies use:
   5 # cmake_policy(PUSH) before `cmake_minimum_required`
   6 # and cmake_policy(POP) after.
   7 cmake_minimum_required (VERSION 3.1 FATAL_ERROR)
   8
   9 set (ADDITIONAL_INLCUDE_DIR_DESCR "Additional directory to be added in the projects include section")
  10 if (NOT DEFINED ADDITIONAL_INLCUDE_DIR)
  11   set (ADDITIONAL_INLCUDE_DIR "" CACHE PATH ${ADDITIONAL_INLCUDE_DIR_DESCR})
  12   get_filename_component (ADDITIONAL_INLCUDE_DIR "${ADDITIONAL_INLCUDE_DIR}" ABSOLUTE)
  13 else()
  14   file (TO_CMAKE_PATH "${ADDITIONAL_INLCUDE_DIR}" ADDITIONAL_INLCUDE_DIR)
  15   set (ADDITIONAL_INLCUDE_DIR "${ADDITIONAL_INLCUDE_DIR}" CACHE PATH "${ADDITIONAL_INLCUDE_DIR_DESCR}" FORCE)
  16 endif()
  17
  18 set (ADDITIONAL_DLL_DIR_DESCR "Additional directories that should be included into PATH")
  19 if (NOT DEFINED ADDITIONAL_DLL_DIR)
  20   set (ADDITIONAL_DLL_DIR "" CACHE PATH ${ADDITIONAL_DLL_DIR_DESCR})
  21   get_filename_component (ADDITIONAL_DLL_DIR "${ADDITIONAL_DLL_DIR}" ABSOLUTE)
  22 else()
  23   file (TO_CMAKE_PATH "${ADDITIONAL_DLL_DIR}" ADDITIONAL_DLL_DIR)
  24   set (ADDITIONAL_DLL_DIR "${ADDITIONAL_DLL_DIR}" CACHE PATH "${ADDITIONAL_DLL_DIR_DESCR}" FORCE)
  25 endif()
  26
  27 set (CURRENT_DIR "${CMAKE_SOURCE_DIR}")
  28 set (CMAKE_SOURCE_DIR "${CMAKE_SOURCE_DIR}/.." CACHE INTERNAL "" FORCE)
  29 set (CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/adm/cmake")
  30
  31 set (CMAKE_SUPPRESS_REGENERATION TRUE)
  32
  33 set (CMAKE_CONFIGURATION_TYPES Release Debug RelWithDebInfo CACHE INTERNAL "" FORCE)
  34
  35 # macro: include patched file if it exists
  36 macro (OCCT_INCLUDE_CMAKE_FILE BEING_INCLUDED_FILE)
  37   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake")
  38     include (${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake)
  39   else()
  40     include (${CMAKE_SOURCE_DIR}/${BEING_INCLUDED_FILE}.cmake)
  41   endif()
  42 endmacro()
  43
  44 macro (OCCT_INCLUDE_3RDPARTY_PRODUCT USE_PRODUCT PRODUCT_CONFIG_FILE)
  45   if (${USE_PRODUCT})
  46     OCCT_INCLUDE_CMAKE_FILE ("${PRODUCT_CONFIG_FILE}")
  47   endif (${USE_PRODUCT})
  48 endmacro()
  49
  50 # include variable description
  51 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vardescr")
  52
  53 # set type of OCCT libraries
  54 if (NOT BUILD_LIBRARY_TYPE)
  55   set (BUILD_LIBRARY_TYPE "Shared" CACHE STRING "${BUILD_LIBRARY_TYPE_DESCR}" FORCE)
  56   SET_PROPERTY(CACHE BUILD_LIBRARY_TYPE PROPERTY STRINGS Shared Static)
  57 endif()
  58
  59 if ("${BUILD_LIBRARY_TYPE}" STREQUAL "Shared")
  60   set (BUILD_SHARED_LIBS ON)
  61
  62   if (NOT DEFINED BUILD_SHARED_LIBRARY_NAME_POSTFIX)
  63     set (BUILD_SHARED_LIBRARY_NAME_POSTFIX "" CACHE STRING "${BUILD_SHARED_LIBRARY_NAME_POSTFIX_DESCR}" FORCE)
  64   endif()
  65 else()
  66   unset (BUILD_SHARED_LIBS)
  67   unset (BUILD_SHARED_LIBRARY_NAME_POSTFIX)
  68 endif()
  69
  70 # the name of the project
  71 project (Inspector)
  72
  73 if (WIN32)
  74   add_definitions(-DUNICODE)
  75   add_definitions(-D_UNICODE)
  76 endif()
  77
  78 # include occt macros
  79 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_macros")
  80
  81 # Solution folder property
  82 set_property (GLOBAL PROPERTY USE_FOLDERS ON)
  83
  84 # a single-configuration generator like the Makefile generator defines CMAKE_BUILD_TYPE variable
  85 # check this variable and set if it's required
  86 if (DEFINED CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE) # single-configuration generator.
  87   set (CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel." FORCE)
  88 endif()
  89
  90 if (BUILD_WITH_DEBUG)
  91   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:DEBUG>:OCCT_DEBUG>)
  92 endif()
  93
  94 # install dir of the project
  95 if (NOT DEFINED INSTALL_DIR)
  96   # set default install directory for Windows
  97   if (WIN32 AND NOT DEFINED CMAKE_INSTALL_PREFIX)
  98     set (CMAKE_INSTALL_PREFIX "C:/opencascade-${OCC_VERSION_STRING_EXT}/inspector")
  99   endif()
 100   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}")
 101 else()
 102   file (TO_CMAKE_PATH "${INSTALL_DIR}" INSTALL_DIR)
 103   set (INSTALL_DIR "${INSTALL_DIR}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
 104 endif()
 105
 106 # choose a variant of the layout of the install paths
 107 if (NOT INSTALL_DIR_LAYOUT)
 108   if (WIN32)
 109     set (INSTALL_DIR_LAYOUT "Windows" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
 110   else()
 111     set (INSTALL_DIR_LAYOUT "Unix" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
 112   endif()
 113   SET_PROPERTY(CACHE INSTALL_DIR_LAYOUT PROPERTY STRINGS Windows Unix)
 114 endif()
 115
 116 # check INSTALL_DIR_LAYOUT changes and update INSTALL_DIR_* paths if necessary
 117 if (NOT DEFINED INSTALL_DIR_LAYOUT_PREV)
 118   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
 119 elseif (NOT "${INSTALL_DIR_LAYOUT_PREV}" STREQUAL "${INSTALL_DIR_LAYOUT}")
 120   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
 121   # The structure of install folder should be reset due to changed layout
 122   OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
 123
 124   # Unset INSTALL_DIR_WITH_VERSION on windows
 125   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
 126     OCCT_CHECK_AND_UNSET (INSTALL_DIR_WITH_VERSION)
 127   else()
 128     if (NOT DEFINED INSTALL_DIR_WITH_VERSION)
 129       set (INSTALL_DIR_WITH_VERSION OFF CACHE BOOL "${INSTALL_DIR_WITH_VERSION_DESCR}")
 130     endif()
 131   endif()
 132 endif()
 133
 134 # check CMAKE_INSTALL_PREFIX changes and update INSTALL_DIR if necessary
 135 if (NOT DEFINED CMAKE_INSTALL_PREFIX_PREV)
 136   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
 137 elseif (NOT "${CMAKE_INSTALL_PREFIX_PREV}" STREQUAL "${CMAKE_INSTALL_PREFIX}")
 138   # CMAKE_INSTALL_PREFIX has been changed at previous step
 139   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
 140
 141   # INSTALL_DIR is required to be updated
 142   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
 143 endif()
 144
 145 # check INSTALL_DIR changes and update CMAKE_INSTALL_PREFIX if necessary
 146 if (NOT DEFINED INSTALL_DIR_PREV)
 147   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 148 elseif (NOT "${INSTALL_DIR_PREV}" STREQUAL "${INSTALL_DIR}")
 149   # INSTALL_DIR has been changed at previous step
 150   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 151
 152   # sync CMAKE_INSTALL_PREFIX with INSTALL_DIR
 153   set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 154
 155   # set CMAKE_INSTALL_PREFIX_PREV to avoid the reset of structure of the install folder
 156   set (CMAKE_INSTALL_PREFIX_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 157 endif()
 158
 159 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 160   if (NOT DEFINED INSTALL_DIR_WITH_VERSION_PREV)
 161     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
 162   elseif (NOT "${INSTALL_DIR_WITH_VERSION_PREV}" STREQUAL "${INSTALL_DIR_WITH_VERSION}")
 163     # INSTALL_DIR_WITH_VERSION has been changed at previous step
 164     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
 165
 166     OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
 167   endif()
 168 endif()
 169
 170 # hide CMAKE_INSTALL_PREFIX from a user
 171 set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 172
 173 set (BIN_LETTER "")
 174 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
 175   set (BIN_LETTER "d")
 176 elseif ("${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo")
 177   set (BIN_LETTER "i")
 178 endif()
 179
 180 # Get all used variables: OS_WITH_BIT, COMPILER
 181 OCCT_MAKE_OS_WITH_BITNESS()
 182 OCCT_MAKE_COMPILER_SHORT_NAME()
 183
 184 # do not define INSTALL_DIR_BIN for win.
 185 # Leave library structure for win: <prefix>/win64/vc10/bin(d)
 186 if (NOT DEFINED INSTALL_DIR_BIN)
 187   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 188     set (INSTALL_DIR_BIN "bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
 189   else()
 190     set (INSTALL_DIR_BIN "${OS_WITH_BIT}/${COMPILER}/bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
 191   endif()
 192 endif()
 193
 194 # define folder containing all shell/batch scripts
 195 if (NOT DEFINED INSTALL_DIR_SCRIPT)
 196   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 197     set (INSTALL_DIR_SCRIPT "${INSTALL_DIR_BIN}" CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
 198   else()
 199     set (INSTALL_DIR_SCRIPT "." CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
 200   endif()
 201 endif()
 202
 203 # place the libraries to <prefix>/lib folder for unix and leave old structure for windows
 204 if (NOT DEFINED INSTALL_DIR_LIB)
 205   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 206     set (INSTALL_DIR_LIB "lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
 207   else()
 208     set (INSTALL_DIR_LIB "${OS_WITH_BIT}/${COMPILER}/lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
 209   endif()
 210 endif()
 211
 212 # OCCT headers: <prefix>/inc for windows,
 213 #               <prefix>/include/opencascade-7.0.0 for unix
 214 if (NOT DEFINED INSTALL_DIR_INCLUDE)
 215   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 216     set (INSTALL_DIR_INCLUDE "include/opencascade" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
 217     if (INSTALL_DIR_WITH_VERSION)
 218       set (INSTALL_DIR_INCLUDE "include/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}" FORCE)
 219     endif()
 220   else()
 221     set (INSTALL_DIR_INCLUDE "inc" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
 222   endif()
 223 endif()
 224
 225 # OCCT resources: <prefix>/src for windows,
 226 #                 <prefix>/share/opencascade-7.0.0/resources for unix
 227 if (NOT DEFINED INSTALL_DIR_RESOURCE)
 228   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 229     set (INSTALL_DIR_RESOURCE "share/opencascade/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
 230     if (INSTALL_DIR_WITH_VERSION)
 231       set (INSTALL_DIR_RESOURCE "share/opencascade-${OCC_VERSION_STRING_EXT}/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}" FORCE)
 232     endif()
 233   else()
 234     set (INSTALL_DIR_RESOURCE "src" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
 235   endif()
 236 endif()
 237
 238 # OCCT data
 239 if (NOT DEFINED INSTALL_DIR_DATA)
 240   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 241     set (INSTALL_DIR_DATA "share/opencascade/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
 242     if (INSTALL_DIR_WITH_VERSION)
 243       set (INSTALL_DIR_DATA "share/opencascade-${OCC_VERSION_STRING_EXT}/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}" FORCE)
 244     endif()
 245   else()
 246     set (INSTALL_DIR_DATA "data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
 247   endif()
 248 endif()
 249
 250 # include the patched or original list of definitions and flags
 251 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_defs_flags")
 252
 253 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/3rdparty_macro")
 254
 255 if (NOT DEFINED 3RDPARTY_DIR)
 256   set (3RDPARTY_DIR "" CACHE PATH ${3RDPARTY_DIR_DESCR})
 257   get_filename_component (3RDPARTY_DIR "${3RDPARTY_DIR}" ABSOLUTE)
 258 else()
 259   file (TO_CMAKE_PATH "${3RDPARTY_DIR}" 3RDPARTY_DIR)
 260   set (3RDPARTY_DIR "${3RDPARTY_DIR}" CACHE PATH "${3RDPARTY_DIR_DESCR}" FORCE)
 261 endif()
 262
 263 find_package(OpenCASCADE QUIET PATHS "${OpenCASCADE_DIR}" "${OpenCASCADE_INSTALL_PREFIX}" NO_DEFAULT_PATH)
 264 # include OCCT headers
 265 include_directories ("${OpenCASCADE_INCLUDE_DIR}")
 266
 267 if (NOT OpenCASCADE_FOUND)
 268   message (FATAL_ERROR "could not find OpenCASCADE, please set OpenCASCADE_DIR variable" )
 269 else()
 270   set (OpenCASCADE_DIR "${OpenCASCADE_INSTALL_PREFIX}" CACHE PATH "OpenCASCADE directory" FORCE)
 271   message (STATUS "Using OpenCASCADE from \"${OpenCASCADE_DIR}\"" )
 272 endif()
 273
 274 set (USE_TCL "${OpenCASCADE_WITH_TCL}")
 275 set (USE_FREETYPE "${OpenCASCADE_WITH_FREETYPE}")
 276 set (USE_FREEIMAGE "${OpenCASCADE_WITH_FREEIMAGE}")
 277 set (USE_GL2PS "${OpenCASCADE_WITH_GL2PS}")
 278 set (USE_TBB "${OpenCASCADE_WITH_TBB}")
 279 set (USE_VTK "${OpenCASCADE_WITH_VTK}")
 280 set (USE_FFMPEG "${OpenCASCADE_WITH_FFMPEG}")
 281 set (USE_GLES2 "${OpenCASCADE_WITH_GLES2}")
 282 set (USE_GLX "${OpenCASCADE_WITH_GLX}")
 283
 284
 285 # define CSF variable
 286 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_csf")
 287
 288 # custom definitions (CMakeConfig of OCCT)
 289 OCCT_INCLUDE_3RDPARTY_PRODUCT (USE_TCL "adm/cmake/tcl")
 290 OCCT_INCLUDE_3RDPARTY_PRODUCT (USE_FREETYPE "adm/cmake/freetype")
 291 OCCT_INCLUDE_3RDPARTY_PRODUCT (USE_FREEIMAGE "adm/cmake/freeimage")
 292 OCCT_INCLUDE_3RDPARTY_PRODUCT (USE_GL2PS "adm/cmake/gl2ps")
 293 OCCT_INCLUDE_3RDPARTY_PRODUCT (USE_TBB "adm/cmake/tbb")
 294 OCCT_INCLUDE_3RDPARTY_PRODUCT (USE_VTK "adm/cmake/vtk")
 295 OCCT_INCLUDE_3RDPARTY_PRODUCT (USE_FFMPEG "adm/cmake/ffmpeg")
 296 OCCT_INCLUDE_3RDPARTY_PRODUCT (USE_GLES2 "adm/cmake/egl")
 297 OCCT_INCLUDE_3RDPARTY_PRODUCT (USE_GLES2 "adm/cmake/gles2")
 298 OCCT_INCLUDE_3RDPARTY_PRODUCT (USE_GLX "adm/cmake/glx")
 299
 300
 301 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/qt")
 302 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_macros")
 303
 304 #include (${CMAKE_SOURCE_DIR}/adm/cmake/3rdparty.cmake)
 305
 306 set (3RDPARTY_DLL_DEB_PATH "${3RDPARTY_DLL_PATH}")
 307
 308 # build directories
 309 if (SINGLE_GENERATOR)
 310   set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
 311   set (CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
 312   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
 313   if (WIN32)
 314     set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
 315   endif()
 316 endif()
 317
 318 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
 319 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
 320 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
 321
 322 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
 323 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
 324 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
 325
 326 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
 327 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
 328 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
 329
 330 if (WIN32)
 331   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE        "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
 332   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
 333   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG          "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
 334 endif()
 335
 336 # OCCT tools
 337 # include the patched or original list of tools
 338 # list <TOOLNAME>_TOOLKITS is created foreach tool and contains its toolkits
 339 # list <OCCT_TOOLS> will contain all tools
 340 #if (BUILD_Inspector)
 341   OCCT_MODULES_AND_TOOLKITS (TOOLS "TOOL_TOOLKITS" OCCT_TOOLS)
 342   foreach (OCCT_TOOL ${OCCT_TOOLS})
 343     list (APPEND BUILD_TOOL_TOOLKITS ${${OCCT_TOOL}_TOOL_TOOLKITS})
 344   endforeach()
 345
 346   # collect all the headers to <binary dir>/inc/inspector folder
 347   string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
 348   message (STATUS "\nInfo: \(${CURRENT_TIME}\) Start collecting all OCCT tool header files into ${CMAKE_BINARY_DIR}/inc/inspector ...")
 349   COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}" "${BUILD_TOOL_TOOLKITS}" "${CMAKE_SOURCE_DIR}/tools" "${INSTALL_DIR_INCLUDE}/inspector")
 350 #endif()
 351
 352 # include <cmake binary folder>/inc
 353 include_directories (${CMAKE_BINARY_DIR}/${INSTALL_DIR_INCLUDE})
 354
 355 include_directories (${ADDITIONAL_INLCUDE_DIR})
 356
 357 if (3RDPARTY_INCLUDE_DIRS)
 358   list (REMOVE_DUPLICATES 3RDPARTY_INCLUDE_DIRS)
 359   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_INCLUDE_DIRS_WITH_ENDS "${3RDPARTY_INCLUDE_DIRS}")
 360   message (STATUS "Info: The directories of 3rdparty headers: \n\t${3RDPARTY_INCLUDE_DIRS_WITH_ENDS}")
 361   include_directories (${3RDPARTY_INCLUDE_DIRS})
 362 endif()
 363
 364 if (3RDPARTY_LIBRARY_DIRS)
 365   list (REMOVE_DUPLICATES 3RDPARTY_LIBRARY_DIRS)
 366   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_LIBRARY_DIRS_WITH_ENDS "${3RDPARTY_LIBRARY_DIRS}")
 367   message (STATUS "Info: The directories of 3rdparty libraries: \n\t${3RDPARTY_LIBRARY_DIRS_WITH_ENDS}")
 368   link_directories (${3RDPARTY_LIBRARY_DIRS})
 369 endif()
 370
 371 # include patched toolkit projects or original ones
 372 if (BUILD_TOOL_TOOLKITS)
 373   foreach (BUILD_TOOL_TOOLKIT ${BUILD_TOOL_TOOLKITS})
 374     OCCT_ADD_SUBDIRECTORY ("tools/${BUILD_TOOL_TOOLKIT}")
 375   endforeach()
 376 endif()
 377
 378 message (STATUS "Info: \(${CURRENT_TIME}\) OCCT toolkits processed")
 379
 380 OCCT_MODULES_AND_TOOLKITS (SAMPLES "SAMPLES_TOOLKITS" OCCT_SAMPLES)
 381
 382 # patch TInspectorEXE
 383 if (MSVC AND 3RDPARTY_DLL_DIRS)
 384   list (REMOVE_DUPLICATES 3RDPARTY_DLL_DIRS)
 385   set (3RDPARTY_DLL_DIRS_FOR_PATH "")
 386
 387   foreach (3RDPARTY_DLL_DIR ${3RDPARTY_DLL_DIRS})
 388     set (3RDPARTY_DLL_DIRS_FOR_PATH "${3RDPARTY_DLL_DIRS_FOR_PATH};${3RDPARTY_DLL_DIR}")
 389   endforeach()
 390
 391   if (ADDITIONAL_DLL_DIR)
 392     foreach (3RDPARTY_DLL_DIR ${ADDITIONAL_DLL_DIR})
 393       set (3RDPARTY_DLL_DIRS_FOR_PATH "${3RDPARTY_DLL_DIRS_FOR_PATH};${3RDPARTY_DLL_DIR}")
 394     endforeach()
 395   endif (ADDITIONAL_DLL_DIR)
 396
 397   OCCT_MAKE_COMPILER_BITNESS()
 398   set (X_COMPILER_BITNESS "x64")
 399   if ("${COMPILER_BITNESS}" STREQUAL "32")
 400     set (X_COMPILER_BITNESS "Win32")
 401   endif()
 402
 403   # patch TInspectorEXE
 404   OCCT_CONFIGURE ("adm/templates/TInspectorEXE.vcxproj.user.in" "${CMAKE_BINARY_DIR}/TInspectorEXE/TInspectorEXE.vcxproj.user")
 405 endif()
 406
 407 message (STATUS "Info: \(${CURRENT_TIME}\) Inspector configuration files prepared")