0031225: Visualization, TKOpenGl - support cubemap for environment texture within...
[occt.git] / src / Shaders / RaytraceBase.fs
1 #ifdef ADAPTIVE_SAMPLING
2   #extension GL_ARB_shader_image_load_store : require
3 #endif
4 #ifdef ADAPTIVE_SAMPLING_ATOMIC
5   #extension GL_NV_shader_atomic_float : require
6 #endif
7
8 #ifdef USE_TEXTURES
9   #extension GL_ARB_bindless_texture : require
10 #endif
11
12 //! Normalized pixel coordinates.
13 in vec2 vPixel;
14
15 //! Sub-pixel offset in X direction for FSAA.
16 uniform float uOffsetX = 0.f;
17 //! Sub-pixel offset in Y direction for FSAA.
18 uniform float uOffsetY = 0.f;
19
20 //! Origin of viewing ray in left-top corner.
21 uniform vec3 uOriginLT;
22 //! Origin of viewing ray in left-bottom corner.
23 uniform vec3 uOriginLB;
24 //! Origin of viewing ray in right-top corner.
25 uniform vec3 uOriginRT;
26 //! Origin of viewing ray in right-bottom corner.
27 uniform vec3 uOriginRB;
28
29 //! Width of the rendering window.
30 uniform int uWinSizeX;
31 //! Height of the rendering window.
32 uniform int uWinSizeY;
33
34 //! Direction of viewing ray in left-top corner.
35 uniform vec3 uDirectLT;
36 //! Direction of viewing ray in left-bottom corner.
37 uniform vec3 uDirectLB;
38 //! Direction of viewing ray in right-top corner.
39 uniform vec3 uDirectRT;
40 //! Direction of viewing ray in right-bottom corner.
41 uniform vec3 uDirectRB;
42
43 //! Inverse model-view-projection matrix.
44 uniform mat4 uUnviewMat;
45
46 //! Model-view-projection matrix.
47 uniform mat4 uViewMat;
48
49 //! Texture buffer of data records of bottom-level BVH nodes.
50 uniform isamplerBuffer uSceneNodeInfoTexture;
51 //! Texture buffer of minimum points of bottom-level BVH nodes.
52 uniform samplerBuffer uSceneMinPointTexture;
53 //! Texture buffer of maximum points of bottom-level BVH nodes.
54 uniform samplerBuffer uSceneMaxPointTexture;
55 //! Texture buffer of transformations of high-level BVH nodes.
56 uniform samplerBuffer uSceneTransformTexture;
57
58 //! Texture buffer of vertex coords.
59 uniform samplerBuffer uGeometryVertexTexture;
60 //! Texture buffer of vertex normals.
61 uniform samplerBuffer uGeometryNormalTexture;
62 #ifdef USE_TEXTURES
63   //! Texture buffer of per-vertex UV-coordinates.
64   uniform samplerBuffer uGeometryTexCrdTexture;
65 #endif
66 //! Texture buffer of triangle indices.
67 uniform isamplerBuffer uGeometryTriangTexture;
68
69 //! Texture buffer of material properties.
70 uniform samplerBuffer uRaytraceMaterialTexture;
71 //! Texture buffer of light source properties.
72 uniform samplerBuffer uRaytraceLightSrcTexture;
73
74 #ifdef BACKGROUND_CUBEMAP
75   //! Environment cubemap texture.
76   uniform samplerCube uEnvMapTexture;
77   //! Coefficient of Y controlling horizontal flip of cubemap
78   uniform int uYCoeff;
79   //! Coefficient of Z controlling vertical flip of cubemap
80   uniform int uZCoeff;
81 #else
82   //! Environment map texture.
83   uniform sampler2D uEnvMapTexture;
84 #endif
85
86 //! Total number of light sources.
87 uniform int uLightCount;
88 //! Intensity of global ambient light.
89 uniform vec4 uGlobalAmbient;
90
91 //! Enables/disables hard shadows.
92 uniform int uShadowsEnabled;
93 //! Enables/disables specular reflections.
94 uniform int uReflectEnabled;
95 //! Enables/disables environment map lighting.
96 uniform int uEnvMapEnabled;
97 //! Enables/disables environment map background.
98 uniform int uEnvMapForBack;
99
100 //! Radius of bounding sphere of the scene.
101 uniform float uSceneRadius;
102 //! Scene epsilon to prevent self-intersections.
103 uniform float uSceneEpsilon;
104
105 #ifdef USE_TEXTURES
106   //! Unique 64-bit handles of OpenGL textures.
107   uniform uvec2 uTextureSamplers[MAX_TEX_NUMBER];
108 #endif
109
110 #ifdef ADAPTIVE_SAMPLING
111   //! OpenGL image used for accumulating rendering result.
112   volatile restrict layout(r32f) uniform image2D  uRenderImage;
113
114 #ifdef ADAPTIVE_SAMPLING_ATOMIC
115   //! OpenGL image storing offsets of sampled pixels blocks.
116   coherent restrict layout(rg32i) uniform iimage2D uOffsetImage;
117 #else
118   //! OpenGL image defining per-tile amount of samples.
119   volatile restrict layout(r32i) uniform iimage2D uTilesImage;
120 #endif
121
122   //! Screen space tile size.
123   uniform ivec2 uTileSize;
124 #endif
125
126 //! Top color of gradient background.
127 uniform vec4 uBackColorTop = vec4 (0.0);
128 //! Bottom color of gradient background.
129 uniform vec4 uBackColorBot = vec4 (0.0);
130
131 //! Aperture radius of camera used for depth-of-field
132 uniform float uApertureRadius = 0.f;
133
134 //! Focal distance of camera used for depth-of field
135 uniform float uFocalPlaneDist = 10.f;
136
137 //! Camera position used for projective mode
138 uniform vec3 uEyeOrig;
139
140 //! Camera view direction used for projective mode
141 uniform vec3 uEyeView;
142
143 //! Camera's screen vertical direction used for projective mode
144 uniform vec3 uEyeVert;
145
146 //! Camera's screen horizontal direction used for projective mode
147 uniform vec3 uEyeSide;
148
149 //! Camera's screen size used for projective mode
150 uniform vec2 uEyeSize;
151
152 /////////////////////////////////////////////////////////////////////////////////////////
153 // Specific data types
154
155 //! Stores ray parameters.
156 struct SRay
157 {
158   vec3 Origin;
159
160   vec3 Direct;
161 };
162
163 //! Stores intersection parameters.
164 struct SIntersect
165 {
166   float Time;
167
168   vec2 UV;
169
170   vec3 Normal;
171 };
172
173 /////////////////////////////////////////////////////////////////////////////////////////
174 // Some useful constants
175
176 #define MAXFLOAT 1e15f
177
178 #define SMALL vec3 (exp2 (-80.0f))
179
180 #define ZERO vec3 (0.0f, 0.0f, 0.0f)
181 #define UNIT vec3 (1.0f, 1.0f, 1.0f)
182
183 #define AXIS_X vec3 (1.0f, 0.0f, 0.0f)
184 #define AXIS_Y vec3 (0.0f, 1.0f, 0.0f)
185 #define AXIS_Z vec3 (0.0f, 0.0f, 1.0f)
186
187 #define M_PI   3.141592653f
188 #define M_2_PI 6.283185307f
189 #define M_PI_2 1.570796327f
190
191 #define LUMA vec3 (0.2126f, 0.7152f, 0.0722f)
192
193 // =======================================================================
194 // function : MatrixRowMultiplyDir
195 // purpose  : Multiplies a vector by matrix
196 // =======================================================================
197 vec3 MatrixRowMultiplyDir (in vec3 v,
198                            in vec4 m0,
199                            in vec4 m1,
200                            in vec4 m2)
201 {
202   return vec3 (dot (m0.xyz, v),
203                dot (m1.xyz, v),
204                dot (m2.xyz, v));
205 }
206
207 //! 32-bit state of random number generator.
208 uint RandState;
209
210 // =======================================================================
211 // function : SeedRand
212 // purpose  : Applies hash function by Thomas Wang to randomize seeds
213 //            (see http://www.burtleburtle.net/bob/hash/integer.html)
214 // =======================================================================
215 void SeedRand (in int theSeed, in int theSizeX, in int theRadius)
216 {
217   RandState = uint (int (gl_FragCoord.y) / theRadius * theSizeX + int (gl_FragCoord.x) / theRadius + theSeed);
218
219   RandState = (RandState + 0x479ab41du) + (RandState <<  8);
220   RandState = (RandState ^ 0xe4aa10ceu) ^ (RandState >>  5);
221   RandState = (RandState + 0x9942f0a6u) - (RandState << 14);
222   RandState = (RandState ^ 0x5aedd67du) ^ (RandState >>  3);
223   RandState = (RandState + 0x17bea992u) + (RandState <<  7);
224 }
225
226 // =======================================================================
227 // function : RandInt
228 // purpose  : Generates integer using Xorshift algorithm by G. Marsaglia
229 // =======================================================================
230 uint RandInt()
231 {
232   RandState ^= (RandState << 13);
233   RandState ^= (RandState >> 17);
234   RandState ^= (RandState <<  5);
235
236   return RandState;
237 }
238
239 // =======================================================================
240 // function : RandFloat
241 // purpose  : Generates a random float in 0 <= x < 1 range
242 // =======================================================================
243 float RandFloat()
244 {
245   return float (RandInt()) * (1.f / 4294967296.f);
246 }
247
248 // =======================================================================
249 // function : MatrixColMultiplyPnt
250 // purpose  : Multiplies a vector by matrix
251 // =======================================================================
252 vec3 MatrixColMultiplyPnt (in vec3 v,
253                            in vec4 m0,
254                            in vec4 m1,
255                            in vec4 m2,
256                            in vec4 m3)
257 {
258   return vec3 (m0.x * v.x + m1.x * v.y + m2.x * v.z + m3.x,
259                m0.y * v.x + m1.y * v.y + m2.y * v.z + m3.y,
260                m0.z * v.x + m1.z * v.y + m2.z * v.z + m3.z);
261 }
262
263 // =======================================================================
264 // function : MatrixColMultiplyDir
265 // purpose  : Multiplies a vector by matrix
266 // =======================================================================
267 vec3 MatrixColMultiplyDir (in vec3 v,
268                            in vec4 m0,
269                            in vec4 m1,
270                            in vec4 m2)
271 {
272   return vec3 (m0.x * v.x + m1.x * v.y + m2.x * v.z,
273                m0.y * v.x + m1.y * v.y + m2.y * v.z,
274                m0.z * v.x + m1.z * v.y + m2.z * v.z);
275 }
276
277 //=======================================================================
278 // function : InverseDirection
279 // purpose  : Returns safely inverted direction of the given one
280 //=======================================================================
281 vec3 InverseDirection (in vec3 theInput)
282 {
283   vec3 anInverse = 1.f / max (abs (theInput), SMALL);
284
285   return mix (-anInverse, anInverse, step (ZERO, theInput));
286 }
287
288 //=======================================================================
289 // function : BackgroundColor
290 // purpose  : Returns color of gradient background
291 //=======================================================================
292 vec4 BackgroundColor()
293 {
294 #ifdef ADAPTIVE_SAMPLING_ATOMIC
295
296   ivec2 aFragCoord = ivec2 (gl_FragCoord.xy);
297
298   ivec2 aTileXY = imageLoad (uOffsetImage, aFragCoord / uTileSize).xy * uTileSize;
299
300   aTileXY.y += aFragCoord.y % min (uWinSizeY - aTileXY.y, uTileSize.y);
301
302   return mix (uBackColorBot, uBackColorTop, float (aTileXY.y) / uWinSizeY);
303
304 #else
305
306   return mix (uBackColorBot, uBackColorTop, vPixel.y);
307
308 #endif
309 }
310
311 /////////////////////////////////////////////////////////////////////////////////////////
312 // Functions for compute ray-object intersection
313
314 //=======================================================================
315 // function : sampleUniformDisk
316 // purpose  :
317 //=======================================================================
318 vec2 sampleUniformDisk ()
319 {
320   vec2 aPoint;
321
322   float aKsi1 = 2.f * RandFloat () - 1.f;
323   float aKsi2 = 2.f * RandFloat () - 1.f;
324
325   if (aKsi1 > -aKsi2)
326   {
327     if (aKsi1 > aKsi2)
328       aPoint = vec2 (aKsi1, (M_PI / 4.f) * (0.f + aKsi2 / aKsi1));
329     else
330       aPoint = vec2 (aKsi2, (M_PI / 4.f) * (2.f - aKsi1 / aKsi2));
331   }
332   else
333   {
334     if (aKsi1 < aKsi2)
335       aPoint = vec2 (-aKsi1, (M_PI / 4.f) * (4.f + aKsi2 / aKsi1));
336     else
337       aPoint = vec2 (-aKsi2, (M_PI / 4.f) * (6.f - aKsi1 / aKsi2));
338   }
339
340   return vec2 (sin (aPoint.y), cos (aPoint.y)) * aPoint.x;
341 }
342
343 // =======================================================================
344 // function : GenerateRay
345 // purpose  :
346 // =======================================================================
347 SRay GenerateRay (in vec2 thePixel)
348 {
349 #ifndef DEPTH_OF_FIELD
350
351   vec3 aP0 = mix (uOriginLB, uOriginRB, thePixel.x);
352   vec3 aP1 = mix (uOriginLT, uOriginRT, thePixel.x);
353
354   vec3 aD0 = mix (uDirectLB, uDirectRB, thePixel.x);
355   vec3 aD1 = mix (uDirectLT, uDirectRT, thePixel.x);
356
357   vec3 aDirection = normalize (mix (aD0, aD1, thePixel.y));
358
359   return SRay (mix (aP0, aP1, thePixel.y), aDirection);
360
361 #else
362
363   vec2 aPixel = uEyeSize * (thePixel - vec2 (0.5f)) * 2.f;
364
365   vec2 aAperturePnt = sampleUniformDisk () * uApertureRadius;
366
367   vec3 aLocalDir = normalize (vec3 (
368     aPixel * uFocalPlaneDist - aAperturePnt, uFocalPlaneDist));
369
370   vec3 aOrigin = uEyeOrig +
371                  uEyeSide * aAperturePnt.x +
372                  uEyeVert * aAperturePnt.y;
373
374   vec3 aDirect = uEyeView * aLocalDir.z +
375                  uEyeSide * aLocalDir.x +
376                  uEyeVert * aLocalDir.y;
377
378   return SRay (aOrigin, aDirect);
379
380 #endif
381 }
382
383 // =======================================================================
384 // function : IntersectSphere
385 // purpose  : Computes ray-sphere intersection
386 // =======================================================================
387 float IntersectSphere (in SRay theRay, in float theRadius)
388 {
389   float aDdotD = dot (theRay.Direct, theRay.Direct);
390   float aDdotO = dot (theRay.Direct, theRay.Origin);
391   float aOdotO = dot (theRay.Origin, theRay.Origin);
392
393   float aD = aDdotO * aDdotO - aDdotD * (aOdotO - theRadius * theRadius);
394
395   if (aD > 0.0f)
396   {
397     float aTime = (sqrt (aD) - aDdotO) * (1.0f / aDdotD);
398     
399     return aTime > 0.0f ? aTime : MAXFLOAT;
400   }
401
402   return MAXFLOAT;
403 }
404
405 // =======================================================================
406 // function : IntersectTriangle
407 // purpose  : Computes ray-triangle intersection (branchless version)
408 // =======================================================================
409 void IntersectTriangle (in SRay theRay,
410                         in vec3 thePnt0,
411                         in vec3 thePnt1,
412                         in vec3 thePnt2,
413                         out vec3 theUVT,
414                         out vec3 theNorm)
415 {
416   vec3 aToTrg = thePnt0 - theRay.Origin;
417
418   vec3 aEdge0 = thePnt1 - thePnt0;
419   vec3 aEdge1 = thePnt0 - thePnt2;
420
421   theNorm = cross (aEdge1, aEdge0);
422
423   vec3 theVect = cross (theRay.Direct, aToTrg);
424
425   theUVT = vec3 (dot (theNorm, aToTrg),
426                  dot (theVect, aEdge1),
427                  dot (theVect, aEdge0)) * (1.f / dot (theNorm, theRay.Direct));
428
429   theUVT.x = any (lessThan (theUVT, ZERO)) || (theUVT.y + theUVT.z) > 1.f ? MAXFLOAT : theUVT.x;
430 }
431
432 #define EMPTY_ROOT ivec4(0)
433
434 //! Utility structure containing information about
435 //! currently traversing sub-tree of scene's BVH.
436 struct SSubTree
437 {
438   //! Transformed ray.
439   SRay  TrsfRay;
440
441   //! Inversed ray direction.
442   vec3  Inverse;
443
444   //! Parameters of sub-root node.
445   ivec4 SubData;
446 };
447
448 #define MATERIAL_AMBN(index) (19 * index + 0)
449 #define MATERIAL_DIFF(index) (19 * index + 1)
450 #define MATERIAL_SPEC(index) (19 * index + 2)
451 #define MATERIAL_EMIS(index) (19 * index + 3)
452 #define MATERIAL_REFL(index) (19 * index + 4)
453 #define MATERIAL_REFR(index) (19 * index + 5)
454 #define MATERIAL_TRAN(index) (19 * index + 6)
455 #define MATERIAL_TRS1(index) (19 * index + 7)
456 #define MATERIAL_TRS2(index) (19 * index + 8)
457 #define MATERIAL_TRS3(index) (19 * index + 9)
458
459 #define TRS_OFFSET(treelet) treelet.SubData.x
460 #define BVH_OFFSET(treelet) treelet.SubData.y
461 #define VRT_OFFSET(treelet) treelet.SubData.z
462 #define TRG_OFFSET(treelet) treelet.SubData.w
463
464 //! Identifies the absence of intersection.
465 #define INALID_HIT ivec4 (-1)
466
467 //! Global stack shared between traversal functions.
468 int Stack[STACK_SIZE];
469
470 // =======================================================================
471 // function : pop
472 // purpose  :
473 // =======================================================================
474 int pop (inout int theHead)
475 {
476   int aData = Stack[theHead];
477
478   int aMask = aData >> 26;
479   int aNode = aMask & 0x3;
480
481   aMask >>= 2;
482
483   if ((aMask & 0x3) == aNode)
484   {
485     --theHead;
486   }
487   else
488   {
489     aMask |= (aMask << 2) & 0x30;
490
491     Stack[theHead] = (aData & 0x03FFFFFF) | (aMask << 26);
492   }
493
494   return (aData & 0x03FFFFFF) + aNode;
495 }
496
497 // =======================================================================
498 // function : SceneNearestHit
499 // purpose  : Finds intersection with nearest scene triangle
500 // =======================================================================
501 ivec4 SceneNearestHit (in SRay theRay, in vec3 theInverse, inout SIntersect theHit, out int theTrsfId)
502 {
503   ivec4 aTriIndex = INALID_HIT;
504
505   int aNode =  0; // node to traverse
506   int aHead = -1; // pointer of stack
507   int aStop = -1; // BVH level switch
508
509   SSubTree aSubTree = SSubTree (theRay, theInverse, EMPTY_ROOT);
510
511   for (bool toContinue = true; toContinue; /* none */)
512   {
513     ivec4 aData = texelFetch (uSceneNodeInfoTexture, aNode);
514
515     if (aData.x == 0) // if inner node
516     {
517       aData.y += BVH_OFFSET (aSubTree);
518
519       vec4 aHitTimes = vec4 (MAXFLOAT,
520                              MAXFLOAT,
521                              MAXFLOAT,
522                              MAXFLOAT);
523
524       vec3 aRayOriginInverse = -aSubTree.TrsfRay.Origin * aSubTree.Inverse;
525
526       vec3 aNodeMin0 = texelFetch (uSceneMinPointTexture, aData.y +                0).xyz * aSubTree.Inverse + aRayOriginInverse;
527       vec3 aNodeMin1 = texelFetch (uSceneMinPointTexture, aData.y +                1).xyz * aSubTree.Inverse + aRayOriginInverse;
528       vec3 aNodeMin2 = texelFetch (uSceneMinPointTexture, aData.y + min (2, aData.z)).xyz * aSubTree.Inverse + aRayOriginInverse;
529       vec3 aNodeMin3 = texelFetch (uSceneMinPointTexture, aData.y + min (3, aData.z)).xyz * aSubTree.Inverse + aRayOriginInverse;
530       vec3 aNodeMax0 = texelFetch (uSceneMaxPointTexture, aData.y +                0).xyz * aSubTree.Inverse + aRayOriginInverse;
531       vec3 aNodeMax1 = texelFetch (uSceneMaxPointTexture, aData.y +                1).xyz * aSubTree.Inverse + aRayOriginInverse;
532       vec3 aNodeMax2 = texelFetch (uSceneMaxPointTexture, aData.y + min (2, aData.z)).xyz * aSubTree.Inverse + aRayOriginInverse;
533       vec3 aNodeMax3 = texelFetch (uSceneMaxPointTexture, aData.y + min (3, aData.z)).xyz * aSubTree.Inverse + aRayOriginInverse;
534
535       vec3 aTimeMax = max (aNodeMin0, aNodeMax0);
536       vec3 aTimeMin = min (aNodeMin0, aNodeMax0);
537
538       float aTimeLeave = min (aTimeMax.x, min (aTimeMax.y, aTimeMax.z));
539       float aTimeEnter = max (aTimeMin.x, max (aTimeMin.y, aTimeMin.z));
540
541       aHitTimes.x = (aTimeEnter <= aTimeLeave && aTimeEnter <= theHit.Time && aTimeLeave >= 0.f) ? aTimeEnter : MAXFLOAT;
542
543       aTimeMax = max (aNodeMin1, aNodeMax1);
544       aTimeMin = min (aNodeMin1, aNodeMax1);
545
546       aTimeLeave = min (aTimeMax.x, min (aTimeMax.y, aTimeMax.z));
547       aTimeEnter = max (aTimeMin.x, max (aTimeMin.y, aTimeMin.z));
548
549       aHitTimes.y = (aTimeEnter <= aTimeLeave && aTimeEnter <= theHit.Time && aTimeLeave >= 0.f) ? aTimeEnter : MAXFLOAT;
550
551       aTimeMax = max (aNodeMin2, aNodeMax2);
552       aTimeMin = min (aNodeMin2, aNodeMax2);
553
554       aTimeLeave = min (aTimeMax.x, min (aTimeMax.y, aTimeMax.z));
555       aTimeEnter = max (aTimeMin.x, max (aTimeMin.y, aTimeMin.z));
556
557       aHitTimes.z = (aTimeEnter <= aTimeLeave && aTimeEnter <= theHit.Time && aTimeLeave >= 0.f && aData.z > 1) ? aTimeEnter : MAXFLOAT;
558
559       aTimeMax = max (aNodeMin3, aNodeMax3);
560       aTimeMin = min (aNodeMin3, aNodeMax3);
561
562       aTimeLeave = min (aTimeMax.x, min (aTimeMax.y, aTimeMax.z));
563       aTimeEnter = max (aTimeMin.x, max (aTimeMin.y, aTimeMin.z));
564
565       aHitTimes.w = (aTimeEnter <= aTimeLeave && aTimeEnter <= theHit.Time && aTimeLeave >= 0.f && aData.z > 2) ? aTimeEnter : MAXFLOAT;
566
567       ivec4 aChildren = ivec4 (0, 1, 2, 3);
568
569       aChildren.xy = aHitTimes.y < aHitTimes.x ? aChildren.yx : aChildren.xy;
570       aHitTimes.xy = aHitTimes.y < aHitTimes.x ? aHitTimes.yx : aHitTimes.xy;
571       aChildren.zw = aHitTimes.w < aHitTimes.z ? aChildren.wz : aChildren.zw;
572       aHitTimes.zw = aHitTimes.w < aHitTimes.z ? aHitTimes.wz : aHitTimes.zw;
573       aChildren.xz = aHitTimes.z < aHitTimes.x ? aChildren.zx : aChildren.xz;
574       aHitTimes.xz = aHitTimes.z < aHitTimes.x ? aHitTimes.zx : aHitTimes.xz;
575       aChildren.yw = aHitTimes.w < aHitTimes.y ? aChildren.wy : aChildren.yw;
576       aHitTimes.yw = aHitTimes.w < aHitTimes.y ? aHitTimes.wy : aHitTimes.yw;
577       aChildren.yz = aHitTimes.z < aHitTimes.y ? aChildren.zy : aChildren.yz;
578       aHitTimes.yz = aHitTimes.z < aHitTimes.y ? aHitTimes.zy : aHitTimes.yz;
579
580       if (aHitTimes.x != MAXFLOAT)
581       {
582         int aHitMask = (aHitTimes.w != MAXFLOAT ? aChildren.w : aChildren.z) << 2
583                      | (aHitTimes.z != MAXFLOAT ? aChildren.z : aChildren.y);
584
585         if (aHitTimes.y != MAXFLOAT)
586           Stack[++aHead] = aData.y | (aHitMask << 2 | aChildren.y) << 26;
587
588         aNode = aData.y + aChildren.x;
589       }
590       else
591       {
592         toContinue = (aHead >= 0);
593
594         if (aHead == aStop) // go to top-level BVH
595         {
596           aStop = -1; aSubTree = SSubTree (theRay, theInverse, EMPTY_ROOT);
597         }
598
599         if (aHead >= 0)
600           aNode = pop (aHead);
601       }
602     }
603     else if (aData.x < 0) // leaf node (contains triangles)
604     {
605       vec3 aNormal;
606       vec3 aTimeUV;
607
608       for (int anIdx = aData.y; anIdx <= aData.z; ++anIdx)
609       {
610         ivec4 aTriangle = texelFetch (uGeometryTriangTexture, anIdx + TRG_OFFSET (aSubTree));
611
612         vec3 aPoint0 = texelFetch (uGeometryVertexTexture, aTriangle.x += VRT_OFFSET (aSubTree)).xyz;
613         vec3 aPoint1 = texelFetch (uGeometryVertexTexture, aTriangle.y += VRT_OFFSET (aSubTree)).xyz;
614         vec3 aPoint2 = texelFetch (uGeometryVertexTexture, aTriangle.z += VRT_OFFSET (aSubTree)).xyz;
615
616         IntersectTriangle (aSubTree.TrsfRay, aPoint0, aPoint1, aPoint2, aTimeUV, aNormal);
617
618         if (aTimeUV.x < theHit.Time)
619         {
620           aTriIndex = aTriangle;
621
622           theTrsfId = TRS_OFFSET (aSubTree);
623
624           theHit = SIntersect (aTimeUV.x, aTimeUV.yz, aNormal);
625         }
626       }
627
628       toContinue = (aHead >= 0);
629
630       if (aHead == aStop) // go to top-level BVH
631       {
632         aStop = -1; aSubTree = SSubTree (theRay, theInverse, EMPTY_ROOT);
633       }
634
635       if (aHead >= 0)
636         aNode = pop (aHead);
637     }
638     else if (aData.x > 0) // switch node
639     {
640       aSubTree.SubData = ivec4 (4 * aData.x - 4, aData.yzw); // store BVH sub-root
641
642       vec4 aInvTransf0 = texelFetch (uSceneTransformTexture, TRS_OFFSET (aSubTree) + 0);
643       vec4 aInvTransf1 = texelFetch (uSceneTransformTexture, TRS_OFFSET (aSubTree) + 1);
644       vec4 aInvTransf2 = texelFetch (uSceneTransformTexture, TRS_OFFSET (aSubTree) + 2);
645       vec4 aInvTransf3 = texelFetch (uSceneTransformTexture, TRS_OFFSET (aSubTree) + 3);
646
647       aSubTree.TrsfRay.Direct = MatrixColMultiplyDir (theRay.Direct,
648                                                       aInvTransf0,
649                                                       aInvTransf1,
650                                                       aInvTransf2);
651
652       aSubTree.Inverse = mix (-UNIT, UNIT, step (ZERO, aSubTree.TrsfRay.Direct)) /
653         max (abs (aSubTree.TrsfRay.Direct), SMALL);
654
655       aSubTree.TrsfRay.Origin = MatrixColMultiplyPnt (theRay.Origin,
656                                                       aInvTransf0,
657                                                       aInvTransf1,
658                                                       aInvTransf2,
659                                                       aInvTransf3);
660
661       aNode = BVH_OFFSET (aSubTree); // go to sub-root node
662
663       aStop = aHead; // store current stack pointer
664     }
665   }
666
667   return aTriIndex;
668 }
669
670 // =======================================================================
671 // function : SceneAnyHit
672 // purpose  : Finds intersection with any scene triangle
673 // =======================================================================
674 float SceneAnyHit (in SRay theRay, in vec3 theInverse, in float theDistance)
675 {
676   float aFactor = 1.f;
677
678   int aNode =  0; // node to traverse
679   int aHead = -1; // pointer of stack
680   int aStop = -1; // BVH level switch
681
682   SSubTree aSubTree = SSubTree (theRay, theInverse, EMPTY_ROOT);
683
684   for (bool toContinue = true; toContinue; /* none */)
685   {
686     ivec4 aData = texelFetch (uSceneNodeInfoTexture, aNode);
687
688     if (aData.x == 0) // if inner node
689     {
690       aData.y += BVH_OFFSET (aSubTree);
691
692       vec4 aHitTimes = vec4 (MAXFLOAT,
693                              MAXFLOAT,
694                              MAXFLOAT,
695                              MAXFLOAT);
696
697       vec3 aRayOriginInverse = -aSubTree.TrsfRay.Origin * aSubTree.Inverse;
698
699       vec3 aNodeMin0 = texelFetch (uSceneMinPointTexture, aData.y +                0).xyz * aSubTree.Inverse + aRayOriginInverse;
700       vec3 aNodeMin1 = texelFetch (uSceneMinPointTexture, aData.y +                1).xyz * aSubTree.Inverse + aRayOriginInverse;
701       vec3 aNodeMin2 = texelFetch (uSceneMinPointTexture, aData.y + min (2, aData.z)).xyz * aSubTree.Inverse + aRayOriginInverse;
702       vec3 aNodeMin3 = texelFetch (uSceneMinPointTexture, aData.y + min (3, aData.z)).xyz * aSubTree.Inverse + aRayOriginInverse;
703       vec3 aNodeMax0 = texelFetch (uSceneMaxPointTexture, aData.y +                0).xyz * aSubTree.Inverse + aRayOriginInverse;
704       vec3 aNodeMax1 = texelFetch (uSceneMaxPointTexture, aData.y +                1).xyz * aSubTree.Inverse + aRayOriginInverse;
705       vec3 aNodeMax2 = texelFetch (uSceneMaxPointTexture, aData.y + min (2, aData.z)).xyz * aSubTree.Inverse + aRayOriginInverse;
706       vec3 aNodeMax3 = texelFetch (uSceneMaxPointTexture, aData.y + min (3, aData.z)).xyz * aSubTree.Inverse + aRayOriginInverse;
707
708       vec3 aTimeMax = max (aNodeMin0, aNodeMax0);
709       vec3 aTimeMin = min (aNodeMin0, aNodeMax0);
710
711       float aTimeLeave = min (aTimeMax.x, min (aTimeMax.y, aTimeMax.z));
712       float aTimeEnter = max (aTimeMin.x, max (aTimeMin.y, aTimeMin.z));
713
714       aHitTimes.x = (aTimeEnter <= aTimeLeave && aTimeEnter <= theDistance && aTimeLeave >= 0.f) ? aTimeEnter : MAXFLOAT;
715
716       aTimeMax = max (aNodeMin1, aNodeMax1);
717       aTimeMin = min (aNodeMin1, aNodeMax1);
718
719       aTimeLeave = min (aTimeMax.x, min (aTimeMax.y, aTimeMax.z));
720       aTimeEnter = max (aTimeMin.x, max (aTimeMin.y, aTimeMin.z));
721
722       aHitTimes.y = (aTimeEnter <= aTimeLeave && aTimeEnter <= theDistance && aTimeLeave >= 0.f) ? aTimeEnter : MAXFLOAT;
723
724       aTimeMax = max (aNodeMin2, aNodeMax2);
725       aTimeMin = min (aNodeMin2, aNodeMax2);
726
727       aTimeLeave = min (aTimeMax.x, min (aTimeMax.y, aTimeMax.z));
728       aTimeEnter = max (aTimeMin.x, max (aTimeMin.y, aTimeMin.z));
729
730       aHitTimes.z = (aTimeEnter <= aTimeLeave && aTimeEnter <= theDistance && aTimeLeave >= 0.f && aData.z > 1) ? aTimeEnter : MAXFLOAT;
731
732       aTimeMax = max (aNodeMin3, aNodeMax3);
733       aTimeMin = min (aNodeMin3, aNodeMax3);
734
735       aTimeLeave = min (aTimeMax.x, min (aTimeMax.y, aTimeMax.z));
736       aTimeEnter = max (aTimeMin.x, max (aTimeMin.y, aTimeMin.z));
737
738       aHitTimes.w = (aTimeEnter <= aTimeLeave && aTimeEnter <= theDistance && aTimeLeave >= 0.f && aData.z > 2) ? aTimeEnter : MAXFLOAT;
739
740       ivec4 aChildren = ivec4 (0, 1, 2, 3);
741
742       aChildren.xy = aHitTimes.y < aHitTimes.x ? aChildren.yx : aChildren.xy;
743       aHitTimes.xy = aHitTimes.y < aHitTimes.x ? aHitTimes.yx : aHitTimes.xy;
744       aChildren.zw = aHitTimes.w < aHitTimes.z ? aChildren.wz : aChildren.zw;
745       aHitTimes.zw = aHitTimes.w < aHitTimes.z ? aHitTimes.wz : aHitTimes.zw;
746       aChildren.xz = aHitTimes.z < aHitTimes.x ? aChildren.zx : aChildren.xz;
747       aHitTimes.xz = aHitTimes.z < aHitTimes.x ? aHitTimes.zx : aHitTimes.xz;
748       aChildren.yw = aHitTimes.w < aHitTimes.y ? aChildren.wy : aChildren.yw;
749       aHitTimes.yw = aHitTimes.w < aHitTimes.y ? aHitTimes.wy : aHitTimes.yw;
750       aChildren.yz = aHitTimes.z < aHitTimes.y ? aChildren.zy : aChildren.yz;
751       aHitTimes.yz = aHitTimes.z < aHitTimes.y ? aHitTimes.zy : aHitTimes.yz;
752
753       if (aHitTimes.x != MAXFLOAT)
754       {
755         int aHitMask = (aHitTimes.w != MAXFLOAT ? aChildren.w : aChildren.z) << 2
756                      | (aHitTimes.z != MAXFLOAT ? aChildren.z : aChildren.y);
757
758         if (aHitTimes.y != MAXFLOAT)
759           Stack[++aHead] = aData.y | (aHitMask << 2 | aChildren.y) << 26;
760
761         aNode = aData.y + aChildren.x;
762       }
763       else
764       {
765         toContinue = (aHead >= 0);
766
767         if (aHead == aStop) // go to top-level BVH
768         {
769           aStop = -1; aSubTree = SSubTree (theRay, theInverse, EMPTY_ROOT);
770         }
771
772         if (aHead >= 0)
773           aNode = pop (aHead);
774       }
775     }
776     else if (aData.x < 0) // leaf node
777     {
778       vec3 aNormal;
779       vec3 aTimeUV;
780
781       for (int anIdx = aData.y; anIdx <= aData.z; ++anIdx)
782       {
783         ivec4 aTriangle = texelFetch (uGeometryTriangTexture, anIdx + TRG_OFFSET (aSubTree));
784
785         vec3 aPoint0 = texelFetch (uGeometryVertexTexture, aTriangle.x += VRT_OFFSET (aSubTree)).xyz;
786         vec3 aPoint1 = texelFetch (uGeometryVertexTexture, aTriangle.y += VRT_OFFSET (aSubTree)).xyz;
787         vec3 aPoint2 = texelFetch (uGeometryVertexTexture, aTriangle.z += VRT_OFFSET (aSubTree)).xyz;
788
789         IntersectTriangle (aSubTree.TrsfRay, aPoint0, aPoint1, aPoint2, aTimeUV, aNormal);
790
791 #ifdef TRANSPARENT_SHADOWS
792         if (aTimeUV.x < theDistance)
793         {
794           aFactor *= 1.f - texelFetch (uRaytraceMaterialTexture, MATERIAL_TRAN (aTriangle.w)).x;
795         }
796 #else
797         if (aTimeUV.x < theDistance)
798         {
799           aFactor = 0.f;
800         }
801 #endif
802       }
803
804       toContinue = (aHead >= 0) && (aFactor > 0.1f);
805
806       if (aHead == aStop) // go to top-level BVH
807       {
808         aStop = -1; aSubTree = SSubTree (theRay, theInverse, EMPTY_ROOT);
809       }
810
811       if (aHead >= 0)
812         aNode = pop (aHead);
813     }
814     else if (aData.x > 0) // switch node
815     {
816       aSubTree.SubData = ivec4 (4 * aData.x - 4, aData.yzw); // store BVH sub-root
817
818       vec4 aInvTransf0 = texelFetch (uSceneTransformTexture, TRS_OFFSET (aSubTree) + 0);
819       vec4 aInvTransf1 = texelFetch (uSceneTransformTexture, TRS_OFFSET (aSubTree) + 1);
820       vec4 aInvTransf2 = texelFetch (uSceneTransformTexture, TRS_OFFSET (aSubTree) + 2);
821       vec4 aInvTransf3 = texelFetch (uSceneTransformTexture, TRS_OFFSET (aSubTree) + 3);
822
823       aSubTree.TrsfRay.Direct = MatrixColMultiplyDir (theRay.Direct,
824                                                       aInvTransf0,
825                                                       aInvTransf1,
826                                                       aInvTransf2);
827
828       aSubTree.TrsfRay.Origin = MatrixColMultiplyPnt (theRay.Origin,
829                                                       aInvTransf0,
830                                                       aInvTransf1,
831                                                       aInvTransf2,
832                                                       aInvTransf3);
833
834       aSubTree.Inverse = mix (-UNIT, UNIT, step (ZERO, aSubTree.TrsfRay.Direct)) / max (abs (aSubTree.TrsfRay.Direct), SMALL);
835
836       aNode = BVH_OFFSET (aSubTree); // go to sub-root node
837
838       aStop = aHead; // store current stack pointer
839     }
840   }
841
842   return aFactor;
843 }
844
845 #define PI 3.1415926f
846
847 // =======================================================================
848 // function : Latlong
849 // purpose  : Converts world direction to environment texture coordinates
850 // =======================================================================
851 vec2 Latlong (in vec3 thePoint, in float theRadius)
852 {
853   float aPsi = acos (-thePoint.z / theRadius);
854
855   float aPhi = atan (thePoint.y, thePoint.x) + PI;
856
857   return vec2 (aPhi * 0.1591549f,
858                aPsi * 0.3183098f);
859 }
860
861 #ifdef BACKGROUND_CUBEMAP
862 //! Transform texture coordinates for cubemap lookup.
863 vec3 cubemapVectorTransform (in vec3 theVec, in float theRadius)
864 {
865   vec3 aVec = theVec.yzx;
866   aVec.y *= float(uYCoeff);
867   aVec.z *= float(uZCoeff);
868   return aVec;
869 }
870 #endif
871
872 // =======================================================================
873 // function : SmoothNormal
874 // purpose  : Interpolates normal across the triangle
875 // =======================================================================
876 vec3 SmoothNormal (in vec2 theUV, in ivec4 theTriangle)
877 {
878   vec3 aNormal0 = texelFetch (uGeometryNormalTexture, theTriangle.x).xyz;
879   vec3 aNormal1 = texelFetch (uGeometryNormalTexture, theTriangle.y).xyz;
880   vec3 aNormal2 = texelFetch (uGeometryNormalTexture, theTriangle.z).xyz;
881
882   return normalize (aNormal1 * theUV.x +
883                     aNormal2 * theUV.y +
884                     aNormal0 * (1.0f - theUV.x - theUV.y));
885 }
886
887 #define POLYGON_OFFSET_UNIT 0.f
888 #define POLYGON_OFFSET_FACTOR 1.f
889 #define POLYGON_OFFSET_SCALE 0.006f
890
891 // =======================================================================
892 // function : PolygonOffset
893 // purpose  : Computes OpenGL polygon offset
894 // =======================================================================
895 float PolygonOffset (in vec3 theNormal, in vec3 thePoint)
896 {
897   vec4 aProjectedNorm = vec4 (theNormal, -dot (theNormal, thePoint)) * uUnviewMat;
898
899   float aPolygonOffset = POLYGON_OFFSET_UNIT;
900
901   if (aProjectedNorm.z * aProjectedNorm.z > 1e-20f)
902   {
903     aProjectedNorm.xy *= 1.f / aProjectedNorm.z;
904
905     aPolygonOffset += POLYGON_OFFSET_FACTOR * max (abs (aProjectedNorm.x),
906                                                    abs (aProjectedNorm.y));
907   }
908
909   return aPolygonOffset;
910 }
911
912 // =======================================================================
913 // function : SmoothUV
914 // purpose  : Interpolates UV coordinates across the triangle
915 // =======================================================================
916 #ifdef USE_TEXTURES
917 vec2 SmoothUV (in vec2 theUV, in ivec4 theTriangle)
918 {
919   vec2 aTexCrd0 = texelFetch (uGeometryTexCrdTexture, theTriangle.x).st;
920   vec2 aTexCrd1 = texelFetch (uGeometryTexCrdTexture, theTriangle.y).st;
921   vec2 aTexCrd2 = texelFetch (uGeometryTexCrdTexture, theTriangle.z).st;
922
923   return aTexCrd1 * theUV.x +
924          aTexCrd2 * theUV.y +
925          aTexCrd0 * (1.0f - theUV.x - theUV.y);
926 }
927 #endif
928
929 // =======================================================================
930 // function : FetchEnvironment
931 // purpose  :
932 // =======================================================================
933 vec4 FetchEnvironment (in vec3 theTexCoord, in float theRadius, in bool theIsBackground)
934 {
935   if (uEnvMapEnabled == 0)
936   {
937 #ifdef PATH_TRACING
938     return theIsBackground ? vec4 (0.0, 0.0, 0.0, 1.0) : uGlobalAmbient;
939 #else
940     return vec4 (0.0, 0.0, 0.0, 1.0);
941 #endif
942   }
943
944   vec4 anAmbScale = theIsBackground ? vec4(1.0) : uGlobalAmbient;
945   vec4 anEnvColor =
946 #ifdef BACKGROUND_CUBEMAP
947     textureLod (uEnvMapTexture, cubemapVectorTransform (theTexCoord, theRadius), 0.0);
948 #else
949     textureLod (uEnvMapTexture, Latlong (theTexCoord, theRadius), 0.0);
950 #endif
951   return anEnvColor * anAmbScale;
952 }
953
954 // =======================================================================
955 // function : Refract
956 // purpose  : Computes refraction ray (also handles TIR)
957 // =======================================================================
958 #ifndef PATH_TRACING
959 vec3 Refract (in vec3 theInput,
960               in vec3 theNormal,
961               in float theRefractIndex,
962               in float theInvRefractIndex)
963 {
964   float aNdotI = dot (theInput, theNormal);
965
966   float anIndex = aNdotI < 0.0f
967                 ? theInvRefractIndex
968                 : theRefractIndex;
969
970   float aSquare = anIndex * anIndex * (1.0f - aNdotI * aNdotI);
971
972   if (aSquare > 1.0f)
973   {
974     return reflect (theInput, theNormal);
975   }
976
977   float aNdotT = sqrt (1.0f - aSquare);
978
979   return normalize (anIndex * theInput -
980     (anIndex * aNdotI + (aNdotI < 0.0f ? aNdotT : -aNdotT)) * theNormal);
981 }
982 #endif
983
984 #define MIN_SLOPE 0.0001f
985 #define EPS_SCALE 8.0000f
986
987 #define THRESHOLD vec3 (0.1f)
988
989 #define INVALID_BOUNCES 1000
990
991 #define LIGHT_POS(index) (2 * index + 1)
992 #define LIGHT_PWR(index) (2 * index + 0)
993
994 // =======================================================================
995 // function : Radiance
996 // purpose  : Computes color along the given ray
997 // =======================================================================
998 #ifndef PATH_TRACING
999 vec4 Radiance (in SRay theRay, in vec3 theInverse)
1000 {
1001   vec3 aResult = vec3 (0.0f);
1002   vec4 aWeight = vec4 (1.0f);
1003
1004   int aTrsfId;
1005
1006   float aRaytraceDepth = MAXFLOAT;
1007
1008   for (int aDepth = 0; aDepth < NB_BOUNCES; ++aDepth)
1009   {
1010     SIntersect aHit = SIntersect (MAXFLOAT, vec2 (ZERO), ZERO);
1011
1012     ivec4 aTriIndex = SceneNearestHit (theRay, theInverse, aHit, aTrsfId);
1013
1014     if (aTriIndex.x == -1)
1015     {
1016       vec4 aColor = vec4 (0.0);
1017
1018       if (bool(uEnvMapForBack) || aWeight.w == 0.0f /* reflection */)
1019       {
1020         float aTime = IntersectSphere (theRay, uSceneRadius);
1021
1022         aColor = FetchEnvironment (theRay.Direct * aTime + theRay.Origin, uSceneRadius, aWeight.w != 0.0);
1023       }
1024       else
1025       {
1026         aColor = BackgroundColor();
1027       }
1028
1029       aResult += aWeight.xyz * aColor.xyz; aWeight.w *= aColor.w;
1030
1031       break; // terminate path
1032     }
1033
1034     vec3 aInvTransf0 = texelFetch (uSceneTransformTexture, aTrsfId + 0).xyz;
1035     vec3 aInvTransf1 = texelFetch (uSceneTransformTexture, aTrsfId + 1).xyz;
1036     vec3 aInvTransf2 = texelFetch (uSceneTransformTexture, aTrsfId + 2).xyz;
1037
1038     aHit.Normal = normalize (vec3 (dot (aInvTransf0, aHit.Normal),
1039                                    dot (aInvTransf1, aHit.Normal),
1040                                    dot (aInvTransf2, aHit.Normal)));
1041
1042     theRay.Origin += theRay.Direct * aHit.Time; // intersection point
1043
1044     // Evaluate depth on first hit
1045     if (aDepth == 0)
1046     {
1047       vec4 aNDCPoint = uViewMat * vec4 (theRay.Origin, 1.f);
1048
1049       float aPolygonOffset = PolygonOffset (aHit.Normal, theRay.Origin);
1050       aRaytraceDepth = (aNDCPoint.z / aNDCPoint.w + aPolygonOffset * POLYGON_OFFSET_SCALE) * 0.5f + 0.5f;
1051     }
1052
1053     vec3 aNormal = SmoothNormal (aHit.UV, aTriIndex);
1054
1055     aNormal = normalize (vec3 (dot (aInvTransf0, aNormal),
1056                                dot (aInvTransf1, aNormal),
1057                                dot (aInvTransf2, aNormal)));
1058
1059     vec3 aAmbient  = texelFetch (
1060       uRaytraceMaterialTexture, MATERIAL_AMBN (aTriIndex.w)).rgb;
1061     vec4 aDiffuse  = texelFetch (
1062       uRaytraceMaterialTexture, MATERIAL_DIFF (aTriIndex.w));
1063     vec4 aSpecular = texelFetch (
1064       uRaytraceMaterialTexture, MATERIAL_SPEC (aTriIndex.w));
1065     vec4 aOpacity  = texelFetch (
1066       uRaytraceMaterialTexture, MATERIAL_TRAN (aTriIndex.w));
1067
1068 #ifdef USE_TEXTURES
1069     if (aDiffuse.w >= 0.f)
1070     {
1071       vec4 aTexCoord = vec4 (SmoothUV (aHit.UV, aTriIndex), 0.f, 1.f);
1072
1073       vec4 aTrsfRow1 = texelFetch (
1074         uRaytraceMaterialTexture, MATERIAL_TRS1 (aTriIndex.w));
1075       vec4 aTrsfRow2 = texelFetch (
1076         uRaytraceMaterialTexture, MATERIAL_TRS2 (aTriIndex.w));
1077
1078       aTexCoord.st = vec2 (dot (aTrsfRow1, aTexCoord),
1079                            dot (aTrsfRow2, aTexCoord));
1080
1081       vec4 aTexColor = textureLod (
1082         sampler2D (uTextureSamplers[int(aDiffuse.w)]), aTexCoord.st, 0.f);
1083
1084       aDiffuse.rgb *= aTexColor.rgb;
1085       aAmbient.rgb *= aTexColor.rgb;
1086
1087       // keep refractive index untouched (Z component)
1088       aOpacity.xy = vec2 (aTexColor.w * aOpacity.x, 1.0f - aTexColor.w * aOpacity.x);
1089     }
1090 #endif
1091
1092     vec3 aEmission = texelFetch (
1093       uRaytraceMaterialTexture, MATERIAL_EMIS (aTriIndex.w)).rgb;
1094
1095     float aGeomFactor = dot (aNormal, theRay.Direct);
1096
1097     aResult.xyz += aWeight.xyz * aOpacity.x * (
1098       uGlobalAmbient.xyz * aAmbient * max (abs (aGeomFactor), 0.5f) + aEmission);
1099
1100     vec3 aSidedNormal = mix (aNormal, -aNormal, step (0.0f, aGeomFactor));
1101
1102     for (int aLightIdx = 0; aLightIdx < uLightCount; ++aLightIdx)
1103     {
1104       vec4 aLight = texelFetch (
1105         uRaytraceLightSrcTexture, LIGHT_POS (aLightIdx));
1106
1107       float aDistance = MAXFLOAT;
1108
1109       if (aLight.w != 0.0f) // point light source
1110       {
1111         aDistance = length (aLight.xyz -= theRay.Origin);
1112
1113         aLight.xyz *= 1.0f / aDistance;
1114       }
1115
1116       float aLdotN = dot (aLight.xyz, aSidedNormal);
1117
1118       if (aLdotN > 0.0f) // first check if light source is important
1119       {
1120         float aVisibility = 1.0f;
1121
1122         if (bool(uShadowsEnabled))
1123         {
1124           SRay aShadow = SRay (theRay.Origin, aLight.xyz);
1125
1126           aShadow.Origin += uSceneEpsilon * (aLight.xyz +
1127             mix (-aHit.Normal, aHit.Normal, step (0.0f, dot (aHit.Normal, aLight.xyz))));
1128
1129           vec3 aInverse = 1.0f / max (abs (aLight.xyz), SMALL);
1130
1131           aVisibility = SceneAnyHit (
1132             aShadow, mix (-aInverse, aInverse, step (ZERO, aLight.xyz)), aDistance);
1133         }
1134
1135         if (aVisibility > 0.0f)
1136         {
1137           vec3 aIntensity = min (UNIT, vec3 (texelFetch (
1138             uRaytraceLightSrcTexture, LIGHT_PWR (aLightIdx))));
1139
1140           float aRdotV = dot (reflect (aLight.xyz, aSidedNormal), theRay.Direct);
1141
1142           aResult.xyz += aWeight.xyz * (aOpacity.x * aVisibility) * aIntensity *
1143             (aDiffuse.xyz * aLdotN + aSpecular.xyz * pow (max (0.f, aRdotV), aSpecular.w));
1144         }
1145       }
1146     }
1147
1148     if (aOpacity.x != 1.0f)
1149     {
1150       aWeight *= aOpacity.y;
1151
1152       if (aOpacity.z != 1.0f)
1153       {
1154         theRay.Direct = Refract (theRay.Direct, aNormal, aOpacity.z, aOpacity.w);
1155       }
1156     }
1157     else
1158     {
1159       aWeight *= bool(uReflectEnabled) ?
1160         texelFetch (uRaytraceMaterialTexture, MATERIAL_REFL (aTriIndex.w)) : vec4 (0.0f);
1161
1162       vec3 aReflect = reflect (theRay.Direct, aNormal);
1163
1164       if (dot (aReflect, aHit.Normal) * dot (theRay.Direct, aHit.Normal) > 0.0f)
1165       {
1166         aReflect = reflect (theRay.Direct, aHit.Normal);
1167       }
1168
1169       theRay.Direct = aReflect;
1170     }
1171
1172     if (all (lessThanEqual (aWeight.xyz, THRESHOLD)))
1173     {
1174       aDepth = INVALID_BOUNCES;
1175     }
1176     else if (aOpacity.x == 1.0f || aOpacity.z != 1.0f) // if no simple transparency
1177     {
1178       theRay.Origin += aHit.Normal * mix (
1179         -uSceneEpsilon, uSceneEpsilon, step (0.0f, dot (aHit.Normal, theRay.Direct)));
1180
1181       theInverse = 1.0f / max (abs (theRay.Direct), SMALL);
1182
1183       theInverse = mix (-theInverse, theInverse, step (ZERO, theRay.Direct));
1184     }
1185
1186     theRay.Origin += theRay.Direct * uSceneEpsilon;
1187   }
1188
1189   gl_FragDepth = aRaytraceDepth;
1190
1191   return vec4 (aResult.x,
1192                aResult.y,
1193                aResult.z,
1194                aWeight.w);
1195 }
1196 #endif