0030115: Implementation of import from XCAF to VRML.
[occt.git] / samples / qt / IESample / IESample.pro
1 TEMPLATE = app
2 CONFIG += debug_and_release qt
3
4 TARGET = IESample
5
6 SAMPLESROOT = $$quote($$(CSF_OCCTSamplesPath)/qt)
7
8 HEADERS   = $${SAMPLESROOT}/Common/src/*.h \
9             $${SAMPLESROOT}/Interface/src/*.h
10
11 SOURCES   = src/*.cxx \
12             $${SAMPLESROOT}/Common/src/*.cxx \
13             $${SAMPLESROOT}/Interface/src/*.cxx
14
15 TS_FILES  = $${SAMPLESROOT}/Common/src/Common-icon.ts \
16             $${SAMPLESROOT}/Common/src/Common-string.ts \
17             $${SAMPLESROOT}/Interface/src/Interface-string.ts
18
19 RES_FILES = $${SAMPLESROOT}/Common/res/*
20
21 RES_DIR   = $$quote($$(RES_DIR))
22
23 INCLUDEPATH += $$quote($${SAMPLESROOT}/Common/src)
24 INCLUDEPATH += $$quote($${SAMPLESROOT}/Interface/src)
25 INCLUDEPATH += $$quote($$(CSF_OCCTIncludePath))
26
27 OCCT_DEFINES = $$(CSF_DEFINES)
28
29 DEFINES = $$split(OCCT_DEFINES, ;)
30
31 unix {
32     UNAME = $$system(uname -s)
33     LIBLIST = $$(LD_LIBRARY_PATH)
34     LIBPATHS = $$split(LIBLIST,":")
35     for(lib, LIBPATHS):LIBS += -L$${lib}
36
37     CONFIG(debug, debug|release) {
38         DESTDIR = ./$$UNAME/bind
39         OBJECTS_DIR = ./$$UNAME/objd
40         MOC_DIR = ./$$UNAME/mocd
41     } else {
42         DESTDIR = ./$$UNAME/bin
43         OBJECTS_DIR = ./$$UNAME/obj
44         MOC_DIR = ./$$UNAME/moc
45     }
46
47     MACOSX_USE_GLX = $$(MACOSX_USE_GLX)
48
49     !macx | equals(MACOSX_USE_GLX, true): INCLUDEPATH += $$QMAKE_INCDIR_X11 $$QMAKE_INCDIR_OPENGL $$QMAKE_INCDIR_THREAD
50     equals(MACOSX_USE_GLX, true): DEFINES += MACOSX_USE_GLX
51     DEFINES += OCC_CONVERT_SIGNALS QT_NO_STL
52     !macx | equals(MACOSX_USE_GLX, true): LIBS += -L$$QMAKE_LIBDIR_X11 $$QMAKE_LIBS_X11 -L$$QMAKE_LIBDIR_OPENGL $$QMAKE_LIBS_OPENGL $$QMAKE_LIBS_THREAD
53     LIBS += -lfreeimageplus
54     LIBS += -ltbb -ltbbmalloc
55     QMAKE_CXXFLAGS += -std=gnu++11
56 }
57
58 win32 {
59     CONFIG(debug, debug|release) {
60         DEFINES += _DEBUG
61         DESTDIR = ./win$(ARCH)/$(VCVER)/bind
62         OBJECTS_DIR = ./win$(ARCH)/$(VCVER)/objd
63         MOC_DIR = ./win$(ARCH)/$(VCVER)/mocd
64     } else {
65         DEFINES += NDEBUG
66         DESTDIR = ./win$(ARCH)/$(VCVER)/bin
67         OBJECTS_DIR = ./win$(ARCH)/$(VCVER)/obj
68         MOC_DIR = ./win$(ARCH)/$(VCVER)/moc
69     }
70     LIBS = -L$$(QTDIR)/lib;$$(CSF_OCCTLibPath)
71     DEFINES += NO_COMMONSAMPLE_EXPORTS NO_IESAMPLE_EXPORTS
72 }
73
74 LIBS += -lTKernel -lTKMath -lTKService -lTKV3d -lTKOpenGl \
75         -lTKBRep -lTKIGES -lTKSTL -lTKVRML -lTKSTEP -lTKSTEPAttr -lTKSTEP209 \
76         -lTKSTEPBase -lTKGeomBase -lTKGeomAlgo -lTKG3d -lTKG2d \
77         -lTKXSBase -lTKShHealing -lTKHLR -lTKTopAlgo -lTKMesh -lTKPrim \
78         -lTKCDF -lTKBool -lTKBO -lTKFillet -lTKOffset -lTKLCAF \
79
80 !exists($${RES_DIR}) {
81     win32 {
82         system(mkdir $${RES_DIR})
83     } else {
84         system(mkdir -p $${RES_DIR})
85     }
86 }
87
88 lrelease.name = LRELEASE ${QMAKE_FILE_IN}
89 lrelease.commands = lrelease ${QMAKE_FILE_IN} -qm $${RES_DIR}/${QMAKE_FILE_BASE}.qm
90 lrelease.output = ${QMAKE_FILE_BASE}.qm
91 lrelease.input = TS_FILES
92 lrelease.clean = $${RES_DIR}/${QMAKE_FILE_BASE}.qm
93 lrelease.CONFIG += no_link target_predeps
94 QMAKE_EXTRA_COMPILERS += lrelease
95
96 copy_res.name = Copy resource ${QMAKE_FILE_IN}
97 copy_res.output = ${QMAKE_FILE_BASE}${QMAKE_FILE_EXT}
98 copy_res.clean = $${RES_DIR}/${QMAKE_FILE_BASE}${QMAKE_FILE_EXT}
99 copy_res.input = RES_FILES
100 copy_res.CONFIG += no_link target_predeps
101 win32: copy_res.commands = type ${QMAKE_FILE_IN} > $${RES_DIR}/${QMAKE_FILE_BASE}${QMAKE_FILE_EXT}
102 unix:  copy_res.commands = cp -f ${QMAKE_FILE_IN} $${RES_DIR}
103 QMAKE_EXTRA_COMPILERS += copy_res
104 #QMAKE_CXXFLAGS += /wd4996
105
106 greaterThan(QT_MAJOR_VERSION, 4) {
107     QT += widgets
108 }