0024786: Move functionality of WOK command wgenproj to OCCT tool genproj
[occt.git] / adm / templates / msvc.bat
1 @echo off
2
3 rem Setup environment
4 call "%~dp0env.bat" %1 %2 %3
5
6 rem Define path to project file
7 set "PRJFILE=%~dp0\adm\msvc\%VCVER%\OCCT.sln"
8 if not exist "%PRJFILE%" set "PRJFILE=%~dp0\adm\msvc\%VCVER%\Products.sln"
9 if not "%4" == "" (
10   set "PRJFILE=%4"
11 )
12
13 set "VisualStudioExpressName=VCExpress"
14
15 if "%VCVER%" == "vc8" (
16   set "DevEnvDir=%VS80COMNTOOLS%..\IDE"
17 ) else if "%VCVER%" == "vc9" (
18   set "DevEnvDir=%VS90COMNTOOLS%..\IDE"
19 ) else if "%VCVER%" == "vc10" (
20   set "DevEnvDir=%VS100COMNTOOLS%..\IDE"
21 ) else if "%VCVER%" == "vc11" (
22   set "DevEnvDir=%VS110COMNTOOLS%..\IDE"
23   rem Visual Studio Express starting from VS 2012 is called "for Windows Desktop"
24   rem and has a new name for executable - WDExpress
25   set "VisualStudioExpressName=WDExpress"
26 ) else if "%VCVER%" == "vc12" (
27   set "DevEnvDir=%VS120COMNTOOLS%..\IDE"
28   set "VisualStudioExpressName=WDExpress"
29 ) else (
30   echo Error: wrong VS identifier
31   exit /B
32 )
33
34 rem Launch Visual Studio - either professional (devenv) or Express, as available
35 if exist "%DevEnvDir%\devenv.exe"  (
36   start "" "%DevEnvDir%\devenv.exe" "%PRJFILE%"
37 ) else if exist "%DevEnvDir%\%VisualStudioExpressName%.exe"  (
38   start "" "%DevEnvDir%\%VisualStudioExpressName%.exe" "%PRJFILE%"
39 ) else (
40   echo Error: Could not find MS Visual Studio ^(%VCVER%^)
41   echo Check relevant environment variable ^(e.g. VS80COMNTOOLS for vc8^)
42 )