0028920: Samples - fix msvc.bat for building samples without CMake
[occt.git] / adm / templates / env.bat
1 @echo off
2
3 rem Use:
4 rem - first argument specifies version of Visual Studio (vc8, vc9, or vc10),
5 rem - second argument specifies architecture (win32 or win64),
6 rem - third argument specifies build mode (Debug or Release)
7 rem Default options are:
8 rem   vc8 win32 Release
9
10 set "SCRIPTROOT=%~dp0"
11 set "SCRIPTROOT=%SCRIPTROOT:~0,-1%"
12
13 rem ----- Reset values to defaults -----
14 set "CASDEB="
15 set "VCVER=vc10"
16 set "ARCH=64"
17 set "VCVARS="
18 set "HAVE_TBB=false"
19 set "HAVE_OPENCL=false"
20 set "HAVE_FREEIMAGE=false"
21 set "HAVE_FFMPEG=false"
22 set "HAVE_GL2PS=false"
23 set "HAVE_VTK=false"
24 set "HAVE_GLES2=false"
25 set "HAVE_D3D=false"
26 set "HAVE_ZLIB=false"
27 set "HAVE_LIBLZMA=false"
28 set "CSF_OPT_INC="
29 set "CSF_OPT_LIB32="
30 set "CSF_OPT_LIB64="
31 set "CSF_OPT_BIN32="
32 set "CSF_OPT_BIN64="
33
34 rem ----- Load local settings -----
35 if exist "%~dp0custom.bat" (
36   call "%~dp0custom.bat" %1 %2 %3 %4 %5
37 )
38
39 if not ["%CASROOT%"] == [""] if exist "%SCRIPTROOT%\%CASROOT%" set "CASROOT=%SCRIPTROOT%\%CASROOT%"
40 if     ["%CASROOT%"] == [""] set "CASROOT=%SCRIPTROOT%"
41
42 rem ----- Read script arguments (override local settings) -----
43 if not ["%1"]    == [""]      set "VCVER=%1"
44 if not ["%2"]    == [""]      set "ARCH=%2"
45 if /I ["%ARCH%"] == ["win32"] set "ARCH=32"
46 if /I ["%ARCH%"] == ["win64"] set "ARCH=64"
47 if /I ["%3"]     == ["debug"] set "CASDEB=d"
48 if /I ["%3"]     == ["d"]     set "CASDEB=d"
49 if /I ["%3"]     == ["i"]     set "CASDEB=i"
50 if /I ["%3"]     == ["relwithdeb"] set "CASDEB=i"
51
52 rem Decode VCVER
53 call "%~dp0adm\vcver.bat"
54
55 rem ----- Parsing of Visual Studio platform -----
56 set "VisualStudioExpressName=VCExpress"
57
58 if not "%DevEnvDir%" == "" (
59   rem If DevEnvDir is already defined (e.g. in custom.bat), use that value
60 ) else if /I "%VCFMT%" == "vc10" (
61   set "DevEnvDir=%VS100COMNTOOLS%..\IDE"
62 ) else if /I "%VCFMT%" == "vc11" (
63   set "DevEnvDir=%VS110COMNTOOLS%..\IDE"
64   rem Visual Studio Express starting from VS 2012 is called "for Windows Desktop"
65   rem and has a new name for executable - WDExpress
66   set "VisualStudioExpressName=WDExpress"
67 ) else if /I "%VCFMT%" == "vc12" (
68   set "DevEnvDir=%VS120COMNTOOLS%..\IDE"
69   set "VisualStudioExpressName=WDExpress"
70 ) else if /I "%VCFMT%" == "vc14" (
71   set "DevEnvDir=%VS140COMNTOOLS%..\IDE"
72 ) else if /I "%VCFMT%" == "vc141" (
73   for /f "usebackq delims=" %%i in (`vswhere.exe -version "[15.0,15.99]" -requires Microsoft.VisualStudio.Workload.%VCPROP% -property installationPath`) do (
74     set "DevEnvDir=%%i\Common7\IDE\"
75   )
76 ) else (
77   echo Error: wrong VS identifier
78   exit /B
79 )
80
81 rem ----- Parsing vcvarsall for qt samples and define PlatformToolset -----
82 if /I "%VCFMT%" == "vc10" (
83   set "VCVARS=%VS100COMNTOOLS%..\..\VC\vcvarsall.bat"
84   set "VCPlatformToolSet=v100"
85 ) else if /I "%VCFMT%" == "vc11" (
86   set "VCVARS=%VS110COMNTOOLS%..\..\VC\vcvarsall.bat"
87   set "VCPlatformToolSet=v110"
88 ) else if /I "%VCFMT%" == "vc12" (
89   set "VCVARS=%VS120COMNTOOLS%..\..\VC\vcvarsall.bat"
90   set "VCPlatformToolSet=v120"
91 ) else if /I "%VCFMT%" == "vc14" (
92   set "VCVARS=%VS140COMNTOOLS%..\..\VC\vcvarsall.bat"
93   set "VCPlatformToolSet=v140"
94 ) else if /I "%VCFMT%" == "vc141" (
95   for /f "usebackq delims=" %%i in (`vswhere.exe -version "[15.0,15.99]" -requires Microsoft.VisualStudio.Workload.%VCPROP% -property installationPath`) do (
96     set "VCVARS=%%i\VC\Auxiliary\Build\vcvarsall.bat"
97   )
98   set "VCPlatformToolSet=v141"
99 ) else (
100   echo Error: first argument ^(%VCVER%^) should specify supported version of Visual C++,
101   echo one of: vc10 ^(VS 2010 SP3^), vc11 ^(VS 2012 SP3^), vc12 ^(VS 2013^) or vc14 ^(VS 2015^)
102   exit
103 )
104
105 set "CSF_OPT_LIB32D=%CSF_OPT_LIB32%"
106 set "CSF_OPT_LIB64D=%CSF_OPT_LIB64%"
107 set "CSF_OPT_BIN32D=%CSF_OPT_BIN32%"
108 set "CSF_OPT_BIN64D=%CSF_OPT_BIN64%"
109 set "CSF_OPT_LIB32I=%CSF_OPT_LIB32%"
110 set "CSF_OPT_LIB64I=%CSF_OPT_LIB64%"
111 set "CSF_OPT_BIN32I=%CSF_OPT_BIN32%"
112 set "CSF_OPT_BIN64I=%CSF_OPT_BIN64%"
113
114 rem ----- Optional 3rd-parties should be enabled by HAVE macros -----
115 set "CSF_OPT_CMPL="
116 set "PRODUCTS_DEFINES="
117 if ["%HAVE_TBB%"]       == ["true"] set "PRODUCTS_DEFINES=%PRODUCTS_DEFINES% -DHAVE_TBB"       & set "CSF_DEFINES=HAVE_TBB;%CSF_DEFINES%"
118 if ["%HAVE_OPENCL%"]    == ["true"] set "PRODUCTS_DEFINES=%PRODUCTS_DEFINES% -DHAVE_OPENCL"    & set "CSF_DEFINES=HAVE_OPENCL;%CSF_DEFINES%"
119 if ["%HAVE_GL2PS%"]     == ["true"] set "PRODUCTS_DEFINES=%PRODUCTS_DEFINES% -DHAVE_GL2PS"     & set "CSF_DEFINES=HAVE_GL2PS;%CSF_DEFINES%"
120 if ["%HAVE_FREEIMAGE%"] == ["true"] set "PRODUCTS_DEFINES=%PRODUCTS_DEFINES% -DHAVE_FREEIMAGE" & set "CSF_DEFINES=HAVE_FREEIMAGE;%CSF_DEFINES%"
121 if ["%HAVE_FFMPEG%"]    == ["true"] set "PRODUCTS_DEFINES=%PRODUCTS_DEFINES% -DHAVE_FFMPEG"    & set "CSF_DEFINES=HAVE_FFMPEG;%CSF_DEFINES%"
122 if ["%HAVE_VTK%"]       == ["true"] set "PRODUCTS_DEFINES=%PRODUCTS_DEFINES% -DHAVE_VTK"       & set "CSF_DEFINES=HAVE_VTK;%CSF_DEFINES%"
123 if ["%HAVE_GLES2%"]     == ["true"] set "PRODUCTS_DEFINES=%PRODUCTS_DEFINES% -DHAVE_GLES2"     & set "CSF_DEFINES=HAVE_GLES2;%CSF_DEFINES%"
124 if ["%HAVE_D3D%"]       == ["true"] set "PRODUCTS_DEFINES=%PRODUCTS_DEFINES% -DHAVE_D3D"       & set "CSF_DEFINES=HAVE_D3D;%CSF_DEFINES%"
125 if ["%HAVE_ZLIB%"]      == ["true"] set "PRODUCTS_DEFINES=%PRODUCTS_DEFINES% -DHAVE_ZLIB"      & set "CSF_DEFINES=HAVE_ZLIB;%CSF_DEFINES%"
126 if ["%HAVE_LIBLZMA%"]   == ["true"] set "PRODUCTS_DEFINES=%PRODUCTS_DEFINES% -DHAVE_LIBLZMA"   & set "CSF_DEFINES=HAVE_LIBLZMA;%CSF_DEFINES%"
127
128 rem Eliminate VS warning
129 if ["%CSF_DEFINES%"]  == [""] set "CSF_DEFINES=;"
130
131 rem ----- Optional 3rd-parties should be enabled by HAVE macros -----
132 if not ["%PRODUCTS_DEFINES%"] == [""] set "CSF_OPT_CMPL=%CSF_OPT_CMPL% %PRODUCTS_DEFINES%"
133
134 rem ----- Colect 3rd-parties additional include paths into compiler options -----
135 for %%a in ("%CSF_OPT_INC:;=";"%") do (
136   set "anItem=%%~a"
137   if not ["%%~a"] == [""] call :concatCmplInc %%~a
138 )
139
140 rem ----- Colect 3rd-parties additional library paths (32-bit) into linker options -----
141 set "OPT_LIB32="
142 for %%a in ("%CSF_OPT_LIB32:;=";"%") do (
143   set "anItem=%%~a"
144   if not ["%%~a"] == [""] call :concatLib32 %%~a
145 )
146
147 rem ----- Colect 3rd-parties additional library paths (64-bit) into linker options -----
148 set "OPT_LIB64="
149 for %%a in ("%CSF_OPT_LIB64:;=";"%") do (
150   set "anItem=%%~a"
151   if not ["%%~a"] == [""] call :concatLib64 %%~a
152 )
153
154 set "CSF_OPT_LNK32=%CSF_OPT_LNK32% %OPT_LIB32%"
155 set "CSF_OPT_LNK64=%CSF_OPT_LNK64% %OPT_LIB64%"
156 set "CSF_OPT_LNK32D=%CSF_OPT_LNK32D% %OPT_LIB32%"
157 set "CSF_OPT_LNK64D=%CSF_OPT_LNK64D% %OPT_LIB64%"
158 set "CSF_OPT_LNK32I=%CSF_OPT_LNK32I% %OPT_LIB32%"
159 set "CSF_OPT_LNK64I=%CSF_OPT_LNK64I% %OPT_LIB64%"
160
161 rem ----- Default paths to sub-folders (can be different in install env) -----
162 if "%CSF_OCCTIncludePath%" == "" set "CSF_OCCTIncludePath=%CASROOT%\inc"
163 if "%CSF_OCCTResourcePath%" == "" set "CSF_OCCTResourcePath=%CASROOT%\src"
164 if "%CSF_OCCTSamplesPath%" == "" set "CSF_OCCTSamplesPath=%CASROOT%\samples"
165 if "%CSF_OCCTDataPath%" == "" set "CSF_OCCTDataPath=%CASROOT%\data"
166 if "%CSF_OCCTTestsPath%" == "" set "CSF_OCCTTestsPath=%CASROOT%\tests"
167 if "%CSF_OCCTBinPath%" == "" set "CSF_OCCTBinPath=%CASROOT%\win%ARCH%\%VCLIB%\bin%CASDEB%"
168 if "%CSF_OCCTLibPath%" == "" set "CSF_OCCTLibPath=%CASROOT%\win%ARCH%\%VCLIB%\lib%CASDEB%"
169
170 rem ----- Set path to 3rd party and OCCT libraries -----
171 set "PATH=%CSF_OCCTBinPath%;%PATH%"
172 if ["%CASDEB%"] == [""] if ["%ARCH%"] == ["32"] set "PATH=%CSF_OPT_BIN32%;%PATH%"
173 if ["%CASDEB%"] == [""] if ["%ARCH%"] == ["64"] set "PATH=%CSF_OPT_BIN64%;%PATH%"
174 if ["%CASDEB%"] == ["d"] if ["%ARCH%"] == ["32"] set "PATH=%CSF_OPT_BIN32D%;%PATH%"
175 if ["%CASDEB%"] == ["d"] if ["%ARCH%"] == ["64"] set "PATH=%CSF_OPT_BIN64D%;%PATH%"
176 if ["%CASDEB%"] == ["i"] if ["%ARCH%"] == ["32"] set "PATH=%CSF_OPT_BIN32I%;%PATH%"
177 if ["%CASDEB%"] == ["i"] if ["%ARCH%"] == ["64"] set "PATH=%CSF_OPT_BIN64I%;%PATH%"
178
179 rem ----- Set envoronment variables used by OCCT -----
180 set CSF_LANGUAGE=us
181 set MMGT_CLEAR=1
182 set "CSF_SHMessage=%CSF_OCCTResourcePath%\SHMessage"
183 set "CSF_MDTVTexturesDirectory=%CSF_OCCTResourcePath%\Textures"
184 set "CSF_ShadersDirectory=%CSF_OCCTResourcePath%\Shaders"
185 set "CSF_XSMessage=%CSF_OCCTResourcePath%\XSMessage"
186 set "CSF_TObjMessage=%CSF_OCCTResourcePath%\TObj"
187 set "CSF_StandardDefaults=%CSF_OCCTResourcePath%\StdResource"
188 set "CSF_PluginDefaults=%CSF_OCCTResourcePath%\StdResource"
189 set "CSF_XCAFDefaults=%CSF_OCCTResourcePath%\StdResource"
190 set "CSF_TObjDefaults=%CSF_OCCTResourcePath%\StdResource"
191 set "CSF_StandardLiteDefaults=%CSF_OCCTResourcePath%\StdResource"
192 set "CSF_IGESDefaults=%CSF_OCCTResourcePath%\XSTEPResource"
193 set "CSF_STEPDefaults=%CSF_OCCTResourcePath%\XSTEPResource"
194 set "CSF_XmlOcafResource=%CSF_OCCTResourcePath%\XmlOcafResource"
195 set "CSF_MIGRATION_TYPES=%CSF_OCCTResourcePath%\StdResource\MigrationSheet.txt"
196
197 rem Draw Harness special stuff
198 if exist "%CSF_OCCTResourcePath%\DrawResources\DrawDefault" (
199   set "DRAWDEFAULT=%CSF_OCCTResourcePath%\DrawResources\DrawDefault"
200 )
201 if exist "%CSF_OCCTResourcePath%\DrawResources" (
202   set "DRAWHOME=%CSF_OCCTResourcePath%\DrawResources"
203   set "CSF_DrawPluginDefaults=%DRAWHOME%"
204 )
205 goto :eof
206
207 :concatCmplInc
208 set "CSF_OPT_CMPL=%CSF_OPT_CMPL% -I%1"
209 goto :eof
210
211 :concatLib32
212 rem Compiler options for Code::Blocks: -L for gcc/mingw and /LIBPATH for msvc
213 rem set "OPT_LIB32=%OPT_LIB32% /LIBPATH:%1"
214 set "OPT_LIB32=%OPT_LIB32% -L%1"
215 goto :eof
216
217 :concatLib64
218 rem Compiler options for Code::Blocks: -L for gcc/mingw and /LIBPATH for msvc
219 rem set "OPT_LIB64=%OPT_LIB64% /LIBPATH:%1"
220 set "OPT_LIB64=%OPT_LIB64% -L%1"
221 goto :eof