0027212: Make cmake configurator flexible concerning option BUILD_WITH_DEBUG
[occt.git] / CMakeLists.txt
1 cmake_minimum_required (VERSION 2.8.12 FATAL_ERROR)
2
3 set (CMAKE_SUPPRESS_REGENERATION TRUE)
4
5 set (CMAKE_CONFIGURATION_TYPES Release Debug RelWithDebInfo CACHE INTERNAL "" FORCE)
6
7 # macro: include patched file if it exists
8 macro (OCCT_INCLUDE_CMAKE_FILE BEING_INCLUDED_FILE)
9   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake")
10     include (${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake)
11   else()
12     include (${CMAKE_SOURCE_DIR}/${BEING_INCLUDED_FILE}.cmake)
13   endif()
14 endmacro()
15
16 # include variable description
17 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vardescr")
18
19 # set type of OCCT libraries
20 if (NOT BUILD_LIBRARY_TYPE)
21   set (BUILD_LIBRARY_TYPE "Shared" CACHE STRING "${BUILD_LIBRARY_TYPE_DESCR}" FORCE)
22   SET_PROPERTY(CACHE BUILD_LIBRARY_TYPE PROPERTY STRINGS Shared Static)
23 endif()
24
25 if ("${BUILD_LIBRARY_TYPE}" STREQUAL "Shared")
26   set (BUILD_SHARED_LIBS ON)
27
28   if (NOT DEFINED BUILD_SHARED_LIBRARY_NAME_POSTFIX)
29     set (BUILD_SHARED_LIBRARY_NAME_POSTFIX "" CACHE STRING "${BUILD_SHARED_LIBRARY_NAME_POSTFIX_DESCR}" FORCE)
30   endif()
31 else()
32   unset (BUILD_SHARED_LIBS)
33   message (STATUS "Info: Only 3rdparty's header files are used for building of static OCCT libraries")
34   unset (BUILD_SHARED_LIBRARY_NAME_POSTFIX)
35 endif()
36
37 # the name of the project
38 project (OCCT)
39
40 # include occt macros
41 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_macros")
42
43 # Solution folder property
44 set_property (GLOBAL PROPERTY USE_FOLDERS ON)
45
46 # get current OCCT version
47 OCC_VERSION (OCC_VERSION_MAJOR OCC_VERSION_MINOR OCC_VERSION_MAINTENANCE OCC_VERSION_DEVELOPMENT OCC_VERSION_STRING_EXT)
48
49 set_property (GLOBAL PROPERTY OCC_VERSION_MAJOR ${OCC_VERSION_MAJOR})
50 set_property (GLOBAL PROPERTY OCC_VERSION_MINOR ${OCC_VERSION_MINOR})
51 set_property (GLOBAL PROPERTY OCC_VERSION_MAINTENANCE ${OCC_VERSION_MAINTENANCE})
52
53 set (INSTALL_TEST_CASES OFF CACHE BOOL "${INSTALL_TEST_CASES_DESCR}")
54
55 # single-configuration generator
56 set (SINGLE_GENERATOR OFF)
57 if (CMAKE_BUILD_TYPE)
58   set (SINGLE_GENERATOR ON)
59 endif()
60
61 # a single-configuration generator like the Makefile generator defines CMAKE_BUILD_TYPE variable
62 # check this variable and set if it's required
63 if (DEFINED CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE) # single-configuration generator.
64   set (CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel." FORCE)
65 endif()
66
67 # enable extended messages of many OCCT algorithms
68 if ((SINGLE_GENERATOR AND "${CMAKE_BUILD_TYPE}" STREQUAL "Debug") OR NOT SINGLE_GENERATOR)
69   if (NOT BUILD_WITH_DEBUG)
70     set (BUILD_WITH_DEBUG OFF CACHE BOOL "${BUILD_WITH_DEBUG_DESCR}")
71   endif()
72 else()
73   OCCT_CHECK_AND_UNSET (BUILD_WITH_DEBUG)
74 endif()
75
76 if (BUILD_WITH_DEBUG)
77   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:DEBUG>:OCCT_DEBUG>)
78 endif()
79
80 # copy samples to install directory
81 set (INSTALL_SAMPLES OFF CACHE BOOL "${INSTALL_SAMPLES_DESCR}")
82
83 # install dir of the project
84 if (NOT DEFINED INSTALL_DIR)
85   # set default install directory for Windows
86   if (WIN32 AND NOT DEFINED CMAKE_INSTALL_PREFIX)
87     set (CMAKE_INSTALL_PREFIX "C:/opencascade-${OCC_VERSION_STRING_EXT}")
88   endif()
89   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}")
90 else()
91   file (TO_CMAKE_PATH "${INSTALL_DIR}" INSTALL_DIR)
92   set (INSTALL_DIR "${INSTALL_DIR}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
93 endif()
94
95 # choose a variant of the layout of the install paths
96 if (NOT INSTALL_DIR_LAYOUT)
97   if (WIN32)
98     set (INSTALL_DIR_LAYOUT "Windows" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
99   else()
100     set (INSTALL_DIR_LAYOUT "Unix" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
101   endif()
102   SET_PROPERTY(CACHE INSTALL_DIR_LAYOUT PROPERTY STRINGS Windows Unix)
103 endif()
104
105 # check INSTALL_DIR_LAYOUT changes and update INSTALL_DIR_* paths if necessary
106 if (NOT DEFINED INSTALL_DIR_LAYOUT_PREV)
107   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
108 elseif (NOT "${INSTALL_DIR_LAYOUT_PREV}" STREQUAL "${INSTALL_DIR_LAYOUT}")
109   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
110   # The structure of install folder should be reset due to changed layout
111   OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
112
113   # Unset INSTALL_DIR_WITH_VERSION on windows
114   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
115     OCCT_CHECK_AND_UNSET (INSTALL_DIR_WITH_VERSION)
116   else()
117     if (NOT DEFINED INSTALL_DIR_WITH_VERSION)
118       set (INSTALL_DIR_WITH_VERSION OFF CACHE BOOL "${INSTALL_DIR_WITH_VERSION_DESCR}")
119     endif()
120   endif()
121 endif()
122
123 # check CMAKE_INSTALL_PREFIX changes and update INSTALL_DIR if necessary
124 if (NOT DEFINED CMAKE_INSTALL_PREFIX_PREV)
125   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
126 elseif (NOT "${CMAKE_INSTALL_PREFIX_PREV}" STREQUAL "${CMAKE_INSTALL_PREFIX}")
127   # CMAKE_INSTALL_PREFIX has been changed at previous step
128   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
129   
130   # INSTALL_DIR is required to be updated
131   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
132 endif()
133
134 # check INSTALL_DIR changes and update CMAKE_INSTALL_PREFIX if necessary
135 if (NOT DEFINED INSTALL_DIR_PREV)
136   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
137 elseif (NOT "${INSTALL_DIR_PREV}" STREQUAL "${INSTALL_DIR}")
138   # INSTALL_DIR has been changed at previous step
139   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
140
141   # sync CMAKE_INSTALL_PREFIX with INSTALL_DIR 
142   set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
143
144   # set CMAKE_INSTALL_PREFIX_PREV to avoid the reset of structure of the install folder 
145   set (CMAKE_INSTALL_PREFIX_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
146 endif()
147
148 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
149   if (NOT DEFINED INSTALL_DIR_WITH_VERSION_PREV)
150     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
151   elseif (NOT "${INSTALL_DIR_WITH_VERSION_PREV}" STREQUAL "${INSTALL_DIR_WITH_VERSION}")
152     # INSTALL_DIR_WITH_VERSION has been changed at previous step
153     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
154
155     OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
156   endif()
157 endif()
158
159 # hide CMAKE_INSTALL_PREFIX from a user
160 set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
161
162 set (BIN_LETTER "")
163 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
164   set (BIN_LETTER "d")
165 elseif ("${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo")
166   set (BIN_LETTER "i")
167 endif()
168
169 # Get all used variables: OS_WITH_BIT, COMPILER
170 OCCT_MAKE_OS_WITH_BITNESS()
171 OCCT_MAKE_COMPILER_SHORT_NAME()
172
173 # do not define INSTALL_DIR_BIN for win.
174 # Leave library structure for win: <prefix>/win64/vc10/bin(d)
175 if (NOT DEFINED INSTALL_DIR_BIN)
176   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
177     set (INSTALL_DIR_BIN "bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
178   else()
179     set (INSTALL_DIR_BIN "${OS_WITH_BIT}/${COMPILER}/bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
180   endif()
181 endif()
182
183 # define folder contaning all shell/batch scripts
184 if (NOT DEFINED INSTALL_DIR_SCRIPT)
185   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
186     set (INSTALL_DIR_SCRIPT "${INSTALL_DIR_BIN}" CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
187   else()
188     set (INSTALL_DIR_SCRIPT "." CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
189   endif()
190 endif()
191
192 # place the libraries to <prefix>/lib folder for unix and leave old structure for windows
193 if (NOT DEFINED INSTALL_DIR_LIB)
194   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
195     set (INSTALL_DIR_LIB "lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
196   else()
197     set (INSTALL_DIR_LIB "${OS_WITH_BIT}/${COMPILER}/lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
198   endif()
199 endif()
200
201 # OCCT headers: <prefix>/inc for windows,
202 #               <prefix>/include/opencascade-7.0.0 for unix
203 if (NOT DEFINED INSTALL_DIR_INCLUDE)
204   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
205     set (INSTALL_DIR_INCLUDE "include/opencascade" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
206     if (INSTALL_DIR_WITH_VERSION)
207       set (INSTALL_DIR_INCLUDE "include/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}" FORCE)
208     endif()
209   else()
210     set (INSTALL_DIR_INCLUDE "inc" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
211   endif()
212 endif()
213
214 # OCCT resources: <prefix>/src for windows,
215 #                 <prefix>/share/opencascade-7.0.0/resources for unix
216 if (NOT DEFINED INSTALL_DIR_RESOURCE)
217   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
218     set (INSTALL_DIR_RESOURCE "share/opencascade/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
219     if (INSTALL_DIR_WITH_VERSION)
220       set (INSTALL_DIR_RESOURCE "share/opencascade-${OCC_VERSION_STRING_EXT}/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}" FORCE)
221     endif()
222   else()
223     set (INSTALL_DIR_RESOURCE "src" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
224   endif()
225 endif()
226
227 # OCCT data
228 if (NOT DEFINED INSTALL_DIR_DATA)
229   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
230     set (INSTALL_DIR_DATA "share/opencascade/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
231     if (INSTALL_DIR_WITH_VERSION)
232       set (INSTALL_DIR_DATA "share/opencascade-${OCC_VERSION_STRING_EXT}/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}" FORCE)
233     endif()
234   else()
235     set (INSTALL_DIR_DATA "data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
236   endif()
237 endif()
238
239 # OCCT samples
240 if (NOT DEFINED INSTALL_DIR_SAMPLES)
241   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
242     set (INSTALL_DIR_SAMPLES "share/opencascade/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
243     if (INSTALL_DIR_WITH_VERSION)
244       set (INSTALL_DIR_SAMPLES "share/opencascade-${OCC_VERSION_STRING_EXT}/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}" FORCE)
245     endif()
246   else()
247     set (INSTALL_DIR_SAMPLES "samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
248   endif()
249 endif()
250
251 # OCCT tests
252 if (NOT DEFINED INSTALL_DIR_TESTS)
253   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
254     set (INSTALL_DIR_TESTS "share/opencascade/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
255     if (INSTALL_DIR_WITH_VERSION)
256       set (INSTALL_DIR_TESTS "share/opencascade-${OCC_VERSION_STRING_EXT}/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}" FORCE)
257     endif()
258   else()
259     set (INSTALL_DIR_TESTS "tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
260   endif()
261 endif()
262
263 # OCCT doc
264 if (NOT DEFINED INSTALL_DIR_DOC)
265   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
266     set (INSTALL_DIR_DOC "share/doc/opencascade" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
267     if (INSTALL_DIR_WITH_VERSION)
268       set (INSTALL_DIR_DOC "share/doc/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_DOC_DESCR}" FORCE)
269     endif()
270   else()
271     set (INSTALL_DIR_DOC "doc" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
272   endif()
273 endif()
274
275 # define folder contaning CMake configuration files
276 if (NOT DEFINED INSTALL_DIR_CMAKE)
277   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
278     if (INSTALL_DIR_WITH_VERSION)
279       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
280     else()
281       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
282     endif()
283   else()
284     set (INSTALL_DIR_CMAKE "cmake" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
285   endif()
286 endif()
287
288 # install LICENSE_LGPL_21.txt and OCCT_LGPL_EXCEPTION.txt files
289 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
290   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" "${INSTALL_DIR}/${INSTALL_DIR_DOC}")
291   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" "${INSTALL_DIR}/${INSTALL_DIR_DOC}")
292 else()
293   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" "${INSTALL_DIR}")
294   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" "${INSTALL_DIR}")
295 endif()
296
297 # a directory recognized as a 'patch' for OCCT
298 set (BUILD_PATCH "" CACHE PATH "${BUILD_PATCH_DESCR}")
299
300 # the list of being built toolkits
301 set (BUILD_ADDITIONAL_TOOLKITS "" CACHE STRING "${BUILD_ADDITIONAL_TOOLKITS_DESCR}")
302 separate_arguments (BUILD_ADDITIONAL_TOOLKITS)
303
304 if (MSVC)
305   set (BUILD_MODULE_MfcSamples OFF CACHE BOOL "${BUILD_MODULE_MfcSamples_DESCR}")
306 endif()
307
308 # whether use optional 3rdparty or not
309 if (APPLE)
310   set (USE_GLX OFF CACHE BOOL "${USE_GLX_DESCR}")
311 endif()
312
313 if (WIN32)
314   set (USE_D3D OFF CACHE BOOL "${USE_D3D_DESCR}")
315 endif()
316
317 # include the patched or original list of modules
318 # list <MODULENAME>_TOOLKITS is created foreach module and contains its toolkits
319 # list <OCCT_MODULES> will contain all modules
320 OCCT_MODULES_AND_TOOLKITS (OCCT_MODULES)
321
322 foreach (OCCT_MODULE ${OCCT_MODULES})
323   BUILD_MODULE (${OCCT_MODULE})
324 endforeach()
325
326 if (ANDROID AND BUILD_MODULE_Draw)
327   message (STATUS "Info. Draw module is turned off due to it is not supported on Android")
328   set (BUILD_MODULE_Draw OFF CACHE BOOL "${BUILD_MODULE_Draw_DESCR}" FORCE)
329 endif()
330
331 # Overview
332 if (NOT DEFINED BUILD_DOC_Overview)
333   set (DO_ONLY_CHECK_FOR_DOXYGEN ON)
334   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
335   set (DO_ONLY_CHECK_FOR_DOXYGEN OFF)
336   
337   if (CAN_DOXYGEN_BE_USED)
338     message (STATUS "Info. Overview building is turned on")
339   endif()
340
341   set (BUILD_DOC_Overview ${CAN_DOXYGEN_BE_USED} CACHE BOOL "${BUILD_DOC_Overview_DESCR}")
342 endif()
343
344 if (NOT USE_D3D)
345   list (REMOVE_ITEM Visualization_TOOLKITS TKD3DHost)
346 endif()
347
348 # accumulate used toolkits (first level) in BUILD_TOOLKITS variable
349 list (APPEND BUILD_TOOLKITS ${BUILD_ADDITIONAL_TOOLKITS})
350
351 foreach (OCCT_MODULE ${OCCT_MODULES})
352   if (BUILD_MODULE_${OCCT_MODULE})
353     list (APPEND BUILD_TOOLKITS ${${OCCT_MODULE}_TOOLKITS})
354   endif()
355 endforeach()
356
357 # DRAWEXE excluded when library build is static
358 if (NOT BUILD_SHARED_LIBS)
359   list (REMOVE_ITEM BUILD_TOOLKITS DRAWEXE)
360   message (STATUS "Info: DRAWEXE is not included due to ${BUILD_LIBRARY_TYPE} build library type")
361 endif()
362
363 # accumulate all used toolkits
364 list (REMOVE_DUPLICATES BUILD_TOOLKITS)
365 set (RAW_BUILD_TOOLKITS)
366 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
367   OCCT_TOOLKIT_FULL_DEP (${BUILD_TOOLKIT} TOOLKIT_FULL_DEPS)
368   list (APPEND RAW_BUILD_TOOLKITS ${BUILD_TOOLKIT} ${TOOLKIT_FULL_DEPS})
369 endforeach()
370
371 list (REMOVE_DUPLICATES RAW_BUILD_TOOLKITS)
372 set (BUILD_TOOLKITS ${RAW_BUILD_TOOLKITS})
373
374 # include the patched or original list of definitions and flags
375 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_defs_flags")
376
377 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/3rdparty_macro")
378
379 # search for TKIVtk and TKIVtkDraw in BUILD_TOOLKITS
380 list (FIND BUILD_TOOLKITS TKIVtk CAN_USE_VTK)
381 if (CAN_USE_VTK EQUAL -1)
382   list (FIND BUILD_TOOLKITS TKIVtkDraw CAN_USE_VTK)
383 endif()
384
385 if (NOT CAN_USE_VTK EQUAL -1)
386   if (NOT DEFINED USE_VTK)
387     set (USE_VTK OFF CACHE BOOL "${USE_VTK_DESCR}")
388   endif()
389 else()
390   OCCT_CHECK_AND_UNSET (USE_VTK)
391 endif()
392
393 # Rebuild *.yacc and *.lex files that are contained by TKMath toolkit
394 list (FIND BUILD_TOOLKITS TKMath   CAN_REBUILD_PDC_FOR_TKMATH)
395 list (FIND BUILD_TOOLKITS StepFile CAN_REBUILD_PDC_FOR_STEPFILE)
396
397 if (NOT ${CAN_REBUILD_PDC_FOR_TKMATH} EQUAL -1 OR NOT ${CAN_REBUILD_PDC_FOR_STEPFILE} EQUAL -1)
398   set (BUILD_YACCLEX OFF CACHE BOOL "${BUILD_YACCLEX_DESCR}")
399 else()
400   OCCT_CHECK_AND_UNSET (BUILD_YACCLEX)
401 endif()
402
403 if (NOT DEFINED 3RDPARTY_DIR)
404   set (3RDPARTY_DIR "" CACHE PATH ${3RDPARTY_DIR_DESCR})
405   get_filename_component (3RDPARTY_DIR "${3RDPARTY_DIR}" ABSOLUTE)
406 else()
407   file (TO_CMAKE_PATH "${3RDPARTY_DIR}" 3RDPARTY_DIR)
408   set (3RDPARTY_DIR "${3RDPARTY_DIR}" CACHE PATH "${3RDPARTY_DIR_DESCR}" FORCE)
409 endif()
410
411 # search for CSF_TclLibs variable in EXTERNLIB of each being used toolkit
412 OCCT_IS_PRODUCT_REQUIRED (CSF_TclLibs USE_TCL)
413
414 if (USE_TCL)
415   message (STATUS "Info: TCL is used by OCCT")
416   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tcl")
417   
418   message (STATUS "Info: TK is used by OCCT")
419   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tk")
420 else()
421   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TCL")
422   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TK")
423
424   OCCT_CHECK_AND_UNSET ("INSTALL_TCL")
425   OCCT_CHECK_AND_UNSET ("INSTALL_TK")
426 endif()
427
428 # search for CSF_FREETYPE variable in EXTERNLIB of each being used toolkit
429 OCCT_IS_PRODUCT_REQUIRED (CSF_FREETYPE USE_FREETYPE)
430
431 if (USE_FREETYPE)
432   message (STATUS "Info: Freetype is used by OCCT")
433   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freetype")
434 else()
435   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREETYPE")
436   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2")
437   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build")
438   OCCT_CHECK_AND_UNSET ("INSTALL_FREETYPE")
439 endif()
440
441 # VTK
442 if (USE_VTK)
443   add_definitions (-DHAVE_VTK)
444   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vtk")
445 else()
446   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_VTK")
447   
448   if (NOT CAN_USE_VTK EQUAL -1)
449     message (STATUS "Info: TKIVtk and TKIVtkDraw toolkits excluded due to VTK usage is disabled")
450
451     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtk)
452     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtkDraw)
453   endif()
454 endif()
455
456 # D3D
457 if (USE_D3D)
458   add_definitions (-DHAVE_D3D)
459   #if(MSVC_VERSION LESS 1700)
460   #OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/d3d")
461   #endif()
462 endif()
463
464 # GLX
465 if (USE_GLX)
466   add_definitions (-DMACOSX_USE_GLX)
467   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/glx")
468 endif()
469
470 # FREEIMAGE
471 # search for CSF_FREEIMAGE variable in EXTERNLIB of each being used toolkit
472 OCCT_IS_PRODUCT_REQUIRED (CSF_FREEIMAGE     CAN_USE_FREEIMAGE)
473 OCCT_IS_PRODUCT_REQUIRED (CSF_FreeImagePlus CAN_USE_FREEIMAGEPLUS)
474
475 if (CAN_USE_FREEIMAGE OR CAN_USE_FREEIMAGEPLUS)
476   set (USE_FREEIMAGE OFF CACHE BOOL "${USE_FREEIMAGE_DESCR}")
477
478   if (USE_FREEIMAGE)
479     add_definitions (-DHAVE_FREEIMAGE)
480     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimage")
481     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimageplus")
482   else()
483     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
484     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGEPLUS")
485     OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
486     OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGEPLUS")
487   endif()
488 else()
489   OCCT_CHECK_AND_UNSET ("USE_FREEIMAGE")
490
491   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
492   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGEPLUS")
493   OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
494   OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGEPLUS")
495 endif()
496
497 # GL2PS
498 # search for CSF_GL2PS variable in EXTERNLIB of each being used toolkit
499 OCCT_IS_PRODUCT_REQUIRED (CSF_GL2PS CAN_USE_GL2PS)
500
501 if (NOT DEFINED ANDROID AND CAN_USE_GL2PS)
502   set (USE_GL2PS OFF CACHE BOOL "${USE_GL2PS_DESCR}")
503
504   if (USE_GL2PS)
505     add_definitions (-DHAVE_GL2PS)
506     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gl2ps")
507   else()
508     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
509     OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
510   endif()
511 else()
512   OCCT_CHECK_AND_UNSET ("USE_GL2PS")
513
514   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
515   OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
516 endif()
517
518 # TBB
519 # search for CSF_TBB variable in EXTERNLIB of each being used toolkit
520 OCCT_IS_PRODUCT_REQUIRED (CSF_TBB CAN_USE_TBB)
521
522 if (NOT DEFINED ANDROID AND CAN_USE_TBB)
523   set (USE_TBB OFF CACHE BOOL "${USE_TBB_DESCR}")
524
525   if (USE_TBB)
526     add_definitions (-DHAVE_TBB)
527     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tbb")
528   else()
529     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
530     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
531     OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
532   endif()
533 else()
534   OCCT_CHECK_AND_UNSET ("USE_TBB")
535
536   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
537   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
538   OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
539 endif()
540
541 # Doxygen
542 if (BUILD_DOC_Overview)
543   if (NOT DEFINED INSTALL_DOC_Overview)
544     set (INSTALL_DOC_Overview OFF CACHE BOOL "${INSTALL_DOC_Overview_DESCR}")
545   endif()
546
547   if (INSTALL_DOC_Overview)
548     install (DIRECTORY "${CMAKE_BINARY_DIR}/doc/overview" DESTINATION  "${INSTALL_DIR}/${INSTALL_DIR_DOC}")
549
550     # create overview.html only for windows
551     if (WIN32 AND "${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
552       OCCT_INSTALL_FILE_OR_DIR ("dox/resources/overview.html" "${INSTALL_DIR}/${INSTALL_DIR_DOC}/..")
553     endif()
554   endif()
555
556   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
557 else()
558   OCCT_CHECK_AND_UNSET ("INSTALL_DOC_Overview")
559
560   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOXYGEN_EXECUTABLE")
561   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOT_EXECUTABLE")
562 endif()
563
564 # bison 
565 if (BUILD_YACCLEX)
566   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/bison")
567 else()
568   OCCT_CHECK_AND_UNSET ("3RDPARTY_BISON_EXECUTABLE")
569 endif()
570
571 # flex 
572 if (BUILD_YACCLEX)
573   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/flex")
574 else()
575   OCCT_CHECK_AND_UNSET ("3RDPARTY_FLEX_EXECUTABLE")
576 endif()
577
578 string (REGEX REPLACE ";" " " 3RDPARTY_NOT_INCLUDED "${3RDPARTY_NOT_INCLUDED}")
579
580 # check all 3rdparty paths
581 if (3RDPARTY_NOT_INCLUDED)
582   message (FATAL_ERROR "NOT FOUND: ${3RDPARTY_NOT_INCLUDED}" )
583 endif()
584
585 if (3RDPARTY_INCLUDE_DIRS)
586   list (REMOVE_DUPLICATES 3RDPARTY_INCLUDE_DIRS)
587   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_INCLUDE_DIRS_WITH_ENDS "${3RDPARTY_INCLUDE_DIRS}")
588   message (STATUS "Info: The directories of 3rdparty headers: \n\t${3RDPARTY_INCLUDE_DIRS_WITH_ENDS}")
589   include_directories (${3RDPARTY_INCLUDE_DIRS})
590 endif()
591
592 # include <cmake binary folder>/inc
593 include_directories (${CMAKE_BINARY_DIR}/inc)
594
595 if (3RDPARTY_LIBRARY_DIRS AND BUILD_SHARED_LIBS)
596   list (REMOVE_DUPLICATES 3RDPARTY_LIBRARY_DIRS)
597   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_LIBRARY_DIRS_WITH_ENDS "${3RDPARTY_LIBRARY_DIRS}")
598   message (STATUS "Info: The directories of 3rdparty libraries: \n\t${3RDPARTY_LIBRARY_DIRS_WITH_ENDS}")
599   link_directories (${3RDPARTY_LIBRARY_DIRS})
600 endif()
601
602 # build directories
603 if (SINGLE_GENERATOR)
604   set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
605   set (CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
606   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
607   if (WIN32)
608     set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
609   endif()
610 endif()
611
612 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
613 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
614 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
615
616 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
617 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
618 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
619
620 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
621 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
622 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
623
624 if (WIN32) 
625   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE        "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
626   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
627   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG          "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
628 endif()
629
630 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
631 message (STATUS "\nInfo: \(${CURRENT_TIME}\) Start collecting all OCCT header files into ${CMAKE_BINARY_DIR}/inc ...")
632
633 # collect all the headers to <binary dir>/inc folder
634 COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}" "${BUILD_TOOLKITS}")
635
636 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
637 message (STATUS "Info: \(${CURRENT_TIME}\) End the collecting")
638
639 OCCT_INSTALL_FILE_OR_DIR ("data/" "${INSTALL_DIR}/${INSTALL_DIR_DATA}")
640
641 if (WIN32)
642   set (SCRIPT_EXT bat)
643 else()
644   set (SCRIPT_EXT sh)
645 endif()
646
647 # OCCT samples
648 if (INSTALL_SAMPLES)
649   OCCT_CONFIGURE ("adm/templates/env.samples.${SCRIPT_EXT}.in" "env.samples.${SCRIPT_EXT}")
650   if (WIN32)
651     OCCT_INSTALL_FILE_OR_DIR ("samples/CSharp" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
652     OCCT_INSTALL_FILE_OR_DIR ("samples/mfc" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
653
654     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}/CSharp" RENAME "env.${SCRIPT_EXT}")
655     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}/mfc/standard" RENAME "env.${SCRIPT_EXT}")
656   endif()
657
658   OCCT_INSTALL_FILE_OR_DIR ("samples/java" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
659   OCCT_INSTALL_FILE_OR_DIR ("samples/ocafsamples" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
660   OCCT_INSTALL_FILE_OR_DIR ("samples/qt" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
661
662   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}/qt/FuncDemo" RENAME "env.${SCRIPT_EXT}")
663   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}/qt/IESample" RENAME "env.${SCRIPT_EXT}")
664   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}/qt/Tutorial" RENAME "env.${SCRIPT_EXT}")
665 endif()
666
667 OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
668
669 if (INSTALL_TEST_CASES)
670   OCCT_INSTALL_FILE_OR_DIR ("tests/" "${INSTALL_DIR}/${INSTALL_DIR_TESTS}")
671 endif()
672
673 # copy draw script to install script folder
674 if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}")
675   install (FILES "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}"
676           PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
677 else()
678   install (FILES "${CMAKE_SOURCE_DIR}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}"
679           PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
680 endif()
681
682 # copy draw script to CMake binary folder
683 OCCT_COPY_FILE_OR_DIR ("adm/templates/draw.${SCRIPT_EXT}" "${CMAKE_BINARY_DIR}")
684
685 set (SUB_CUSTOM_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.${SCRIPT_EXT}")
686
687 if (WIN32)
688   set (ADDITIONAL_CUSTOM_CONTENT "\nif exist \"%~dp0${SUB_CUSTOM_NAME}\" (\n  call \"%~dp0${SUB_CUSTOM_NAME}\" %1 %2 %3 \n)")
689 else()
690   set (ADDITIONAL_CUSTOM_CONTENT "\nif [ -e \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" ]; then\n  source \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" \"\$1\" \"\$2\" \nfi")
691 endif()
692
693  # change custom.bat/sh
694 if (EXISTS "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}")
695   file (READ "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" CUSTOM_CONTENT)
696
697   set (CUSTOM_CONTENT "${CUSTOM_CONTENT} ${ADDITIONAL_CUSTOM_CONTENT}")
698
699   file (WRITE "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" "${CUSTOM_CONTENT}")
700 else()
701   OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.${SCRIPT_EXT}.main" "custom.${SCRIPT_EXT}" "custom.${SCRIPT_EXT}" "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}")
702 endif()
703
704 # write current custom.bat/sh (for install directory)
705 set (SUB_CUSTOM_BUILD_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.install.${SCRIPT_EXT}")
706 OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.install.${SCRIPT_EXT}.in" "${SUB_CUSTOM_BUILD_NAME}" "${SUB_CUSTOM_NAME}" "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}")
707
708 # write current custom.bat/sh (for build directory)
709 OCCT_CONFIGURE ("adm/templates/custom.build.${SCRIPT_EXT}.in" "${SUB_CUSTOM_NAME}")
710
711 if (BUILD_MODULE_MfcSamples)
712   OCCT_INSTALL_FILE_OR_DIR ("adm/templates/sample.bat" "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}")
713   OCCT_COPY_FILE_OR_DIR    ("adm/templates/sample.bat" "${CMAKE_BINARY_DIR}")
714 endif()
715
716 # env script for draw in building environment
717 OCCT_CONFIGURE ("adm/templates/env.${SCRIPT_EXT}.in" "env.${SCRIPT_EXT}")
718
719 # install env script
720 install (FILES "${CMAKE_BINARY_DIR}/env.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}")
721
722 # copy DrawAppliInit from OCCT source to build directory
723 if (NOT EXISTS "${CMAKE_BINARY_DIR}/DrawAppliInit")
724   OCCT_COPY_FILE_OR_DIR (DrawAppliInit "${CMAKE_BINARY_DIR}")
725 endif()
726
727 # RESOURCES
728 FILE_TO_LIST ("adm/RESOURCES" RESOURCES)
729 foreach(RESOURCE ${RESOURCES})
730   get_filename_component(RESOURCE_FOLDER ${RESOURCE} DIRECTORY)
731   if(NOT "${RESOURCE_FOLDER}" STREQUAL "")
732     get_filename_component(RESOURCE_FOLDER ${RESOURCE_FOLDER} NAME)
733     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR}/${INSTALL_DIR_RESOURCE}/${RESOURCE_FOLDER}")
734   else()
735     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR}/${INSTALL_DIR_RESOURCE}")
736   endif()
737 endforeach()
738
739 # patch installed DrawDefault file if BUILD_SHARED_LIBRARY_NAME_POSTFIX is changed
740 if (NOT "${BUILD_SHARED_LIBRARY_NAME_POSTFIX}" STREQUAL "")
741   OCCT_UPDATE_DRAW_DEFAULT_FILE()
742 endif()
743
744 # define CSF variable
745 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_csf")
746
747 # include patched toolkit projects or original ones
748 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
749   OCCT_ADD_SUBDIRECTORY ("src/${BUILD_TOOLKIT}")
750 endforeach()
751
752 if (BUILD_DOC_Overview)
753   OCCT_ADD_SUBDIRECTORY (dox)
754 endif()
755
756 # patch DRAWEXE
757 if (MSVC AND 3RDPARTY_DLL_DIRS)
758   list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
759   if (${DRAWEXE_INDEX} GREATER -1)
760     list (REMOVE_DUPLICATES 3RDPARTY_DLL_DIRS)
761     set (3RDPARTY_DLL_DIRS_FOR_PATH "")
762
763     foreach (3RDPARTY_DLL_DIR ${3RDPARTY_DLL_DIRS})
764       set (3RDPARTY_DLL_DIRS_FOR_PATH "${3RDPARTY_DLL_DIRS_FOR_PATH};${3RDPARTY_DLL_DIR}")
765     endforeach()
766
767     OCCT_MAKE_COMPILER_BITNESS()
768     set (X_COMPILER_BITNESS "x64")
769     if ("${COMPILER_BITNESS}" STREQUAL "32")
770       set (X_COMPILER_BITNESS "Win32")
771     endif()
772
773     OCCT_CONFIGURE ("adm/templates/DRAWEXE.vcxproj.user.in" "${CMAKE_BINARY_DIR}/src/DRAWEXE/DRAWEXE.vcxproj.user")
774   endif()
775 endif()
776
777 # samples do not support patch usage
778 if (BUILD_MODULE_MfcSamples)
779   set (OCCT_ROOT ${CMAKE_SOURCE_DIR})
780
781   set (MFC_STANDARD_SAMPLES_DIR ${OCCT_ROOT}/samples/mfc/standard)
782   set (COMMON_WINMAIN_FILE      ${MFC_STANDARD_SAMPLES_DIR}/Common/Winmain.cpp)
783
784   add_subdirectory(samples/mfc/standard/mfcsample)
785   add_subdirectory(samples/mfc/standard/01_Geometry)
786   add_subdirectory(samples/mfc/standard/02_Modeling)
787   add_subdirectory(samples/mfc/standard/03_Viewer2d)
788   add_subdirectory(samples/mfc/standard/04_Viewer3d)
789   add_subdirectory(samples/mfc/standard/05_ImportExport)
790   add_subdirectory(samples/mfc/standard/06_Ocaf)
791   add_subdirectory(samples/mfc/standard/07_Triangulation)
792   add_subdirectory(samples/mfc/standard/08_HLR)
793   add_subdirectory(samples/mfc/standard/09_Animation)
794   add_subdirectory(samples/mfc/standard/10_Convert)
795 endif()
796
797 # Prepare variables for configuration of OpenCASCADE cmake config file
798 set (OCCT_MODULES_ENABLED)
799 set (OCCT_LIBRARIES)
800 set (SET_OpenCASCADE_MODULES_TOOLKITS "\n# List of available OpenCASCADE libraries for each module\n")
801 foreach (OCCT_TOOLKIT ${BUILD_TOOLKITS})
802   if (TARGET ${OCCT_TOOLKIT})
803
804     # get all libraries
805     get_target_property (${OCCT_TOOLKIT}_TYPE ${OCCT_TOOLKIT} "TYPE")
806     if ("${${OCCT_TOOLKIT}_TYPE}" STREQUAL "STATIC_LIBRARY" OR "${${OCCT_TOOLKIT}_TYPE}" STREQUAL "SHARED_LIBRARY" )
807       list (APPEND OCCT_LIBRARIES ${OCCT_TOOLKIT})
808
809       # get all modules
810       get_target_property (${OCCT_TOOLKIT}_MODULE ${OCCT_TOOLKIT} "MODULE")
811       list (APPEND OCCT_MODULES_ENABLED ${${OCCT_TOOLKIT}_MODULE})
812       list (APPEND OpenCASCADE_${${OCCT_TOOLKIT}_MODULE}_TOOLKITS ${OCCT_TOOLKIT})
813     endif()
814   endif()
815 endforeach()
816 list (REMOVE_DUPLICATES OCCT_MODULES_ENABLED)
817
818 foreach (OCCT_MODULE ${OCCT_MODULES})
819   if (BUILD_MODULE_${OCCT_MODULE})
820     set (SET_OpenCASCADE_MODULES_TOOLKITS "${SET_OpenCASCADE_MODULES_TOOLKITS}set (OpenCASCADE_${OCCT_MODULE}_LIBRARIES ${OpenCASCADE_${OCCT_MODULE}_TOOLKITS})\n")
821   endif()
822
823   # sort enabled modules for correct work of OpenCASCADE config file
824   list(FIND OCCT_MODULES_ENABLED "${OCCT_MODULE}" OCCT_MODULE_INDEX)
825   if (NOT ${OCCT_MODULE_INDEX} EQUAL -1)
826     list (APPEND OCCT_MODULES_ENABLED_SORTED ${OCCT_MODULE})
827   endif()
828 endforeach()
829 set (OCCT_MODULES_ENABLED ${OCCT_MODULES_ENABLED_SORTED})
830
831 # Add all targets to the build-tree export set
832 export (TARGETS ${OCCT_LIBRARIES} FILE "${CMAKE_BINARY_DIR}/OpenCASCADETargets.cmake")
833
834 # Export the package for use from the build-tree
835 # (this registers the build-tree with a global CMake-registry)
836 export(PACKAGE OpenCASCADE)
837
838 if (CMAKE_BUILD_TYPE)
839   set (SET_OpenCASCADE_BUILD_TYPE "set (OpenCASCADE_BUILD_TYPE        \"${CMAKE_BUILD_TYPE}\")")
840 endif()
841
842 if (BUILD_SHARED_LIBS)
843   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_SHARED_LINKER_FLAGS}\")")
844 else()
845   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_STATIC_LINKER_FLAGS}\")")
846 endif()
847
848 if (WIN32)
849   set (SET_OpenCASCADE_WITH_D3D "set (OpenCASCADE_WITH_D3D       ${USE_D3D})")
850 endif()
851 if (APPLE)
852   set (SET_OpenCASCADE_WITH_GLX "set (OpenCASCADE_WITH_GLX       ${USE_GLX})")
853 endif()
854
855 if (NOT SINGLE_GENERATOR)
856   OCCT_INSERT_CODE_FOR_TARGET()
857 endif()
858
859 # Configure and install cmake config file
860 configure_file("${CMAKE_SOURCE_DIR}/adm/templates/OpenCASCADEConfig.cmake.in" "OpenCASCADEConfig.cmake" @ONLY)
861 install(FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfig.cmake" DESTINATION  "${INSTALL_DIR}/${INSTALL_DIR_CMAKE}")
862
863 # Configure cmake version file
864 include(CMakePackageConfigHelpers)
865 write_basic_package_version_file( ${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake
866                                   VERSION ${OCC_VERSION_MAJOR}.${OCC_VERSION_MINOR}.${OCC_VERSION_MAINTENANCE}
867                                   COMPATIBILITY ExactVersion )
868
869 # Install cmake version file
870 install (FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_CMAKE}")
871
872 # Install the export set for use with the install-tree for each configuration
873 foreach (OCCT_MODULE ${OCCT_MODULES_ENABLED})
874   install(EXPORT OpenCASCADE${OCCT_MODULE}Targets DESTINATION "${INSTALL_DIR_CMAKE}")
875 endforeach()
876
877 # Update generated OpenCASCADETargets-*.cmake files 
878 # to have correct paths to libraries depending on the configuration
879 OCCT_UPDATE_TARGET_FILE ()