CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.12 FATAL_ERROR)
   2
   3 set (CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/adm/cmake")
   4
   5 set (CMAKE_SUPPRESS_REGENERATION TRUE)
   6
   7 set (CMAKE_CONFIGURATION_TYPES Release Debug RelWithDebInfo CACHE INTERNAL "" FORCE)
   8
   9 # macro: include patched file if it exists
  10 macro (OCCT_INCLUDE_CMAKE_FILE BEING_INCLUDED_FILE)
  11   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake")
  12     include (${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake)
  13   else()
  14     include (${CMAKE_SOURCE_DIR}/${BEING_INCLUDED_FILE}.cmake)
  15   endif()
  16 endmacro()
  17
  18 # include variable description
  19 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vardescr")
  20
  21 # set type of OCCT libraries
  22 if (NOT BUILD_LIBRARY_TYPE)
  23   set (BUILD_LIBRARY_TYPE "Shared" CACHE STRING "${BUILD_LIBRARY_TYPE_DESCR}" FORCE)
  24   SET_PROPERTY(CACHE BUILD_LIBRARY_TYPE PROPERTY STRINGS Shared Static)
  25 endif()
  26
  27 if ("${BUILD_LIBRARY_TYPE}" STREQUAL "Shared")
  28   set (BUILD_SHARED_LIBS ON)
  29
  30   if (NOT DEFINED BUILD_SHARED_LIBRARY_NAME_POSTFIX)
  31     set (BUILD_SHARED_LIBRARY_NAME_POSTFIX "" CACHE STRING "${BUILD_SHARED_LIBRARY_NAME_POSTFIX_DESCR}" FORCE)
  32   endif()
  33 else()
  34   unset (BUILD_SHARED_LIBS)
  35   message (STATUS "Info: Only 3rdparty's header files are used for building of static OCCT libraries")
  36   unset (BUILD_SHARED_LIBRARY_NAME_POSTFIX)
  37 endif()
  38
  39 # the name of the project
  40 project (OCCT)
  41
  42 if (WIN32)
  43   add_definitions(-DUNICODE)
  44   add_definitions(-D_UNICODE)
  45 endif()
  46
  47 # include occt macros
  48 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_macros")
  49
  50 # Solution folder property
  51 set_property (GLOBAL PROPERTY USE_FOLDERS ON)
  52
  53 # get current OCCT version
  54 OCC_VERSION (OCC_VERSION_MAJOR OCC_VERSION_MINOR OCC_VERSION_MAINTENANCE OCC_VERSION_DEVELOPMENT OCC_VERSION_STRING_EXT)
  55
  56 set_property (GLOBAL PROPERTY OCC_VERSION_MAJOR ${OCC_VERSION_MAJOR})
  57 set_property (GLOBAL PROPERTY OCC_VERSION_MINOR ${OCC_VERSION_MINOR})
  58 set_property (GLOBAL PROPERTY OCC_VERSION_MAINTENANCE ${OCC_VERSION_MAINTENANCE})
  59
  60 set (INSTALL_TEST_CASES OFF CACHE BOOL "${INSTALL_TEST_CASES_DESCR}")
  61
  62 # Regeneration of OCCT resource files
  63 set (BUILD_RESOURCES OFF CACHE BOOL "${BUILD_RESOURCES_DESCR}")
  64
  65 # single-configuration generator
  66 set (SINGLE_GENERATOR OFF)
  67 if (CMAKE_BUILD_TYPE)
  68   set (SINGLE_GENERATOR ON)
  69 endif()
  70
  71 # a single-configuration generator like the Makefile generator defines CMAKE_BUILD_TYPE variable
  72 # check this variable and set if it's required
  73 if (DEFINED CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE) # single-configuration generator.
  74   set (CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel." FORCE)
  75 endif()
  76
  77 # enable extended messages of many OCCT algorithms
  78 if (((SINGLE_GENERATOR AND "${CMAKE_BUILD_TYPE}" STREQUAL "Debug") OR NOT SINGLE_GENERATOR) AND (NOT "${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore"))
  79   if (NOT BUILD_WITH_DEBUG)
  80     set (BUILD_WITH_DEBUG OFF CACHE BOOL "${BUILD_WITH_DEBUG_DESCR}")
  81   endif()
  82 else()
  83   OCCT_CHECK_AND_UNSET (BUILD_WITH_DEBUG)
  84 endif()
  85
  86 if (BUILD_WITH_DEBUG)
  87   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:DEBUG>:OCCT_DEBUG>)
  88 endif()
  89
  90 # option to enable or disable use of precompiled headers
  91 if (NOT DEFINED BUILD_USE_PCH)
  92   set (BUILD_USE_PCH OFF CACHE BOOL "${BUILD_USE_PCH_DESCR}")
  93 endif()
  94
  95 if (BUILD_USE_PCH)
  96
  97   # Load Cotire tool for accelerating build procedure
  98   include(cotire)
  99
 100   # Set Cotire to ignore lxx, pxx, gxx
 101   set (COTIRE_ADDITIONAL_PREFIX_HEADER_IGNORE_EXTENSIONS "lxx;pxx;gxx" CACHE STRING "Set Cotire to ignore OCCT specific files that can be #included" FORCE)
 102
 103   # Set priority for inclusion of system headers in PCH to reduce problems
 104   # due to incomplete inclusion or wrong order.
 105   if (WIN32)
 106     # on Windows, assume that SDK (windows.h) is in default location
 107     set(ProgramFilesX86 "ProgramFiles(x86)")
 108     file(TO_CMAKE_PATH "$ENV{${ProgramFilesX86}}" ProgramFilesX86)
 109     set_property (DIRECTORY PROPERTY COTIRE_PREFIX_HEADER_INCLUDE_PRIORITY_PATH "${ProgramFilesX86}")
 110     unset(ProgramFilesX86)
 111   endif()
 112
 113 endif()
 114
 115 # copy samples to install directory
 116 set (INSTALL_SAMPLES OFF CACHE BOOL "${INSTALL_SAMPLES_DESCR}")
 117
 118 # install dir of the project
 119 if (NOT DEFINED INSTALL_DIR)
 120   # set default install directory for Windows
 121   if (WIN32 AND NOT DEFINED CMAKE_INSTALL_PREFIX)
 122     set (CMAKE_INSTALL_PREFIX "C:/opencascade-${OCC_VERSION_STRING_EXT}")
 123   endif()
 124   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}")
 125 else()
 126   file (TO_CMAKE_PATH "${INSTALL_DIR}" INSTALL_DIR)
 127   set (INSTALL_DIR "${INSTALL_DIR}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
 128 endif()
 129
 130 # choose a variant of the layout of the install paths
 131 if (NOT INSTALL_DIR_LAYOUT)
 132   if (WIN32)
 133     set (INSTALL_DIR_LAYOUT "Windows" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
 134   else()
 135     set (INSTALL_DIR_LAYOUT "Unix" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
 136   endif()
 137   SET_PROPERTY(CACHE INSTALL_DIR_LAYOUT PROPERTY STRINGS Windows Unix)
 138 endif()
 139
 140 # check INSTALL_DIR_LAYOUT changes and update INSTALL_DIR_* paths if necessary
 141 if (NOT DEFINED INSTALL_DIR_LAYOUT_PREV)
 142   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
 143 elseif (NOT "${INSTALL_DIR_LAYOUT_PREV}" STREQUAL "${INSTALL_DIR_LAYOUT}")
 144   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
 145   # The structure of install folder should be reset due to changed layout
 146   OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
 147
 148   # Unset INSTALL_DIR_WITH_VERSION on windows
 149   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
 150     OCCT_CHECK_AND_UNSET (INSTALL_DIR_WITH_VERSION)
 151   else()
 152     if (NOT DEFINED INSTALL_DIR_WITH_VERSION)
 153       set (INSTALL_DIR_WITH_VERSION OFF CACHE BOOL "${INSTALL_DIR_WITH_VERSION_DESCR}")
 154     endif()
 155   endif()
 156 endif()
 157
 158 # check CMAKE_INSTALL_PREFIX changes and update INSTALL_DIR if necessary
 159 if (NOT DEFINED CMAKE_INSTALL_PREFIX_PREV)
 160   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
 161 elseif (NOT "${CMAKE_INSTALL_PREFIX_PREV}" STREQUAL "${CMAKE_INSTALL_PREFIX}")
 162   # CMAKE_INSTALL_PREFIX has been changed at previous step
 163   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
 164
 165   # INSTALL_DIR is required to be updated
 166   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
 167 endif()
 168
 169 # check INSTALL_DIR changes and update CMAKE_INSTALL_PREFIX if necessary
 170 if (NOT DEFINED INSTALL_DIR_PREV)
 171   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 172 elseif (NOT "${INSTALL_DIR_PREV}" STREQUAL "${INSTALL_DIR}")
 173   # INSTALL_DIR has been changed at previous step
 174   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 175
 176   # sync CMAKE_INSTALL_PREFIX with INSTALL_DIR
 177   set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 178
 179   # set CMAKE_INSTALL_PREFIX_PREV to avoid the reset of structure of the install folder
 180   set (CMAKE_INSTALL_PREFIX_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 181 endif()
 182
 183 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 184   if (NOT DEFINED INSTALL_DIR_WITH_VERSION_PREV)
 185     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
 186   elseif (NOT "${INSTALL_DIR_WITH_VERSION_PREV}" STREQUAL "${INSTALL_DIR_WITH_VERSION}")
 187     # INSTALL_DIR_WITH_VERSION has been changed at previous step
 188     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
 189
 190     OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
 191   endif()
 192 endif()
 193
 194 # hide CMAKE_INSTALL_PREFIX from a user
 195 set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
 196
 197 set (BIN_LETTER "")
 198 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
 199   set (BIN_LETTER "d")
 200 elseif ("${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo")
 201   set (BIN_LETTER "i")
 202 endif()
 203
 204 # Get all used variables: OS_WITH_BIT, COMPILER
 205 OCCT_MAKE_OS_WITH_BITNESS()
 206 OCCT_MAKE_COMPILER_SHORT_NAME()
 207
 208 # do not define INSTALL_DIR_BIN for win.
 209 # Leave library structure for win: <prefix>/win64/vc10/bin(d)
 210 if (NOT DEFINED INSTALL_DIR_BIN)
 211   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 212     set (INSTALL_DIR_BIN "bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
 213   else()
 214     set (INSTALL_DIR_BIN "${OS_WITH_BIT}/${COMPILER}/bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
 215   endif()
 216 endif()
 217
 218 # define folder contaning all shell/batch scripts
 219 if (NOT DEFINED INSTALL_DIR_SCRIPT)
 220   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 221     set (INSTALL_DIR_SCRIPT "${INSTALL_DIR_BIN}" CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
 222   else()
 223     set (INSTALL_DIR_SCRIPT "." CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
 224   endif()
 225 endif()
 226
 227 # place the libraries to <prefix>/lib folder for unix and leave old structure for windows
 228 if (NOT DEFINED INSTALL_DIR_LIB)
 229   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 230     set (INSTALL_DIR_LIB "lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
 231   else()
 232     set (INSTALL_DIR_LIB "${OS_WITH_BIT}/${COMPILER}/lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
 233   endif()
 234 endif()
 235
 236 # OCCT headers: <prefix>/inc for windows,
 237 #               <prefix>/include/opencascade-7.0.0 for unix
 238 if (NOT DEFINED INSTALL_DIR_INCLUDE)
 239   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 240     set (INSTALL_DIR_INCLUDE "include/opencascade" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
 241     if (INSTALL_DIR_WITH_VERSION)
 242       set (INSTALL_DIR_INCLUDE "include/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}" FORCE)
 243     endif()
 244   else()
 245     set (INSTALL_DIR_INCLUDE "inc" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
 246   endif()
 247 endif()
 248
 249 # OCCT resources: <prefix>/src for windows,
 250 #                 <prefix>/share/opencascade-7.0.0/resources for unix
 251 if (NOT DEFINED INSTALL_DIR_RESOURCE)
 252   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 253     set (INSTALL_DIR_RESOURCE "share/opencascade/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
 254     if (INSTALL_DIR_WITH_VERSION)
 255       set (INSTALL_DIR_RESOURCE "share/opencascade-${OCC_VERSION_STRING_EXT}/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}" FORCE)
 256     endif()
 257   else()
 258     set (INSTALL_DIR_RESOURCE "src" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
 259   endif()
 260 endif()
 261
 262 # OCCT data
 263 if (NOT DEFINED INSTALL_DIR_DATA)
 264   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 265     set (INSTALL_DIR_DATA "share/opencascade/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
 266     if (INSTALL_DIR_WITH_VERSION)
 267       set (INSTALL_DIR_DATA "share/opencascade-${OCC_VERSION_STRING_EXT}/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}" FORCE)
 268     endif()
 269   else()
 270     set (INSTALL_DIR_DATA "data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
 271   endif()
 272 endif()
 273
 274 # OCCT samples
 275 if (NOT DEFINED INSTALL_DIR_SAMPLES)
 276   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 277     set (INSTALL_DIR_SAMPLES "share/opencascade/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
 278     if (INSTALL_DIR_WITH_VERSION)
 279       set (INSTALL_DIR_SAMPLES "share/opencascade-${OCC_VERSION_STRING_EXT}/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}" FORCE)
 280     endif()
 281   else()
 282     set (INSTALL_DIR_SAMPLES "samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
 283   endif()
 284 endif()
 285
 286 # OCCT tests
 287 if (NOT DEFINED INSTALL_DIR_TESTS)
 288   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 289     set (INSTALL_DIR_TESTS "share/opencascade/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
 290     if (INSTALL_DIR_WITH_VERSION)
 291       set (INSTALL_DIR_TESTS "share/opencascade-${OCC_VERSION_STRING_EXT}/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}" FORCE)
 292     endif()
 293   else()
 294     set (INSTALL_DIR_TESTS "tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
 295   endif()
 296 endif()
 297
 298 # OCCT doc
 299 if (NOT DEFINED INSTALL_DIR_DOC)
 300   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 301     set (INSTALL_DIR_DOC "share/doc/opencascade" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
 302     if (INSTALL_DIR_WITH_VERSION)
 303       set (INSTALL_DIR_DOC "share/doc/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_DOC_DESCR}" FORCE)
 304     endif()
 305   else()
 306     set (INSTALL_DIR_DOC "doc" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
 307   endif()
 308 endif()
 309
 310 # define folder contaning CMake configuration files
 311 if (NOT DEFINED INSTALL_DIR_CMAKE)
 312   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 313     if (INSTALL_DIR_WITH_VERSION)
 314       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
 315     else()
 316       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
 317     endif()
 318   else()
 319     set (INSTALL_DIR_CMAKE "cmake" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
 320   endif()
 321 endif()
 322
 323 # include occt macros
 324 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_resources")
 325
 326 # install LICENSE_LGPL_21.txt and OCCT_LGPL_EXCEPTION.txt files
 327 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
 328   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" "${INSTALL_DIR_DOC}")
 329   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" "${INSTALL_DIR_DOC}")
 330 else()
 331   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" ".")
 332   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" ".")
 333 endif()
 334
 335 if(APPLE)
 336   set (INSTALL_NAME_DIR "" CACHE STRING "install_name library suffix on OS X (e.g. @executable_path/../Frameworks)")
 337 endif()
 338
 339 # a directory recognized as a 'patch' for OCCT
 340 set (BUILD_PATCH "" CACHE PATH "${BUILD_PATCH_DESCR}")
 341
 342 # the list of being built toolkits
 343 set (BUILD_ADDITIONAL_TOOLKITS "" CACHE STRING "${BUILD_ADDITIONAL_TOOLKITS_DESCR}")
 344 separate_arguments (BUILD_ADDITIONAL_TOOLKITS)
 345
 346 if (MSVC)
 347   set (BUILD_MODULE_MfcSamples OFF CACHE BOOL "${BUILD_MODULE_MfcSamples_DESCR}")
 348 endif()
 349
 350 # uwp sample
 351 if (MSVC)
 352   if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
 353     set (BUILD_MODULE_UwpSample OFF CACHE BOOL "${BUILD_MODULE_UwpSample_DESCR}")
 354   else()
 355     unset (BUILD_MODULE_UwpSample)
 356   endif()
 357 endif()
 358
 359 # whether use optional 3rdparty or not
 360 if (APPLE)
 361   set (USE_GLX OFF CACHE BOOL "${USE_GLX_DESCR}")
 362 endif()
 363
 364 if (WIN32)
 365   set (USE_D3D OFF CACHE BOOL "${USE_D3D_DESCR}")
 366 endif()
 367
 368 set (USE_QT_TOOLS OFF CACHE BOOL "${USE_QT_TOOLS_DESCR}")
 369 set (USE_QT4 ON CACHE BOOL "${USE_QT4}")
 370
 371 # Enable/Disable the floating point exceptions (FPE) during runtime.
 372 if (NOT BUILD_ENABLE_FPE_SIGNAL_HANDLER)
 373   set (BUILD_ENABLE_FPE_SIGNAL_HANDLER OFF CACHE BOOL "${BUILD_ENABLE_FPE_SIGNAL_HANDLER_DESCR}" FORCE)
 374 endif()
 375
 376 if (BUILD_ENABLE_FPE_SIGNAL_HANDLER)
 377   set (BUILD_ENABLE_FPE_SIGNAL_HANDLER 1)
 378 else()
 379   set (BUILD_ENABLE_FPE_SIGNAL_HANDLER 0)
 380 endif()
 381
 382 # include the patched or original list of modules
 383 # list <MODULENAME>_TOOLKITS is created foreach module and contains its toolkits
 384 # list <OCCT_MODULES> will contain all modules
 385 OCCT_MODULES_AND_TOOLKITS (OCCT_MODULES)
 386
 387 foreach (OCCT_MODULE ${OCCT_MODULES})
 388   BUILD_MODULE (${OCCT_MODULE})
 389 endforeach()
 390
 391 if (ANDROID AND BUILD_MODULE_Draw)
 392   message (STATUS "Info. Draw module is turned off due to it is not supported on Android")
 393   set (BUILD_MODULE_Draw OFF CACHE BOOL "${BUILD_MODULE_Draw_DESCR}" FORCE)
 394 endif()
 395 if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore" AND BUILD_MODULE_Draw)
 396   message (STATUS "Info. Draw module is turned off due to it is not supported on UWP")
 397   set (BUILD_MODULE_Draw OFF CACHE BOOL "${BUILD_MODULE_Draw_DESCR}" FORCE)
 398 endif()
 399
 400 # Overview
 401 if (NOT DEFINED BUILD_DOC_Overview)
 402   set (DO_ONLY_CHECK_FOR_DOXYGEN ON)
 403   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
 404   set (DO_ONLY_CHECK_FOR_DOXYGEN OFF)
 405
 406   if (CAN_DOXYGEN_BE_USED)
 407     message (STATUS "Info. Overview building is turned on")
 408   endif()
 409
 410   set (BUILD_DOC_Overview ${CAN_DOXYGEN_BE_USED} CACHE BOOL "${BUILD_DOC_Overview_DESCR}")
 411 endif()
 412
 413 if (NOT USE_D3D)
 414   list (REMOVE_ITEM Visualization_TOOLKITS TKD3DHost)
 415 endif()
 416
 417 # accumulate used toolkits (first level) in BUILD_TOOLKITS variable
 418 list (APPEND BUILD_TOOLKITS ${BUILD_ADDITIONAL_TOOLKITS})
 419
 420 foreach (OCCT_MODULE ${OCCT_MODULES})
 421   if (BUILD_MODULE_${OCCT_MODULE})
 422     list (APPEND BUILD_TOOLKITS ${${OCCT_MODULE}_TOOLKITS})
 423   endif()
 424 endforeach()
 425
 426 # DRAWEXE excluded when library build is static
 427 if (NOT BUILD_SHARED_LIBS)
 428   list (REMOVE_ITEM BUILD_TOOLKITS DRAWEXE)
 429   message (STATUS "Info: DRAWEXE is not included due to ${BUILD_LIBRARY_TYPE} build library type")
 430 endif()
 431
 432 # accumulate all used toolkits
 433 list (REMOVE_DUPLICATES BUILD_TOOLKITS)
 434 set (RAW_BUILD_TOOLKITS)
 435 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
 436   OCCT_TOOLKIT_FULL_DEP (${BUILD_TOOLKIT} TOOLKIT_FULL_DEPS)
 437   list (APPEND RAW_BUILD_TOOLKITS ${BUILD_TOOLKIT} ${TOOLKIT_FULL_DEPS})
 438 endforeach()
 439
 440 list (REMOVE_DUPLICATES RAW_BUILD_TOOLKITS)
 441 set (BUILD_TOOLKITS ${RAW_BUILD_TOOLKITS})
 442
 443 # include the patched or original list of definitions and flags
 444 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_defs_flags")
 445
 446 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/3rdparty_macro")
 447
 448 # search for TKIVtk and TKIVtkDraw in BUILD_TOOLKITS
 449 list (FIND BUILD_TOOLKITS TKIVtk CAN_USE_VTK)
 450 if (CAN_USE_VTK EQUAL -1)
 451   list (FIND BUILD_TOOLKITS TKIVtkDraw CAN_USE_VTK)
 452 endif()
 453
 454 if (NOT CAN_USE_VTK EQUAL -1)
 455   if (NOT DEFINED USE_VTK)
 456     set (USE_VTK OFF CACHE BOOL "${USE_VTK_DESCR}")
 457   endif()
 458 else()
 459   OCCT_CHECK_AND_UNSET (USE_VTK)
 460 endif()
 461
 462 # Rebuild *.yacc and *.lex files that are contained by TKMath toolkit
 463 list (FIND BUILD_TOOLKITS TKMath   CAN_REBUILD_PDC_FOR_TKMATH)
 464 list (FIND BUILD_TOOLKITS StepFile CAN_REBUILD_PDC_FOR_STEPFILE)
 465
 466 if (NOT ${CAN_REBUILD_PDC_FOR_TKMATH} EQUAL -1 OR NOT ${CAN_REBUILD_PDC_FOR_STEPFILE} EQUAL -1)
 467   set (BUILD_YACCLEX OFF CACHE BOOL "${BUILD_YACCLEX_DESCR}")
 468 else()
 469   OCCT_CHECK_AND_UNSET (BUILD_YACCLEX)
 470 endif()
 471
 472 if (NOT DEFINED 3RDPARTY_DIR)
 473   set (3RDPARTY_DIR "" CACHE PATH ${3RDPARTY_DIR_DESCR})
 474   get_filename_component (3RDPARTY_DIR "${3RDPARTY_DIR}" ABSOLUTE)
 475 else()
 476   file (TO_CMAKE_PATH "${3RDPARTY_DIR}" 3RDPARTY_DIR)
 477   set (3RDPARTY_DIR "${3RDPARTY_DIR}" CACHE PATH "${3RDPARTY_DIR_DESCR}" FORCE)
 478 endif()
 479
 480 # search for CSF variable in EXTERNLIB of each being used toolkit
 481 OCCT_IS_PRODUCT_REQUIRED (CSF_FreeImagePlus CAN_USE_FREEIMAGE)
 482 OCCT_IS_PRODUCT_REQUIRED (CSF_TclLibs USE_TCL)
 483 OCCT_IS_PRODUCT_REQUIRED (CSF_FREETYPE USE_FREETYPE)
 484 OCCT_IS_PRODUCT_REQUIRED (CSF_OpenGlLibs CAN_USE_GLES2)
 485 OCCT_IS_PRODUCT_REQUIRED (CSF_GL2PS CAN_USE_GL2PS)
 486 OCCT_IS_PRODUCT_REQUIRED (CSF_TBB CAN_USE_TBB)
 487 OCCT_IS_PRODUCT_REQUIRED (CSF_EIGEN CAN_USE_EIGEN)
 488
 489 # define CSF variable
 490 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_csf")
 491
 492 if (USE_TCL)
 493   message (STATUS "Info: TCL is used by OCCT")
 494   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tcl")
 495
 496   message (STATUS "Info: TK is used by OCCT")
 497   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tk")
 498 else()
 499   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TCL")
 500   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TK")
 501
 502   OCCT_CHECK_AND_UNSET ("INSTALL_TCL")
 503   OCCT_CHECK_AND_UNSET ("INSTALL_TK")
 504 endif()
 505
 506 if (USE_FREETYPE)
 507   message (STATUS "Info: Freetype is used by OCCT")
 508   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freetype")
 509 else()
 510   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREETYPE")
 511   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2")
 512   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build")
 513   OCCT_CHECK_AND_UNSET ("INSTALL_FREETYPE")
 514 endif()
 515
 516 # VTK
 517 if (USE_VTK)
 518   add_definitions (-DHAVE_VTK)
 519   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vtk")
 520 else()
 521   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_VTK")
 522
 523   if (NOT CAN_USE_VTK EQUAL -1)
 524     message (STATUS "Info: TKIVtk and TKIVtkDraw toolkits excluded due to VTK usage is disabled")
 525
 526     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtk)
 527     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtkDraw)
 528   endif()
 529 endif()
 530
 531 # D3D
 532 if (USE_D3D)
 533   add_definitions (-DHAVE_D3D)
 534   #if(MSVC_VERSION LESS 1700)
 535   #OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/d3d")
 536   #endif()
 537 endif()
 538
 539 # GLX
 540 if (USE_GLX)
 541   add_definitions (-DMACOSX_USE_GLX)
 542   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/glx")
 543 endif()
 544
 545 # FREEIMAGE
 546
 547 if (CAN_USE_FREEIMAGE)
 548   set (USE_FREEIMAGE OFF CACHE BOOL "${USE_FREEIMAGE_DESCR}")
 549
 550   if (USE_FREEIMAGE)
 551     add_definitions (-DHAVE_FREEIMAGE)
 552     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimage")
 553   else()
 554     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
 555     OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
 556   endif()
 557 else()
 558   OCCT_CHECK_AND_UNSET ("USE_FREEIMAGE")
 559
 560   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
 561   OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
 562 endif()
 563
 564 # OpenGL ES 2.0
 565 if (WIN32 AND CAN_USE_GLES2)
 566   if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
 567     set (USE_GLES2 ON)
 568   else()
 569     set (USE_GLES2 OFF CACHE BOOL "${USE_GLES2_DESCR}")
 570   endif()
 571
 572   if (USE_GLES2)
 573     add_definitions (-DHAVE_GLES2)
 574     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/egl")
 575         OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gles2")
 576   else()
 577     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EGL")
 578     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GLES2")
 579     OCCT_CHECK_AND_UNSET ("INSTALL_EGL")
 580     OCCT_CHECK_AND_UNSET ("INSTALL_GLES2")
 581   endif()
 582 else()
 583   OCCT_CHECK_AND_UNSET ("USE_GLES2")
 584
 585   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EGL")
 586   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GLES2")
 587   OCCT_CHECK_AND_UNSET ("INSTALL_EGL")
 588   OCCT_CHECK_AND_UNSET ("INSTALL_GLES2")
 589 endif()
 590
 591 # GL2PS
 592 if (NOT DEFINED ANDROID AND CAN_USE_GL2PS)
 593   set (USE_GL2PS OFF CACHE BOOL "${USE_GL2PS_DESCR}")
 594
 595   if (USE_GL2PS)
 596     add_definitions (-DHAVE_GL2PS)
 597     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gl2ps")
 598   else()
 599     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
 600     OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
 601   endif()
 602 else()
 603   OCCT_CHECK_AND_UNSET ("USE_GL2PS")
 604
 605   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
 606   OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
 607 endif()
 608
 609 # TBB
 610 if (NOT DEFINED ANDROID AND CAN_USE_TBB)
 611   set (USE_TBB OFF CACHE BOOL "${USE_TBB_DESCR}")
 612
 613   if (USE_TBB)
 614     add_definitions (-DHAVE_TBB)
 615     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tbb")
 616   else()
 617     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
 618     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
 619     OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
 620   endif()
 621 else()
 622   OCCT_CHECK_AND_UNSET ("USE_TBB")
 623
 624   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
 625   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
 626   OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
 627 endif()
 628
 629 # EIGEN
 630 if (CAN_USE_EIGEN)
 631   set (USE_EIGEN OFF CACHE BOOL "${USE_EIGEN_DESCR}")
 632
 633   if (USE_EIGEN)
 634     add_definitions (-DHAVE_EIGEN)
 635     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/eigen")
 636   else()
 637     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EIGEN")
 638   endif()
 639 else()
 640   OCCT_CHECK_AND_UNSET ("USE_EIGEN")
 641
 642   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EIGEN")
 643 endif()
 644
 645 # Doxygen
 646 if (BUILD_DOC_Overview)
 647   if (NOT DEFINED INSTALL_DOC_Overview)
 648     set (INSTALL_DOC_Overview OFF CACHE BOOL "${INSTALL_DOC_Overview_DESCR}")
 649   endif()
 650
 651   if (INSTALL_DOC_Overview)
 652     install (DIRECTORY "${CMAKE_BINARY_DIR}/doc/overview" DESTINATION  "${INSTALL_DIR_DOC}")
 653
 654     # create overview.html only for windows
 655     if (WIN32 AND "${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
 656       OCCT_INSTALL_FILE_OR_DIR ("dox/resources/overview.html" "${INSTALL_DIR_DOC}/..")
 657     endif()
 658   endif()
 659
 660   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
 661 else()
 662   OCCT_CHECK_AND_UNSET ("INSTALL_DOC_Overview")
 663
 664   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOXYGEN_EXECUTABLE")
 665   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOT_EXECUTABLE")
 666 endif()
 667
 668 # bison
 669 if (BUILD_YACCLEX)
 670   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/bison")
 671 else()
 672   OCCT_CHECK_AND_UNSET ("3RDPARTY_BISON_EXECUTABLE")
 673 endif()
 674
 675 # flex
 676 if (BUILD_YACCLEX)
 677   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/flex")
 678 else()
 679   OCCT_CHECK_AND_UNSET ("3RDPARTY_FLEX_EXECUTABLE")
 680 endif()
 681
 682 string (REGEX REPLACE ";" " " 3RDPARTY_NOT_INCLUDED "${3RDPARTY_NOT_INCLUDED}")
 683
 684 # check all 3rdparty paths
 685 if (3RDPARTY_NOT_INCLUDED)
 686   message (FATAL_ERROR "NOT FOUND: ${3RDPARTY_NOT_INCLUDED}" )
 687 endif()
 688
 689 if (3RDPARTY_INCLUDE_DIRS)
 690   list (REMOVE_DUPLICATES 3RDPARTY_INCLUDE_DIRS)
 691   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_INCLUDE_DIRS_WITH_ENDS "${3RDPARTY_INCLUDE_DIRS}")
 692   message (STATUS "Info: The directories of 3rdparty headers: \n\t${3RDPARTY_INCLUDE_DIRS_WITH_ENDS}")
 693   include_directories (${3RDPARTY_INCLUDE_DIRS})
 694 endif()
 695
 696 # include <cmake binary folder>/inc
 697 include_directories (${CMAKE_BINARY_DIR}/${INSTALL_DIR_INCLUDE})
 698
 699 if (3RDPARTY_LIBRARY_DIRS AND BUILD_SHARED_LIBS)
 700   list (REMOVE_DUPLICATES 3RDPARTY_LIBRARY_DIRS)
 701   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_LIBRARY_DIRS_WITH_ENDS "${3RDPARTY_LIBRARY_DIRS}")
 702   message (STATUS "Info: The directories of 3rdparty libraries: \n\t${3RDPARTY_LIBRARY_DIRS_WITH_ENDS}")
 703   link_directories (${3RDPARTY_LIBRARY_DIRS})
 704 endif()
 705
 706 # build directories
 707 if (SINGLE_GENERATOR)
 708   set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
 709   set (CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
 710   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
 711   if (WIN32)
 712     set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
 713   endif()
 714 endif()
 715
 716 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
 717 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
 718 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
 719
 720 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
 721 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
 722 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
 723
 724 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
 725 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
 726 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
 727
 728 if (WIN32)
 729   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE        "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
 730   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
 731   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG          "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
 732 endif()
 733
 734 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
 735 message (STATUS "\nInfo: \(${CURRENT_TIME}\) Start collecting all OCCT header files into ${CMAKE_BINARY_DIR}/inc ...")
 736
 737 # collect all the headers to <binary dir>/inc folder
 738 COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}" "${BUILD_TOOLKITS}" "${CMAKE_SOURCE_DIR}/src" "${INSTALL_DIR_INCLUDE}")
 739
 740 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
 741 message (STATUS "Info: \(${CURRENT_TIME}\) End the collecting")
 742
 743 list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
 744 if (${DRAWEXE_INDEX} GREATER -1)
 745   OCCT_INSTALL_FILE_OR_DIR ("data/" "${INSTALL_DIR_DATA}")
 746   OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR_SAMPLES}")
 747 endif()
 748
 749 if (WIN32)
 750   set (SCRIPT_EXT bat)
 751 else()
 752   set (SCRIPT_EXT sh)
 753 endif()
 754
 755 # OCCT tools
 756 # include the patched or original list of tools
 757 # list <TOOLNAME>_TOOLKITS is created foreach tool and contains its toolkits
 758 # list <OCCT_TOOLS> will contain all tools
 759 if (NOT USE_QT_TOOLS)
 760   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_QT")
 761   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TQTMALLOC")
 762   OCCT_CHECK_AND_UNSET ("INSTALL_QT")
 763 else()
 764   OCCT_TOOLS_AND_TOOLKITS (OCCT_TOOLS)
 765   foreach (OCCT_TOOL ${OCCT_TOOLS})
 766     list (APPEND BUILD_TOOL_TOOLKITS ${${OCCT_TOOL}_TOOL_TOOLKITS})
 767   endforeach()
 768
 769   # collect all the headers to <binary dir>/inc folder
 770   string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
 771   message (STATUS "\nInfo: \(${CURRENT_TIME}\) Start collecting all OCCT tool header files into ${CMAKE_BINARY_DIR}/tools/inc ...")
 772   COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}/${INSTALL_DIR_INCLUDE}" "${BUILD_TOOL_TOOLKITS}" "${CMAKE_SOURCE_DIR}/tools" "tools")
 773   include_directories (${CMAKE_BINARY_DIR}/${INSTALL_DIR_INCLUDE}/tools)
 774
 775
 776   # check qt 3rdparty path
 777   add_definitions (-DHAVE_QT)
 778   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/qt5")
 779   message (STATUS "Info: Qt is used by OCCT")
 780 endif()
 781
 782 # OCCT samples
 783 # get absolute path from INSTALL_DIR
 784 set (INSTALL_DIR_ABSOLUTE "${INSTALL_DIR}")
 785 if(NOT IS_ABSOLUTE "${INSTALL_DIR_ABSOLUTE}")
 786   get_filename_component(INSTALL_DIR_ABSOLUTE "${CMAKE_BINARY_DIR}/${INSTALL_DIR}" ABSOLUTE)
 787 endif()
 788
 789 if (INSTALL_SAMPLES)
 790   OCCT_CONFIGURE ("adm/templates/env.samples.${SCRIPT_EXT}.in" "env.samples.${SCRIPT_EXT}")
 791   if (WIN32)
 792     OCCT_INSTALL_FILE_OR_DIR ("samples/CSharp" "${INSTALL_DIR_SAMPLES}")
 793     OCCT_INSTALL_FILE_OR_DIR ("samples/mfc" "${INSTALL_DIR_SAMPLES}")
 794
 795     if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
 796       OCCT_INSTALL_FILE_OR_DIR ("samples/xaml" "${INSTALL_DIR_SAMPLES}")
 797     endif()
 798
 799     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/CSharp" RENAME "env.${SCRIPT_EXT}")
 800     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/mfc/standard" RENAME "env.${SCRIPT_EXT}")
 801   endif()
 802
 803   OCCT_INSTALL_FILE_OR_DIR ("samples/java" "${INSTALL_DIR_SAMPLES}")
 804   OCCT_INSTALL_FILE_OR_DIR ("samples/ocafsamples" "${INSTALL_DIR_SAMPLES}")
 805   OCCT_INSTALL_FILE_OR_DIR ("samples/qt" "${INSTALL_DIR_SAMPLES}")
 806
 807   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/FuncDemo" RENAME "env.${SCRIPT_EXT}")
 808   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/IESample" RENAME "env.${SCRIPT_EXT}")
 809   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/Tutorial" RENAME "env.${SCRIPT_EXT}")
 810 endif()
 811
 812 if (INSTALL_TEST_CASES)
 813   OCCT_INSTALL_FILE_OR_DIR ("tests/" "${INSTALL_DIR_TESTS}")
 814 endif()
 815
 816 list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
 817 if (${DRAWEXE_INDEX} GREATER -1)
 818   # copy data and samples/tcl folders to install script folder
 819   OCCT_INSTALL_FILE_OR_DIR ("data/" "${INSTALL_DIR_DATA}")
 820   OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR_SAMPLES}")
 821
 822   # copy draw script to install script folder
 823   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}")
 824     install (FILES "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
 825             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
 826   else()
 827     install (FILES "${CMAKE_SOURCE_DIR}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
 828             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
 829   endif()
 830
 831   # copy draw script to CMake binary folder
 832   OCCT_COPY_FILE_OR_DIR ("adm/templates/draw.${SCRIPT_EXT}" "${CMAKE_BINARY_DIR}")
 833 endif()
 834
 835 set (SUB_CUSTOM_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.${SCRIPT_EXT}")
 836
 837 if (WIN32)
 838   set (ADDITIONAL_CUSTOM_CONTENT "\nif exist \"%~dp0${SUB_CUSTOM_NAME}\" (\n  call \"%~dp0${SUB_CUSTOM_NAME}\" %1 %2 %3 \n)")
 839 else()
 840   set (ADDITIONAL_CUSTOM_CONTENT "\nif [ -e \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" ]; then\n  source \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" \"\$1\" \"\$2\" \nfi")
 841 endif()
 842
 843  # change custom.bat/sh
 844 if (EXISTS "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}")
 845   file (READ "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" CUSTOM_CONTENT)
 846
 847   set (CUSTOM_CONTENT "${CUSTOM_CONTENT} ${ADDITIONAL_CUSTOM_CONTENT}")
 848
 849   file (WRITE "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" "${CUSTOM_CONTENT}")
 850 else()
 851   OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.${SCRIPT_EXT}.main" "custom.${SCRIPT_EXT}" "custom.${SCRIPT_EXT}" "${INSTALL_DIR_SCRIPT}")
 852 endif()
 853
 854 # write current custom.bat/sh (for install directory)
 855 set (SUB_CUSTOM_BUILD_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.install.${SCRIPT_EXT}")
 856 OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.install.${SCRIPT_EXT}.in" "${SUB_CUSTOM_BUILD_NAME}" "${SUB_CUSTOM_NAME}" "${INSTALL_DIR_SCRIPT}")
 857
 858 # write current custom.bat/sh (for build directory)
 859 OCCT_CONFIGURE ("adm/templates/custom.build.${SCRIPT_EXT}.in" "${SUB_CUSTOM_NAME}")
 860
 861 if (BUILD_MODULE_MfcSamples)
 862   OCCT_INSTALL_FILE_OR_DIR ("adm/templates/sample.bat" "${INSTALL_DIR_SCRIPT}")
 863   OCCT_COPY_FILE_OR_DIR    ("adm/templates/sample.bat" "${CMAKE_BINARY_DIR}")
 864 endif()
 865
 866 # env script for draw in building environment
 867 OCCT_CONFIGURE ("adm/templates/env.${SCRIPT_EXT}.in" "env.${SCRIPT_EXT}")
 868
 869 # install env script
 870 install (FILES "${CMAKE_BINARY_DIR}/env.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SCRIPT}")
 871
 872 # copy DrawAppliInit from OCCT source to build directory
 873 if (NOT EXISTS "${CMAKE_BINARY_DIR}/DrawAppliInit")
 874   OCCT_COPY_FILE_OR_DIR (DrawAppliInit "${CMAKE_BINARY_DIR}")
 875 endif()
 876
 877 # RESOURCES
 878 FILE_TO_LIST ("adm/RESOURCES" RESOURCES)
 879 foreach(RESOURCE ${RESOURCES})
 880   get_filename_component(RESOURCE_FOLDER ${RESOURCE} DIRECTORY)
 881   if(NOT "${RESOURCE_FOLDER}" STREQUAL "")
 882     get_filename_component(RESOURCE_FOLDER ${RESOURCE_FOLDER} NAME)
 883     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR_RESOURCE}/${RESOURCE_FOLDER}")
 884   else()
 885     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR_RESOURCE}")
 886   endif()
 887 endforeach()
 888
 889 # patch installed DrawDefault file if BUILD_SHARED_LIBRARY_NAME_POSTFIX is changed
 890 if (NOT "${BUILD_SHARED_LIBRARY_NAME_POSTFIX}" STREQUAL "")
 891   OCCT_UPDATE_DRAW_DEFAULT_FILE()
 892 endif()
 893
 894 # include patched toolkit projects or original ones
 895 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
 896   OCCT_ADD_SUBDIRECTORY ("src/${BUILD_TOOLKIT}")
 897 endforeach()
 898
 899 if (BUILD_DOC_Overview)
 900   OCCT_ADD_SUBDIRECTORY (dox)
 901 endif()
 902
 903 # patch DRAWEXE
 904 if (MSVC AND 3RDPARTY_DLL_DIRS)
 905   list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
 906   if (${DRAWEXE_INDEX} GREATER -1)
 907     list (REMOVE_DUPLICATES 3RDPARTY_DLL_DIRS)
 908     set (3RDPARTY_DLL_DIRS_FOR_PATH "")
 909
 910     foreach (3RDPARTY_DLL_DIR ${3RDPARTY_DLL_DIRS})
 911       set (3RDPARTY_DLL_DIRS_FOR_PATH "${3RDPARTY_DLL_DIRS_FOR_PATH};${3RDPARTY_DLL_DIR}")
 912     endforeach()
 913
 914     OCCT_MAKE_COMPILER_BITNESS()
 915     set (X_COMPILER_BITNESS "x64")
 916     if ("${COMPILER_BITNESS}" STREQUAL "32")
 917       set (X_COMPILER_BITNESS "Win32")
 918     endif()
 919
 920     OCCT_CONFIGURE ("adm/templates/DRAWEXE.vcxproj.user.in" "${CMAKE_BINARY_DIR}/src/DRAWEXE/DRAWEXE.vcxproj.user")
 921   endif()
 922 endif()
 923
 924 # include patched toolkit projects or original ones
 925 if (BUILD_TOOL_TOOLKITS)
 926   foreach (BUILD_TOOL_TOOLKIT ${BUILD_TOOL_TOOLKITS})
 927     OCCT_ADD_SUBDIRECTORY ("tools/${BUILD_TOOL_TOOLKIT}")
 928   endforeach()
 929 endif()
 930
 931 message (STATUS "Info: \(${CURRENT_TIME}\) OCCT toolkits processed")
 932 # samples do not support patch usage
 933 if (BUILD_MODULE_MfcSamples)
 934   set (OCCT_ROOT ${CMAKE_SOURCE_DIR})
 935
 936   set (MFC_STANDARD_SAMPLES_DIR ${OCCT_ROOT}/samples/mfc/standard)
 937   set (COMMON_WINMAIN_FILE      ${MFC_STANDARD_SAMPLES_DIR}/Common/Winmain.cpp)
 938
 939   add_subdirectory(samples/mfc/standard/mfcsample)
 940   add_subdirectory(samples/mfc/standard/01_Geometry)
 941   add_subdirectory(samples/mfc/standard/02_Modeling)
 942   add_subdirectory(samples/mfc/standard/03_Viewer2d)
 943   add_subdirectory(samples/mfc/standard/04_Viewer3d)
 944   add_subdirectory(samples/mfc/standard/05_ImportExport)
 945   add_subdirectory(samples/mfc/standard/06_Ocaf)
 946   add_subdirectory(samples/mfc/standard/07_Triangulation)
 947   add_subdirectory(samples/mfc/standard/08_HLR)
 948   add_subdirectory(samples/mfc/standard/09_Animation)
 949   add_subdirectory(samples/mfc/standard/10_Convert)
 950
 951   message (STATUS "Info: \(${CURRENT_TIME}\) MFC Sample projects added")
 952 endif()
 953
 954 if (BUILD_MODULE_UwpSample)
 955   add_subdirectory(samples/xaml)
 956 endif()
 957
 958 if (BUILD_TOOL_TOOLKITS)
 959   # copy tinspector script to install script folder
 960   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/adm/templates/dfbrowser.${SCRIPT_EXT}")
 961     install (FILES "${BUILD_PATCH}/adm/templates/dfbrowser.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
 962             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
 963   else()
 964     install (FILES "${CMAKE_SOURCE_DIR}/adm/templates/dfbrowser.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
 965             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
 966   endif()
 967
 968   set (BUILD_SAMPLE_TOOLKITS TInspectorEXE)
 969   foreach (BUILD_SAMPLE_TOOL_TOOLKIT ${BUILD_SAMPLE_TOOLKITS})
 970     OCCT_ADD_SUBDIRECTORY ("samples/tools/${BUILD_SAMPLE_TOOL_TOOLKIT}")
 971   endforeach()
 972 endif()
 973
 974 # Prepare variables for configuration of OpenCASCADE cmake config file
 975 set (OCCT_MODULES_ENABLED)
 976 set (OCCT_LIBRARIES)
 977 set (SET_OpenCASCADE_MODULES_TOOLKITS "\n# List of available OpenCASCADE libraries for each module\n")
 978 set (OCCT_COMPILE_DEFINITIONS)
 979
 980 foreach (OCCT_TOOLKIT ${BUILD_TOOLKITS})
 981   if (TARGET ${OCCT_TOOLKIT})
 982
 983     # get all libraries
 984     get_target_property (${OCCT_TOOLKIT}_TYPE ${OCCT_TOOLKIT} "TYPE")
 985     if ("${${OCCT_TOOLKIT}_TYPE}" STREQUAL "STATIC_LIBRARY" OR "${${OCCT_TOOLKIT}_TYPE}" STREQUAL "SHARED_LIBRARY" )
 986       list (APPEND OCCT_LIBRARIES ${OCCT_TOOLKIT})
 987
 988       # get all modules
 989       get_target_property (${OCCT_TOOLKIT}_MODULE ${OCCT_TOOLKIT} "MODULE")
 990       list (APPEND OCCT_MODULES_ENABLED ${${OCCT_TOOLKIT}_MODULE})
 991       list (APPEND OpenCASCADE_${${OCCT_TOOLKIT}_MODULE}_TOOLKITS ${OCCT_TOOLKIT})
 992
 993       # get compile definitions of target directory
 994       get_directory_property (COMPILE_DEFINITIONS DIRECTORY "${${OCCT_TOOLKIT}_SOURCE_DIR}" "COMPILE_DEFINITIONS")
 995       list (APPEND OCCT_COMPILE_DEFINITIONS ${COMPILE_DEFINITIONS})
 996     endif()
 997   endif()
 998 endforeach()
 999 list (REMOVE_DUPLICATES OCCT_MODULES_ENABLED)
1000 list (REMOVE_DUPLICATES OCCT_COMPILE_DEFINITIONS)
1001
1002 # export compile definitions and C/C++ flags for each configuration to OpenCASCADE config files
1003 foreach (OCCT_CONFIGURATION ${CMAKE_CONFIGURATION_TYPES})
1004   set (SET_OpenCASCADE_COMPILE_DEFINITIONS)
1005   string (TOUPPER "${OCCT_CONFIGURATION}" OCCT_CONFIGURATION_UPPER)
1006   string (TOLOWER "${OCCT_CONFIGURATION}" OCCT_CONFIGURATION_LOWER)
1007   foreach(COMPILE_DEFINITION ${OCCT_COMPILE_DEFINITIONS})
1008     string(REPLACE "(" "\\(" COMPILE_DEFINITION "${COMPILE_DEFINITION}")
1009     string(REPLACE ")" "\\)" COMPILE_DEFINITION "${COMPILE_DEFINITION}")
1010     set (SET_OpenCASCADE_COMPILE_DEFINITIONS "${SET_OpenCASCADE_COMPILE_DEFINITIONS}set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:${OCCT_CONFIGURATION}>:${COMPILE_DEFINITION}>)\n")
1011   endforeach()
1012   set (SET_OpenCASCADE_CMAKE_C_FLAGS "${CMAKE_C_FLAGS_${OCCT_CONFIGURATION_UPPER}}")
1013   set (SET_OpenCASCADE_CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS_${OCCT_CONFIGURATION_UPPER}}")
1014   configure_file("${CMAKE_SOURCE_DIR}/adm/templates/OpenCASCADECompileDefinitionsAndFlags.cmake.in" "OpenCASCADECompileDefinitionsAndFlags-${OCCT_CONFIGURATION_LOWER}.cmake" @ONLY)
1015 endforeach()
1016 # install OpenCASCADE config file with compile definitions and C/C++ flags ONLY for current configuration
1017 install (CODE "string (TOLOWER \"\${CMAKE_INSTALL_CONFIG_NAME}\" CMAKE_INSTALL_CONFIG_NAME_LOWER)")
1018 install (CODE "configure_file(\"${CMAKE_BINARY_DIR}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" \"${INSTALL_DIR}/${INSTALL_DIR_CMAKE}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" COPYONLY)")
1019
1020 foreach (OCCT_MODULE ${OCCT_MODULES})
1021   if (BUILD_MODULE_${OCCT_MODULE})
1022     set (SET_OpenCASCADE_MODULES_TOOLKITS "${SET_OpenCASCADE_MODULES_TOOLKITS}set (OpenCASCADE_${OCCT_MODULE}_LIBRARIES ${OpenCASCADE_${OCCT_MODULE}_TOOLKITS})\n")
1023   endif()
1024
1025   # sort enabled modules for correct work of OpenCASCADE config file
1026   list(FIND OCCT_MODULES_ENABLED "${OCCT_MODULE}" OCCT_MODULE_INDEX)
1027   if (NOT ${OCCT_MODULE_INDEX} EQUAL -1)
1028     list (APPEND OCCT_MODULES_ENABLED_SORTED ${OCCT_MODULE})
1029   endif()
1030 endforeach()
1031 set (OCCT_MODULES_ENABLED ${OCCT_MODULES_ENABLED_SORTED})
1032
1033 # Add all targets to the build-tree export set
1034 export (TARGETS ${OCCT_LIBRARIES} FILE "${CMAKE_BINARY_DIR}/OpenCASCADETargets.cmake")
1035
1036 # Export the package for use from the build-tree
1037 # (this registers the build-tree with a global CMake-registry)
1038 export(PACKAGE OpenCASCADE)
1039
1040 if (CMAKE_BUILD_TYPE)
1041   set (SET_OpenCASCADE_BUILD_TYPE "set (OpenCASCADE_BUILD_TYPE        \"${CMAKE_BUILD_TYPE}\")")
1042 endif()
1043
1044 if (BUILD_SHARED_LIBS)
1045   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_SHARED_LINKER_FLAGS}\")")
1046 else()
1047   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_STATIC_LINKER_FLAGS}\")")
1048 endif()
1049
1050 if (WIN32)
1051   set (SET_OpenCASCADE_WITH_D3D "set (OpenCASCADE_WITH_D3D       ${USE_D3D})")
1052 endif()
1053 if (APPLE)
1054   set (SET_OpenCASCADE_WITH_GLX "set (OpenCASCADE_WITH_GLX       ${USE_GLX})")
1055 endif()
1056
1057 if (NOT SINGLE_GENERATOR)
1058   OCCT_INSERT_CODE_FOR_TARGET()
1059 endif()
1060
1061 # Configure and install cmake config file
1062 configure_file("${CMAKE_SOURCE_DIR}/adm/templates/OpenCASCADEConfig.cmake.in" "OpenCASCADEConfig.cmake" @ONLY)
1063 install(FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfig.cmake" DESTINATION  "${INSTALL_DIR_CMAKE}")
1064
1065 # Configure cmake version file
1066 include(CMakePackageConfigHelpers)
1067 write_basic_package_version_file( ${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake
1068                                   VERSION ${OCC_VERSION_MAJOR}.${OCC_VERSION_MINOR}.${OCC_VERSION_MAINTENANCE}
1069                                   COMPATIBILITY ExactVersion )
1070
1071 # Install cmake version file
1072 install (FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake" DESTINATION "${INSTALL_DIR_CMAKE}")
1073
1074 # Install the export set for use with the install-tree for each configuration
1075 foreach (OCCT_MODULE ${OCCT_MODULES_ENABLED})
1076   install(EXPORT OpenCASCADE${OCCT_MODULE}Targets DESTINATION "${INSTALL_DIR_CMAKE}")
1077 endforeach()
1078
1079 # Update generated OpenCASCADETargets-*.cmake files
1080 # to have correct paths to libraries depending on the configuration
1081 OCCT_UPDATE_TARGET_FILE ()
1082
1083 message (STATUS "Info: \(${CURRENT_TIME}\) OCCT configuration files prepared")