0030681: Configuration - suppress OpenGL deprecation warning on macOS 10.14
[occt.git] / src / OpenGl / OpenGl_Window_1.mm
1 // Created on: 2012-11-12
2 // Created by: Kirill Gavrilov
3 // Copyright (c) 2012-2014 OPEN CASCADE SAS
4 //
5 // This file is part of Open CASCADE Technology software library.
6 //
7 // This library is free software; you can redistribute it and/or modify it under
8 // the terms of the GNU Lesser General Public License version 2.1 as published
9 // by the Free Software Foundation, with special exception defined in the file
10 // OCCT_LGPL_EXCEPTION.txt. Consult the file LICENSE_LGPL_21.txt included in OCCT
11 // distribution for complete text of the license and disclaimer of any warranty.
12 //
13 // Alternatively, this file may be used under the terms of Open CASCADE
14 // commercial license or contractual agreement.
15
16 #if defined(__APPLE__) && !defined(MACOSX_USE_GLX)
17
18 #ifndef GL_GLEXT_LEGACY
19 #define GL_GLEXT_LEGACY // To prevent inclusion of system glext.h on Mac OS X 10.6.8
20 #endif
21
22 // macOS 10.4 deprecated OpenGL framework - suppress useless warnings
23 #define GL_SILENCE_DEPRECATION
24
25 #import <TargetConditionals.h>
26
27 #if defined(TARGET_OS_IPHONE) && TARGET_OS_IPHONE
28   #import <UIKit/UIKit.h>
29 #else
30   #import <Cocoa/Cocoa.h>
31
32 #if !defined(MAC_OS_X_VERSION_10_7) || (MAC_OS_X_VERSION_MAX_ALLOWED < MAC_OS_X_VERSION_10_7)
33 @interface NSView (LionAPI)
34 - (NSSize )convertSizeToBacking: (NSSize )theSize;
35 @end
36 #endif
37
38 #endif
39
40 #include <OpenGl_Window.hxx>
41 #include <OpenGl_FrameBuffer.hxx>
42
43 #include <OpenGl_Context.hxx>
44 #include <Aspect_GraphicDeviceDefinitionError.hxx>
45 #include <Cocoa_LocalPool.hxx>
46 #include <TCollection_AsciiString.hxx>
47 #include <TCollection_ExtendedString.hxx>
48
49 #if defined(TARGET_OS_IPHONE) && TARGET_OS_IPHONE
50   //
51 #else
52   #include <OpenGL/CGLRenderers.h>
53 #endif
54
55 // =======================================================================
56 // function : OpenGl_Window
57 // purpose  :
58 // =======================================================================
59 OpenGl_Window::OpenGl_Window (const Handle(OpenGl_GraphicDriver)& theDriver,
60                               const Handle(Aspect_Window)&  thePlatformWindow,
61                               Aspect_RenderingContext       theGContext,
62                               const Handle(OpenGl_Caps)&    theCaps,
63                               const Handle(OpenGl_Context)& theShareCtx)
64 : myGlContext (new OpenGl_Context (theCaps)),
65   myOwnGContext (theGContext == 0),
66   myPlatformWindow (thePlatformWindow),
67 #if defined(__APPLE__) && defined(TARGET_OS_IPHONE) && TARGET_OS_IPHONE
68   myUIView (NULL),
69 #endif
70   mySwapInterval (theCaps->swapInterval)
71 {
72   (void )theDriver;
73   myPlatformWindow->Size (myWidth, myHeight);
74
75 #if defined(__APPLE__)
76   myWidthPt  = myWidth;
77   myHeightPt = myHeight;
78 #endif
79
80 #if defined(TARGET_OS_IPHONE) && TARGET_OS_IPHONE
81   EAGLContext* aGLContext = theGContext;
82   if (aGLContext == NULL)
83   {
84     void* aViewPtr = (void* )myPlatformWindow->NativeHandle();
85
86     myUIView = (__bridge UIView* )aViewPtr;
87     CAEAGLLayer* anEaglLayer = (CAEAGLLayer* )myUIView.layer;
88     anEaglLayer.opaque = TRUE;
89     anEaglLayer.drawableProperties = [NSDictionary dictionaryWithObjectsAndKeys:
90                                         [NSNumber numberWithBool: FALSE], kEAGLDrawablePropertyRetainedBacking,
91                                         kEAGLColorFormatRGBA8,            kEAGLDrawablePropertyColorFormat,
92                                         NULL];
93
94     aGLContext = [[EAGLContext alloc] initWithAPI: kEAGLRenderingAPIOpenGLES2];
95     if (aGLContext == NULL
96     || ![EAGLContext setCurrentContext: aGLContext])
97     {
98       TCollection_AsciiString aMsg ("OpenGl_Window::CreateWindow: EAGLContext creation failed");
99       throw Aspect_GraphicDeviceDefinitionError(aMsg.ToCString());
100       return;
101     }
102
103     myGlContext->Init (aGLContext, Standard_False);
104   }
105   else
106   {
107     if (![EAGLContext setCurrentContext: aGLContext])
108     {
109       TCollection_AsciiString aMsg ("OpenGl_Window::CreateWindow: EAGLContext can not be assigned");
110       throw Aspect_GraphicDeviceDefinitionError(aMsg.ToCString());
111       return;
112     }
113
114     myGlContext->Init (aGLContext, Standard_False);
115   }
116 #else
117
118   Cocoa_LocalPool aLocalPool;
119
120   // all GL context within one OpenGl_GraphicDriver should be shared!
121   NSOpenGLContext* aGLCtxShare = theShareCtx.IsNull() ? NULL : theShareCtx->myGContext;
122   NSOpenGLContext* aGLContext  = theGContext;
123   bool isCore = false;
124   if (aGLContext == NULL)
125   {
126     NSOpenGLPixelFormatAttribute anAttribs[32] = {};
127     Standard_Integer aLastAttrib = 0;
128     //anAttribs[aLastAttrib++] = NSOpenGLPFAColorSize;    anAttribs[aLastAttrib++] = 32,
129     anAttribs[aLastAttrib++] = NSOpenGLPFADepthSize;    anAttribs[aLastAttrib++] = 24;
130     anAttribs[aLastAttrib++] = NSOpenGLPFAStencilSize;  anAttribs[aLastAttrib++] = 8;
131     anAttribs[aLastAttrib++] = NSOpenGLPFADoubleBuffer;
132     if (theCaps->contextNoAccel)
133     {
134       anAttribs[aLastAttrib++] = NSOpenGLPFARendererID;
135       anAttribs[aLastAttrib++] = (NSOpenGLPixelFormatAttribute )kCGLRendererGenericFloatID;
136     }
137     else
138     {
139       anAttribs[aLastAttrib++] = NSOpenGLPFAAccelerated;
140     }
141     anAttribs[aLastAttrib] = 0;
142     const Standard_Integer aLastMainAttrib = aLastAttrib;
143     Standard_Integer aTryCore   = 0;
144     Standard_Integer aTryStereo = 0;
145     for (aTryCore = 1; aTryCore >= 0; --aTryCore)
146     {
147       aLastAttrib = aLastMainAttrib;
148       if (aTryCore == 1)
149       {
150         if (theCaps->contextCompatible)
151         {
152           continue;
153         }
154
155         // supported since OS X 10.7+
156         anAttribs[aLastAttrib++] = 99;     // NSOpenGLPFAOpenGLProfile
157         anAttribs[aLastAttrib++] = 0x3200; // NSOpenGLProfileVersion3_2Core
158       }
159
160       for (aTryStereo = 1; aTryStereo >= 0; --aTryStereo)
161       {
162         if (aTryStereo == 1)
163         {
164           if (!theCaps->contextStereo)
165           {
166             continue;
167           }
168
169           // deprecated since macOS 10.12 without replacement
170           Standard_DISABLE_DEPRECATION_WARNINGS
171           anAttribs[aLastAttrib++] = NSOpenGLPFAStereo;
172           Standard_ENABLE_DEPRECATION_WARNINGS
173         }
174
175         anAttribs[aLastAttrib] = 0;
176
177         NSOpenGLPixelFormat* aGLFormat = [[[NSOpenGLPixelFormat alloc] initWithAttributes: anAttribs] autorelease];
178         aGLContext = [[NSOpenGLContext alloc] initWithFormat: aGLFormat
179                                                 shareContext: aGLCtxShare];
180         if (aGLContext != NULL)
181         {
182           break;
183         }
184       }
185
186       if (aGLContext != NULL)
187       {
188         break;
189       }
190     }
191
192     if (aGLContext == NULL)
193     {
194       TCollection_AsciiString aMsg ("OpenGl_Window::CreateWindow: NSOpenGLContext creation failed");
195       throw Aspect_GraphicDeviceDefinitionError(aMsg.ToCString());
196       return;
197     }
198
199     if (aTryStereo == 0
200      && theCaps->contextStereo)
201     {
202       TCollection_ExtendedString aMsg("OpenGl_Window::CreateWindow: QuadBuffer is unavailable!");
203       myGlContext->PushMessage (GL_DEBUG_SOURCE_APPLICATION, GL_DEBUG_TYPE_OTHER, 0, GL_DEBUG_SEVERITY_LOW, aMsg);
204     }
205     if (aTryCore == 0
206     && !theCaps->contextCompatible)
207     {
208       TCollection_ExtendedString aMsg("OpenGl_Window::CreateWindow: core profile creation failed.");
209       myGlContext->PushMessage (GL_DEBUG_SOURCE_APPLICATION, GL_DEBUG_TYPE_PORTABILITY, 0, GL_DEBUG_SEVERITY_LOW, aMsg);
210     }
211
212     NSView* aView = (NSView* )myPlatformWindow->NativeHandle();
213     [aGLContext setView: aView];
214     isCore = (aTryCore == 1);
215   }
216
217   myGlContext->Init (aGLContext, isCore);
218 #endif
219
220   myGlContext->Share (theShareCtx);
221   myGlContext->SetSwapInterval (mySwapInterval);
222   Init();
223 }
224
225 // =======================================================================
226 // function : ~OpenGl_Window
227 // purpose  :
228 // =======================================================================
229 OpenGl_Window::~OpenGl_Window()
230 {
231   if (!myOwnGContext
232    ||  myGlContext.IsNull())
233   {
234     myGlContext.Nullify();
235     return;
236   }
237
238 #if defined(TARGET_OS_IPHONE) && TARGET_OS_IPHONE
239   myGlContext.Nullify();
240   [EAGLContext setCurrentContext: NULL];
241   myUIView = NULL;
242 #else
243   NSOpenGLContext* aGLCtx = myGlContext->myGContext;
244   myGlContext.Nullify();
245
246   [NSOpenGLContext clearCurrentContext];
247   [aGLCtx clearDrawable];
248   [aGLCtx release];
249 #endif
250 }
251
252 // =======================================================================
253 // function : Resize
254 // purpose  : call_subr_resize
255 // =======================================================================
256 void OpenGl_Window::Resize()
257 {
258   // If the size is not changed - do nothing
259   Standard_Integer aWidthPt  = 0;
260   Standard_Integer aHeightPt = 0;
261   myPlatformWindow->Size (aWidthPt, aHeightPt);
262   if (myWidthPt  == aWidthPt
263    && myHeightPt == aHeightPt)
264   {
265   #if defined(TARGET_OS_IPHONE) && TARGET_OS_IPHONE
266     return;
267   #else
268     // check backing store change (moving to another screen)
269     NSOpenGLContext* aGLCtx = myGlContext->myGContext;
270     NSView* aView = [aGLCtx view];
271     if (![aView respondsToSelector: @selector(convertSizeToBacking:)])
272     {
273       return;
274     }
275
276     NSRect aBounds = [aView bounds];
277     NSSize aRes    = [aView convertSizeToBacking: aBounds.size];
278     if (myWidth  == Standard_Integer(aRes.width)
279      && myHeight == Standard_Integer(aRes.height))
280     {
281       return;
282     }
283   #endif
284   }
285
286   myWidthPt  = aWidthPt;
287   myHeightPt = aHeightPt;
288
289   Init();
290 }
291
292 // =======================================================================
293 // function : Init
294 // purpose  :
295 // =======================================================================
296 void OpenGl_Window::Init()
297 {
298   if (!Activate())
299   {
300     return;
301   }
302
303 #if defined(TARGET_OS_IPHONE) && TARGET_OS_IPHONE
304   Handle(OpenGl_FrameBuffer) aDefFbo = myGlContext->SetDefaultFrameBuffer (NULL);
305   if (!aDefFbo.IsNull())
306   {
307     aDefFbo->Release (myGlContext.operator->());
308   }
309   else
310   {
311     aDefFbo = new OpenGl_FrameBuffer();
312   }
313
314   if (myOwnGContext)
315   {
316     EAGLContext* aGLCtx      = myGlContext->myGContext;
317     CAEAGLLayer* anEaglLayer = (CAEAGLLayer* )myUIView.layer;
318     GLuint aWinRBColor = 0;
319     ::glGenRenderbuffers (1, &aWinRBColor);
320     ::glBindRenderbuffer (GL_RENDERBUFFER, aWinRBColor);
321     [aGLCtx renderbufferStorage: GL_RENDERBUFFER fromDrawable: anEaglLayer];
322     ::glGetRenderbufferParameteriv (GL_RENDERBUFFER, GL_RENDERBUFFER_WIDTH,  &myWidth);
323     ::glGetRenderbufferParameteriv (GL_RENDERBUFFER, GL_RENDERBUFFER_HEIGHT, &myHeight);
324     ::glBindRenderbuffer (GL_RENDERBUFFER, 0);
325
326     if (!aDefFbo->InitWithRB (myGlContext, myWidth, myHeight, GL_RGBA8, GL_DEPTH24_STENCIL8, aWinRBColor))
327     {
328       TCollection_AsciiString aMsg ("OpenGl_Window::CreateWindow: default FBO creation failed");
329       throw Aspect_GraphicDeviceDefinitionError(aMsg.ToCString());
330       return;
331     }
332   }
333   else
334   {
335     if (!aDefFbo->InitWrapper (myGlContext))
336     {
337       TCollection_AsciiString aMsg ("OpenGl_Window::CreateWindow: default FBO wrapper creation failed");
338       throw Aspect_GraphicDeviceDefinitionError(aMsg.ToCString());
339       return;
340     }
341
342     myWidth  = aDefFbo->GetVPSizeX();
343     myHeight = aDefFbo->GetVPSizeY();
344   }
345   myGlContext->SetDefaultFrameBuffer (aDefFbo);
346   aDefFbo->BindBuffer (myGlContext);
347   aDefFbo.Nullify();
348 #else
349   NSOpenGLContext* aGLCtx  = myGlContext->myGContext;
350   NSView*          aView   = [aGLCtx view];
351   NSRect           aBounds = [aView bounds];
352
353   // we should call this method each time when window is resized
354   [aGLCtx update];
355
356   if ([aView respondsToSelector: @selector(convertSizeToBacking:)])
357   {
358     NSSize aRes = [aView convertSizeToBacking: aBounds.size];
359     myWidth  = Standard_Integer(aRes.width);
360     myHeight = Standard_Integer(aRes.height);
361   }
362   else
363   {
364     myWidth  = Standard_Integer(aBounds.size.width);
365     myHeight = Standard_Integer(aBounds.size.height);
366   }
367   myWidthPt  = Standard_Integer(aBounds.size.width);
368   myHeightPt = Standard_Integer(aBounds.size.height);
369 #endif
370
371   ::glDisable (GL_DITHER);
372   ::glDisable (GL_SCISSOR_TEST);
373   ::glViewport (0, 0, myWidth, myHeight);
374 #if !defined(GL_ES_VERSION_2_0)
375   ::glDrawBuffer (GL_BACK);
376   if (myGlContext->core11 != NULL)
377   {
378     ::glMatrixMode (GL_MODELVIEW);
379   }
380 #endif
381 }
382
383 // =======================================================================
384 // function : SetSwapInterval
385 // purpose  :
386 // =======================================================================
387 void OpenGl_Window::SetSwapInterval()
388 {
389   if (mySwapInterval != myGlContext->caps->swapInterval)
390   {
391     mySwapInterval = myGlContext->caps->swapInterval;
392     myGlContext->SetSwapInterval (mySwapInterval);
393   }
394 }
395
396 #endif // __APPLE__