samples/qt/IESample/IESample.pro

   1 TEMPLATE = app
   2 CONFIG += debug_and_release qt
   3
   4 TARGET = IESample
   5
   6 SAMPLESROOT = $$quote($$(CASROOT)/samples/qt)
   7
   8 HEADERS   = $${SAMPLESROOT}/Common/src/*.h \
   9             $${SAMPLESROOT}/Interface/src/*.h
  10
  11 SOURCES   = src/*.cxx \
  12             $${SAMPLESROOT}/Common/src/*.cxx \
  13             $${SAMPLESROOT}/Interface/src/*.cxx
  14
  15 TS_FILES  = $${SAMPLESROOT}/Common/src/Common-icon.ts \
  16             $${SAMPLESROOT}/Common/src/Common-string.ts \
  17             $${SAMPLESROOT}/Interface/src/Interface-string.ts
  18
  19 RES_FILES = $${SAMPLESROOT}/Common/res/*
  20
  21 RES_DIR   = $$quote($$(RES_DIR))
  22
  23 INCLUDEPATH += $$quote($${SAMPLESROOT}/Common/src)
  24 INCLUDEPATH += $$quote($${SAMPLESROOT}/Interface/src)
  25 INCLUDEPATH += $$quote($$(CASROOT)/inc)
  26
  27 OCCT_DEFINES = $$(CSF_DEFINES)
  28
  29 DEFINES = $$split(OCCT_DEFINES, ;)
  30
  31 unix {
  32     UNAME = $$system(uname -s)
  33     LIBLIST = $$(LD_LIBRARY_PATH)
  34     LIBPATHS = $$split(LIBLIST,":")
  35     for(lib, LIBPATHS):LIBS += -L$${lib}
  36
  37     CONFIG(debug, debug|release) {
  38         DESTDIR = ./$$UNAME/bind
  39         OBJECTS_DIR = ./$$UNAME/objd
  40         MOC_DIR = ./$$UNAME/mocd
  41     } else {
  42         DESTDIR = ./$$UNAME/bin
  43         OBJECTS_DIR = ./$$UNAME/obj
  44         MOC_DIR = ./$$UNAME/moc
  45     }
  46
  47     MACOSX_USE_GLX = $$(MACOSX_USE_GLX)
  48
  49     !macx | equals(MACOSX_USE_GLX, true): INCLUDEPATH += $$QMAKE_INCDIR_X11 $$QMAKE_INCDIR_OPENGL $$QMAKE_INCDIR_THREAD
  50     !macx | equals(MACOSX_USE_GLX, true): DEFINES += LIN LININTEL
  51     equals(MACOSX_USE_GLX, true): DEFINES += MACOSX_USE_GLX
  52     DEFINES += OCC_CONVERT_SIGNALS QT_NO_STL
  53     !macx | equals(MACOSX_USE_GLX, true): LIBS += -L$$QMAKE_LIBDIR_X11 $$QMAKE_LIBS_X11 -L$$QMAKE_LIBDIR_OPENGL $$QMAKE_LIBS_OPENGL $$QMAKE_LIBS_THREAD
  54     LIBS += -lfreeimageplus
  55     LIBS += -ltbb -ltbbmalloc
  56     QMAKE_CXXFLAGS += -std=gnu++11
  57 }
  58
  59 win32 {
  60     CONFIG(debug, debug|release) {
  61         DEFINES += _DEBUG
  62         DESTDIR = ./win$(ARCH)/$(VCVER)/bind
  63         OBJECTS_DIR = ./win$(ARCH)/$(VCVER)/objd
  64         MOC_DIR = ./win$(ARCH)/$(VCVER)/mocd
  65         LIBS = -L$$(QT_DIR)/lib;$$(CASROOT)/win$$(ARCH)/$$(VCVER)/libd
  66     } else {
  67         DEFINES += NDEBUG
  68         DESTDIR = ./win$(ARCH)/$(VCVER)/bin
  69         OBJECTS_DIR = ./win$(ARCH)/$(VCVER)/obj
  70         MOC_DIR = ./win$(ARCH)/$(VCVER)/moc
  71         LIBS = -L$$(QT_DIR)/lib;$$(CASROOT)/win$$(ARCH)/$$(VCVER)/lib
  72     }
  73     DEFINES +=WNT WIN32 NO_COMMONSAMPLE_EXPORTS NO_IESAMPLE_EXPORTS
  74 }
  75
  76 LIBS += -lTKernel -lTKMath -lTKService -lTKV3d -lTKOpenGl \
  77         -lTKBRep -lTKIGES -lTKSTL -lTKVRML -lTKSTEP -lTKSTEPAttr -lTKSTEP209 \
  78         -lTKSTEPBase -lTKGeomBase -lTKGeomAlgo -lTKG3d -lTKG2d \
  79         -lTKXSBase -lTKShHealing -lTKHLR -lTKTopAlgo -lTKMesh -lTKPrim \
  80         -lTKCDF -lTKBool -lTKBO -lTKFillet -lTKOffset \
  81
  82 !exists($${RES_DIR}) {
  83     win32 {
  84         system(mkdir $${RES_DIR})
  85     } else {
  86         system(mkdir -p $${RES_DIR})
  87     }
  88 }
  89
  90 lrelease.name = LRELEASE ${QMAKE_FILE_IN}
  91 lrelease.commands = lrelease ${QMAKE_FILE_IN} -qm $${RES_DIR}/${QMAKE_FILE_BASE}.qm
  92 lrelease.output = ${QMAKE_FILE_BASE}.qm
  93 lrelease.input = TS_FILES
  94 lrelease.clean = $${RES_DIR}/${QMAKE_FILE_BASE}.qm
  95 lrelease.CONFIG += no_link target_predeps
  96 QMAKE_EXTRA_COMPILERS += lrelease
  97
  98 copy_res.name = Copy resource ${QMAKE_FILE_IN}
  99 copy_res.output = ${QMAKE_FILE_BASE}${QMAKE_FILE_EXT}
 100 copy_res.clean = $${RES_DIR}/${QMAKE_FILE_BASE}${QMAKE_FILE_EXT}
 101 copy_res.input = RES_FILES
 102 copy_res.CONFIG += no_link target_predeps
 103 win32: copy_res.commands = type ${QMAKE_FILE_IN} > $${RES_DIR}/${QMAKE_FILE_BASE}${QMAKE_FILE_EXT}
 104 unix:  copy_res.commands = cp -f ${QMAKE_FILE_IN} $${RES_DIR}
 105 QMAKE_EXTRA_COMPILERS += copy_res
 106 #QMAKE_CXXFLAGS += /wd4996
 107
 108 greaterThan(QT_MAJOR_VERSION, 4) {
 109     QT += widgets
 110 }