0027301: CMake: export targets for OCCT
[occt.git] / CMakeLists.txt
1 cmake_minimum_required (VERSION 2.8.12 FATAL_ERROR)
2
3 set (CMAKE_SUPPRESS_REGENERATION TRUE)
4
5 set (CMAKE_CONFIGURATION_TYPES Release Debug RelWithDebInfo CACHE INTERNAL "" FORCE)
6
7 # macro: include patched file if it exists
8 macro (OCCT_INCLUDE_CMAKE_FILE BEING_INCLUDED_FILE)
9   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake")
10     include (${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake)
11   else()
12     include (${CMAKE_SOURCE_DIR}/${BEING_INCLUDED_FILE}.cmake)
13   endif()
14 endmacro()
15
16 # include variable description
17 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vardescr")
18
19 # set type of OCCT libraries
20 if (NOT BUILD_LIBRARY_TYPE)
21   set (BUILD_LIBRARY_TYPE "Shared" CACHE STRING "${BUILD_LIBRARY_TYPE_DESCR}" FORCE)
22   SET_PROPERTY(CACHE BUILD_LIBRARY_TYPE PROPERTY STRINGS Shared Static)
23 endif()
24
25 if ("${BUILD_LIBRARY_TYPE}" STREQUAL "Shared")
26   set (BUILD_SHARED_LIBS ON)
27 else()
28   unset (BUILD_SHARED_LIBS)
29 endif()
30
31 # the name of the project
32 project (OCCT)
33
34 # include occt macros
35 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_macros")
36
37 # Solution folder property
38 set_property (GLOBAL PROPERTY USE_FOLDERS ON)
39
40 # get current OCCT version
41 OCC_VERSION (OCC_VERSION_MAJOR OCC_VERSION_MINOR OCC_VERSION_MAINTENANCE OCC_VERSION_DEVELOPMENT OCC_VERSION_STRING_EXT)
42
43 set_property (GLOBAL PROPERTY OCC_VERSION_MAJOR ${OCC_VERSION_MAJOR})
44 set_property (GLOBAL PROPERTY OCC_VERSION_MINOR ${OCC_VERSION_MINOR})
45 set_property (GLOBAL PROPERTY OCC_VERSION_MAINTENANCE ${OCC_VERSION_MAINTENANCE})
46
47 set (INSTALL_TEST_CASES OFF CACHE BOOL "${INSTALL_TEST_CASES_DESCR}")
48
49 # single-configuration generator
50 set (SINGLE_GENERATOR OFF)
51 if (CMAKE_BUILD_TYPE)
52   set (SINGLE_GENERATOR ON)
53 endif()
54
55 # a single-configuration generator like the Makefile generator defines CMAKE_BUILD_TYPE variable
56 # check this variable and set if it's required
57 if (DEFINED CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE) # single-configuration generator.
58   set (CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel." FORCE)
59 endif()
60
61 # enable extended messages of many OCCT algorithms
62 set (BUILD_WITH_DEBUG OFF CACHE BOOL "${BUILD_WITH_DEBUG_DESCR}")
63 if (BUILD_WITH_DEBUG)
64   add_definitions (-DOCCT_DEBUG)
65 endif()
66
67 # copy samples to install directory
68 set (INSTALL_SAMPLES OFF CACHE BOOL "${INSTALL_SAMPLES_DESCR}")
69
70 # install dir of the project
71 if (NOT DEFINED INSTALL_DIR)
72   # set default install directory for Windows
73   if (WIN32)
74     set (CMAKE_INSTALL_PREFIX "C:/opencascade-${OCC_VERSION_STRING_EXT}")
75   endif()
76   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}")
77 endif()
78
79 # choose a variant of the layout of the install paths
80 if (NOT INSTALL_DIR_LAYOUT)
81   if (WIN32)
82     set (INSTALL_DIR_LAYOUT "Windows" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
83   else()
84     set (INSTALL_DIR_LAYOUT "Unix" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
85   endif()
86   SET_PROPERTY(CACHE INSTALL_DIR_LAYOUT PROPERTY STRINGS Windows Unix)
87 endif()
88
89 # check INSTALL_DIR_LAYOUT changes and update INSTALL_DIR_* paths if necessary
90 if (NOT DEFINED INSTALL_DIR_LAYOUT_PREV)
91   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
92 elseif (NOT "${INSTALL_DIR_LAYOUT_PREV}" STREQUAL "${INSTALL_DIR_LAYOUT}")
93   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
94   # The structure of install folder should be reset due to changed layout
95   OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
96
97   # Unset INSTALL_DIR_WITH_VERSION on windows
98   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
99     OCCT_CHECK_AND_UNSET (INSTALL_DIR_WITH_VERSION)
100   else()
101     if (NOT DEFINED INSTALL_DIR_WITH_VERSION)
102       set (INSTALL_DIR_WITH_VERSION OFF CACHE BOOL "${INSTALL_DIR_WITH_VERSION_DESCR}")
103     endif()
104   endif()
105 endif()
106
107 # check CMAKE_INSTALL_PREFIX changes and update INSTALL_DIR if necessary
108 if (NOT DEFINED CMAKE_INSTALL_PREFIX_PREV)
109   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
110 elseif (NOT "${CMAKE_INSTALL_PREFIX_PREV}" STREQUAL "${CMAKE_INSTALL_PREFIX}")
111   # CMAKE_INSTALL_PREFIX has been changed at previous step
112   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
113   
114   # INSTALL_DIR is required to be updated
115   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
116 endif()
117
118 # check INSTALL_DIR changes and update CMAKE_INSTALL_PREFIX if necessary
119 if (NOT DEFINED INSTALL_DIR_PREV)
120   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
121 elseif (NOT "${INSTALL_DIR_PREV}" STREQUAL "${INSTALL_DIR}")
122   # INSTALL_DIR has been changed at previous step
123   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
124
125   # sync CMAKE_INSTALL_PREFIX with INSTALL_DIR 
126   set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
127
128   # set CMAKE_INSTALL_PREFIX_PREV to avoid the reset of structure of the install folder 
129   set (CMAKE_INSTALL_PREFIX_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
130 endif()
131
132 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
133   if (NOT DEFINED INSTALL_DIR_WITH_VERSION_PREV)
134     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
135   elseif (NOT "${INSTALL_DIR_WITH_VERSION_PREV}" STREQUAL "${INSTALL_DIR_WITH_VERSION}")
136     # INSTALL_DIR_WITH_VERSION has been changed at previous step
137     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
138
139     OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
140   endif()
141 endif()
142
143 # hide CMAKE_INSTALL_PREFIX from a user
144 set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
145
146 set (BIN_LETTER "")
147 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
148   set (BIN_LETTER "d")
149 elseif ("${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo")
150   set (BIN_LETTER "i")
151 endif()
152
153 # Get all used variables: OS_WITH_BIT, COMPILER
154 OCCT_MAKE_OS_WITH_BITNESS()
155 OCCT_MAKE_COMPILER_SHORT_NAME()
156
157 # do not define INSTALL_DIR_BIN for win.
158 # Leave library structure for win: <prefix>/win64/vc10/bin(d)
159 if (NOT DEFINED INSTALL_DIR_BIN)
160   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
161     set (INSTALL_DIR_BIN "bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
162   else()
163     set (INSTALL_DIR_BIN "${OS_WITH_BIT}/${COMPILER}/bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
164   endif()
165 endif()
166
167 # define folder contaning all shell/batch scripts
168 if (NOT DEFINED INSTALL_DIR_SCRIPT)
169   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
170     set (INSTALL_DIR_SCRIPT "${INSTALL_DIR_BIN}" CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
171   else()
172     set (INSTALL_DIR_SCRIPT "." CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
173   endif()
174 endif()
175
176 # place the libraries to <prefix>/lib folder for unix and leave old structure for windows
177 if (NOT DEFINED INSTALL_DIR_LIB)
178   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
179     set (INSTALL_DIR_LIB "lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
180   else()
181     set (INSTALL_DIR_LIB "${OS_WITH_BIT}/${COMPILER}/lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
182   endif()
183 endif()
184
185 # OCCT headers: <prefix>/inc for windows,
186 #               <prefix>/include/opencascade-7.0.0 for unix
187 if (NOT DEFINED INSTALL_DIR_INCLUDE)
188   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
189     set (INSTALL_DIR_INCLUDE "include/opencascade" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
190     if (INSTALL_DIR_WITH_VERSION)
191       set (INSTALL_DIR_INCLUDE "include/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}" FORCE)
192     endif()
193   else()
194     set (INSTALL_DIR_INCLUDE "inc" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
195   endif()
196 endif()
197
198 # OCCT resources: <prefix>/src for windows,
199 #                 <prefix>/share/opencascade-7.0.0/resources for unix
200 if (NOT DEFINED INSTALL_DIR_RESOURCE)
201   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
202     set (INSTALL_DIR_RESOURCE "share/opencascade/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
203     if (INSTALL_DIR_WITH_VERSION)
204       set (INSTALL_DIR_RESOURCE "share/opencascade-${OCC_VERSION_STRING_EXT}/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}" FORCE)
205     endif()
206   else()
207     set (INSTALL_DIR_RESOURCE "src" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
208   endif()
209 endif()
210
211 # OCCT data
212 if (NOT DEFINED INSTALL_DIR_DATA)
213   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
214     set (INSTALL_DIR_DATA "share/opencascade/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
215     if (INSTALL_DIR_WITH_VERSION)
216       set (INSTALL_DIR_DATA "share/opencascade-${OCC_VERSION_STRING_EXT}/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}" FORCE)
217     endif()
218   else()
219     set (INSTALL_DIR_DATA "data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
220   endif()
221 endif()
222
223 # OCCT samples
224 if (NOT DEFINED INSTALL_DIR_SAMPLES)
225   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
226     set (INSTALL_DIR_SAMPLES "share/opencascade/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
227     if (INSTALL_DIR_WITH_VERSION)
228       set (INSTALL_DIR_SAMPLES "share/opencascade-${OCC_VERSION_STRING_EXT}/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}" FORCE)
229     endif()
230   else()
231     set (INSTALL_DIR_SAMPLES "samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
232   endif()
233 endif()
234
235 # OCCT tests
236 if (NOT DEFINED INSTALL_DIR_TESTS)
237   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
238     set (INSTALL_DIR_TESTS "share/opencascade/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
239     if (INSTALL_DIR_WITH_VERSION)
240       set (INSTALL_DIR_TESTS "share/opencascade-${OCC_VERSION_STRING_EXT}/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}" FORCE)
241     endif()
242   else()
243     set (INSTALL_DIR_TESTS "tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
244   endif()
245 endif()
246
247 # OCCT doc
248 if (NOT DEFINED INSTALL_DIR_DOC)
249   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
250     set (INSTALL_DIR_DOC "share/doc/opencascade" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
251     if (INSTALL_DIR_WITH_VERSION)
252       set (INSTALL_DIR_DOC "share/doc/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_DOC_DESCR}" FORCE)
253     endif()
254   else()
255     set (INSTALL_DIR_DOC "doc" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
256   endif()
257 endif()
258
259 # define folder contaning CMake configuration files
260 if (NOT DEFINED INSTALL_DIR_CMAKE)
261   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
262     if (INSTALL_DIR_WITH_VERSION)
263       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
264     else()
265       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
266     endif()
267   else()
268     set (INSTALL_DIR_CMAKE "cmake" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
269   endif()
270 endif()
271
272 # install LICENSE_LGPL_21.txt and OCCT_LGPL_EXCEPTION.txt files
273 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
274   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" "${INSTALL_DIR}/${INSTALL_DIR_DOC}")
275   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" "${INSTALL_DIR}/${INSTALL_DIR_DOC}")
276 else()
277   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" "${INSTALL_DIR}")
278   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" "${INSTALL_DIR}")
279 endif()
280
281 # a directory recognized as a 'patch' for OCCT
282 set (BUILD_PATCH "" CACHE PATH "${BUILD_PATCH_DESCR}")
283
284 # the list of being built toolkits
285 set (BUILD_ADDITIONAL_TOOLKITS "" CACHE STRING "${BUILD_ADDITIONAL_TOOLKITS_DESCR}")
286 separate_arguments (BUILD_ADDITIONAL_TOOLKITS)
287
288 if (MSVC)
289   set (BUILD_MODULE_MfcSamples OFF CACHE BOOL "${BUILD_MODULE_MfcSamples_DESCR}")
290 endif()
291
292 # whether use optional 3rdparty or not
293 if (APPLE)
294   set (USE_GLX OFF CACHE BOOL "${USE_GLX_DESCR}")
295 endif()
296
297 if (WIN32)
298   set (USE_D3D OFF CACHE BOOL "${USE_D3D_DESCR}")
299 endif()
300
301 # include the patched or original list of modules
302 # list <MODULENAME>_TOOLKITS is created foreach module and contains its toolkits
303 # list <OCCT_MODULES> will contain all modules
304 OCCT_MODULES_AND_TOOLKITS (OCCT_MODULES)
305
306 foreach (OCCT_MODULE ${OCCT_MODULES})
307   BUILD_MODULE (${OCCT_MODULE})
308 endforeach()
309
310 if (ANDROID AND BUILD_MODULE_Draw)
311   message (STATUS "Info. Draw module is turned off due to it is not supported on Android")
312   set (BUILD_MODULE_Draw OFF CACHE BOOL "${BUILD_MODULE_Draw_DESCR}" FORCE)
313 endif()
314
315 # Overview
316 set (BUILD_DOC_Overview OFF CACHE BOOL "${BUILD_DOC_Overview_DESCR}")
317
318 if (NOT USE_D3D)
319   list (REMOVE_ITEM Visualization_TOOLKITS TKD3DHost)
320 endif()
321
322 # accumulate used toolkits (first level) in BUILD_TOOLKITS variable
323 list (APPEND BUILD_TOOLKITS ${BUILD_ADDITIONAL_TOOLKITS})
324
325 foreach (OCCT_MODULE ${OCCT_MODULES})
326   if (BUILD_MODULE_${OCCT_MODULE})
327     list (APPEND BUILD_TOOLKITS ${${OCCT_MODULE}_TOOLKITS})
328   endif()
329 endforeach()
330
331 # DRAWEXE excluded when library build is static
332 if (NOT BUILD_SHARED_LIBS)
333   list (REMOVE_ITEM BUILD_TOOLKITS DRAWEXE)
334   message (STATUS "Info: DRAWEXE is not included due to ${BUILD_LIBRARY_TYPE} build library type")
335 endif()
336
337 # accumulate all used toolkits
338 list (REMOVE_DUPLICATES BUILD_TOOLKITS)
339 set (RAW_BUILD_TOOLKITS)
340 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
341   OCCT_TOOLKIT_FULL_DEP (${BUILD_TOOLKIT} TOOLKIT_FULL_DEPS)
342   list (APPEND RAW_BUILD_TOOLKITS ${BUILD_TOOLKIT} ${TOOLKIT_FULL_DEPS})
343 endforeach()
344
345 list (REMOVE_DUPLICATES RAW_BUILD_TOOLKITS)
346 set (BUILD_TOOLKITS ${RAW_BUILD_TOOLKITS})
347
348 # include the patched or original list of definitions and flags
349 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_defs_flags")
350
351 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/3rdparty_macro")
352
353 # search for TKIVtk and TKIVtkDraw in BUILD_TOOLKITS
354 list (FIND BUILD_TOOLKITS TKIVtk CAN_USE_VTK)
355 if (CAN_USE_VTK EQUAL -1)
356   list (FIND BUILD_TOOLKITS TKIVtkDraw CAN_USE_VTK)
357 endif()
358
359 if (NOT CAN_USE_VTK EQUAL -1)
360   if (NOT DEFINED USE_VTK)
361     set (USE_VTK OFF CACHE BOOL "${USE_VTK_DESCR}")
362   endif()
363 else()
364   OCCT_CHECK_AND_UNSET (USE_VTK)
365 endif()
366
367 # Rebuild *.yacc and *.lex files that are contained by TKMath toolkit
368 list (FIND BUILD_TOOLKITS TKMath   CAN_REBUILD_PDC_FOR_TKMATH)
369 list (FIND BUILD_TOOLKITS StepFile CAN_REBUILD_PDC_FOR_STEPFILE)
370
371 if (NOT ${CAN_REBUILD_PDC_FOR_TKMATH} EQUAL -1 OR NOT ${CAN_REBUILD_PDC_FOR_STEPFILE} EQUAL -1)
372   set (BUILD_YACCLEX OFF CACHE BOOL "${BUILD_YACCLEX_DESCR}")
373 else()
374   OCCT_CHECK_AND_UNSET (BUILD_YACCLEX)
375 endif()
376
377 if (NOT DEFINED 3RDPARTY_DIR)
378   set (3RDPARTY_DIR "" CACHE PATH ${3RDPARTY_DIR_DESCR})
379   get_filename_component (3RDPARTY_DIR "${3RDPARTY_DIR}" ABSOLUTE)
380 endif()
381
382 # search for CSF_TclLibs variable in EXTERNLIB of each being used toolkit
383 OCCT_IS_PRODUCT_REQUIRED (CSF_TclLibs USE_TCL)
384
385 if (USE_TCL)
386   message (STATUS "Info: TCL is used by OCCT")
387   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tcl")
388   
389   message (STATUS "Info: TK is used by OCCT")
390   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tk")
391 else()
392   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TCL")
393   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TK")
394
395   OCCT_CHECK_AND_UNSET ("INSTALL_TCL")
396   OCCT_CHECK_AND_UNSET ("INSTALL_TK")
397 endif()
398
399 # search for CSF_FREETYPE variable in EXTERNLIB of each being used toolkit
400 OCCT_IS_PRODUCT_REQUIRED (CSF_FREETYPE USE_FREETYPE)
401
402 if (USE_FREETYPE)
403   message (STATUS "Info: Freetype is used by OCCT")
404   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freetype")
405 else()
406   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREETYPE")
407   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2")
408   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build")
409   OCCT_CHECK_AND_UNSET ("INSTALL_FREETYPE")
410 endif()
411
412 # VTK
413 if (USE_VTK)
414   add_definitions (-DHAVE_VTK)
415   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vtk")
416 else()
417   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_VTK")
418   
419   if (NOT CAN_USE_VTK EQUAL -1)
420     message (STATUS "Info: TKIVtk and TKIVtkDraw toolkits excluded due to VTK usage is disabled")
421
422     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtk)
423     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtkDraw)
424   endif()
425 endif()
426
427 # D3D
428 if (USE_D3D)
429   add_definitions (-DHAVE_D3D)
430   #if(MSVC_VERSION LESS 1700)
431   #OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/d3d")
432   #endif()
433 endif()
434
435 # GLX
436 if (USE_GLX)
437   add_definitions (-DMACOSX_USE_GLX)
438   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/glx")
439 endif()
440
441 # FREEIMAGE
442 # search for CSF_FREEIMAGE variable in EXTERNLIB of each being used toolkit
443 OCCT_IS_PRODUCT_REQUIRED (CSF_FREEIMAGE     CAN_USE_FREEIMAGE)
444 OCCT_IS_PRODUCT_REQUIRED (CSF_FreeImagePlus CAN_USE_FREEIMAGEPLUS)
445
446 if (CAN_USE_FREEIMAGE OR CAN_USE_FREEIMAGEPLUS)
447   set (USE_FREEIMAGE OFF CACHE BOOL "${USE_FREEIMAGE_DESCR}")
448
449   if (USE_FREEIMAGE)
450     add_definitions (-DHAVE_FREEIMAGE)
451     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimage")
452     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimageplus")
453   else()
454     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
455     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGEPLUS")
456     OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
457     OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGEPLUS")
458   endif()
459 else()
460   OCCT_CHECK_AND_UNSET ("USE_FREEIMAGE")
461
462   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
463   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGEPLUS")
464   OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
465   OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGEPLUS")
466 endif()
467
468 # GL2PS
469 # search for CSF_GL2PS variable in EXTERNLIB of each being used toolkit
470 OCCT_IS_PRODUCT_REQUIRED (CSF_GL2PS CAN_USE_GL2PS)
471
472 if (NOT DEFINED ANDROID AND CAN_USE_GL2PS)
473   set (USE_GL2PS OFF CACHE BOOL "${USE_GL2PS_DESCR}")
474
475   if (USE_GL2PS)
476     add_definitions (-DHAVE_GL2PS)
477     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gl2ps")
478   else()
479     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
480     OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
481   endif()
482 else()
483   OCCT_CHECK_AND_UNSET ("USE_GL2PS")
484
485   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
486   OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
487 endif()
488
489 # TBB
490 # search for CSF_TBB variable in EXTERNLIB of each being used toolkit
491 OCCT_IS_PRODUCT_REQUIRED (CSF_TBB CAN_USE_TBB)
492
493 if (NOT DEFINED ANDROID AND CAN_USE_TBB)
494   set (USE_TBB OFF CACHE BOOL "${USE_TBB_DESCR}")
495
496   if (USE_TBB)
497     add_definitions (-DHAVE_TBB)
498     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tbb")
499   else()
500     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
501     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
502     OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
503   endif()
504 else()
505   OCCT_CHECK_AND_UNSET ("USE_TBB")
506
507   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
508   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
509   OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
510 endif()
511
512 # Doxygen
513 if (BUILD_DOC_Overview)
514   if (NOT DEFINED INSTALL_DOC_Overview)
515     set (INSTALL_DOC_Overview OFF CACHE BOOL "${INSTALL_DOC_Overview_DESCR}")
516   endif()
517
518   if (INSTALL_DOC_Overview)
519     install (DIRECTORY "${CMAKE_BINARY_DIR}/doc/overview" DESTINATION  "${INSTALL_DIR}/${INSTALL_DIR_DOC}")
520
521     # create overview.html only for windows
522     if (WIN32 AND "${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
523       OCCT_INSTALL_FILE_OR_DIR ("dox/resources/overview.html" "${INSTALL_DIR}/${INSTALL_DIR_DOC}/..")
524     endif()
525   endif()
526
527   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
528 else()
529   OCCT_CHECK_AND_UNSET ("INSTALL_DOC_Overview")
530
531   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOXYGEN_EXECUTABLE")
532   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOT_EXECUTABLE")
533 endif()
534
535 # bison 
536 if (BUILD_YACCLEX)
537   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/bison")
538 else()
539   OCCT_CHECK_AND_UNSET ("3RDPARTY_BISON_EXECUTABLE")
540 endif()
541
542 # flex 
543 if (BUILD_YACCLEX)
544   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/flex")
545 else()
546   OCCT_CHECK_AND_UNSET ("3RDPARTY_FLEX_EXECUTABLE")
547 endif()
548
549 string (REGEX REPLACE ";" " " 3RDPARTY_NOT_INCLUDED "${3RDPARTY_NOT_INCLUDED}")
550
551 # check all 3rdparty paths
552 if (3RDPARTY_NOT_INCLUDED)
553   message (FATAL_ERROR "NOT FOUND: ${3RDPARTY_NOT_INCLUDED}" )
554 endif()
555
556 if (3RDPARTY_INCLUDE_DIRS)
557   list (REMOVE_DUPLICATES 3RDPARTY_INCLUDE_DIRS)
558   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_INCLUDE_DIRS_WITH_ENDS "${3RDPARTY_INCLUDE_DIRS}")
559   message (STATUS "Info: The directories of 3rdparty headers: \n\t${3RDPARTY_INCLUDE_DIRS_WITH_ENDS}")
560   include_directories (${3RDPARTY_INCLUDE_DIRS})
561 endif()
562
563 # include <cmake binary folder>/inc
564 include_directories (${CMAKE_BINARY_DIR}/inc)
565
566 if (3RDPARTY_LIBRARY_DIRS)
567   list (REMOVE_DUPLICATES 3RDPARTY_LIBRARY_DIRS)
568   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_LIBRARY_DIRS_WITH_ENDS "${3RDPARTY_LIBRARY_DIRS}")
569   message (STATUS "Info: The directories of 3rdparty libraries: \n\t${3RDPARTY_LIBRARY_DIRS_WITH_ENDS}")
570   link_directories (${3RDPARTY_LIBRARY_DIRS})
571 endif()
572
573 # build directories
574 if (SINGLE_GENERATOR)
575   set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
576   set (CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
577   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
578   if (WIN32)
579     set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
580   endif()
581 endif()
582
583 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
584 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
585 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
586
587 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
588 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
589 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
590
591 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
592 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
593 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
594
595 if (WIN32) 
596   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE        "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
597   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
598   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG          "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
599 endif()
600
601 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
602 message (STATUS "\nInfo: \(${CURRENT_TIME}\) Start collecting all OCCT header files into ${CMAKE_BINARY_DIR}/inc ...")
603
604 # collect all the headers to <binary dir>/inc folder
605 COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}" "${BUILD_TOOLKITS}")
606
607 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
608 message (STATUS "Info: \(${CURRENT_TIME}\) End the collecting")
609
610 OCCT_INSTALL_FILE_OR_DIR ("data/" "${INSTALL_DIR}/${INSTALL_DIR_DATA}")
611
612 if (WIN32)
613   set (SCRIPT_EXT bat)
614 else()
615   set (SCRIPT_EXT sh)
616 endif()
617
618 # OCCT samples
619 if (INSTALL_SAMPLES)
620   OCCT_CONFIGURE ("adm/templates/env.samples.${SCRIPT_EXT}.in" "env.samples.${SCRIPT_EXT}")
621   if (WIN32)
622     OCCT_INSTALL_FILE_OR_DIR ("samples/CSharp" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
623     OCCT_INSTALL_FILE_OR_DIR ("samples/mfc" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
624
625     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}/CSharp" RENAME "env.${SCRIPT_EXT}")
626     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}/mfc/standard" RENAME "env.${SCRIPT_EXT}")
627   endif()
628
629   OCCT_INSTALL_FILE_OR_DIR ("samples/java" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
630   OCCT_INSTALL_FILE_OR_DIR ("samples/ocafsamples" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
631   OCCT_INSTALL_FILE_OR_DIR ("samples/qt" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
632
633   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}/qt/FuncDemo" RENAME "env.${SCRIPT_EXT}")
634   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}/qt/IESample" RENAME "env.${SCRIPT_EXT}")
635   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}/qt/Tutorial" RENAME "env.${SCRIPT_EXT}")
636 endif()
637
638 OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
639
640 if (INSTALL_TEST_CASES)
641   OCCT_INSTALL_FILE_OR_DIR ("tests/" "${INSTALL_DIR}/${INSTALL_DIR_TESTS}")
642 endif()
643
644 # copy draw script to install script folder
645 if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}")
646   install (FILES "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}"
647           PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
648 else()
649   install (FILES "${CMAKE_SOURCE_DIR}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}"
650           PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
651 endif()
652
653 # copy draw script to CMake binary folder
654 OCCT_COPY_FILE_OR_DIR ("adm/templates/draw.${SCRIPT_EXT}" "${CMAKE_BINARY_DIR}")
655
656 set (SUB_CUSTOM_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.${SCRIPT_EXT}")
657
658 if (WIN32)
659   set (ADDITIONAL_CUSTOM_CONTENT "\nif exist \"%~dp0${SUB_CUSTOM_NAME}\" (\n  call \"%~dp0${SUB_CUSTOM_NAME}\" %1 %2 %3 \n)")
660 else()
661   set (ADDITIONAL_CUSTOM_CONTENT "\nif [ -e \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" ]; then\n  source \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" \"\$1\" \"\$2\" \nfi")
662 endif()
663
664  # change custom.bat/sh
665 if (EXISTS "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}")
666   file (READ "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" CUSTOM_CONTENT)
667
668   set (CUSTOM_CONTENT "${CUSTOM_CONTENT} ${ADDITIONAL_CUSTOM_CONTENT}")
669
670   file (WRITE "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" "${CUSTOM_CONTENT}")
671 else()
672   OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.${SCRIPT_EXT}.main" "custom.${SCRIPT_EXT}" "custom.${SCRIPT_EXT}" "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}")
673 endif()
674
675 # write current custom.bat/sh (for install directory)
676 set (SUB_CUSTOM_BUILD_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.install.${SCRIPT_EXT}")
677 OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.install.${SCRIPT_EXT}.in" "${SUB_CUSTOM_BUILD_NAME}" "${SUB_CUSTOM_NAME}" "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}")
678
679 # write current custom.bat/sh (for build directory)
680 OCCT_CONFIGURE ("adm/templates/custom.build.${SCRIPT_EXT}.in" "${SUB_CUSTOM_NAME}")
681
682 if (BUILD_MODULE_MfcSamples)
683   OCCT_INSTALL_FILE_OR_DIR ("adm/templates/sample.bat" "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}")
684   OCCT_COPY_FILE_OR_DIR    ("adm/templates/sample.bat" "${CMAKE_BINARY_DIR}")
685 endif()
686
687 # env script for draw in building environment
688 OCCT_CONFIGURE ("adm/templates/env.${SCRIPT_EXT}.in" "env.${SCRIPT_EXT}")
689
690 # install env script
691 install (FILES "${CMAKE_BINARY_DIR}/env.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}")
692
693 # copy DrawAppliInit from OCCT source to build directory
694 if (NOT EXISTS "${CMAKE_BINARY_DIR}/DrawAppliInit")
695   OCCT_COPY_FILE_OR_DIR (DrawAppliInit "${CMAKE_BINARY_DIR}")
696 endif()
697
698 # RESOURCES
699 FILE_TO_LIST ("adm/RESOURCES" RESOURCES)
700 foreach(RESOURCE ${RESOURCES})
701   get_filename_component(RESOURCE_FOLDER ${RESOURCE} DIRECTORY)
702   if(NOT "${RESOURCE_FOLDER}" STREQUAL "")
703     get_filename_component(RESOURCE_FOLDER ${RESOURCE_FOLDER} NAME)
704     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR}/${INSTALL_DIR_RESOURCE}/${RESOURCE_FOLDER}")
705   else()
706     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR}/${INSTALL_DIR_RESOURCE}")
707   endif()
708 endforeach()
709
710 # define CSF variable
711 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_csf")
712
713 # include patched toolkit projects or original ones
714 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
715   OCCT_ADD_SUBDIRECTORY ("src/${BUILD_TOOLKIT}")
716 endforeach()
717
718 if (BUILD_DOC_Overview)
719   OCCT_ADD_SUBDIRECTORY (dox)
720 endif()
721
722 # patch DRAWEXE
723 if (MSVC AND 3RDPARTY_DLL_DIRS)
724   list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
725   if (${DRAWEXE_INDEX} GREATER -1)
726     list (REMOVE_DUPLICATES 3RDPARTY_DLL_DIRS)
727     set (3RDPARTY_DLL_DIRS_FOR_PATH "")
728
729     foreach (3RDPARTY_DLL_DIR ${3RDPARTY_DLL_DIRS})
730       set (3RDPARTY_DLL_DIRS_FOR_PATH "${3RDPARTY_DLL_DIRS_FOR_PATH};${3RDPARTY_DLL_DIR}")
731     endforeach()
732
733     OCCT_MAKE_COMPILER_BITNESS()
734     set (X_COMPILER_BITNESS "x64")
735     if ("${COMPILER_BITNESS}" STREQUAL "32")
736       set (X_COMPILER_BITNESS "Win32")
737     endif()
738
739     OCCT_CONFIGURE ("adm/templates/DRAWEXE.vcxproj.user.in" "${CMAKE_BINARY_DIR}/src/DRAWEXE/DRAWEXE.vcxproj.user")
740   endif()
741 endif()
742
743 # samples do not support patch usage
744 if (BUILD_MODULE_MfcSamples)
745   set (OCCT_ROOT ${CMAKE_SOURCE_DIR})
746
747   set (MFC_STANDARD_SAMPLES_DIR ${OCCT_ROOT}/samples/mfc/standard)
748   set (COMMON_WINMAIN_FILE      ${MFC_STANDARD_SAMPLES_DIR}/Common/Winmain.cpp)
749
750   add_subdirectory(samples/mfc/standard/mfcsample)
751   add_subdirectory(samples/mfc/standard/01_Geometry)
752   add_subdirectory(samples/mfc/standard/02_Modeling)
753   add_subdirectory(samples/mfc/standard/03_Viewer2d)
754   add_subdirectory(samples/mfc/standard/04_Viewer3d)
755   add_subdirectory(samples/mfc/standard/05_ImportExport)
756   add_subdirectory(samples/mfc/standard/06_Ocaf)
757   add_subdirectory(samples/mfc/standard/07_Triangulation)
758   add_subdirectory(samples/mfc/standard/08_HLR)
759   add_subdirectory(samples/mfc/standard/09_Animation)
760   add_subdirectory(samples/mfc/standard/10_Convert)
761 endif()
762
763 # Prepare variables for configuration of OpenCASCADE cmake config file
764 set (OCCT_MODULES_ENABLED)
765 set (OCCT_LIBRARIES)
766 set (SET_OpenCASCADE_MODULES_TOOLKITS "\n# List of available OpenCASCADE libraries for each module\n")
767 foreach (OCCT_TOOLKIT ${BUILD_TOOLKITS})
768   if (TARGET ${OCCT_TOOLKIT})
769
770     # get all libraries
771     get_target_property (${OCCT_TOOLKIT}_TYPE ${OCCT_TOOLKIT} "TYPE")
772     if ("${${OCCT_TOOLKIT}_TYPE}" STREQUAL "STATIC_LIBRARY" OR "${${OCCT_TOOLKIT}_TYPE}" STREQUAL "SHARED_LIBRARY" )
773       list (APPEND OCCT_LIBRARIES ${OCCT_TOOLKIT})
774
775       # get all modules
776       get_target_property (${OCCT_TOOLKIT}_MODULE ${OCCT_TOOLKIT} "MODULE")
777       list (APPEND OCCT_MODULES_ENABLED ${${OCCT_TOOLKIT}_MODULE})
778       list (APPEND OpenCASCADE_${${OCCT_TOOLKIT}_MODULE}_TOOLKITS ${OCCT_TOOLKIT})
779     endif()
780   endif()
781 endforeach()
782 list (REMOVE_DUPLICATES OCCT_MODULES_ENABLED)
783
784 foreach (OCCT_MODULE ${OCCT_MODULES})
785   if (BUILD_MODULE_${OCCT_MODULE})
786     set (SET_OpenCASCADE_MODULES_TOOLKITS "${SET_OpenCASCADE_MODULES_TOOLKITS}set (OpenCASCADE_${OCCT_MODULE}_LIBRARIES ${OpenCASCADE_${OCCT_MODULE}_TOOLKITS})\n")
787   endif()
788 endforeach()
789
790 # Add all targets to the build-tree export set
791 export (TARGETS ${OCCT_LIBRARIES} FILE "${CMAKE_BINARY_DIR}/OpenCASCADETargets.cmake")
792
793 # Export the package for use from the build-tree
794 # (this registers the build-tree with a global CMake-registry)
795 export(PACKAGE OpenCASCADE)
796
797 if (CMAKE_BUILD_TYPE)
798   set (SET_OpenCASCADE_BUILD_TYPE "set (OpenCASCADE_BUILD_TYPE        \"${CMAKE_BUILD_TYPE}\")")
799 endif()
800
801 if (BUILD_SHARED_LIBS)
802   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_SHARED_LINKER_FLAGS}\")")
803 else()
804   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_STATIC_LINKER_FLAGS}\")")
805 endif()
806
807 if (WIN32)
808   set (SET_OpenCASCADE_WITH_D3D "set (OpenCASCADE_WITH_D3D       ${USE_D3D})")
809 endif()
810 if (APPLE)
811   set (SET_OpenCASCADE_WITH_GLX "set (OpenCASCADE_WITH_GLX       ${USE_GLX})")
812 endif()
813
814 if (NOT SINGLE_GENERATOR)
815   OCCT_INSERT_CODE_FOR_TARGET()
816 endif()
817
818 # Configure and install cmake config file
819 configure_file("${CMAKE_SOURCE_DIR}/adm/templates/OpenCASCADEConfig.cmake.in" "OpenCASCADEConfig.cmake" @ONLY)
820 install(FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfig.cmake" DESTINATION  "${INSTALL_DIR}/${INSTALL_DIR_CMAKE}")
821
822 # Configure cmake version file
823 include(CMakePackageConfigHelpers)
824 write_basic_package_version_file( ${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake
825                                   VERSION ${OCC_VERSION_MAJOR}.${OCC_VERSION_MINOR}.${OCC_VERSION_MAINTENANCE}
826                                   COMPATIBILITY ExactVersion )
827
828 # Install cmake version file
829 install (FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_CMAKE}")
830
831 # Install the export set for use with the install-tree for each configuration
832 foreach (OCCT_MODULE ${OCCT_MODULES})
833   if (BUILD_MODULE_${OCCT_MODULE})
834     install(EXPORT OpenCASCADE${OCCT_MODULE}Targets DESTINATION "${INSTALL_DIR_CMAKE}")
835   endif()
836 endforeach()
837
838 # Update generated OpenCASCADETargets-*.cmake files 
839 # to have correct paths to libraries depending on the configuration
840 OCCT_UPDATE_TARGET_FILE ()