CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.12 FATAL_ERROR)
   2
   3 set (CMAKE_SUPPRESS_REGENERATION TRUE)
   4
   5 set (CMAKE_CONFIGURATION_TYPES Release Debug RelWithDebInfo CACHE INTERNAL "" FORCE)
   6
   7 # macro: include patched file if it exists
   8 macro (OCCT_INCLUDE_CMAKE_FILE BEING_INCLUDED_FILE)
   9   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake")
  10     include (${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake)
  11   else()
  12     include (${CMAKE_SOURCE_DIR}/${BEING_INCLUDED_FILE}.cmake)
  13   endif()
  14 endmacro()
  15
  16 # include variable description
  17 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vardescr")
  18
  19 # set type of OCCT libraries
  20 if (NOT BUILD_LIBRARY_TYPE)
  21   set (BUILD_LIBRARY_TYPE "Shared" CACHE STRING "${BUILD_LIBRARY_TYPE_DESCR}" FORCE)
  22   SET_PROPERTY(CACHE BUILD_LIBRARY_TYPE PROPERTY STRINGS Shared Static)
  23 endif()
  24
  25 if ("${BUILD_LIBRARY_TYPE}" STREQUAL "Shared")
  26   set (BUILD_SHARED_LIBS ON)
  27
  28   if (NOT DEFINED BUILD_SHARED_LIBRARY_NAME_POSTFIX)
  29     set (BUILD_SHARED_LIBRARY_NAME_POSTFIX "" CACHE STRING "${BUILD_SHARED_LIBRARY_NAME_POSTFIX_DESCR}" FORCE)
  30   endif()
  31 else()
  32   unset (BUILD_SHARED_LIBS)
  33   message (STATUS "Info: Only 3rdparty's header files are used for building of static OCCT libraries")
  34   unset (BUILD_SHARED_LIBRARY_NAME_POSTFIX)
  35 endif()
  36
  37 # the name of the project
  38 project (OCCT)
  39
  40 # include occt macros
  41 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_macros")
  42
  43 # Solution folder property
  44 set_property (GLOBAL PROPERTY USE_FOLDERS ON)
  45
  46 # get current OCCT version
  47 OCC_VERSION (OCC_VERSION_MAJOR OCC_VERSION_MINOR OCC_VERSION_MAINTENANCE OCC_VERSION_DEVELOPMENT OCC_VERSION_STRING_EXT)
  48
  49 set_property (GLOBAL PROPERTY OCC_VERSION_MAJOR ${OCC_VERSION_MAJOR})
  50 set_property (GLOBAL PROPERTY OCC_VERSION_MINOR ${OCC_VERSION_MINOR})
  51 set_property (GLOBAL PROPERTY OCC_VERSION_MAINTENANCE ${OCC_VERSION_MAINTENANCE})
  52
  53 set (INSTALL_TEST_CASES OFF CACHE BOOL "${INSTALL_TEST_CASES_DESCR}")
  54
  55 # single-configuration generator
  56 set (SINGLE_GENERATOR OFF)
  57 if (CMAKE_BUILD_TYPE)
  58   set (SINGLE_GENERATOR ON)
  59 endif()
  60
  61 # a single-configuration generator like the Makefile generator defines CMAKE_BUILD_TYPE variable
  62 # check this variable and set if it's required
  63 if (DEFINED CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE) # single-configuration generator.
  64   set (CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel." FORCE)
  65 endif()
  66
  67 # enable extended messages of many OCCT algorithms
  68 if (((SINGLE_GENERATOR AND "${CMAKE_BUILD_TYPE}" STREQUAL "Debug") OR NOT SINGLE_GENERATOR) AND (NOT "${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore"))
  69   if (NOT BUILD_WITH_DEBUG)
  70     set (BUILD_WITH_DEBUG OFF CACHE BOOL "${BUILD_WITH_DEBUG_DESCR}")
  71   endif()
  72 else()
  73   OCCT_CHECK_AND_UNSET (BUILD_WITH_DEBUG)
  74 endif()
  75
  76 if (BUILD_WITH_DEBUG)
  77   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:DEBUG>:OCCT_DEBUG>)
  78 endif()
  79
  80 # copy samples to install directory
  81 set (INSTALL_SAMPLES OFF CACHE BOOL "${INSTALL_SAMPLES_DESCR}")
  82
  83 # install dir of the project
  84 if (NOT DEFINED INSTALL_DIR)
  85   # set default install directory for Windows
  86   if (WIN32 AND NOT DEFINED CMAKE_INSTALL_PREFIX)
  87     set (CMAKE_INSTALL_PREFIX "C:/opencascade-${OCC_VERSION_STRING_EXT}")
  88   endif()
  89   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}")
  90 else()
  91   file (TO_CMAKE_PATH "${INSTALL_DIR}" INSTALL_DIR)
  92   set (INSTALL_DIR "${INSTALL_DIR}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
  93 endif()
  94
  95 # choose a variant of the layout of the install paths
  96 if (NOT INSTALL_DIR_LAYOUT)
  97   if (WIN32)
  98     set (INSTALL_DIR_LAYOUT "Windows" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
  99   else()
 100     set (INSTALL_DIR_LAYOUT "Unix" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
 101   endif()
 102   SET_PROPERTY(CACHE INSTALL_DIR_LAYOUT PROPERTY STRINGS Windows Unix)
 103 endif()
 104
 105 # check INSTALL_DIR_LAYOUT changes and update INSTALL_DIR_* paths if necessary
 106 if (NOT DEFINED INSTALL_DIR_LAYOUT_PREV)
 107   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
 108 elseif (NOT "${INSTALL_DIR_LAYOUT_PREV}" STREQUAL "${INSTALL_DIR_LAYOUT}")
 109   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
 110   # The structure of install folder should be reset due to changed layout
 111   OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
 112
 113   # Unset INSTALL_DIR_WITH_VERSION on windows
 114   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
 115     OCCT_CHECK_AND_UNSET (INSTALL_DIR_WITH_VERSION)
 116   else()
 117     if (NOT DEFINED INSTALL_DIR_WITH_VERSION)
 118       set (INSTALL_DIR_WITH_VERSION OFF CACHE BOOL "${INSTALL_DIR_WITH_VERSION_DESCR}")
 119     endif()
 120   endif()
 121 endif()
 122
 123 # check CMAKE_INSTALL_PREFIX changes and update INSTALL_DIR if necessary
 124 if (NOT DEFINED CMAKE_INSTALL_PREFIX_PREV)
 125   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
 126 elseif (NOT "${CMAKE_INSTALL_PREFIX_PREV}" STREQUAL "${CMAKE_INSTALL_PREFIX}")
 127   # CMAKE_INSTALL_PREFIX has been changed at previous step
 128   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
 129
 130   # INSTALL_DIR is required to be updated
 131   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
 132 endif()
 133
 134 # check INSTALL_DIR changes and update CMAKE_INSTALL_PREFIX if necessary
 135 if (NOT DEFINED INSTALL_DIR_PREV)
 136   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 137 elseif (NOT "${INSTALL_DIR_PREV}" STREQUAL "${INSTALL_DIR}")
 138   # INSTALL_DIR has been changed at previous step
 139   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 140
 141   # sync CMAKE_INSTALL_PREFIX with INSTALL_DIR
 142   set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 143
 144   # set CMAKE_INSTALL_PREFIX_PREV to avoid the reset of structure of the install folder
 145   set (CMAKE_INSTALL_PREFIX_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 146 endif()
 147
 148 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 149   if (NOT DEFINED INSTALL_DIR_WITH_VERSION_PREV)
 150     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
 151   elseif (NOT "${INSTALL_DIR_WITH_VERSION_PREV}" STREQUAL "${INSTALL_DIR_WITH_VERSION}")
 152     # INSTALL_DIR_WITH_VERSION has been changed at previous step
 153     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
 154
 155     OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
 156   endif()
 157 endif()
 158
 159 # hide CMAKE_INSTALL_PREFIX from a user
 160 set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 161
 162 set (BIN_LETTER "")
 163 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
 164   set (BIN_LETTER "d")
 165 elseif ("${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo")
 166   set (BIN_LETTER "i")
 167 endif()
 168
 169 # Get all used variables: OS_WITH_BIT, COMPILER
 170 OCCT_MAKE_OS_WITH_BITNESS()
 171 OCCT_MAKE_COMPILER_SHORT_NAME()
 172
 173 # do not define INSTALL_DIR_BIN for win.
 174 # Leave library structure for win: <prefix>/win64/vc10/bin(d)
 175 if (NOT DEFINED INSTALL_DIR_BIN)
 176   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 177     set (INSTALL_DIR_BIN "bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
 178   else()
 179     set (INSTALL_DIR_BIN "${OS_WITH_BIT}/${COMPILER}/bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
 180   endif()
 181 endif()
 182
 183 # define folder contaning all shell/batch scripts
 184 if (NOT DEFINED INSTALL_DIR_SCRIPT)
 185   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 186     set (INSTALL_DIR_SCRIPT "${INSTALL_DIR_BIN}" CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
 187   else()
 188     set (INSTALL_DIR_SCRIPT "." CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
 189   endif()
 190 endif()
 191
 192 # place the libraries to <prefix>/lib folder for unix and leave old structure for windows
 193 if (NOT DEFINED INSTALL_DIR_LIB)
 194   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 195     set (INSTALL_DIR_LIB "lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
 196   else()
 197     set (INSTALL_DIR_LIB "${OS_WITH_BIT}/${COMPILER}/lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
 198   endif()
 199 endif()
 200
 201 # OCCT headers: <prefix>/inc for windows,
 202 #               <prefix>/include/opencascade-7.0.0 for unix
 203 if (NOT DEFINED INSTALL_DIR_INCLUDE)
 204   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 205     set (INSTALL_DIR_INCLUDE "include/opencascade" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
 206     if (INSTALL_DIR_WITH_VERSION)
 207       set (INSTALL_DIR_INCLUDE "include/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}" FORCE)
 208     endif()
 209   else()
 210     set (INSTALL_DIR_INCLUDE "inc" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
 211   endif()
 212 endif()
 213
 214 # OCCT resources: <prefix>/src for windows,
 215 #                 <prefix>/share/opencascade-7.0.0/resources for unix
 216 if (NOT DEFINED INSTALL_DIR_RESOURCE)
 217   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 218     set (INSTALL_DIR_RESOURCE "share/opencascade/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
 219     if (INSTALL_DIR_WITH_VERSION)
 220       set (INSTALL_DIR_RESOURCE "share/opencascade-${OCC_VERSION_STRING_EXT}/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}" FORCE)
 221     endif()
 222   else()
 223     set (INSTALL_DIR_RESOURCE "src" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
 224   endif()
 225 endif()
 226
 227 # OCCT data
 228 if (NOT DEFINED INSTALL_DIR_DATA)
 229   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 230     set (INSTALL_DIR_DATA "share/opencascade/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
 231     if (INSTALL_DIR_WITH_VERSION)
 232       set (INSTALL_DIR_DATA "share/opencascade-${OCC_VERSION_STRING_EXT}/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}" FORCE)
 233     endif()
 234   else()
 235     set (INSTALL_DIR_DATA "data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
 236   endif()
 237 endif()
 238
 239 # OCCT samples
 240 if (NOT DEFINED INSTALL_DIR_SAMPLES)
 241   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 242     set (INSTALL_DIR_SAMPLES "share/opencascade/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
 243     if (INSTALL_DIR_WITH_VERSION)
 244       set (INSTALL_DIR_SAMPLES "share/opencascade-${OCC_VERSION_STRING_EXT}/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}" FORCE)
 245     endif()
 246   else()
 247     set (INSTALL_DIR_SAMPLES "samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
 248   endif()
 249 endif()
 250
 251 # OCCT tests
 252 if (NOT DEFINED INSTALL_DIR_TESTS)
 253   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 254     set (INSTALL_DIR_TESTS "share/opencascade/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
 255     if (INSTALL_DIR_WITH_VERSION)
 256       set (INSTALL_DIR_TESTS "share/opencascade-${OCC_VERSION_STRING_EXT}/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}" FORCE)
 257     endif()
 258   else()
 259     set (INSTALL_DIR_TESTS "tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
 260   endif()
 261 endif()
 262
 263 # OCCT doc
 264 if (NOT DEFINED INSTALL_DIR_DOC)
 265   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 266     set (INSTALL_DIR_DOC "share/doc/opencascade" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
 267     if (INSTALL_DIR_WITH_VERSION)
 268       set (INSTALL_DIR_DOC "share/doc/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_DOC_DESCR}" FORCE)
 269     endif()
 270   else()
 271     set (INSTALL_DIR_DOC "doc" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
 272   endif()
 273 endif()
 274
 275 # define folder contaning CMake configuration files
 276 if (NOT DEFINED INSTALL_DIR_CMAKE)
 277   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 278     if (INSTALL_DIR_WITH_VERSION)
 279       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
 280     else()
 281       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
 282     endif()
 283   else()
 284     set (INSTALL_DIR_CMAKE "cmake" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
 285   endif()
 286 endif()
 287
 288 # install LICENSE_LGPL_21.txt and OCCT_LGPL_EXCEPTION.txt files
 289 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 290   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" "${INSTALL_DIR}/${INSTALL_DIR_DOC}")
 291   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" "${INSTALL_DIR}/${INSTALL_DIR_DOC}")
 292 else()
 293   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" "${INSTALL_DIR}")
 294   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" "${INSTALL_DIR}")
 295 endif()
 296
 297 if(APPLE)
 298   set (INSTALL_NAME_DIR "" CACHE STRING "install_name library suffix on OS X (e.g. @executable_path/../Frameworks)")
 299 endif()
 300
 301 # a directory recognized as a 'patch' for OCCT
 302 set (BUILD_PATCH "" CACHE PATH "${BUILD_PATCH_DESCR}")
 303
 304 # the list of being built toolkits
 305 set (BUILD_ADDITIONAL_TOOLKITS "" CACHE STRING "${BUILD_ADDITIONAL_TOOLKITS_DESCR}")
 306 separate_arguments (BUILD_ADDITIONAL_TOOLKITS)
 307
 308 if (MSVC)
 309   set (BUILD_MODULE_MfcSamples OFF CACHE BOOL "${BUILD_MODULE_MfcSamples_DESCR}")
 310 endif()
 311
 312 # uwp sample
 313 if (MSVC)
 314   if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
 315     set (BUILD_MODULE_UwpSample OFF CACHE BOOL "${BUILD_MODULE_UwpSample_DESCR}")
 316   else()
 317     unset (BUILD_MODULE_UwpSample)
 318   endif()
 319 endif()
 320
 321 # whether use optional 3rdparty or not
 322 if (APPLE)
 323   set (USE_GLX OFF CACHE BOOL "${USE_GLX_DESCR}")
 324 endif()
 325
 326 if (WIN32)
 327   set (USE_D3D OFF CACHE BOOL "${USE_D3D_DESCR}")
 328 endif()
 329
 330 # include the patched or original list of modules
 331 # list <MODULENAME>_TOOLKITS is created foreach module and contains its toolkits
 332 # list <OCCT_MODULES> will contain all modules
 333 OCCT_MODULES_AND_TOOLKITS (OCCT_MODULES)
 334
 335 foreach (OCCT_MODULE ${OCCT_MODULES})
 336   BUILD_MODULE (${OCCT_MODULE})
 337 endforeach()
 338
 339 if (ANDROID AND BUILD_MODULE_Draw)
 340   message (STATUS "Info. Draw module is turned off due to it is not supported on Android")
 341   set (BUILD_MODULE_Draw OFF CACHE BOOL "${BUILD_MODULE_Draw_DESCR}" FORCE)
 342 endif()
 343
 344 # Overview
 345 if (NOT DEFINED BUILD_DOC_Overview)
 346   set (DO_ONLY_CHECK_FOR_DOXYGEN ON)
 347   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
 348   set (DO_ONLY_CHECK_FOR_DOXYGEN OFF)
 349
 350   if (CAN_DOXYGEN_BE_USED)
 351     message (STATUS "Info. Overview building is turned on")
 352   endif()
 353
 354   set (BUILD_DOC_Overview ${CAN_DOXYGEN_BE_USED} CACHE BOOL "${BUILD_DOC_Overview_DESCR}")
 355 endif()
 356
 357 if (NOT USE_D3D)
 358   list (REMOVE_ITEM Visualization_TOOLKITS TKD3DHost)
 359 endif()
 360
 361 # accumulate used toolkits (first level) in BUILD_TOOLKITS variable
 362 list (APPEND BUILD_TOOLKITS ${BUILD_ADDITIONAL_TOOLKITS})
 363
 364 foreach (OCCT_MODULE ${OCCT_MODULES})
 365   if (BUILD_MODULE_${OCCT_MODULE})
 366     list (APPEND BUILD_TOOLKITS ${${OCCT_MODULE}_TOOLKITS})
 367   endif()
 368 endforeach()
 369
 370 # DRAWEXE excluded when library build is static
 371 if (NOT BUILD_SHARED_LIBS)
 372   list (REMOVE_ITEM BUILD_TOOLKITS DRAWEXE)
 373   message (STATUS "Info: DRAWEXE is not included due to ${BUILD_LIBRARY_TYPE} build library type")
 374 endif()
 375
 376 # accumulate all used toolkits
 377 list (REMOVE_DUPLICATES BUILD_TOOLKITS)
 378 set (RAW_BUILD_TOOLKITS)
 379 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
 380   OCCT_TOOLKIT_FULL_DEP (${BUILD_TOOLKIT} TOOLKIT_FULL_DEPS)
 381   list (APPEND RAW_BUILD_TOOLKITS ${BUILD_TOOLKIT} ${TOOLKIT_FULL_DEPS})
 382 endforeach()
 383
 384 list (REMOVE_DUPLICATES RAW_BUILD_TOOLKITS)
 385 set (BUILD_TOOLKITS ${RAW_BUILD_TOOLKITS})
 386
 387 # include the patched or original list of definitions and flags
 388 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_defs_flags")
 389
 390 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/3rdparty_macro")
 391
 392 # search for TKIVtk and TKIVtkDraw in BUILD_TOOLKITS
 393 list (FIND BUILD_TOOLKITS TKIVtk CAN_USE_VTK)
 394 if (CAN_USE_VTK EQUAL -1)
 395   list (FIND BUILD_TOOLKITS TKIVtkDraw CAN_USE_VTK)
 396 endif()
 397
 398 if (NOT CAN_USE_VTK EQUAL -1)
 399   if (NOT DEFINED USE_VTK)
 400     set (USE_VTK OFF CACHE BOOL "${USE_VTK_DESCR}")
 401   endif()
 402 else()
 403   OCCT_CHECK_AND_UNSET (USE_VTK)
 404 endif()
 405
 406 # Rebuild *.yacc and *.lex files that are contained by TKMath toolkit
 407 list (FIND BUILD_TOOLKITS TKMath   CAN_REBUILD_PDC_FOR_TKMATH)
 408 list (FIND BUILD_TOOLKITS StepFile CAN_REBUILD_PDC_FOR_STEPFILE)
 409
 410 if (NOT ${CAN_REBUILD_PDC_FOR_TKMATH} EQUAL -1 OR NOT ${CAN_REBUILD_PDC_FOR_STEPFILE} EQUAL -1)
 411   set (BUILD_YACCLEX OFF CACHE BOOL "${BUILD_YACCLEX_DESCR}")
 412 else()
 413   OCCT_CHECK_AND_UNSET (BUILD_YACCLEX)
 414 endif()
 415
 416 if (NOT DEFINED 3RDPARTY_DIR)
 417   set (3RDPARTY_DIR "" CACHE PATH ${3RDPARTY_DIR_DESCR})
 418   get_filename_component (3RDPARTY_DIR "${3RDPARTY_DIR}" ABSOLUTE)
 419 else()
 420   file (TO_CMAKE_PATH "${3RDPARTY_DIR}" 3RDPARTY_DIR)
 421   set (3RDPARTY_DIR "${3RDPARTY_DIR}" CACHE PATH "${3RDPARTY_DIR_DESCR}" FORCE)
 422 endif()
 423
 424 # search for CSF_TclLibs variable in EXTERNLIB of each being used toolkit
 425 OCCT_IS_PRODUCT_REQUIRED (CSF_TclLibs USE_TCL)
 426
 427 if (USE_TCL)
 428   message (STATUS "Info: TCL is used by OCCT")
 429   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tcl")
 430
 431   message (STATUS "Info: TK is used by OCCT")
 432   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tk")
 433 else()
 434   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TCL")
 435   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TK")
 436
 437   OCCT_CHECK_AND_UNSET ("INSTALL_TCL")
 438   OCCT_CHECK_AND_UNSET ("INSTALL_TK")
 439 endif()
 440
 441 # search for CSF_FREETYPE variable in EXTERNLIB of each being used toolkit
 442 OCCT_IS_PRODUCT_REQUIRED (CSF_FREETYPE USE_FREETYPE)
 443
 444 if (USE_FREETYPE)
 445   message (STATUS "Info: Freetype is used by OCCT")
 446   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freetype")
 447 else()
 448   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREETYPE")
 449   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2")
 450   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build")
 451   OCCT_CHECK_AND_UNSET ("INSTALL_FREETYPE")
 452 endif()
 453
 454 # VTK
 455 if (USE_VTK)
 456   add_definitions (-DHAVE_VTK)
 457   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vtk")
 458 else()
 459   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_VTK")
 460
 461   if (NOT CAN_USE_VTK EQUAL -1)
 462     message (STATUS "Info: TKIVtk and TKIVtkDraw toolkits excluded due to VTK usage is disabled")
 463
 464     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtk)
 465     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtkDraw)
 466   endif()
 467 endif()
 468
 469 # D3D
 470 if (USE_D3D)
 471   add_definitions (-DHAVE_D3D)
 472   #if(MSVC_VERSION LESS 1700)
 473   #OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/d3d")
 474   #endif()
 475 endif()
 476
 477 # GLX
 478 if (USE_GLX)
 479   add_definitions (-DMACOSX_USE_GLX)
 480   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/glx")
 481 endif()
 482
 483 # FREEIMAGE
 484 # search for CSF_FREEIMAGE variable in EXTERNLIB of each being used toolkit
 485 OCCT_IS_PRODUCT_REQUIRED (CSF_FreeImagePlus CAN_USE_FREEIMAGE)
 486
 487 if (CAN_USE_FREEIMAGE)
 488   set (USE_FREEIMAGE OFF CACHE BOOL "${USE_FREEIMAGE_DESCR}")
 489
 490   if (USE_FREEIMAGE)
 491     add_definitions (-DHAVE_FREEIMAGE)
 492     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimage")
 493   else()
 494     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
 495     OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
 496   endif()
 497 else()
 498   OCCT_CHECK_AND_UNSET ("USE_FREEIMAGE")
 499
 500   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
 501   OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
 502 endif()
 503
 504 # OpenGL ES 2.0
 505 OCCT_IS_PRODUCT_REQUIRED (CSF_OpenGlLibs CAN_USE_GLES2)
 506 if (WIN32 AND CAN_USE_GLES2)
 507   if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
 508     set (USE_GLES2 ON)
 509   else()
 510     set (USE_GLES2 OFF CACHE BOOL "${USE_GLES2_DESCR}")
 511   endif()
 512
 513   if (USE_GLES2)
 514     add_definitions (-DHAVE_GLES2)
 515     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/egl")
 516         OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gles2")
 517   else()
 518     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EGL")
 519     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GLES2")
 520     OCCT_CHECK_AND_UNSET ("INSTALL_EGL")
 521     OCCT_CHECK_AND_UNSET ("INSTALL_GLES2")
 522   endif()
 523 else()
 524   OCCT_CHECK_AND_UNSET ("USE_GLES2")
 525
 526   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EGL")
 527   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GLES2")
 528   OCCT_CHECK_AND_UNSET ("INSTALL_EGL")
 529   OCCT_CHECK_AND_UNSET ("INSTALL_GLES2")
 530 endif()
 531
 532 # GL2PS
 533 # search for CSF_GL2PS variable in EXTERNLIB of each being used toolkit
 534 OCCT_IS_PRODUCT_REQUIRED (CSF_GL2PS CAN_USE_GL2PS)
 535
 536 if (NOT DEFINED ANDROID AND CAN_USE_GL2PS)
 537   set (USE_GL2PS OFF CACHE BOOL "${USE_GL2PS_DESCR}")
 538
 539   if (USE_GL2PS)
 540     add_definitions (-DHAVE_GL2PS)
 541     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gl2ps")
 542   else()
 543     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
 544     OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
 545   endif()
 546 else()
 547   OCCT_CHECK_AND_UNSET ("USE_GL2PS")
 548
 549   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
 550   OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
 551 endif()
 552
 553 # TBB
 554 # search for CSF_TBB variable in EXTERNLIB of each being used toolkit
 555 OCCT_IS_PRODUCT_REQUIRED (CSF_TBB CAN_USE_TBB)
 556
 557 if (NOT DEFINED ANDROID AND CAN_USE_TBB)
 558   set (USE_TBB OFF CACHE BOOL "${USE_TBB_DESCR}")
 559
 560   if (USE_TBB)
 561     add_definitions (-DHAVE_TBB)
 562     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tbb")
 563   else()
 564     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
 565     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
 566     OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
 567   endif()
 568 else()
 569   OCCT_CHECK_AND_UNSET ("USE_TBB")
 570
 571   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
 572   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
 573   OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
 574 endif()
 575
 576 # Doxygen
 577 if (BUILD_DOC_Overview)
 578   if (NOT DEFINED INSTALL_DOC_Overview)
 579     set (INSTALL_DOC_Overview OFF CACHE BOOL "${INSTALL_DOC_Overview_DESCR}")
 580   endif()
 581
 582   if (INSTALL_DOC_Overview)
 583     install (DIRECTORY "${CMAKE_BINARY_DIR}/doc/overview" DESTINATION  "${INSTALL_DIR}/${INSTALL_DIR_DOC}")
 584
 585     # create overview.html only for windows
 586     if (WIN32 AND "${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
 587       OCCT_INSTALL_FILE_OR_DIR ("dox/resources/overview.html" "${INSTALL_DIR}/${INSTALL_DIR_DOC}/..")
 588     endif()
 589   endif()
 590
 591   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
 592 else()
 593   OCCT_CHECK_AND_UNSET ("INSTALL_DOC_Overview")
 594
 595   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOXYGEN_EXECUTABLE")
 596   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOT_EXECUTABLE")
 597 endif()
 598
 599 # bison
 600 if (BUILD_YACCLEX)
 601   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/bison")
 602 else()
 603   OCCT_CHECK_AND_UNSET ("3RDPARTY_BISON_EXECUTABLE")
 604 endif()
 605
 606 # flex
 607 if (BUILD_YACCLEX)
 608   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/flex")
 609 else()
 610   OCCT_CHECK_AND_UNSET ("3RDPARTY_FLEX_EXECUTABLE")
 611 endif()
 612
 613 string (REGEX REPLACE ";" " " 3RDPARTY_NOT_INCLUDED "${3RDPARTY_NOT_INCLUDED}")
 614
 615 # check all 3rdparty paths
 616 if (3RDPARTY_NOT_INCLUDED)
 617   message (FATAL_ERROR "NOT FOUND: ${3RDPARTY_NOT_INCLUDED}" )
 618 endif()
 619
 620 if (3RDPARTY_INCLUDE_DIRS)
 621   list (REMOVE_DUPLICATES 3RDPARTY_INCLUDE_DIRS)
 622   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_INCLUDE_DIRS_WITH_ENDS "${3RDPARTY_INCLUDE_DIRS}")
 623   message (STATUS "Info: The directories of 3rdparty headers: \n\t${3RDPARTY_INCLUDE_DIRS_WITH_ENDS}")
 624   include_directories (${3RDPARTY_INCLUDE_DIRS})
 625 endif()
 626
 627 # include <cmake binary folder>/inc
 628 include_directories (${CMAKE_BINARY_DIR}/inc)
 629
 630 if (3RDPARTY_LIBRARY_DIRS AND BUILD_SHARED_LIBS)
 631   list (REMOVE_DUPLICATES 3RDPARTY_LIBRARY_DIRS)
 632   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_LIBRARY_DIRS_WITH_ENDS "${3RDPARTY_LIBRARY_DIRS}")
 633   message (STATUS "Info: The directories of 3rdparty libraries: \n\t${3RDPARTY_LIBRARY_DIRS_WITH_ENDS}")
 634   link_directories (${3RDPARTY_LIBRARY_DIRS})
 635 endif()
 636
 637 # build directories
 638 if (SINGLE_GENERATOR)
 639   set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
 640   set (CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
 641   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
 642   if (WIN32)
 643     set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
 644   endif()
 645 endif()
 646
 647 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
 648 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
 649 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
 650
 651 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
 652 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
 653 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
 654
 655 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
 656 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
 657 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
 658
 659 if (WIN32)
 660   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE        "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
 661   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
 662   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG          "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
 663 endif()
 664
 665 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
 666 message (STATUS "\nInfo: \(${CURRENT_TIME}\) Start collecting all OCCT header files into ${CMAKE_BINARY_DIR}/inc ...")
 667
 668 # collect all the headers to <binary dir>/inc folder
 669 COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}" "${BUILD_TOOLKITS}")
 670
 671 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
 672 message (STATUS "Info: \(${CURRENT_TIME}\) End the collecting")
 673
 674 if (WIN32)
 675   set (SCRIPT_EXT bat)
 676 else()
 677   set (SCRIPT_EXT sh)
 678 endif()
 679
 680 # OCCT samples
 681 if (INSTALL_SAMPLES)
 682   OCCT_CONFIGURE ("adm/templates/env.samples.${SCRIPT_EXT}.in" "env.samples.${SCRIPT_EXT}")
 683   if (WIN32)
 684     OCCT_INSTALL_FILE_OR_DIR ("samples/CSharp" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
 685     OCCT_INSTALL_FILE_OR_DIR ("samples/mfc" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
 686
 687     if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
 688       OCCT_INSTALL_FILE_OR_DIR ("samples/xaml" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
 689     endif()
 690
 691     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}/CSharp" RENAME "env.${SCRIPT_EXT}")
 692     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}/mfc/standard" RENAME "env.${SCRIPT_EXT}")
 693   endif()
 694
 695   OCCT_INSTALL_FILE_OR_DIR ("samples/java" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
 696   OCCT_INSTALL_FILE_OR_DIR ("samples/ocafsamples" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
 697   OCCT_INSTALL_FILE_OR_DIR ("samples/qt" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
 698
 699   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}/qt/FuncDemo" RENAME "env.${SCRIPT_EXT}")
 700   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}/qt/IESample" RENAME "env.${SCRIPT_EXT}")
 701   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}/qt/Tutorial" RENAME "env.${SCRIPT_EXT}")
 702 endif()
 703
 704 if (INSTALL_TEST_CASES)
 705   OCCT_INSTALL_FILE_OR_DIR ("tests/" "${INSTALL_DIR}/${INSTALL_DIR_TESTS}")
 706 endif()
 707
 708 list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
 709 if (${DRAWEXE_INDEX} GREATER -1)
 710   # copy data and samples/tcl folders to install script folder
 711   OCCT_INSTALL_FILE_OR_DIR ("data/" "${INSTALL_DIR}/${INSTALL_DIR_DATA}")
 712   OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR}/${INSTALL_DIR_SAMPLES}")
 713
 714   # copy draw script to install script folder
 715   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}")
 716     install (FILES "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}"
 717             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
 718   else()
 719     install (FILES "${CMAKE_SOURCE_DIR}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}"
 720             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
 721   endif()
 722
 723   # copy draw script to CMake binary folder
 724   OCCT_COPY_FILE_OR_DIR ("adm/templates/draw.${SCRIPT_EXT}" "${CMAKE_BINARY_DIR}")
 725 endif()
 726
 727 set (SUB_CUSTOM_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.${SCRIPT_EXT}")
 728
 729 if (WIN32)
 730   set (ADDITIONAL_CUSTOM_CONTENT "\nif exist \"%~dp0${SUB_CUSTOM_NAME}\" (\n  call \"%~dp0${SUB_CUSTOM_NAME}\" %1 %2 %3 \n)")
 731 else()
 732   set (ADDITIONAL_CUSTOM_CONTENT "\nif [ -e \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" ]; then\n  source \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" \"\$1\" \"\$2\" \nfi")
 733 endif()
 734
 735  # change custom.bat/sh
 736 if (EXISTS "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}")
 737   file (READ "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" CUSTOM_CONTENT)
 738
 739   set (CUSTOM_CONTENT "${CUSTOM_CONTENT} ${ADDITIONAL_CUSTOM_CONTENT}")
 740
 741   file (WRITE "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" "${CUSTOM_CONTENT}")
 742 else()
 743   OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.${SCRIPT_EXT}.main" "custom.${SCRIPT_EXT}" "custom.${SCRIPT_EXT}" "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}")
 744 endif()
 745
 746 # write current custom.bat/sh (for install directory)
 747 set (SUB_CUSTOM_BUILD_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.install.${SCRIPT_EXT}")
 748 OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.install.${SCRIPT_EXT}.in" "${SUB_CUSTOM_BUILD_NAME}" "${SUB_CUSTOM_NAME}" "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}")
 749
 750 # write current custom.bat/sh (for build directory)
 751 OCCT_CONFIGURE ("adm/templates/custom.build.${SCRIPT_EXT}.in" "${SUB_CUSTOM_NAME}")
 752
 753 if (BUILD_MODULE_MfcSamples)
 754   OCCT_INSTALL_FILE_OR_DIR ("adm/templates/sample.bat" "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}")
 755   OCCT_COPY_FILE_OR_DIR    ("adm/templates/sample.bat" "${CMAKE_BINARY_DIR}")
 756 endif()
 757
 758 # env script for draw in building environment
 759 OCCT_CONFIGURE ("adm/templates/env.${SCRIPT_EXT}.in" "env.${SCRIPT_EXT}")
 760
 761 # install env script
 762 install (FILES "${CMAKE_BINARY_DIR}/env.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}")
 763
 764 # copy DrawAppliInit from OCCT source to build directory
 765 if (NOT EXISTS "${CMAKE_BINARY_DIR}/DrawAppliInit")
 766   OCCT_COPY_FILE_OR_DIR (DrawAppliInit "${CMAKE_BINARY_DIR}")
 767 endif()
 768
 769 # RESOURCES
 770 FILE_TO_LIST ("adm/RESOURCES" RESOURCES)
 771 foreach(RESOURCE ${RESOURCES})
 772   get_filename_component(RESOURCE_FOLDER ${RESOURCE} DIRECTORY)
 773   if(NOT "${RESOURCE_FOLDER}" STREQUAL "")
 774     get_filename_component(RESOURCE_FOLDER ${RESOURCE_FOLDER} NAME)
 775     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR}/${INSTALL_DIR_RESOURCE}/${RESOURCE_FOLDER}")
 776   else()
 777     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR}/${INSTALL_DIR_RESOURCE}")
 778   endif()
 779 endforeach()
 780
 781 # patch installed DrawDefault file if BUILD_SHARED_LIBRARY_NAME_POSTFIX is changed
 782 if (NOT "${BUILD_SHARED_LIBRARY_NAME_POSTFIX}" STREQUAL "")
 783   OCCT_UPDATE_DRAW_DEFAULT_FILE()
 784 endif()
 785
 786 # define CSF variable
 787 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_csf")
 788
 789 # include patched toolkit projects or original ones
 790 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
 791   OCCT_ADD_SUBDIRECTORY ("src/${BUILD_TOOLKIT}")
 792 endforeach()
 793
 794 if (BUILD_DOC_Overview)
 795   OCCT_ADD_SUBDIRECTORY (dox)
 796 endif()
 797
 798 # patch DRAWEXE
 799 if (MSVC AND 3RDPARTY_DLL_DIRS)
 800   list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
 801   if (${DRAWEXE_INDEX} GREATER -1)
 802     list (REMOVE_DUPLICATES 3RDPARTY_DLL_DIRS)
 803     set (3RDPARTY_DLL_DIRS_FOR_PATH "")
 804
 805     foreach (3RDPARTY_DLL_DIR ${3RDPARTY_DLL_DIRS})
 806       set (3RDPARTY_DLL_DIRS_FOR_PATH "${3RDPARTY_DLL_DIRS_FOR_PATH};${3RDPARTY_DLL_DIR}")
 807     endforeach()
 808
 809     OCCT_MAKE_COMPILER_BITNESS()
 810     set (X_COMPILER_BITNESS "x64")
 811     if ("${COMPILER_BITNESS}" STREQUAL "32")
 812       set (X_COMPILER_BITNESS "Win32")
 813     endif()
 814
 815     OCCT_CONFIGURE ("adm/templates/DRAWEXE.vcxproj.user.in" "${CMAKE_BINARY_DIR}/src/DRAWEXE/DRAWEXE.vcxproj.user")
 816   endif()
 817 endif()
 818
 819 # samples do not support patch usage
 820 if (BUILD_MODULE_MfcSamples)
 821   set (OCCT_ROOT ${CMAKE_SOURCE_DIR})
 822
 823   set (MFC_STANDARD_SAMPLES_DIR ${OCCT_ROOT}/samples/mfc/standard)
 824   set (COMMON_WINMAIN_FILE      ${MFC_STANDARD_SAMPLES_DIR}/Common/Winmain.cpp)
 825
 826   add_subdirectory(samples/mfc/standard/mfcsample)
 827   add_subdirectory(samples/mfc/standard/01_Geometry)
 828   add_subdirectory(samples/mfc/standard/02_Modeling)
 829   add_subdirectory(samples/mfc/standard/03_Viewer2d)
 830   add_subdirectory(samples/mfc/standard/04_Viewer3d)
 831   add_subdirectory(samples/mfc/standard/05_ImportExport)
 832   add_subdirectory(samples/mfc/standard/06_Ocaf)
 833   add_subdirectory(samples/mfc/standard/07_Triangulation)
 834   add_subdirectory(samples/mfc/standard/08_HLR)
 835   add_subdirectory(samples/mfc/standard/09_Animation)
 836   add_subdirectory(samples/mfc/standard/10_Convert)
 837 endif()
 838
 839 if (BUILD_MODULE_UwpSample)
 840   add_subdirectory(samples/xaml)
 841 endif()
 842
 843 # Prepare variables for configuration of OpenCASCADE cmake config file
 844 set (OCCT_MODULES_ENABLED)
 845 set (OCCT_LIBRARIES)
 846 set (SET_OpenCASCADE_MODULES_TOOLKITS "\n# List of available OpenCASCADE libraries for each module\n")
 847 set (OCCT_COMPILE_DEFINITIONS)
 848
 849 foreach (OCCT_TOOLKIT ${BUILD_TOOLKITS})
 850   if (TARGET ${OCCT_TOOLKIT})
 851
 852     # get all libraries
 853     get_target_property (${OCCT_TOOLKIT}_TYPE ${OCCT_TOOLKIT} "TYPE")
 854     if ("${${OCCT_TOOLKIT}_TYPE}" STREQUAL "STATIC_LIBRARY" OR "${${OCCT_TOOLKIT}_TYPE}" STREQUAL "SHARED_LIBRARY" )
 855       list (APPEND OCCT_LIBRARIES ${OCCT_TOOLKIT})
 856
 857       # get all modules
 858       get_target_property (${OCCT_TOOLKIT}_MODULE ${OCCT_TOOLKIT} "MODULE")
 859       list (APPEND OCCT_MODULES_ENABLED ${${OCCT_TOOLKIT}_MODULE})
 860       list (APPEND OpenCASCADE_${${OCCT_TOOLKIT}_MODULE}_TOOLKITS ${OCCT_TOOLKIT})
 861
 862       # get compile definitions of target directory
 863       get_directory_property (COMPILE_DEFINITIONS DIRECTORY "${${OCCT_TOOLKIT}_SOURCE_DIR}" "COMPILE_DEFINITIONS")
 864       list (APPEND OCCT_COMPILE_DEFINITIONS ${COMPILE_DEFINITIONS})
 865     endif()
 866   endif()
 867 endforeach()
 868 list (REMOVE_DUPLICATES OCCT_MODULES_ENABLED)
 869 list (REMOVE_DUPLICATES OCCT_COMPILE_DEFINITIONS)
 870
 871 # export compile definitions and C/C++ flags for each configuration to OpenCASCADE config files
 872 foreach (OCCT_CONFIGURATION ${CMAKE_CONFIGURATION_TYPES})
 873   set (SET_OpenCASCADE_COMPILE_DEFINITIONS)
 874   string (TOUPPER "${OCCT_CONFIGURATION}" OCCT_CONFIGURATION_UPPER)
 875   string (TOLOWER "${OCCT_CONFIGURATION}" OCCT_CONFIGURATION_LOWER)
 876   foreach(COMPILE_DEFINITION ${OCCT_COMPILE_DEFINITIONS})
 877     string(REPLACE "(" "\\(" COMPILE_DEFINITION "${COMPILE_DEFINITION}")
 878     string(REPLACE ")" "\\)" COMPILE_DEFINITION "${COMPILE_DEFINITION}")
 879     set (SET_OpenCASCADE_COMPILE_DEFINITIONS "${SET_OpenCASCADE_COMPILE_DEFINITIONS}set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:${OCCT_CONFIGURATION}>:${COMPILE_DEFINITION}>)\n")
 880   endforeach()
 881   set (SET_OpenCASCADE_CMAKE_C_FLAGS "${CMAKE_C_FLAGS_${OCCT_CONFIGURATION_UPPER}}")
 882   set (SET_OpenCASCADE_CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS_${OCCT_CONFIGURATION_UPPER}}")
 883   configure_file("${CMAKE_SOURCE_DIR}/adm/templates/OpenCASCADECompileDefinitionsAndFlags.cmake.in" "OpenCASCADECompileDefinitionsAndFlags-${OCCT_CONFIGURATION_LOWER}.cmake" @ONLY)
 884 endforeach()
 885 # install OpenCASCADE config file with compile definitions and C/C++ flags ONLY for current configuration
 886 install (CODE "string (TOLOWER \"\${CMAKE_INSTALL_CONFIG_NAME}\" CMAKE_INSTALL_CONFIG_NAME_LOWER)")
 887 install (CODE "configure_file(\"${CMAKE_BINARY_DIR}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" \"${INSTALL_DIR}/${INSTALL_DIR_CMAKE}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" COPYONLY)")
 888
 889 foreach (OCCT_MODULE ${OCCT_MODULES})
 890   if (BUILD_MODULE_${OCCT_MODULE})
 891     set (SET_OpenCASCADE_MODULES_TOOLKITS "${SET_OpenCASCADE_MODULES_TOOLKITS}set (OpenCASCADE_${OCCT_MODULE}_LIBRARIES ${OpenCASCADE_${OCCT_MODULE}_TOOLKITS})\n")
 892   endif()
 893
 894   # sort enabled modules for correct work of OpenCASCADE config file
 895   list(FIND OCCT_MODULES_ENABLED "${OCCT_MODULE}" OCCT_MODULE_INDEX)
 896   if (NOT ${OCCT_MODULE_INDEX} EQUAL -1)
 897     list (APPEND OCCT_MODULES_ENABLED_SORTED ${OCCT_MODULE})
 898   endif()
 899 endforeach()
 900 set (OCCT_MODULES_ENABLED ${OCCT_MODULES_ENABLED_SORTED})
 901
 902 # Add all targets to the build-tree export set
 903 export (TARGETS ${OCCT_LIBRARIES} FILE "${CMAKE_BINARY_DIR}/OpenCASCADETargets.cmake")
 904
 905 # Export the package for use from the build-tree
 906 # (this registers the build-tree with a global CMake-registry)
 907 export(PACKAGE OpenCASCADE)
 908
 909 if (CMAKE_BUILD_TYPE)
 910   set (SET_OpenCASCADE_BUILD_TYPE "set (OpenCASCADE_BUILD_TYPE        \"${CMAKE_BUILD_TYPE}\")")
 911 endif()
 912
 913 if (BUILD_SHARED_LIBS)
 914   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_SHARED_LINKER_FLAGS}\")")
 915 else()
 916   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_STATIC_LINKER_FLAGS}\")")
 917 endif()
 918
 919 if (WIN32)
 920   set (SET_OpenCASCADE_WITH_D3D "set (OpenCASCADE_WITH_D3D       ${USE_D3D})")
 921 endif()
 922 if (APPLE)
 923   set (SET_OpenCASCADE_WITH_GLX "set (OpenCASCADE_WITH_GLX       ${USE_GLX})")
 924 endif()
 925
 926 if (NOT SINGLE_GENERATOR)
 927   OCCT_INSERT_CODE_FOR_TARGET()
 928 endif()
 929
 930 # Configure and install cmake config file
 931 configure_file("${CMAKE_SOURCE_DIR}/adm/templates/OpenCASCADEConfig.cmake.in" "OpenCASCADEConfig.cmake" @ONLY)
 932 install(FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfig.cmake" DESTINATION  "${INSTALL_DIR}/${INSTALL_DIR_CMAKE}")
 933
 934 # Configure cmake version file
 935 include(CMakePackageConfigHelpers)
 936 write_basic_package_version_file( ${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake
 937                                   VERSION ${OCC_VERSION_MAJOR}.${OCC_VERSION_MINOR}.${OCC_VERSION_MAINTENANCE}
 938                                   COMPATIBILITY ExactVersion )
 939
 940 # Install cmake version file
 941 install (FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake" DESTINATION "${INSTALL_DIR}/${INSTALL_DIR_CMAKE}")
 942
 943 # Install the export set for use with the install-tree for each configuration
 944 foreach (OCCT_MODULE ${OCCT_MODULES_ENABLED})
 945   install(EXPORT OpenCASCADE${OCCT_MODULE}Targets DESTINATION "${INSTALL_DIR_CMAKE}")
 946 endforeach()
 947
 948 # Update generated OpenCASCADETargets-*.cmake files
 949 # to have correct paths to libraries depending on the configuration
 950 OCCT_UPDATE_TARGET_FILE ()