adm/cmake/freetype.cmake

   1 # freetype
   2
   3 if (NOT DEFINED INSTALL_FREETYPE)
   4   set (INSTALL_FREETYPE OFF CACHE BOOL "${INSTALL_FREETYPE_DESCR}")
   5 endif()
   6
   7 if (NOT DEFINED 3RDPARTY_FREETYPE_DIR)
   8   set (3RDPARTY_FREETYPE_DIR "" CACHE PATH "The directory containing freetype")
   9 endif()
  10
  11 # include occt macros. compiler_bitness, os_wiht_bit, compiler
  12 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_macros")
  13
  14 OCCT_MAKE_COMPILER_SHORT_NAME()
  15 OCCT_MAKE_COMPILER_BITNESS()
  16
  17 # specify freetype folder in connectin with 3RDPARTY_DIR
  18 if (3RDPARTY_DIR AND EXISTS "${3RDPARTY_DIR}")
  19   #CHECK_PATH_FOR_CONSISTENCY (3RDPARTY_DIR 3RDPARTY_FREETYPE_DIR PATH "The directory containing freetype")
  20
  21   if (NOT 3RDPARTY_FREETYPE_DIR OR NOT EXISTS "${3RDPARTY_FREETYPE_DIR}")
  22     FIND_PRODUCT_DIR ("${3RDPARTY_DIR}" FREETYPE FREETYPE_DIR_NAME)
  23     if (FREETYPE_DIR_NAME)
  24       set (3RDPARTY_FREETYPE_DIR "${3RDPARTY_DIR}/${FREETYPE_DIR_NAME}" CACHE PATH "The directory containing freetype" FORCE)
  25     endif()
  26   endif()
  27 else()
  28   #set (3RDPARTY_FREETYPE_DIR "" CACHE PATH "The directory containing freetype" FORCE)
  29 endif()
  30
  31 # define required freetype variables
  32 if (NOT DEFINED 3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build)
  33   set (3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build  "" CACHE FILEPATH "the path of ft2build.h")
  34 endif()
  35
  36 if (NOT DEFINED 3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2)
  37   set (3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2 "" CACHE FILEPATH "the path of freetype2")
  38 endif()
  39
  40 if (NOT DEFINED 3RDPARTY_FREETYPE_LIBRARY OR NOT 3RDPARTY_FREETYPE_LIBRARY_DIR OR NOT EXISTS "${3RDPARTY_FREETYPE_LIBRARY_DIR}")
  41   set (3RDPARTY_FREETYPE_LIBRARY               "" CACHE FILEPATH "freetype library" FORCE)
  42 endif()
  43
  44 if (NOT DEFINED 3RDPARTY_FREETYPE_LIBRARY_DIR)
  45   set (3RDPARTY_FREETYPE_LIBRARY_DIR           "" CACHE PATH "The directory containing freetype library")
  46 endif()
  47
  48 if (WIN32)
  49   if (NOT DEFINED 3RDPARTY_FREETYPE_DLL OR NOT 3RDPARTY_FREETYPE_DLL_DIR OR NOT EXISTS "${3RDPARTY_FREETYPE_DLL_DIR}")
  50     set (3RDPARTY_FREETYPE_DLL                 "" CACHE FILEPATH "freetype shared library" FORCE)
  51   endif()
  52 endif()
  53
  54 if (WIN32)
  55   if (NOT DEFINED 3RDPARTY_FREETYPE_DLL_DIR)
  56     set (3RDPARTY_FREETYPE_DLL_DIR               "" CACHE PATH "The directory containing freetype shared library")
  57   endif()
  58 endif()
  59
  60 # check 3RDPARTY_FREETYPE_ paths for consistency with specified 3RDPARTY_FREETYPE_DIR
  61 if (3RDPARTY_FREETYPE_DIR AND EXISTS "${3RDPARTY_FREETYPE_DIR}")
  62   CHECK_PATH_FOR_CONSISTENCY (3RDPARTY_FREETYPE_DIR 3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build FILEPATH "the path to ft2build.h")
  63   CHECK_PATH_FOR_CONSISTENCY (3RDPARTY_FREETYPE_DIR 3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2 FILEPATH "the path to ftheader.h")
  64   CHECK_PATH_FOR_CONSISTENCY (3RDPARTY_FREETYPE_DIR 3RDPARTY_FREETYPE_LIBRARY FILEPATH "the path to freetype library")
  65
  66   if (3RDPARTY_FREETYPE_LIBRARY AND EXISTS "${3RDPARTY_FREETYPE_LIBRARY}")
  67     get_filename_component (3RDPARTY_FREETYPE_LIBRARY_DIR "${3RDPARTY_FREETYPE_LIBRARY}" PATH)
  68     set (3RDPARTY_FREETYPE_LIBRARY_DIR "${3RDPARTY_FREETYPE_LIBRARY_DIR}" CACHE PATH "The directory containing freetype library" FORCE)
  69   else()
  70     CHECK_PATH_FOR_CONSISTENCY (3RDPARTY_FREETYPE_DIR 3RDPARTY_FREETYPE_LIBRARY_DIR PATH "The directory containing freetype library")
  71   endif()
  72
  73   if (WIN32)
  74     CHECK_PATH_FOR_CONSISTENCY (3RDPARTY_FREETYPE_DIR 3RDPARTY_FREETYPE_DLL FILEPATH "the path to freetype shared library")
  75
  76     if (3RDPARTY_FREETYPE_DLL AND EXISTS "${3RDPARTY_FREETYPE_DLL}")
  77       get_filename_component (3RDPARTY_FREETYPE_DLL_DIR "${3RDPARTY_FREETYPE_DLL}" PATH)
  78       set (3RDPARTY_FREETYPE_DLL_DIR "${3RDPARTY_FREETYPE_DLL_DIR}" CACHE PATH "The directory containing freetype shared library" FORCE)
  79     else()
  80
  81     CHECK_PATH_FOR_CONSISTENCY (3RDPARTY_FREETYPE_DIR 3RDPARTY_FREETYPE_DLL_DIR PATH "The directory containing freetype shared library")
  82     endif()
  83   endif()
  84 endif()
  85
  86 # the FIRST step in search for freetype library and header folders (built-in search engine)
  87
  88 # execute built-in search engine to seek freetype
  89 set (IS_BUILTIN_SEARCH_REQUIRED OFF)
  90 if (NOT 3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build OR NOT EXISTS "${3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build}")
  91   set (IS_BUILTIN_SEARCH_REQUIRED ON)
  92 elseif (NOT 3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2 OR NOT EXISTS "${3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2}")
  93   set (IS_BUILTIN_SEARCH_REQUIRED ON)
  94 elseif (NOT 3RDPARTY_FREETYPE_LIBRARY OR NOT EXISTS "${3RDPARTY_FREETYPE_LIBRARY}")
  95   set (IS_BUILTIN_SEARCH_REQUIRED ON)
  96 #elseif (WIN32)
  97   #if (NOT 3RDPARTY_FREETYPE_DLL OR NOT EXISTS "${3RDPARTY_FREETYPE_DLL}")
  98   #  set (IS_BUILTIN_SEARCH_REQUIRED ON)
  99   #endif()
 100 endif()
 101
 102 if (IS_BUILTIN_SEARCH_REQUIRED)
 103
 104   # use 3RDPARTY_FREETYPE_DIR if it is specified for freetype search
 105   if (3RDPARTY_FREETYPE_DIR AND EXISTS "${3RDPARTY_FREETYPE_DIR}")
 106     set (CACHED_FREETYPE_DIR $ENV{FREETYPE_DIR})
 107     set (ENV{FREETYPE_DIR} "${3RDPARTY_FREETYPE_DIR}")
 108   endif()
 109
 110   find_package(Freetype)
 111
 112   # restore ENV{FREETYPE_DIR}
 113   if (3RDPARTY_FREETYPE_DIR AND EXISTS "${3RDPARTY_FREETYPE_DIR}")
 114     set (ENV{FREETYPE_DIR} ${CACHED_FREETYPE_DIR})
 115   endif()
 116
 117   # check the found paths for consistency with specified 3RDPARTY_FREETYPE_DIR
 118   if (3RDPARTY_FREETYPE_DIR AND EXISTS "${3RDPARTY_FREETYPE_DIR}")
 119     CHECK_PATH_FOR_CONSISTENCY (3RDPARTY_FREETYPE_DIR FREETYPE_INCLUDE_DIR_ft2build FILEPATH "the path to ft2build.h")
 120     CHECK_PATH_FOR_CONSISTENCY (3RDPARTY_FREETYPE_DIR FREETYPE_INCLUDE_DIR_freetype2 FILEPATH "the path to ftheader.h")
 121     CHECK_PATH_FOR_CONSISTENCY (3RDPARTY_FREETYPE_DIR FREETYPE_LIBRARY FILEPATH "freetype library")
 122   endif()
 123
 124   # assign the found paths to corresponding 3RDPARTY_FREETYPE_ variables
 125   if (NOT 3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build OR NOT EXISTS "${3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build}")
 126     if (FREETYPE_INCLUDE_DIR_ft2build AND EXISTS "${FREETYPE_INCLUDE_DIR_ft2build}")
 127       set (3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build  "${FREETYPE_INCLUDE_DIR_ft2build}" CACHE FILEPATH "the path to ft2build.h" FORCE)
 128     endif()
 129   endif()
 130
 131   if (NOT 3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2 OR NOT EXISTS "${3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2}")
 132     if (FREETYPE_INCLUDE_DIR_freetype2 AND EXISTS "${FREETYPE_INCLUDE_DIR_freetype2}")
 133       set (3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2  "${FREETYPE_INCLUDE_DIR_freetype2}" CACHE FILEPATH "the path to ftheader.h" FORCE)
 134     endif()
 135   endif()
 136
 137   if (NOT 3RDPARTY_FREETYPE_LIBRARY OR NOT EXISTS "${3RDPARTY_FREETYPE_LIBRARY}")
 138     if (FREETYPE_LIBRARY AND EXISTS "${FREETYPE_LIBRARY}")
 139       set (3RDPARTY_FREETYPE_LIBRARY  "${FREETYPE_LIBRARY}" CACHE FILEPATH "The path to freetype library" FORCE)
 140     endif()
 141   endif()
 142
 143   if (3RDPARTY_FREETYPE_LIBRARY AND EXISTS "${3RDPARTY_FREETYPE_LIBRARY}")
 144     get_filename_component (3RDPARTY_FREETYPE_LIBRARY_DIR "${3RDPARTY_FREETYPE_LIBRARY}" PATH)
 145     set (3RDPARTY_FREETYPE_LIBRARY_DIR "${3RDPARTY_FREETYPE_LIBRARY_DIR}" CACHE PATH "The directory containing freetype library" FORCE)
 146   else()
 147     set (3RDPARTY_FREETYPE_LIBRARY_DIR "" CACHE PATH "The directory containing freetype library" FORCE)
 148   endif()
 149 endif()
 150
 151 # the SECOND step in search for freetype library and header folders (additional search algorithms)
 152
 153 # ft2build.h
 154 if (NOT 3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build OR NOT EXISTS "${3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build}")
 155   set (FT2BUILD_NAMES ft2build.h config/ft2build.h freetype/config/ft2build.h)
 156
 157   # set 3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build as notfound, otherwise find_library can't assign a new value to 3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build
 158   set (3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build "3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build-NOTFOUND" CACHE FILEPATH "the path to ft2build.h" FORCE)
 159
 160   # cmake (version < 3.0) doesn't find ft2build.h of freetype (version is >= 2.5.1)
 161   # do search taking into account freetype structure of 2.5.1 version
 162   if (3RDPARTY_FREETYPE_DIR AND EXISTS "${3RDPARTY_FREETYPE_DIR}")
 163     find_path (3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build NAMES ${FT2BUILD_NAMES}
 164                                                       PATHS ${3RDPARTY_FREETYPE_DIR}
 165                                                       PATH_SUFFIXES include freetype2 include/freetype2
 166                                                       CMAKE_FIND_ROOT_PATH_BOTH
 167                                                       NO_DEFAULT_PATH)
 168   else()
 169     find_path (3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build NAMES ${FT2BUILD_NAMES}
 170                                                       PATHS /usr/X11R6 /usr/local/X11R6 /usr/local/X11 /usr/freeware
 171                                                       PATH_SUFFIXES include/freetype2 include freetype2
 172                                                       CMAKE_FIND_ROOT_PATH_BOTH)
 173   endif()
 174 endif()
 175
 176 if (3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build AND EXISTS "${3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build}")
 177   list (APPEND 3RDPARTY_INCLUDE_DIRS "${3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build}")
 178 else()
 179   list (APPEND 3RDPARTY_NOT_INCLUDED 3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build)
 180
 181   set (3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build "" CACHE FILEPATH "the path to ft2build.h" FORCE)
 182 endif()
 183
 184 # ftheader.h
 185 if (NOT 3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2 OR NOT EXISTS "${3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2}")
 186   set (FTHEADER_NAMES ftheader.h config/ftheader.h freetype/config/ftheader.h)
 187
 188   # set 3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2 as notfound, otherwise find_library can't assign a new value to 3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2
 189   set (3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2 "3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2-NOTFOUND" CACHE FILEPATH "the path to ftheader.h" FORCE)
 190
 191   if (3RDPARTY_FREETYPE_DIR AND EXISTS "${3RDPARTY_FREETYPE_DIR}")
 192     find_path (3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2 NAMES ${FTHEADER_NAMES}
 193                                                        HINTS ${3RDPARTY_FREETYPE_DIR}
 194                                                        PATH_SUFFIXES include/freetype2 include freetype2
 195                                                        CMAKE_FIND_ROOT_PATH_BOTH
 196                                                        NO_DEFAULT_PATH)
 197   else()
 198     find_path (3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2 NAMES ${FTHEADER_NAMES}
 199                                                        PATHS /usr/X11R6 /usr/local/X11R6 /usr/local/X11 /usr/freeware
 200                                                        PATH_SUFFIXES include/freetype2 include freetype2
 201                                                        CMAKE_FIND_ROOT_PATH_BOTH)
 202   endif()
 203 endif()
 204
 205 if (3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2 AND EXISTS "${3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2}")
 206   list (APPEND 3RDPARTY_INCLUDE_DIRS "${3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2}")
 207 else()
 208   list (APPEND 3RDPARTY_NOT_INCLUDED 3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2)
 209
 210   set (3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2 "" CACHE FILEPATH "the path to ftheader.h" FORCE)
 211 endif()
 212
 213 # freetype library
 214 if (NOT 3RDPARTY_FREETYPE_LIBRARY OR NOT EXISTS "${3RDPARTY_FREETYPE_LIBRARY}")
 215   set (CMAKE_FIND_LIBRARY_SUFFIXES .lib .so .dylib)
 216
 217   set (FREETYPE_PATH_SUFFIXES lib)
 218   if (ANDROID)
 219     set (FREETYPE_PATH_SUFFIXES ${FREETYPE_PATH_SUFFIXES} libs/${ANDROID_ABI})
 220   endif()
 221
 222   # set 3RDPARTY_FREETYPE_LIBRARY as notfound, otherwise find_library can't assign a new value to 3RDPARTY_FREETYPE_LIBRARY
 223   set (3RDPARTY_FREETYPE_LIBRARY "3RDPARTY_FREETYPE_LIBRARY-NOTFOUND" CACHE FILEPATH "The path to freetype library" FORCE)
 224
 225   if (3RDPARTY_FREETYPE_DIR AND EXISTS "${3RDPARTY_FREETYPE_DIR}")
 226     find_library (3RDPARTY_FREETYPE_LIBRARY freetype
 227                                             PATHS "${3RDPARTY_FREETYPE_LIBRARY_DIR}" "${3RDPARTY_FREETYPE_DIR}"
 228                                             PATH_SUFFIXES ${FREETYPE_PATH_SUFFIXES}
 229                                             CMAKE_FIND_ROOT_PATH_BOTH
 230                                             NO_DEFAULT_PATH)
 231   else()
 232     find_library (3RDPARTY_FREETYPE_LIBRARY freetype
 233                                             PATH_SUFFIXES ${FREETYPE_PATH_SUFFIXES}
 234                                             CMAKE_FIND_ROOT_PATH_BOTH)
 235   endif()
 236
 237   if (3RDPARTY_FREETYPE_LIBRARY AND EXISTS "${3RDPARTY_FREETYPE_LIBRARY}")
 238     get_filename_component (3RDPARTY_FREETYPE_LIBRARY_DIR "${3RDPARTY_FREETYPE_LIBRARY}" PATH)
 239     set (3RDPARTY_FREETYPE_LIBRARY_DIR "${3RDPARTY_FREETYPE_LIBRARY_DIR}" CACHE PATH "The directory containing freetype library" FORCE)
 240   else()
 241     set (3RDPARTY_FREETYPE_LIBRARY_DIR "" CACHE PATH "The directory containing freetype library" FORCE)
 242   endif()
 243 endif()
 244
 245 if (3RDPARTY_FREETYPE_LIBRARY_DIR AND EXISTS "${3RDPARTY_FREETYPE_LIBRARY_DIR}")
 246   list (APPEND 3RDPARTY_LIBRARY_DIRS "${3RDPARTY_FREETYPE_LIBRARY_DIR}")
 247 else()
 248   list (APPEND 3RDPARTY_NOT_INCLUDED 3RDPARTY_FREETYPE_LIBRARY_DIR)
 249
 250   set (3RDPARTY_FREETYPE_LIBRARY "" CACHE FILEPATH "The path to freetype library" FORCE)
 251 endif()
 252
 253 # freetype shared library
 254 if (WIN32)
 255   if (NOT 3RDPARTY_FREETYPE_DLL OR NOT EXISTS "${3RDPARTY_FREETYPE_DLL}")
 256
 257     set (CMAKE_FIND_LIBRARY_SUFFIXES .dll)
 258
 259     # set 3RDPARTY_FREETYPE_DLL as notfound, otherwise find_library can't assign a new value to 3RDPARTY_FREETYPE_DLL
 260     set (3RDPARTY_FREETYPE_DLL "3RDPARTY_FREETYPE_DLL-NOTFOUND" CACHE FILEPATH "The path to freetype shared library" FORCE)
 261
 262     if (3RDPARTY_FREETYPE_DIR AND EXISTS "${3RDPARTY_FREETYPE_DIR}")
 263       find_library (3RDPARTY_FREETYPE_DLL freetype
 264                                           PATHS "${3RDPARTY_FREETYPE_DIR}"
 265                                           PATH_SUFFIXES bin
 266                                           NO_DEFAULT_PATH)
 267     else()
 268       find_library (3RDPARTY_FREETYPE_DLL freetype
 269                                           PATH_SUFFIXES bin)
 270     endif()
 271
 272     if (3RDPARTY_FREETYPE_DLL AND EXISTS "${3RDPARTY_FREETYPE_DLL}")
 273       get_filename_component (3RDPARTY_FREETYPE_DLL_DIR "${3RDPARTY_FREETYPE_DLL}" PATH)
 274       set (3RDPARTY_FREETYPE_DLL_DIR "${3RDPARTY_FREETYPE_DLL_DIR}" CACHE PATH "The directory containing freetype library" FORCE)
 275     else()
 276       set (3RDPARTY_FREETYPE_DLL_DIR "" CACHE PATH "The directory containing freetype shared library" FORCE)
 277
 278       set (3RDPARTY_FREETYPE_DLL "" CACHE FILEPATH "freetype shared library" FORCE)
 279     endif()
 280   endif()
 281
 282   if (3RDPARTY_FREETYPE_DLL_DIR OR EXISTS "${3RDPARTY_FREETYPE_DLL_DIR}")
 283     list (APPEND 3RDPARTY_DLL_DIRS "${3RDPARTY_FREETYPE_DLL_DIR}")
 284   else()
 285     list (APPEND 3RDPARTY_NOT_INCLUDED 3RDPARTY_FREETYPE_DLL_DIR)
 286   endif()
 287 endif()
 288
 289
 290 # install instructions
 291 if (INSTALL_FREETYPE)
 292   OCCT_MAKE_OS_WITH_BITNESS()
 293
 294   if (WIN32)
 295     if (DEFINED INSTALL_BIN_DIR)
 296       install (FILES "${3RDPARTY_FREETYPE_DLL}" DESTINATION "${INSTALL_BIN_DIR}")
 297     else()
 298       install (FILES "${3RDPARTY_FREETYPE_DLL}"
 299                CONFIGURATIONS Release
 300                DESTINATION "${INSTALL_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
 301       install (FILES "${3RDPARTY_FREETYPE_DLL}"
 302                CONFIGURATIONS RelWithDebInfo
 303                DESTINATION "${INSTALL_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
 304       install (FILES "${3RDPARTY_FREETYPE_DLL}"
 305                CONFIGURATIONS Debug
 306                DESTINATION "${INSTALL_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
 307     endif()
 308   else()
 309     get_filename_component(3RDPARTY_FREETYPE_LIBRARY_ABS ${3RDPARTY_FREETYPE_LIBRARY} REALPATH)
 310     get_filename_component(3RDPARTY_FREETYPE_LIBRARY_NAME ${3RDPARTY_FREETYPE_LIBRARY} NAME)
 311
 312     if (DEFINED INSTALL_LIB_DIR)
 313       install (FILES "${3RDPARTY_FREETYPE_LIBRARY_ABS}"
 314                DESTINATION "${INSTALL_LIB_DIR}"
 315                RENAME ${3RDPARTY_FREETYPE_LIBRARY_NAME}.6)
 316     else()
 317       install (FILES "${3RDPARTY_FREETYPE_LIBRARY_ABS}"
 318                CONFIGURATIONS Release
 319                DESTINATION "${INSTALL_DIR}/${OS_WITH_BIT}/${COMPILER}/lib"
 320                RENAME ${3RDPARTY_FREETYPE_LIBRARY_NAME}.6)
 321       install (FILES "${3RDPARTY_FREETYPE_LIBRARY_ABS}"
 322                CONFIGURATIONS RelWithDebInfo
 323                DESTINATION "${INSTALL_DIR}/${OS_WITH_BIT}/${COMPILER}/libi"
 324                RENAME ${3RDPARTY_FREETYPE_LIBRARY_NAME}.6)
 325       install (FILES "${3RDPARTY_FREETYPE_LIBRARY_ABS}"
 326                CONFIGURATIONS Debug
 327                DESTINATION "${INSTALL_DIR}/${OS_WITH_BIT}/${COMPILER}/libd"
 328                RENAME ${3RDPARTY_FREETYPE_LIBRARY_NAME}.6)
 329     endif()
 330   endif()
 331
 332   set (USED_3RDPARTY_FREETYPE_DIR "")
 333 else()
 334   # the library directory for using by the executable
 335   if (WIN32)
 336     set (USED_3RDPARTY_FREETYPE_DIR ${3RDPARTY_FREETYPE_DLL_DIR})
 337   else()
 338     set (USED_3RDPARTY_FREETYPE_DIR ${3RDPARTY_FREETYPE_LIBRARY_DIR})
 339   endif()
 340 endif()
 341
 342 # unset all redundant variables
 343 OCCT_CHECK_AND_UNSET(FREETYPE_INCLUDE_DIR_ft2build)
 344 OCCT_CHECK_AND_UNSET(FREETYPE_INCLUDE_DIR_freetype2)
 345 OCCT_CHECK_AND_UNSET(FREETYPE_LIBRARY)
 346
 347 mark_as_advanced (3RDPARTY_FREETYPE_LIBRARY 3RDPARTY_FREETYPE_DLL)