0029025: TInspector include files are not installed to inc directory by CMake
[occt.git] / CMakeLists.txt
1 cmake_minimum_required (VERSION 2.8.12 FATAL_ERROR)
2
3 set (CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/adm/cmake")
4
5 set (CMAKE_SUPPRESS_REGENERATION TRUE)
6
7 set (CMAKE_CONFIGURATION_TYPES Release Debug RelWithDebInfo CACHE INTERNAL "" FORCE)
8
9 # macro: include patched file if it exists
10 macro (OCCT_INCLUDE_CMAKE_FILE BEING_INCLUDED_FILE)
11   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake")
12     include (${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake)
13   else()
14     include (${CMAKE_SOURCE_DIR}/${BEING_INCLUDED_FILE}.cmake)
15   endif()
16 endmacro()
17
18 # include variable description
19 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vardescr")
20
21 # set type of OCCT libraries
22 if (NOT BUILD_LIBRARY_TYPE)
23   set (BUILD_LIBRARY_TYPE "Shared" CACHE STRING "${BUILD_LIBRARY_TYPE_DESCR}" FORCE)
24   SET_PROPERTY(CACHE BUILD_LIBRARY_TYPE PROPERTY STRINGS Shared Static)
25 endif()
26
27 if ("${BUILD_LIBRARY_TYPE}" STREQUAL "Shared")
28   set (BUILD_SHARED_LIBS ON)
29
30   if (NOT DEFINED BUILD_SHARED_LIBRARY_NAME_POSTFIX)
31     set (BUILD_SHARED_LIBRARY_NAME_POSTFIX "" CACHE STRING "${BUILD_SHARED_LIBRARY_NAME_POSTFIX_DESCR}" FORCE)
32   endif()
33 else()
34   unset (BUILD_SHARED_LIBS)
35   message (STATUS "Info: Only 3rdparty's header files are used for building of static OCCT libraries")
36   unset (BUILD_SHARED_LIBRARY_NAME_POSTFIX)
37 endif()
38
39 # the name of the project
40 project (OCCT)
41
42 if (WIN32)
43   add_definitions(-DUNICODE)
44   add_definitions(-D_UNICODE)
45 endif()
46
47 # include occt macros
48 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_macros")
49
50 # Solution folder property
51 set_property (GLOBAL PROPERTY USE_FOLDERS ON)
52
53 # get current OCCT version
54 OCC_VERSION (OCC_VERSION_MAJOR OCC_VERSION_MINOR OCC_VERSION_MAINTENANCE OCC_VERSION_DEVELOPMENT OCC_VERSION_STRING_EXT)
55
56 set_property (GLOBAL PROPERTY OCC_VERSION_MAJOR ${OCC_VERSION_MAJOR})
57 set_property (GLOBAL PROPERTY OCC_VERSION_MINOR ${OCC_VERSION_MINOR})
58 set_property (GLOBAL PROPERTY OCC_VERSION_MAINTENANCE ${OCC_VERSION_MAINTENANCE})
59
60 set (INSTALL_TEST_CASES OFF CACHE BOOL "${INSTALL_TEST_CASES_DESCR}")
61
62 # Regeneration of OCCT resource files
63 set (BUILD_RESOURCES OFF CACHE BOOL "${BUILD_RESOURCES_DESCR}")
64
65 # single-configuration generator
66 set (SINGLE_GENERATOR OFF)
67 if (CMAKE_BUILD_TYPE)
68   set (SINGLE_GENERATOR ON)
69 endif()
70
71 # a single-configuration generator like the Makefile generator defines CMAKE_BUILD_TYPE variable
72 # check this variable and set if it's required
73 if (DEFINED CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE) # single-configuration generator.
74   set (CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel." FORCE)
75 endif()
76
77 # enable extended messages of many OCCT algorithms
78 if (((SINGLE_GENERATOR AND "${CMAKE_BUILD_TYPE}" STREQUAL "Debug") OR NOT SINGLE_GENERATOR) AND (NOT "${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore"))
79   if (NOT BUILD_WITH_DEBUG)
80     set (BUILD_WITH_DEBUG OFF CACHE BOOL "${BUILD_WITH_DEBUG_DESCR}")
81   endif()
82 else()
83   OCCT_CHECK_AND_UNSET (BUILD_WITH_DEBUG)
84 endif()
85
86 if (BUILD_WITH_DEBUG)
87   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:DEBUG>:OCCT_DEBUG>)
88 endif()
89
90 # option to enable or disable use of precompiled headers
91 if (NOT DEFINED BUILD_USE_PCH)
92   set (BUILD_USE_PCH OFF CACHE BOOL "${BUILD_USE_PCH_DESCR}")
93 endif()
94
95 if (BUILD_USE_PCH)
96
97   # Load Cotire tool for accelerating build procedure
98   include(cotire)
99
100   # Set Cotire to ignore lxx, pxx, gxx 
101   set (COTIRE_ADDITIONAL_PREFIX_HEADER_IGNORE_EXTENSIONS "lxx;pxx;gxx" CACHE STRING "Set Cotire to ignore OCCT specific files that can be #included" FORCE)
102
103   # Set priority for inclusion of system headers in PCH to reduce problems
104   # due to incomplete inclusion or wrong order.
105   if (WIN32)
106     # on Windows, assume that SDK (windows.h) is in default location
107     set(ProgramFilesX86 "ProgramFiles(x86)")
108     file(TO_CMAKE_PATH "$ENV{${ProgramFilesX86}}" ProgramFilesX86)
109     set_property (DIRECTORY PROPERTY COTIRE_PREFIX_HEADER_INCLUDE_PRIORITY_PATH "${ProgramFilesX86}")
110     unset(ProgramFilesX86)
111   endif()
112
113 endif()
114
115 # copy samples to install directory
116 set (INSTALL_SAMPLES OFF CACHE BOOL "${INSTALL_SAMPLES_DESCR}")
117
118 # install dir of the project
119 if (NOT DEFINED INSTALL_DIR)
120   # set default install directory for Windows
121   if (WIN32 AND NOT DEFINED CMAKE_INSTALL_PREFIX)
122     set (CMAKE_INSTALL_PREFIX "C:/opencascade-${OCC_VERSION_STRING_EXT}")
123   endif()
124   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}")
125 else()
126   file (TO_CMAKE_PATH "${INSTALL_DIR}" INSTALL_DIR)
127   set (INSTALL_DIR "${INSTALL_DIR}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
128 endif()
129
130 # choose a variant of the layout of the install paths
131 if (NOT INSTALL_DIR_LAYOUT)
132   if (WIN32)
133     set (INSTALL_DIR_LAYOUT "Windows" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
134   else()
135     set (INSTALL_DIR_LAYOUT "Unix" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
136   endif()
137   SET_PROPERTY(CACHE INSTALL_DIR_LAYOUT PROPERTY STRINGS Windows Unix)
138 endif()
139
140 # check INSTALL_DIR_LAYOUT changes and update INSTALL_DIR_* paths if necessary
141 if (NOT DEFINED INSTALL_DIR_LAYOUT_PREV)
142   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
143 elseif (NOT "${INSTALL_DIR_LAYOUT_PREV}" STREQUAL "${INSTALL_DIR_LAYOUT}")
144   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
145   # The structure of install folder should be reset due to changed layout
146   OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
147
148   # Unset INSTALL_DIR_WITH_VERSION on windows
149   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
150     OCCT_CHECK_AND_UNSET (INSTALL_DIR_WITH_VERSION)
151   else()
152     if (NOT DEFINED INSTALL_DIR_WITH_VERSION)
153       set (INSTALL_DIR_WITH_VERSION OFF CACHE BOOL "${INSTALL_DIR_WITH_VERSION_DESCR}")
154     endif()
155   endif()
156 endif()
157
158 # check CMAKE_INSTALL_PREFIX changes and update INSTALL_DIR if necessary
159 if (NOT DEFINED CMAKE_INSTALL_PREFIX_PREV)
160   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
161 elseif (NOT "${CMAKE_INSTALL_PREFIX_PREV}" STREQUAL "${CMAKE_INSTALL_PREFIX}")
162   # CMAKE_INSTALL_PREFIX has been changed at previous step
163   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
164   
165   # INSTALL_DIR is required to be updated
166   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
167 endif()
168
169 # check INSTALL_DIR changes and update CMAKE_INSTALL_PREFIX if necessary
170 if (NOT DEFINED INSTALL_DIR_PREV)
171   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
172 elseif (NOT "${INSTALL_DIR_PREV}" STREQUAL "${INSTALL_DIR}")
173   # INSTALL_DIR has been changed at previous step
174   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
175
176   # sync CMAKE_INSTALL_PREFIX with INSTALL_DIR 
177   set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
178
179   # set CMAKE_INSTALL_PREFIX_PREV to avoid the reset of structure of the install folder 
180   set (CMAKE_INSTALL_PREFIX_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
181 endif()
182
183 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
184   if (NOT DEFINED INSTALL_DIR_WITH_VERSION_PREV)
185     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
186   elseif (NOT "${INSTALL_DIR_WITH_VERSION_PREV}" STREQUAL "${INSTALL_DIR_WITH_VERSION}")
187     # INSTALL_DIR_WITH_VERSION has been changed at previous step
188     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
189
190     OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
191   endif()
192 endif()
193
194 # hide CMAKE_INSTALL_PREFIX from a user
195 set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
196
197 set (BIN_LETTER "")
198 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
199   set (BIN_LETTER "d")
200 elseif ("${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo")
201   set (BIN_LETTER "i")
202 endif()
203
204 # Get all used variables: OS_WITH_BIT, COMPILER
205 OCCT_MAKE_OS_WITH_BITNESS()
206 OCCT_MAKE_COMPILER_SHORT_NAME()
207
208 # do not define INSTALL_DIR_BIN for win.
209 # Leave library structure for win: <prefix>/win64/vc10/bin(d)
210 if (NOT DEFINED INSTALL_DIR_BIN)
211   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
212     set (INSTALL_DIR_BIN "bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
213   else()
214     set (INSTALL_DIR_BIN "${OS_WITH_BIT}/${COMPILER}/bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
215   endif()
216 endif()
217
218 # define folder contaning all shell/batch scripts
219 if (NOT DEFINED INSTALL_DIR_SCRIPT)
220   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
221     set (INSTALL_DIR_SCRIPT "${INSTALL_DIR_BIN}" CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
222   else()
223     set (INSTALL_DIR_SCRIPT "." CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
224   endif()
225 endif()
226
227 # place the libraries to <prefix>/lib folder for unix and leave old structure for windows
228 if (NOT DEFINED INSTALL_DIR_LIB)
229   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
230     set (INSTALL_DIR_LIB "lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
231   else()
232     set (INSTALL_DIR_LIB "${OS_WITH_BIT}/${COMPILER}/lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
233   endif()
234 endif()
235
236 # OCCT headers: <prefix>/inc for windows,
237 #               <prefix>/include/opencascade-7.0.0 for unix
238 if (NOT DEFINED INSTALL_DIR_INCLUDE)
239   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
240     set (INSTALL_DIR_INCLUDE "include/opencascade" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
241     if (INSTALL_DIR_WITH_VERSION)
242       set (INSTALL_DIR_INCLUDE "include/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}" FORCE)
243     endif()
244   else()
245     set (INSTALL_DIR_INCLUDE "inc" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
246   endif()
247 endif()
248
249 # OCCT resources: <prefix>/src for windows,
250 #                 <prefix>/share/opencascade-7.0.0/resources for unix
251 if (NOT DEFINED INSTALL_DIR_RESOURCE)
252   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
253     set (INSTALL_DIR_RESOURCE "share/opencascade/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
254     if (INSTALL_DIR_WITH_VERSION)
255       set (INSTALL_DIR_RESOURCE "share/opencascade-${OCC_VERSION_STRING_EXT}/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}" FORCE)
256     endif()
257   else()
258     set (INSTALL_DIR_RESOURCE "src" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
259   endif()
260 endif()
261
262 # OCCT data
263 if (NOT DEFINED INSTALL_DIR_DATA)
264   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
265     set (INSTALL_DIR_DATA "share/opencascade/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
266     if (INSTALL_DIR_WITH_VERSION)
267       set (INSTALL_DIR_DATA "share/opencascade-${OCC_VERSION_STRING_EXT}/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}" FORCE)
268     endif()
269   else()
270     set (INSTALL_DIR_DATA "data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
271   endif()
272 endif()
273
274 # OCCT samples
275 if (NOT DEFINED INSTALL_DIR_SAMPLES)
276   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
277     set (INSTALL_DIR_SAMPLES "share/opencascade/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
278     if (INSTALL_DIR_WITH_VERSION)
279       set (INSTALL_DIR_SAMPLES "share/opencascade-${OCC_VERSION_STRING_EXT}/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}" FORCE)
280     endif()
281   else()
282     set (INSTALL_DIR_SAMPLES "samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
283   endif()
284 endif()
285
286 # OCCT tests
287 if (NOT DEFINED INSTALL_DIR_TESTS)
288   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
289     set (INSTALL_DIR_TESTS "share/opencascade/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
290     if (INSTALL_DIR_WITH_VERSION)
291       set (INSTALL_DIR_TESTS "share/opencascade-${OCC_VERSION_STRING_EXT}/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}" FORCE)
292     endif()
293   else()
294     set (INSTALL_DIR_TESTS "tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
295   endif()
296 endif()
297
298 # OCCT doc
299 if (NOT DEFINED INSTALL_DIR_DOC)
300   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
301     set (INSTALL_DIR_DOC "share/doc/opencascade" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
302     if (INSTALL_DIR_WITH_VERSION)
303       set (INSTALL_DIR_DOC "share/doc/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_DOC_DESCR}" FORCE)
304     endif()
305   else()
306     set (INSTALL_DIR_DOC "doc" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
307   endif()
308 endif()
309
310 # define folder contaning CMake configuration files
311 if (NOT DEFINED INSTALL_DIR_CMAKE)
312   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
313     if (INSTALL_DIR_WITH_VERSION)
314       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
315     else()
316       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
317     endif()
318   else()
319     set (INSTALL_DIR_CMAKE "cmake" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
320   endif()
321 endif()
322
323 # include occt macros
324 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_resources")
325
326 # install LICENSE_LGPL_21.txt and OCCT_LGPL_EXCEPTION.txt files
327 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
328   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" "${INSTALL_DIR_DOC}")
329   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" "${INSTALL_DIR_DOC}")
330 else()
331   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" ".")
332   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" ".")
333 endif()
334
335 if(APPLE)
336   set (INSTALL_NAME_DIR "" CACHE STRING "install_name library suffix on OS X (e.g. @executable_path/../Frameworks)")
337 endif()
338
339 # a directory recognized as a 'patch' for OCCT
340 set (BUILD_PATCH "" CACHE PATH "${BUILD_PATCH_DESCR}")
341
342 # the list of being built toolkits
343 set (BUILD_ADDITIONAL_TOOLKITS "" CACHE STRING "${BUILD_ADDITIONAL_TOOLKITS_DESCR}")
344 separate_arguments (BUILD_ADDITIONAL_TOOLKITS)
345
346 if (MSVC)
347   set (BUILD_MODULE_MfcSamples OFF CACHE BOOL "${BUILD_MODULE_MfcSamples_DESCR}")
348 endif()
349
350 set (BUILD_Inspector OFF CACHE BOOL "${BUILD_Inspector_DESCR}")
351
352 # uwp sample
353 if (MSVC)
354   if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
355     set (BUILD_MODULE_UwpSample OFF CACHE BOOL "${BUILD_MODULE_UwpSample_DESCR}")
356   else()
357     unset (BUILD_MODULE_UwpSample)
358   endif()
359 endif()
360
361 # whether use optional 3rdparty or not
362 if (APPLE)
363   set (USE_GLX OFF CACHE BOOL "${USE_GLX_DESCR}")
364 endif()
365
366 if (WIN32)
367   set (USE_D3D OFF CACHE BOOL "${USE_D3D_DESCR}")
368 endif()
369
370 # Enable/Disable the floating point exceptions (FPE) during runtime.
371 if (NOT BUILD_ENABLE_FPE_SIGNAL_HANDLER)
372   set (BUILD_ENABLE_FPE_SIGNAL_HANDLER OFF CACHE BOOL "${BUILD_ENABLE_FPE_SIGNAL_HANDLER_DESCR}" FORCE)
373 endif()
374
375 if (BUILD_ENABLE_FPE_SIGNAL_HANDLER)
376   set (BUILD_ENABLE_FPE_SIGNAL_HANDLER 1)
377 else()
378   set (BUILD_ENABLE_FPE_SIGNAL_HANDLER 0)
379 endif()
380
381 # include the patched or original list of modules
382 # list <MODULENAME>_TOOLKITS is created foreach module and contains its toolkits
383 # list <OCCT_MODULES> will contain all modules
384 OCCT_MODULES_AND_TOOLKITS (OCCT_MODULES)
385
386 foreach (OCCT_MODULE ${OCCT_MODULES})
387   BUILD_MODULE (${OCCT_MODULE})
388 endforeach()
389
390 if (ANDROID AND BUILD_MODULE_Draw)
391   message (STATUS "Info. Draw module is turned off due to it is not supported on Android")
392   set (BUILD_MODULE_Draw OFF CACHE BOOL "${BUILD_MODULE_Draw_DESCR}" FORCE)
393 endif()
394 if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore" AND BUILD_MODULE_Draw)
395   message (STATUS "Info. Draw module is turned off due to it is not supported on UWP")
396   set (BUILD_MODULE_Draw OFF CACHE BOOL "${BUILD_MODULE_Draw_DESCR}" FORCE)
397 endif()
398
399 # Overview
400 if (NOT DEFINED BUILD_DOC_Overview)
401   set (DO_ONLY_CHECK_FOR_DOXYGEN ON)
402   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
403   set (DO_ONLY_CHECK_FOR_DOXYGEN OFF)
404   
405   if (CAN_DOXYGEN_BE_USED)
406     message (STATUS "Info. Overview building is turned on")
407   endif()
408
409   set (BUILD_DOC_Overview ${CAN_DOXYGEN_BE_USED} CACHE BOOL "${BUILD_DOC_Overview_DESCR}")
410 endif()
411
412 if (NOT USE_D3D)
413   list (REMOVE_ITEM Visualization_TOOLKITS TKD3DHost)
414 endif()
415
416 # accumulate used toolkits (first level) in BUILD_TOOLKITS variable
417 list (APPEND BUILD_TOOLKITS ${BUILD_ADDITIONAL_TOOLKITS})
418
419 foreach (OCCT_MODULE ${OCCT_MODULES})
420   if (BUILD_MODULE_${OCCT_MODULE})
421     list (APPEND BUILD_TOOLKITS ${${OCCT_MODULE}_TOOLKITS})
422   endif()
423 endforeach()
424
425 # DRAWEXE excluded when library build is static
426 if (NOT BUILD_SHARED_LIBS)
427   list (REMOVE_ITEM BUILD_TOOLKITS DRAWEXE)
428   message (STATUS "Info: DRAWEXE is not included due to ${BUILD_LIBRARY_TYPE} build library type")
429 endif()
430
431 # accumulate all used toolkits
432 list (REMOVE_DUPLICATES BUILD_TOOLKITS)
433 set (RAW_BUILD_TOOLKITS)
434 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
435   OCCT_TOOLKIT_FULL_DEP (${BUILD_TOOLKIT} TOOLKIT_FULL_DEPS)
436   list (APPEND RAW_BUILD_TOOLKITS ${BUILD_TOOLKIT} ${TOOLKIT_FULL_DEPS})
437 endforeach()
438
439 list (REMOVE_DUPLICATES RAW_BUILD_TOOLKITS)
440 set (BUILD_TOOLKITS ${RAW_BUILD_TOOLKITS})
441
442 # include the patched or original list of definitions and flags
443 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_defs_flags")
444
445 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/3rdparty_macro")
446
447 # search for TKIVtk and TKIVtkDraw in BUILD_TOOLKITS
448 list (FIND BUILD_TOOLKITS TKIVtk CAN_USE_VTK)
449 if (CAN_USE_VTK EQUAL -1)
450   list (FIND BUILD_TOOLKITS TKIVtkDraw CAN_USE_VTK)
451 endif()
452
453 if (NOT CAN_USE_VTK EQUAL -1)
454   if (NOT DEFINED USE_VTK)
455     set (USE_VTK OFF CACHE BOOL "${USE_VTK_DESCR}")
456   endif()
457 else()
458   OCCT_CHECK_AND_UNSET (USE_VTK)
459 endif()
460
461 # Rebuild *.yacc and *.lex files that are contained by TKMath toolkit
462 list (FIND BUILD_TOOLKITS TKMath   CAN_REBUILD_PDC_FOR_TKMATH)
463 list (FIND BUILD_TOOLKITS StepFile CAN_REBUILD_PDC_FOR_STEPFILE)
464
465 if (NOT ${CAN_REBUILD_PDC_FOR_TKMATH} EQUAL -1 OR NOT ${CAN_REBUILD_PDC_FOR_STEPFILE} EQUAL -1)
466   set (BUILD_YACCLEX OFF CACHE BOOL "${BUILD_YACCLEX_DESCR}")
467 else()
468   OCCT_CHECK_AND_UNSET (BUILD_YACCLEX)
469 endif()
470
471 if (NOT DEFINED 3RDPARTY_DIR)
472   set (3RDPARTY_DIR "" CACHE PATH ${3RDPARTY_DIR_DESCR})
473   get_filename_component (3RDPARTY_DIR "${3RDPARTY_DIR}" ABSOLUTE)
474 else()
475   file (TO_CMAKE_PATH "${3RDPARTY_DIR}" 3RDPARTY_DIR)
476   set (3RDPARTY_DIR "${3RDPARTY_DIR}" CACHE PATH "${3RDPARTY_DIR_DESCR}" FORCE)
477 endif()
478
479 # search for CSF variable in EXTERNLIB of each being used toolkit
480 OCCT_IS_PRODUCT_REQUIRED (CSF_FreeImagePlus CAN_USE_FREEIMAGE)
481 OCCT_IS_PRODUCT_REQUIRED (CSF_TclLibs USE_TCL)
482 OCCT_IS_PRODUCT_REQUIRED (CSF_FREETYPE USE_FREETYPE)
483 OCCT_IS_PRODUCT_REQUIRED (CSF_OpenGlLibs CAN_USE_GLES2)
484 OCCT_IS_PRODUCT_REQUIRED (CSF_GL2PS CAN_USE_GL2PS)
485 OCCT_IS_PRODUCT_REQUIRED (CSF_TBB CAN_USE_TBB)
486 OCCT_IS_PRODUCT_REQUIRED (CSF_EIGEN CAN_USE_EIGEN)
487
488 # define CSF variable
489 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_csf")
490
491 if (USE_TCL)
492   message (STATUS "Info: TCL is used by OCCT")
493   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tcl")
494   
495   message (STATUS "Info: TK is used by OCCT")
496   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tk")
497 else()
498   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TCL")
499   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TK")
500
501   OCCT_CHECK_AND_UNSET ("INSTALL_TCL")
502   OCCT_CHECK_AND_UNSET ("INSTALL_TK")
503 endif()
504
505 if (USE_FREETYPE)
506   message (STATUS "Info: Freetype is used by OCCT")
507   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freetype")
508 else()
509   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREETYPE")
510   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2")
511   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build")
512   OCCT_CHECK_AND_UNSET ("INSTALL_FREETYPE")
513 endif()
514
515 # VTK
516 if (USE_VTK)
517   add_definitions (-DHAVE_VTK)
518   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vtk")
519 else()
520   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_VTK")
521   
522   if (NOT CAN_USE_VTK EQUAL -1)
523     message (STATUS "Info: TKIVtk and TKIVtkDraw toolkits excluded due to VTK usage is disabled")
524
525     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtk)
526     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtkDraw)
527   endif()
528 endif()
529
530 # D3D
531 if (USE_D3D)
532   add_definitions (-DHAVE_D3D)
533   #if(MSVC_VERSION LESS 1700)
534   #OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/d3d")
535   #endif()
536 endif()
537
538 # GLX
539 if (USE_GLX)
540   add_definitions (-DMACOSX_USE_GLX)
541   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/glx")
542 endif()
543
544 # FREEIMAGE
545
546 if (CAN_USE_FREEIMAGE)
547   set (USE_FREEIMAGE OFF CACHE BOOL "${USE_FREEIMAGE_DESCR}")
548
549   if (USE_FREEIMAGE)
550     add_definitions (-DHAVE_FREEIMAGE)
551     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimage")
552   else()
553     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
554     OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
555   endif()
556 else()
557   OCCT_CHECK_AND_UNSET ("USE_FREEIMAGE")
558
559   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
560   OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
561 endif()
562
563 # FFmpeg
564 # search for CSF_FFmpeg variable in EXTERNLIB of each being used toolkit
565 OCCT_IS_PRODUCT_REQUIRED (CSF_FFmpeg CAN_USE_FFMPEG)
566
567 if (CAN_USE_FFMPEG)
568   set (USE_FFMPEG OFF CACHE BOOL "${USE_FFMPEG_DESCR}")
569
570   if (USE_FFMPEG)
571     add_definitions (-DHAVE_FFMPEG)
572     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/ffmpeg")
573   else()
574     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FFMPEG")
575     OCCT_CHECK_AND_UNSET ("INSTALL_FFMPEG")
576   endif()
577 else()
578   OCCT_CHECK_AND_UNSET ("USE_FFMPEG")
579
580   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FFMPEG")
581   OCCT_CHECK_AND_UNSET ("INSTALL_FFMPEG")
582 endif()
583
584 # OpenGL ES 2.0
585 if (WIN32 AND CAN_USE_GLES2)
586   if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
587     set (USE_GLES2 ON)
588   else()
589     set (USE_GLES2 OFF CACHE BOOL "${USE_GLES2_DESCR}")
590   endif()
591
592   if (USE_GLES2)
593     add_definitions (-DHAVE_GLES2)
594     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/egl")
595         OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gles2")
596   else()
597     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EGL")
598     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GLES2")
599     OCCT_CHECK_AND_UNSET ("INSTALL_EGL")
600     OCCT_CHECK_AND_UNSET ("INSTALL_GLES2")
601   endif()
602 else()
603   OCCT_CHECK_AND_UNSET ("USE_GLES2")
604
605   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EGL")
606   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GLES2")
607   OCCT_CHECK_AND_UNSET ("INSTALL_EGL")
608   OCCT_CHECK_AND_UNSET ("INSTALL_GLES2")
609 endif()
610
611 # GL2PS
612 if (NOT DEFINED ANDROID AND CAN_USE_GL2PS)
613   set (USE_GL2PS OFF CACHE BOOL "${USE_GL2PS_DESCR}")
614
615   if (USE_GL2PS)
616     add_definitions (-DHAVE_GL2PS)
617     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gl2ps")
618   else()
619     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
620     OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
621   endif()
622 else()
623   OCCT_CHECK_AND_UNSET ("USE_GL2PS")
624
625   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
626   OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
627 endif()
628
629 # TBB
630 if (NOT DEFINED ANDROID AND CAN_USE_TBB)
631   set (USE_TBB OFF CACHE BOOL "${USE_TBB_DESCR}")
632
633   if (USE_TBB)
634     add_definitions (-DHAVE_TBB)
635     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tbb")
636   else()
637     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
638     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
639     OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
640   endif()
641 else()
642   OCCT_CHECK_AND_UNSET ("USE_TBB")
643
644   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
645   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
646   OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
647 endif()
648
649 # EIGEN
650 if (CAN_USE_EIGEN)
651   set (USE_EIGEN OFF CACHE BOOL "${USE_EIGEN_DESCR}")
652
653   if (USE_EIGEN)
654     add_definitions (-DHAVE_EIGEN)
655     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/eigen")
656   else()
657     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EIGEN")
658   endif()
659 else()
660   OCCT_CHECK_AND_UNSET ("USE_EIGEN")
661
662   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EIGEN")
663 endif()
664
665 # Doxygen
666 if (BUILD_DOC_Overview)
667   if (NOT DEFINED INSTALL_DOC_Overview)
668     set (INSTALL_DOC_Overview OFF CACHE BOOL "${INSTALL_DOC_Overview_DESCR}")
669   endif()
670
671   if (INSTALL_DOC_Overview)
672     install (DIRECTORY "${CMAKE_BINARY_DIR}/doc/overview" DESTINATION  "${INSTALL_DIR_DOC}")
673
674     # create overview.html only for windows
675     if (WIN32 AND "${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
676       OCCT_INSTALL_FILE_OR_DIR ("dox/resources/overview.html" "${INSTALL_DIR_DOC}/..")
677     endif()
678   endif()
679
680   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
681 else()
682   OCCT_CHECK_AND_UNSET ("INSTALL_DOC_Overview")
683
684   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOXYGEN_EXECUTABLE")
685   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOT_EXECUTABLE")
686 endif()
687
688 # bison 
689 if (BUILD_YACCLEX)
690   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/bison")
691 else()
692   OCCT_CHECK_AND_UNSET ("3RDPARTY_BISON_EXECUTABLE")
693 endif()
694
695 # flex 
696 if (BUILD_YACCLEX)
697   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/flex")
698 else()
699   OCCT_CHECK_AND_UNSET ("3RDPARTY_FLEX_EXECUTABLE")
700 endif()
701
702 string (REGEX REPLACE ";" " " 3RDPARTY_NOT_INCLUDED "${3RDPARTY_NOT_INCLUDED}")
703
704 # check all 3rdparty paths
705 if (3RDPARTY_NOT_INCLUDED)
706   message (FATAL_ERROR "NOT FOUND: ${3RDPARTY_NOT_INCLUDED}" )
707 endif()
708
709 if (3RDPARTY_INCLUDE_DIRS)
710   list (REMOVE_DUPLICATES 3RDPARTY_INCLUDE_DIRS)
711   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_INCLUDE_DIRS_WITH_ENDS "${3RDPARTY_INCLUDE_DIRS}")
712   message (STATUS "Info: The directories of 3rdparty headers: \n\t${3RDPARTY_INCLUDE_DIRS_WITH_ENDS}")
713   include_directories (${3RDPARTY_INCLUDE_DIRS})
714 endif()
715
716 # include <cmake binary folder>/inc
717 include_directories (${CMAKE_BINARY_DIR}/${INSTALL_DIR_INCLUDE})
718
719 if (3RDPARTY_LIBRARY_DIRS AND BUILD_SHARED_LIBS)
720   list (REMOVE_DUPLICATES 3RDPARTY_LIBRARY_DIRS)
721   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_LIBRARY_DIRS_WITH_ENDS "${3RDPARTY_LIBRARY_DIRS}")
722   message (STATUS "Info: The directories of 3rdparty libraries: \n\t${3RDPARTY_LIBRARY_DIRS_WITH_ENDS}")
723   link_directories (${3RDPARTY_LIBRARY_DIRS})
724 endif()
725
726 # build directories
727 if (SINGLE_GENERATOR)
728   set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
729   set (CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
730   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
731   if (WIN32)
732     set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
733   endif()
734 endif()
735
736 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
737 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
738 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
739
740 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
741 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
742 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
743
744 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
745 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
746 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
747
748 if (WIN32) 
749   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE        "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
750   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
751   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG          "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
752 endif()
753
754 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
755 message (STATUS "\nInfo: \(${CURRENT_TIME}\) Start collecting all OCCT header files into ${CMAKE_BINARY_DIR}/inc ...")
756
757 # collect all the headers to <binary dir>/inc folder
758 COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}" "${BUILD_TOOLKITS}" "${CMAKE_SOURCE_DIR}/src" "${INSTALL_DIR_INCLUDE}")
759
760 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
761 message (STATUS "Info: \(${CURRENT_TIME}\) End the collecting")
762
763 list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
764 if (${DRAWEXE_INDEX} GREATER -1)
765   OCCT_INSTALL_FILE_OR_DIR ("data/" "${INSTALL_DIR_DATA}")
766   OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR_SAMPLES}")
767 endif()
768
769 if (WIN32)
770   set (SCRIPT_EXT bat)
771 else()
772   set (SCRIPT_EXT sh)
773 endif()
774
775 # OCCT tools
776 # include the patched or original list of tools
777 # list <TOOLNAME>_TOOLKITS is created foreach tool and contains its toolkits
778 # list <OCCT_TOOLS> will contain all tools
779 if (NOT BUILD_Inspector)
780   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_QT")
781   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TQTMALLOC")
782   OCCT_CHECK_AND_UNSET ("INSTALL_QT")
783 else()
784   OCCT_TOOLS_AND_TOOLKITS (OCCT_TOOLS)
785   foreach (OCCT_TOOL ${OCCT_TOOLS})
786     list (APPEND BUILD_TOOL_TOOLKITS ${${OCCT_TOOL}_TOOL_TOOLKITS})
787   endforeach()
788
789   # collect all the headers to <binary dir>/inc folder
790   string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
791   message (STATUS "\nInfo: \(${CURRENT_TIME}\) Start collecting all OCCT tool header files into ${CMAKE_BINARY_DIR}/tools/inc ...")
792   COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}" "${BUILD_TOOL_TOOLKITS}" "${CMAKE_SOURCE_DIR}/tools" "${INSTALL_DIR_INCLUDE}/inspector")
793
794
795   # check qt 3rdparty path
796   add_definitions (-DHAVE_QT)
797   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/qt")
798   message (STATUS "Info: Qt is used by OCCT")
799 endif()
800
801 # OCCT samples
802 # get absolute path from INSTALL_DIR
803 set (INSTALL_DIR_ABSOLUTE "${INSTALL_DIR}")
804 if(NOT IS_ABSOLUTE "${INSTALL_DIR_ABSOLUTE}")
805   get_filename_component(INSTALL_DIR_ABSOLUTE "${CMAKE_BINARY_DIR}/${INSTALL_DIR}" ABSOLUTE)
806 endif()
807
808 if (INSTALL_SAMPLES)
809   OCCT_CONFIGURE ("adm/templates/env.samples.${SCRIPT_EXT}.in" "env.samples.${SCRIPT_EXT}")
810   if (WIN32)
811     OCCT_INSTALL_FILE_OR_DIR ("samples/CSharp" "${INSTALL_DIR_SAMPLES}")
812     OCCT_INSTALL_FILE_OR_DIR ("samples/mfc" "${INSTALL_DIR_SAMPLES}")
813
814     if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
815       OCCT_INSTALL_FILE_OR_DIR ("samples/xaml" "${INSTALL_DIR_SAMPLES}")
816     endif()
817
818     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/CSharp" RENAME "env.${SCRIPT_EXT}")
819     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/mfc/standard" RENAME "env.${SCRIPT_EXT}")
820   endif()
821
822   OCCT_INSTALL_FILE_OR_DIR ("samples/java" "${INSTALL_DIR_SAMPLES}")
823   OCCT_INSTALL_FILE_OR_DIR ("samples/ocafsamples" "${INSTALL_DIR_SAMPLES}")
824   OCCT_INSTALL_FILE_OR_DIR ("samples/qt" "${INSTALL_DIR_SAMPLES}")
825
826   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/FuncDemo" RENAME "env.${SCRIPT_EXT}")
827   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/IESample" RENAME "env.${SCRIPT_EXT}")
828   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/Tutorial" RENAME "env.${SCRIPT_EXT}")
829 endif()
830
831 if (INSTALL_TEST_CASES)
832   OCCT_INSTALL_FILE_OR_DIR ("tests/" "${INSTALL_DIR_TESTS}")
833 endif()
834
835 list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
836 if (${DRAWEXE_INDEX} GREATER -1)
837   # copy data and samples/tcl folders to install script folder
838   OCCT_INSTALL_FILE_OR_DIR ("data/" "${INSTALL_DIR_DATA}")
839   OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR_SAMPLES}")
840
841   # copy draw script to install script folder
842   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}")
843     install (FILES "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
844             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
845   else()
846     install (FILES "${CMAKE_SOURCE_DIR}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
847             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
848   endif()
849
850   # copy draw script to CMake binary folder
851   OCCT_COPY_FILE_OR_DIR ("adm/templates/draw.${SCRIPT_EXT}" "${CMAKE_BINARY_DIR}")
852 endif()
853
854 set (SUB_CUSTOM_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.${SCRIPT_EXT}")
855
856 if (WIN32)
857   set (ADDITIONAL_CUSTOM_CONTENT "\nif exist \"%~dp0${SUB_CUSTOM_NAME}\" (\n  call \"%~dp0${SUB_CUSTOM_NAME}\" %1 %2 %3 \n)")
858 else()
859   set (ADDITIONAL_CUSTOM_CONTENT "\nif [ -e \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" ]; then\n  source \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" \"\$1\" \"\$2\" \nfi")
860 endif()
861
862  # change custom.bat/sh
863 if (EXISTS "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}")
864   file (READ "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" CUSTOM_CONTENT)
865
866   set (CUSTOM_CONTENT "${CUSTOM_CONTENT} ${ADDITIONAL_CUSTOM_CONTENT}")
867
868   file (WRITE "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" "${CUSTOM_CONTENT}")
869 else()
870   OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.${SCRIPT_EXT}.main" "custom.${SCRIPT_EXT}" "custom.${SCRIPT_EXT}" "${INSTALL_DIR_SCRIPT}")
871 endif()
872
873 # write current custom.bat/sh (for install directory)
874 set (SUB_CUSTOM_BUILD_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.install.${SCRIPT_EXT}")
875 OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.install.${SCRIPT_EXT}.in" "${SUB_CUSTOM_BUILD_NAME}" "${SUB_CUSTOM_NAME}" "${INSTALL_DIR_SCRIPT}")
876
877 # write current custom.bat/sh (for build directory)
878 OCCT_CONFIGURE ("adm/templates/custom.build.${SCRIPT_EXT}.in" "${SUB_CUSTOM_NAME}")
879
880 if (BUILD_MODULE_MfcSamples)
881   OCCT_INSTALL_FILE_OR_DIR ("adm/templates/sample.bat" "${INSTALL_DIR_SCRIPT}")
882   OCCT_COPY_FILE_OR_DIR    ("adm/templates/sample.bat" "${CMAKE_BINARY_DIR}")
883 endif()
884
885 # env script for draw in building environment
886 OCCT_CONFIGURE ("adm/templates/env.${SCRIPT_EXT}.in" "env.${SCRIPT_EXT}")
887
888 # install env script
889 install (FILES "${CMAKE_BINARY_DIR}/env.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SCRIPT}")
890
891 # copy DrawAppliInit from OCCT source to build directory
892 if (NOT EXISTS "${CMAKE_BINARY_DIR}/DrawAppliInit")
893   OCCT_COPY_FILE_OR_DIR (DrawAppliInit "${CMAKE_BINARY_DIR}")
894 endif()
895
896 # RESOURCES
897 FILE_TO_LIST ("adm/RESOURCES" RESOURCES)
898 foreach(RESOURCE ${RESOURCES})
899   get_filename_component(RESOURCE_FOLDER ${RESOURCE} DIRECTORY)
900   if(NOT "${RESOURCE_FOLDER}" STREQUAL "")
901     get_filename_component(RESOURCE_FOLDER ${RESOURCE_FOLDER} NAME)
902     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR_RESOURCE}/${RESOURCE_FOLDER}")
903   else()
904     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR_RESOURCE}")
905   endif()
906 endforeach()
907
908 # patch installed DrawDefault file if BUILD_SHARED_LIBRARY_NAME_POSTFIX is changed
909 if (NOT "${BUILD_SHARED_LIBRARY_NAME_POSTFIX}" STREQUAL "")
910   OCCT_UPDATE_DRAW_DEFAULT_FILE()
911 endif()
912
913 # include patched toolkit projects or original ones
914 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
915   OCCT_ADD_SUBDIRECTORY ("src/${BUILD_TOOLKIT}")
916 endforeach()
917
918 if (BUILD_DOC_Overview)
919   OCCT_ADD_SUBDIRECTORY (dox)
920 endif()
921
922 # patch DRAWEXE
923 if (MSVC AND 3RDPARTY_DLL_DIRS)
924   list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
925   if (${DRAWEXE_INDEX} GREATER -1)
926     list (REMOVE_DUPLICATES 3RDPARTY_DLL_DIRS)
927     set (3RDPARTY_DLL_DIRS_FOR_PATH "")
928
929     foreach (3RDPARTY_DLL_DIR ${3RDPARTY_DLL_DIRS})
930       set (3RDPARTY_DLL_DIRS_FOR_PATH "${3RDPARTY_DLL_DIRS_FOR_PATH};${3RDPARTY_DLL_DIR}")
931     endforeach()
932
933     OCCT_MAKE_COMPILER_BITNESS()
934     set (X_COMPILER_BITNESS "x64")
935     if ("${COMPILER_BITNESS}" STREQUAL "32")
936       set (X_COMPILER_BITNESS "Win32")
937     endif()
938
939     OCCT_CONFIGURE ("adm/templates/DRAWEXE.vcxproj.user.in" "${CMAKE_BINARY_DIR}/src/DRAWEXE/DRAWEXE.vcxproj.user")
940   endif()
941 endif()
942
943 # include patched toolkit projects or original ones
944 if (BUILD_TOOL_TOOLKITS)
945   foreach (BUILD_TOOL_TOOLKIT ${BUILD_TOOL_TOOLKITS})
946     OCCT_ADD_SUBDIRECTORY ("tools/${BUILD_TOOL_TOOLKIT}")
947   endforeach()
948 endif()
949
950 message (STATUS "Info: \(${CURRENT_TIME}\) OCCT toolkits processed")
951 # samples do not support patch usage
952 if (BUILD_MODULE_MfcSamples)
953   set (OCCT_ROOT ${CMAKE_SOURCE_DIR})
954
955   set (MFC_STANDARD_SAMPLES_DIR ${OCCT_ROOT}/samples/mfc/standard)
956   set (COMMON_WINMAIN_FILE      ${MFC_STANDARD_SAMPLES_DIR}/Common/Winmain.cpp)
957
958   add_subdirectory(samples/mfc/standard/mfcsample)
959   add_subdirectory(samples/mfc/standard/01_Geometry)
960   add_subdirectory(samples/mfc/standard/02_Modeling)
961   add_subdirectory(samples/mfc/standard/03_Viewer2d)
962   add_subdirectory(samples/mfc/standard/04_Viewer3d)
963   add_subdirectory(samples/mfc/standard/05_ImportExport)
964   add_subdirectory(samples/mfc/standard/06_Ocaf)
965   add_subdirectory(samples/mfc/standard/07_Triangulation)
966   add_subdirectory(samples/mfc/standard/08_HLR)
967   add_subdirectory(samples/mfc/standard/09_Animation)
968   add_subdirectory(samples/mfc/standard/10_Convert)
969
970   message (STATUS "Info: \(${CURRENT_TIME}\) MFC Sample projects added")
971 endif()
972
973 if (BUILD_MODULE_UwpSample)
974   add_subdirectory(samples/xaml)
975 endif()
976
977 if (BUILD_TOOL_TOOLKITS)
978   # copy tinspector script to install script folder
979   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/adm/templates/inspector.${SCRIPT_EXT}")
980     install (FILES "${BUILD_PATCH}/adm/templates/inspector.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
981             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
982   else()
983     install (FILES "${CMAKE_SOURCE_DIR}/adm/templates/inspector.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
984             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
985   endif()
986
987   set (BUILD_SAMPLE_TOOLKITS TInspectorEXE)
988   foreach (BUILD_SAMPLE_TOOL_TOOLKIT ${BUILD_SAMPLE_TOOLKITS})
989     OCCT_ADD_SUBDIRECTORY ("samples/tools/${BUILD_SAMPLE_TOOL_TOOLKIT}")
990   endforeach()
991
992   # patch TInspectorEXE
993   OCCT_CONFIGURE ("adm/templates/TInspectorEXE.vcxproj.user.in" "${CMAKE_BINARY_DIR}/samples/tools/TInspectorEXE/TInspectorEXE.vcxproj.user")
994 endif()
995
996 # Prepare variables for configuration of OpenCASCADE cmake config file
997 set (OCCT_MODULES_ENABLED)
998 set (OCCT_LIBRARIES)
999 set (SET_OpenCASCADE_MODULES_TOOLKITS "\n# List of available OpenCASCADE libraries for each module\n")
1000 set (OCCT_COMPILE_DEFINITIONS)
1001
1002 foreach (OCCT_TOOLKIT ${BUILD_TOOLKITS})
1003   if (TARGET ${OCCT_TOOLKIT})
1004
1005     # get all libraries
1006     get_target_property (${OCCT_TOOLKIT}_TYPE ${OCCT_TOOLKIT} "TYPE")
1007     if ("${${OCCT_TOOLKIT}_TYPE}" STREQUAL "STATIC_LIBRARY" OR "${${OCCT_TOOLKIT}_TYPE}" STREQUAL "SHARED_LIBRARY" )
1008       list (APPEND OCCT_LIBRARIES ${OCCT_TOOLKIT})
1009
1010       # get all modules
1011       get_target_property (${OCCT_TOOLKIT}_MODULE ${OCCT_TOOLKIT} "MODULE")
1012       list (APPEND OCCT_MODULES_ENABLED ${${OCCT_TOOLKIT}_MODULE})
1013       list (APPEND OpenCASCADE_${${OCCT_TOOLKIT}_MODULE}_TOOLKITS ${OCCT_TOOLKIT})
1014
1015       # get compile definitions of target directory
1016       get_directory_property (COMPILE_DEFINITIONS DIRECTORY "${${OCCT_TOOLKIT}_SOURCE_DIR}" "COMPILE_DEFINITIONS")
1017       list (APPEND OCCT_COMPILE_DEFINITIONS ${COMPILE_DEFINITIONS})
1018     endif()
1019   endif()
1020 endforeach()
1021 list (REMOVE_DUPLICATES OCCT_MODULES_ENABLED)
1022 list (REMOVE_DUPLICATES OCCT_COMPILE_DEFINITIONS)
1023
1024 # export compile definitions and C/C++ flags for each configuration to OpenCASCADE config files
1025 foreach (OCCT_CONFIGURATION ${CMAKE_CONFIGURATION_TYPES})
1026   set (SET_OpenCASCADE_COMPILE_DEFINITIONS)
1027   string (TOUPPER "${OCCT_CONFIGURATION}" OCCT_CONFIGURATION_UPPER)
1028   string (TOLOWER "${OCCT_CONFIGURATION}" OCCT_CONFIGURATION_LOWER)
1029   foreach(COMPILE_DEFINITION ${OCCT_COMPILE_DEFINITIONS})
1030     string(REPLACE "(" "\\(" COMPILE_DEFINITION "${COMPILE_DEFINITION}")
1031     string(REPLACE ")" "\\)" COMPILE_DEFINITION "${COMPILE_DEFINITION}")
1032     set (SET_OpenCASCADE_COMPILE_DEFINITIONS "${SET_OpenCASCADE_COMPILE_DEFINITIONS}set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:${OCCT_CONFIGURATION}>:${COMPILE_DEFINITION}>)\n")
1033   endforeach()
1034   set (SET_OpenCASCADE_CMAKE_C_FLAGS "${CMAKE_C_FLAGS_${OCCT_CONFIGURATION_UPPER}}")
1035   set (SET_OpenCASCADE_CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS_${OCCT_CONFIGURATION_UPPER}}")
1036   configure_file("${CMAKE_SOURCE_DIR}/adm/templates/OpenCASCADECompileDefinitionsAndFlags.cmake.in" "OpenCASCADECompileDefinitionsAndFlags-${OCCT_CONFIGURATION_LOWER}.cmake" @ONLY)
1037 endforeach()
1038 # install OpenCASCADE config file with compile definitions and C/C++ flags ONLY for current configuration
1039 install (CODE "string (TOLOWER \"\${CMAKE_INSTALL_CONFIG_NAME}\" CMAKE_INSTALL_CONFIG_NAME_LOWER)")
1040 install (CODE "configure_file(\"${CMAKE_BINARY_DIR}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" \"${INSTALL_DIR}/${INSTALL_DIR_CMAKE}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" COPYONLY)")
1041
1042 foreach (OCCT_MODULE ${OCCT_MODULES})
1043   if (BUILD_MODULE_${OCCT_MODULE})
1044     set (SET_OpenCASCADE_MODULES_TOOLKITS "${SET_OpenCASCADE_MODULES_TOOLKITS}set (OpenCASCADE_${OCCT_MODULE}_LIBRARIES ${OpenCASCADE_${OCCT_MODULE}_TOOLKITS})\n")
1045   endif()
1046
1047   # sort enabled modules for correct work of OpenCASCADE config file
1048   list(FIND OCCT_MODULES_ENABLED "${OCCT_MODULE}" OCCT_MODULE_INDEX)
1049   if (NOT ${OCCT_MODULE_INDEX} EQUAL -1)
1050     list (APPEND OCCT_MODULES_ENABLED_SORTED ${OCCT_MODULE})
1051   endif()
1052 endforeach()
1053 set (OCCT_MODULES_ENABLED ${OCCT_MODULES_ENABLED_SORTED})
1054
1055 # Add all targets to the build-tree export set
1056 export (TARGETS ${OCCT_LIBRARIES} FILE "${CMAKE_BINARY_DIR}/OpenCASCADETargets.cmake")
1057
1058 # Export the package for use from the build-tree
1059 # (this registers the build-tree with a global CMake-registry)
1060 export(PACKAGE OpenCASCADE)
1061
1062 if (CMAKE_BUILD_TYPE)
1063   set (SET_OpenCASCADE_BUILD_TYPE "set (OpenCASCADE_BUILD_TYPE        \"${CMAKE_BUILD_TYPE}\")")
1064 endif()
1065
1066 if (BUILD_SHARED_LIBS)
1067   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_SHARED_LINKER_FLAGS}\")")
1068 else()
1069   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_STATIC_LINKER_FLAGS}\")")
1070 endif()
1071
1072 if (WIN32)
1073   set (SET_OpenCASCADE_WITH_D3D "set (OpenCASCADE_WITH_D3D       ${USE_D3D})")
1074 endif()
1075 if (APPLE)
1076   set (SET_OpenCASCADE_WITH_GLX "set (OpenCASCADE_WITH_GLX       ${USE_GLX})")
1077 endif()
1078
1079 if (NOT SINGLE_GENERATOR)
1080   OCCT_INSERT_CODE_FOR_TARGET()
1081 endif()
1082
1083 # Configure and install cmake config file
1084 configure_file("${CMAKE_SOURCE_DIR}/adm/templates/OpenCASCADEConfig.cmake.in" "OpenCASCADEConfig.cmake" @ONLY)
1085 install(FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfig.cmake" DESTINATION  "${INSTALL_DIR_CMAKE}")
1086
1087 # Configure cmake version file
1088 include(CMakePackageConfigHelpers)
1089 write_basic_package_version_file( ${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake
1090                                   VERSION ${OCC_VERSION_MAJOR}.${OCC_VERSION_MINOR}.${OCC_VERSION_MAINTENANCE}
1091                                   COMPATIBILITY ExactVersion )
1092
1093 # Install cmake version file
1094 install (FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake" DESTINATION "${INSTALL_DIR_CMAKE}")
1095
1096 # Install the export set for use with the install-tree for each configuration
1097 foreach (OCCT_MODULE ${OCCT_MODULES_ENABLED})
1098   install(EXPORT OpenCASCADE${OCCT_MODULE}Targets DESTINATION "${INSTALL_DIR_CMAKE}")
1099 endforeach()
1100
1101 # Update generated OpenCASCADETargets-*.cmake files 
1102 # to have correct paths to libraries depending on the configuration
1103 OCCT_UPDATE_TARGET_FILE ()
1104
1105 message (STATUS "Info: \(${CURRENT_TIME}\) OCCT configuration files prepared")