1 # This is an experimental Solution project for building entire OCCT framework using qmake.
2 # It can be also used for just source code navigation in Qt Creator without actually building OCCT.
3 # Note, as this is an experimental project, compiler flags might differ from official builds - use it on your own risk!
4 # Building OCCT using CMake is a preferred solution.
6 # This project GENERATES sub-projects (OCCT modules) dynamically, so to start using it:
7 # - Launch genconf, select Project Format "Qt Project" and configure dependencies; this will also generate "custom.auto.pri".
8 # - Launch genproj to fill in "inc" folder with links to header files.
9 # - Open project in Qt Creator, and call "Run qmake".
10 # - Close the project in Qt Creator, open it again so that you should see the sub-modules in Project tree; call "Run qmake" again.
11 # - "Run qmake" and perform Build.
13 exists(custom.auto.pri) { include(custom.auto.pri) }
14 exists(custom.pri) { include(custom.pri) }
16 OTHER_FILES += OccModule.pro.in \
17 OcctHeaderLink.hxx.in \
24 # Iterate over Modules and generate sub-projects
25 aSolModuleList = $$cat(../MODULES, lines)
26 for (aSolModuleIter, aSolModuleList) {
27 aSolModule = $$first($$list($$aSolModuleIter))
28 eval(occtkgen_$${aSolModule}.input = $$_PRO_FILE_PWD_/OccModule.pro.in)
29 eval(occtkgen_$${aSolModule}.output = $$_PRO_FILE_PWD_/$${aSolModule}/$${aSolModule}.pro)
30 eval(occtkgen_$${aSolModule}.config = verbatim)
31 eval(QMAKE_SUBSTITUTES += occtkgen_$${aSolModule})
32 SUBDIRS += $${aSolModule}
35 # These dependencies are manually defined
36 ModelingData.depends = FoundationClasses
37 ModelingAlgorithms.depends = FoundationClasses ModelingData
38 Visualization.depends = FoundationClasses ModelingData ModelingAlgorithms
39 ApplicationFramework.depends = FoundationClasses ModelingData ModelingAlgorithms Visualization
40 DataExchange.depends = FoundationClasses ModelingData ModelingAlgorithms ApplicationFramework
41 Draw.depends = FoundationClasses ModelingData ModelingAlgorithms ApplicationFramework DataExchange Visualization