0030547: Foundation Classes - NCollection_DoubleMap lacks Seek() method
[occt.git] / CMakeLists.txt
1 cmake_minimum_required (VERSION 2.8.12 FATAL_ERROR)
2
3 set (CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/adm/cmake")
4
5 set (CMAKE_SUPPRESS_REGENERATION TRUE)
6
7 set (CMAKE_CONFIGURATION_TYPES Release Debug RelWithDebInfo CACHE INTERNAL "" FORCE)
8
9 # macro: include patched file if it exists
10 macro (OCCT_INCLUDE_CMAKE_FILE BEING_INCLUDED_FILE)
11   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake")
12     include (${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake)
13   else()
14     include (${CMAKE_SOURCE_DIR}/${BEING_INCLUDED_FILE}.cmake)
15   endif()
16 endmacro()
17
18 # include variable description
19 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vardescr")
20
21 # set type of OCCT libraries
22 if (NOT BUILD_LIBRARY_TYPE)
23   set (BUILD_LIBRARY_TYPE "Shared" CACHE STRING "${BUILD_LIBRARY_TYPE_DESCR}" FORCE)
24   SET_PROPERTY(CACHE BUILD_LIBRARY_TYPE PROPERTY STRINGS Shared Static)
25 endif()
26
27 if ("${BUILD_LIBRARY_TYPE}" STREQUAL "Shared")
28   set (BUILD_SHARED_LIBS ON)
29
30   if (NOT DEFINED BUILD_SHARED_LIBRARY_NAME_POSTFIX)
31     set (BUILD_SHARED_LIBRARY_NAME_POSTFIX "" CACHE STRING "${BUILD_SHARED_LIBRARY_NAME_POSTFIX_DESCR}" FORCE)
32   endif()
33 else()
34   unset (BUILD_SHARED_LIBS)
35   unset (BUILD_SHARED_LIBRARY_NAME_POSTFIX)
36 endif()
37
38 # the name of the project
39 project (OCCT)
40
41 if (WIN32)
42   add_definitions(-DUNICODE)
43   add_definitions(-D_UNICODE)
44 endif()
45
46 # include occt macros
47 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_macros")
48
49 # Solution folder property
50 set_property (GLOBAL PROPERTY USE_FOLDERS ON)
51
52 # get current OCCT version
53 OCC_VERSION (OCC_VERSION_MAJOR OCC_VERSION_MINOR OCC_VERSION_MAINTENANCE OCC_VERSION_DEVELOPMENT OCC_VERSION_STRING_EXT)
54
55 set_property (GLOBAL PROPERTY OCC_VERSION_MAJOR ${OCC_VERSION_MAJOR})
56 set_property (GLOBAL PROPERTY OCC_VERSION_MINOR ${OCC_VERSION_MINOR})
57 set_property (GLOBAL PROPERTY OCC_VERSION_MAINTENANCE ${OCC_VERSION_MAINTENANCE})
58
59 set (INSTALL_TEST_CASES OFF CACHE BOOL "${INSTALL_TEST_CASES_DESCR}")
60
61 # Regeneration of OCCT resource files
62 set (BUILD_RESOURCES OFF CACHE BOOL "${BUILD_RESOURCES_DESCR}")
63
64 # single-configuration generator
65 set (SINGLE_GENERATOR OFF)
66 if (DEFINED CMAKE_BUILD_TYPE)
67   set (SINGLE_GENERATOR ON)
68 endif()
69
70 # a single-configuration generator like the Makefile generator defines CMAKE_BUILD_TYPE variable
71 # check this variable and set if it's required
72 if (DEFINED CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE) # single-configuration generator.
73   set (CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel." FORCE)
74 endif()
75
76 # enable extended messages of many OCCT algorithms
77 if (((SINGLE_GENERATOR AND "${CMAKE_BUILD_TYPE}" STREQUAL "Debug") OR NOT SINGLE_GENERATOR) AND (NOT "${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore"))
78   if (NOT BUILD_WITH_DEBUG)
79     set (BUILD_WITH_DEBUG OFF CACHE BOOL "${BUILD_WITH_DEBUG_DESCR}")
80   endif()
81 else()
82   OCCT_CHECK_AND_UNSET (BUILD_WITH_DEBUG)
83 endif()
84
85 if (BUILD_WITH_DEBUG)
86   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:DEBUG>:OCCT_DEBUG>)
87 endif()
88
89 # option to enable or disable use of precompiled headers
90 if (NOT DEFINED BUILD_USE_PCH)
91   set (BUILD_USE_PCH OFF CACHE BOOL "${BUILD_USE_PCH_DESCR}")
92 endif()
93
94 if (BUILD_USE_PCH)
95
96   # Load Cotire tool for accelerating build procedure
97   include(cotire)
98
99   # Set Cotire to ignore lxx, pxx, gxx 
100   set (COTIRE_ADDITIONAL_PREFIX_HEADER_IGNORE_EXTENSIONS "lxx;pxx;gxx" CACHE STRING "Set Cotire to ignore OCCT specific files that can be #included" FORCE)
101
102   # Set priority for inclusion of system headers in PCH to reduce problems
103   # due to incomplete inclusion or wrong order.
104   if (WIN32)
105     # on Windows, assume that SDK (windows.h) is in default location
106     set(ProgramFilesX86 "ProgramFiles(x86)")
107     file(TO_CMAKE_PATH "$ENV{${ProgramFilesX86}}" ProgramFilesX86)
108     set_property (DIRECTORY PROPERTY COTIRE_PREFIX_HEADER_INCLUDE_PRIORITY_PATH "${ProgramFilesX86}")
109     unset(ProgramFilesX86)
110   endif()
111
112 endif()
113
114 # copy samples to install directory
115 set (INSTALL_SAMPLES OFF CACHE BOOL "${INSTALL_SAMPLES_DESCR}")
116
117 # install dir of the project
118 if (NOT DEFINED INSTALL_DIR)
119   # set default install directory for Windows
120   if (WIN32 AND NOT DEFINED CMAKE_INSTALL_PREFIX)
121     set (CMAKE_INSTALL_PREFIX "C:/opencascade-${OCC_VERSION_STRING_EXT}")
122   endif()
123   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}")
124 else()
125   file (TO_CMAKE_PATH "${INSTALL_DIR}" INSTALL_DIR)
126   set (INSTALL_DIR "${INSTALL_DIR}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
127 endif()
128
129 # choose a variant of the layout of the install paths
130 if (NOT INSTALL_DIR_LAYOUT)
131   if (WIN32)
132     set (INSTALL_DIR_LAYOUT "Windows" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
133   else()
134     set (INSTALL_DIR_LAYOUT "Unix" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
135   endif()
136   SET_PROPERTY(CACHE INSTALL_DIR_LAYOUT PROPERTY STRINGS Windows Unix)
137 endif()
138
139 # check INSTALL_DIR_LAYOUT changes and update INSTALL_DIR_* paths if necessary
140 if (NOT DEFINED INSTALL_DIR_LAYOUT_PREV)
141   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
142 elseif (NOT "${INSTALL_DIR_LAYOUT_PREV}" STREQUAL "${INSTALL_DIR_LAYOUT}")
143   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
144   # The structure of install folder should be reset due to changed layout
145   OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
146
147   # Unset INSTALL_DIR_WITH_VERSION on windows
148   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
149     OCCT_CHECK_AND_UNSET (INSTALL_DIR_WITH_VERSION)
150   else()
151     if (NOT DEFINED INSTALL_DIR_WITH_VERSION)
152       set (INSTALL_DIR_WITH_VERSION OFF CACHE BOOL "${INSTALL_DIR_WITH_VERSION_DESCR}")
153     endif()
154   endif()
155 endif()
156
157 # check CMAKE_INSTALL_PREFIX changes and update INSTALL_DIR if necessary
158 if (NOT DEFINED CMAKE_INSTALL_PREFIX_PREV)
159   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
160 elseif (NOT "${CMAKE_INSTALL_PREFIX_PREV}" STREQUAL "${CMAKE_INSTALL_PREFIX}")
161   # CMAKE_INSTALL_PREFIX has been changed at previous step
162   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
163   
164   # INSTALL_DIR is required to be updated
165   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
166 endif()
167
168 # check INSTALL_DIR changes and update CMAKE_INSTALL_PREFIX if necessary
169 if (NOT DEFINED INSTALL_DIR_PREV)
170   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
171 elseif (NOT "${INSTALL_DIR_PREV}" STREQUAL "${INSTALL_DIR}")
172   # INSTALL_DIR has been changed at previous step
173   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
174
175   # sync CMAKE_INSTALL_PREFIX with INSTALL_DIR 
176   set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
177
178   # set CMAKE_INSTALL_PREFIX_PREV to avoid the reset of structure of the install folder 
179   set (CMAKE_INSTALL_PREFIX_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
180 endif()
181
182 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
183   if (NOT DEFINED INSTALL_DIR_WITH_VERSION_PREV)
184     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
185   elseif (NOT "${INSTALL_DIR_WITH_VERSION_PREV}" STREQUAL "${INSTALL_DIR_WITH_VERSION}")
186     # INSTALL_DIR_WITH_VERSION has been changed at previous step
187     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
188
189     OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
190   endif()
191 endif()
192
193 # hide CMAKE_INSTALL_PREFIX from a user
194 set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
195
196 set (BIN_LETTER "")
197 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
198   set (BIN_LETTER "d")
199 elseif ("${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo")
200   set (BIN_LETTER "i")
201 endif()
202
203 # Get all used variables: OS_WITH_BIT, COMPILER
204 OCCT_MAKE_OS_WITH_BITNESS()
205 OCCT_MAKE_COMPILER_SHORT_NAME()
206
207 # do not define INSTALL_DIR_BIN for win.
208 # Leave library structure for win: <prefix>/win64/vc10/bin(d)
209 if (NOT DEFINED INSTALL_DIR_BIN)
210   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
211     set (INSTALL_DIR_BIN "bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
212   else()
213     set (INSTALL_DIR_BIN "${OS_WITH_BIT}/${COMPILER}/bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
214   endif()
215 endif()
216
217 # define folder contaning all shell/batch scripts
218 if (NOT DEFINED INSTALL_DIR_SCRIPT)
219   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
220     set (INSTALL_DIR_SCRIPT "${INSTALL_DIR_BIN}" CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
221   else()
222     set (INSTALL_DIR_SCRIPT "." CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
223   endif()
224 endif()
225
226 # place the libraries to <prefix>/lib folder for unix and leave old structure for windows
227 if (NOT DEFINED INSTALL_DIR_LIB)
228   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
229     set (INSTALL_DIR_LIB "lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
230   else()
231     set (INSTALL_DIR_LIB "${OS_WITH_BIT}/${COMPILER}/lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
232   endif()
233 endif()
234
235 # OCCT headers: <prefix>/inc for windows,
236 #               <prefix>/include/opencascade-7.0.0 for unix
237 if (NOT DEFINED INSTALL_DIR_INCLUDE)
238   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
239     set (INSTALL_DIR_INCLUDE "include/opencascade" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
240     if (INSTALL_DIR_WITH_VERSION)
241       set (INSTALL_DIR_INCLUDE "include/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}" FORCE)
242     endif()
243   else()
244     set (INSTALL_DIR_INCLUDE "inc" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
245   endif()
246 endif()
247
248 # OCCT resources: <prefix>/src for windows,
249 #                 <prefix>/share/opencascade-7.0.0/resources for unix
250 if (NOT DEFINED INSTALL_DIR_RESOURCE)
251   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
252     set (INSTALL_DIR_RESOURCE "share/opencascade/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
253     if (INSTALL_DIR_WITH_VERSION)
254       set (INSTALL_DIR_RESOURCE "share/opencascade-${OCC_VERSION_STRING_EXT}/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}" FORCE)
255     endif()
256   else()
257     set (INSTALL_DIR_RESOURCE "src" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
258   endif()
259 endif()
260
261 # OCCT data
262 if (NOT DEFINED INSTALL_DIR_DATA)
263   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
264     set (INSTALL_DIR_DATA "share/opencascade/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
265     if (INSTALL_DIR_WITH_VERSION)
266       set (INSTALL_DIR_DATA "share/opencascade-${OCC_VERSION_STRING_EXT}/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}" FORCE)
267     endif()
268   else()
269     set (INSTALL_DIR_DATA "data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
270   endif()
271 endif()
272
273 # OCCT samples
274 if (NOT DEFINED INSTALL_DIR_SAMPLES)
275   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
276     set (INSTALL_DIR_SAMPLES "share/opencascade/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
277     if (INSTALL_DIR_WITH_VERSION)
278       set (INSTALL_DIR_SAMPLES "share/opencascade-${OCC_VERSION_STRING_EXT}/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}" FORCE)
279     endif()
280   else()
281     set (INSTALL_DIR_SAMPLES "samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
282   endif()
283 endif()
284
285 # OCCT tests
286 if (NOT DEFINED INSTALL_DIR_TESTS)
287   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
288     set (INSTALL_DIR_TESTS "share/opencascade/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
289     if (INSTALL_DIR_WITH_VERSION)
290       set (INSTALL_DIR_TESTS "share/opencascade-${OCC_VERSION_STRING_EXT}/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}" FORCE)
291     endif()
292   else()
293     set (INSTALL_DIR_TESTS "tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
294   endif()
295 endif()
296
297 # OCCT doc
298 if (NOT DEFINED INSTALL_DIR_DOC)
299   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
300     set (INSTALL_DIR_DOC "share/doc/opencascade" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
301     if (INSTALL_DIR_WITH_VERSION)
302       set (INSTALL_DIR_DOC "share/doc/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_DOC_DESCR}" FORCE)
303     endif()
304   else()
305     set (INSTALL_DIR_DOC "doc" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
306   endif()
307 endif()
308
309 # define folder contaning CMake configuration files
310 if (NOT DEFINED INSTALL_DIR_CMAKE)
311   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
312     if (INSTALL_DIR_WITH_VERSION)
313       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
314     else()
315       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
316     endif()
317   else()
318     set (INSTALL_DIR_CMAKE "cmake" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
319   endif()
320 endif()
321
322 # include occt macros
323 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_resources")
324
325 # install LICENSE_LGPL_21.txt and OCCT_LGPL_EXCEPTION.txt files
326 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
327   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" "${INSTALL_DIR_DOC}")
328   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" "${INSTALL_DIR_DOC}")
329 else()
330   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" ".")
331   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" ".")
332 endif()
333
334 if(APPLE)
335   set (INSTALL_NAME_DIR "" CACHE STRING "install_name library suffix on OS X (e.g. @executable_path/../Frameworks)")
336 endif()
337
338 # a directory recognized as a 'patch' for OCCT
339 set (BUILD_PATCH "" CACHE PATH "${BUILD_PATCH_DESCR}")
340
341 # the list of being built toolkits
342 set (BUILD_ADDITIONAL_TOOLKITS "" CACHE STRING "${BUILD_ADDITIONAL_TOOLKITS_DESCR}")
343 separate_arguments (BUILD_ADDITIONAL_TOOLKITS)
344
345 if (MSVC)
346   set (BUILD_SAMPLES_MFC OFF CACHE BOOL "${BUILD_SAMPLES_MFC_DESCR}")
347 endif()
348 set (BUILD_SAMPLES_QT OFF CACHE BOOL "${BUILD_SAMPLES_QT_DESCR}")
349
350 set (BUILD_Inspector OFF CACHE BOOL "${BUILD_Inspector_DESCR}")
351
352 # uwp sample
353 if (MSVC)
354   if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
355     set (BUILD_MODULE_UwpSample OFF CACHE BOOL "${BUILD_MODULE_UwpSample_DESCR}")
356   else()
357     unset (BUILD_MODULE_UwpSample)
358   endif()
359 endif()
360
361 # whether use optional 3rdparty or not
362 if (APPLE)
363   set (USE_GLX OFF CACHE BOOL "${USE_GLX_DESCR}")
364 endif()
365
366 if (WIN32)
367   set (USE_D3D OFF CACHE BOOL "${USE_D3D_DESCR}")
368 endif()
369
370 # Enable/Disable the floating point exceptions (FPE) during runtime.
371 if (NOT BUILD_ENABLE_FPE_SIGNAL_HANDLER)
372   set (BUILD_ENABLE_FPE_SIGNAL_HANDLER OFF CACHE BOOL "${BUILD_ENABLE_FPE_SIGNAL_HANDLER_DESCR}" FORCE)
373 endif()
374
375 if (BUILD_ENABLE_FPE_SIGNAL_HANDLER)
376   set (BUILD_ENABLE_FPE_SIGNAL_HANDLER 1)
377 else()
378   set (BUILD_ENABLE_FPE_SIGNAL_HANDLER 0)
379 endif()
380
381 # include the patched or original list of modules
382 # list <MODULENAME>_TOOLKITS is created foreach module and contains its toolkits
383 # list <OCCT_MODULES> will contain all modules
384 OCCT_MODULES_AND_TOOLKITS (MODULES "TOOLKITS" OCCT_MODULES)
385
386 foreach (OCCT_MODULE ${OCCT_MODULES})
387   BUILD_MODULE (${OCCT_MODULE})
388 endforeach()
389
390 if (ANDROID AND BUILD_MODULE_Draw)
391   message (STATUS "Info. Draw module is turned off due to it is not supported on Android")
392   set (BUILD_MODULE_Draw OFF CACHE BOOL "${BUILD_MODULE_Draw_DESCR}" FORCE)
393 endif()
394 if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore" AND BUILD_MODULE_Draw)
395   message (STATUS "Info. Draw module is turned off due to it is not supported on UWP")
396   set (BUILD_MODULE_Draw OFF CACHE BOOL "${BUILD_MODULE_Draw_DESCR}" FORCE)
397 endif()
398
399 # Overview
400 if (NOT DEFINED BUILD_DOC_Overview)
401   set (DO_ONLY_CHECK_FOR_DOXYGEN ON)
402   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
403   set (DO_ONLY_CHECK_FOR_DOXYGEN OFF)
404   
405   if (CAN_DOXYGEN_BE_USED)
406     message (STATUS "Info. Overview building is turned on")
407   endif()
408
409   set (BUILD_DOC_Overview ${CAN_DOXYGEN_BE_USED} CACHE BOOL "${BUILD_DOC_Overview_DESCR}")
410 endif()
411
412 if (NOT USE_D3D)
413   list (REMOVE_ITEM Visualization_TOOLKITS TKD3DHost)
414 endif()
415
416 # accumulate used toolkits (first level) in BUILD_TOOLKITS variable
417 list (APPEND BUILD_TOOLKITS ${BUILD_ADDITIONAL_TOOLKITS})
418
419 foreach (OCCT_MODULE ${OCCT_MODULES})
420   if (BUILD_MODULE_${OCCT_MODULE})
421     list (APPEND BUILD_TOOLKITS ${${OCCT_MODULE}_TOOLKITS})
422   endif()
423 endforeach()
424
425 # DRAWEXE excluded when library build is static
426 if (NOT BUILD_SHARED_LIBS)
427   list (REMOVE_ITEM BUILD_TOOLKITS DRAWEXE)
428   message (STATUS "Info: DRAWEXE is not included due to ${BUILD_LIBRARY_TYPE} build library type")
429 endif()
430
431 # accumulate all used toolkits
432 list (REMOVE_DUPLICATES BUILD_TOOLKITS)
433 set (RAW_BUILD_TOOLKITS)
434 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
435   OCCT_TOOLKIT_FULL_DEP (${BUILD_TOOLKIT} TOOLKIT_FULL_DEPS)
436   list (APPEND RAW_BUILD_TOOLKITS ${BUILD_TOOLKIT} ${TOOLKIT_FULL_DEPS})
437 endforeach()
438
439 list (REMOVE_DUPLICATES RAW_BUILD_TOOLKITS)
440 set (BUILD_TOOLKITS ${RAW_BUILD_TOOLKITS})
441
442 # include the patched or original list of definitions and flags
443 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_defs_flags")
444
445 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/3rdparty_macro")
446
447 # search for TKIVtk and TKIVtkDraw in BUILD_TOOLKITS
448 list (FIND BUILD_TOOLKITS TKIVtk CAN_USE_VTK)
449 if (CAN_USE_VTK EQUAL -1)
450   list (FIND BUILD_TOOLKITS TKIVtkDraw CAN_USE_VTK)
451 endif()
452
453 if (NOT CAN_USE_VTK EQUAL -1)
454   if (NOT DEFINED USE_VTK)
455     set (USE_VTK OFF CACHE BOOL "${USE_VTK_DESCR}")
456   endif()
457 else()
458   OCCT_CHECK_AND_UNSET (USE_VTK)
459 endif()
460
461 # Rebuild *.yacc and *.lex files that are contained by TKMath toolkit
462 list (FIND BUILD_TOOLKITS TKMath   CAN_REBUILD_PDC_FOR_TKMATH)
463 list (FIND BUILD_TOOLKITS StepFile CAN_REBUILD_PDC_FOR_STEPFILE)
464
465 if (NOT ${CAN_REBUILD_PDC_FOR_TKMATH} EQUAL -1 OR NOT ${CAN_REBUILD_PDC_FOR_STEPFILE} EQUAL -1)
466   set (BUILD_YACCLEX OFF CACHE BOOL "${BUILD_YACCLEX_DESCR}")
467 else()
468   OCCT_CHECK_AND_UNSET (BUILD_YACCLEX)
469 endif()
470
471 if (NOT DEFINED 3RDPARTY_DIR)
472   set (3RDPARTY_DIR "" CACHE PATH ${3RDPARTY_DIR_DESCR})
473   get_filename_component (3RDPARTY_DIR "${3RDPARTY_DIR}" ABSOLUTE)
474 else()
475   file (TO_CMAKE_PATH "${3RDPARTY_DIR}" 3RDPARTY_DIR)
476   set (3RDPARTY_DIR "${3RDPARTY_DIR}" CACHE PATH "${3RDPARTY_DIR_DESCR}" FORCE)
477 endif()
478
479 # search for CSF variable in EXTERNLIB of each being used toolkit
480 OCCT_IS_PRODUCT_REQUIRED (CSF_FreeImagePlus CAN_USE_FREEIMAGE)
481 OCCT_IS_PRODUCT_REQUIRED (CSF_TclLibs USE_TCL)
482 OCCT_IS_PRODUCT_REQUIRED (CSF_FREETYPE USE_FREETYPE)
483 OCCT_IS_PRODUCT_REQUIRED (CSF_OpenGlLibs CAN_USE_GLES2)
484 OCCT_IS_PRODUCT_REQUIRED (CSF_TBB CAN_USE_TBB)
485 OCCT_IS_PRODUCT_REQUIRED (CSF_EIGEN CAN_USE_EIGEN)
486
487 # define CSF variable
488 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_csf")
489
490 if (USE_TCL)
491   message (STATUS "Info: TCL is used by OCCT")
492   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tcl")
493   
494   message (STATUS "Info: TK is used by OCCT")
495   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tk")
496 else()
497   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TCL")
498   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TK")
499
500   OCCT_CHECK_AND_UNSET ("INSTALL_TCL")
501   OCCT_CHECK_AND_UNSET ("INSTALL_TK")
502 endif()
503
504 if (USE_FREETYPE)
505   message (STATUS "Info: Freetype is used by OCCT")
506   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freetype")
507 else()
508   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREETYPE")
509   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2")
510   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build")
511   OCCT_CHECK_AND_UNSET ("INSTALL_FREETYPE")
512 endif()
513
514 # VTK
515 if (USE_VTK)
516   add_definitions (-DHAVE_VTK)
517   set (OCCT_VTK_USED_TARGETS "" CACHE INTERNAL "" FORCE)
518   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vtk")
519 else()
520   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_VTK")
521   
522   if (NOT CAN_USE_VTK EQUAL -1)
523     message (STATUS "Info: TKIVtk and TKIVtkDraw toolkits excluded due to VTK usage is disabled")
524
525     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtk)
526     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtkDraw)
527   endif()
528 endif()
529
530 # D3D
531 if (USE_D3D)
532   add_definitions (-DHAVE_D3D)
533   #if(MSVC_VERSION LESS 1700)
534   #OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/d3d")
535   #endif()
536 endif()
537
538 # GLX
539 if (USE_GLX)
540   add_definitions (-DMACOSX_USE_GLX)
541   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/glx")
542 endif()
543
544 # FREEIMAGE
545
546 if (CAN_USE_FREEIMAGE)
547   set (USE_FREEIMAGE OFF CACHE BOOL "${USE_FREEIMAGE_DESCR}")
548
549   if (USE_FREEIMAGE)
550     add_definitions (-DHAVE_FREEIMAGE)
551     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimage")
552   else()
553     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
554     OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
555   endif()
556 else()
557   OCCT_CHECK_AND_UNSET ("USE_FREEIMAGE")
558
559   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
560   OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
561 endif()
562
563 # FFmpeg
564 # search for CSF_FFmpeg variable in EXTERNLIB of each being used toolkit
565 OCCT_IS_PRODUCT_REQUIRED (CSF_FFmpeg CAN_USE_FFMPEG)
566
567 if (CAN_USE_FFMPEG)
568   set (USE_FFMPEG OFF CACHE BOOL "${USE_FFMPEG_DESCR}")
569
570   if (USE_FFMPEG)
571     add_definitions (-DHAVE_FFMPEG)
572     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/ffmpeg")
573   else()
574     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FFMPEG")
575     OCCT_CHECK_AND_UNSET ("INSTALL_FFMPEG")
576   endif()
577 else()
578   OCCT_CHECK_AND_UNSET ("USE_FFMPEG")
579
580   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FFMPEG")
581   OCCT_CHECK_AND_UNSET ("INSTALL_FFMPEG")
582 endif()
583
584 # OpenGL ES 2.0
585 if (CAN_USE_GLES2)
586   if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
587     set (USE_GLES2 ON)
588   else()
589     set (USE_GLES2 OFF CACHE BOOL "${USE_GLES2_DESCR}")
590   endif()
591
592   if (USE_GLES2)
593     add_definitions (-DHAVE_GLES2)
594     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/egl")
595         OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gles2")
596   else()
597     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EGL")
598     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GLES2")
599     OCCT_CHECK_AND_UNSET ("INSTALL_EGL")
600     OCCT_CHECK_AND_UNSET ("INSTALL_GLES2")
601   endif()
602 else()
603   OCCT_CHECK_AND_UNSET ("USE_GLES2")
604
605   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EGL")
606   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GLES2")
607   OCCT_CHECK_AND_UNSET ("INSTALL_EGL")
608   OCCT_CHECK_AND_UNSET ("INSTALL_GLES2")
609 endif()
610
611 # TBB
612 if (NOT DEFINED ANDROID AND CAN_USE_TBB)
613   set (USE_TBB OFF CACHE BOOL "${USE_TBB_DESCR}")
614
615   if (USE_TBB)
616     add_definitions (-DHAVE_TBB)
617     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tbb")
618   else()
619     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
620     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
621     OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
622   endif()
623 else()
624   OCCT_CHECK_AND_UNSET ("USE_TBB")
625
626   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
627   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
628   OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
629 endif()
630
631 # EIGEN
632 if (CAN_USE_EIGEN)
633   set (USE_EIGEN OFF CACHE BOOL "${USE_EIGEN_DESCR}")
634
635   if (USE_EIGEN)
636     add_definitions (-DHAVE_EIGEN)
637     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/eigen")
638   else()
639     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EIGEN")
640     OCCT_CHECK_AND_UNSET ("INSTALL_EIGEN")
641   endif()
642 else()
643   OCCT_CHECK_AND_UNSET ("USE_EIGEN")
644
645   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EIGEN")
646   OCCT_CHECK_AND_UNSET ("INSTALL_EIGEN")
647 endif()
648
649 # Doxygen
650 if (BUILD_DOC_Overview)
651   if (NOT DEFINED INSTALL_DOC_Overview)
652     set (INSTALL_DOC_Overview OFF CACHE BOOL "${INSTALL_DOC_Overview_DESCR}")
653   endif()
654
655   if (INSTALL_DOC_Overview)
656     install (DIRECTORY "${CMAKE_BINARY_DIR}/doc/overview" DESTINATION  "${INSTALL_DIR_DOC}")
657
658     # create overview.html only for windows
659     if (WIN32 AND "${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
660       OCCT_INSTALL_FILE_OR_DIR ("dox/resources/overview.html" "${INSTALL_DIR_DOC}/..")
661     endif()
662   endif()
663
664   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
665 else()
666   OCCT_CHECK_AND_UNSET ("INSTALL_DOC_Overview")
667
668   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOXYGEN_EXECUTABLE")
669   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOT_EXECUTABLE")
670 endif()
671
672 # bison 
673 if (BUILD_YACCLEX)
674   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/bison")
675 else()
676   OCCT_CHECK_AND_UNSET ("3RDPARTY_BISON_EXECUTABLE")
677 endif()
678
679 # flex 
680 if (BUILD_YACCLEX)
681   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/flex")
682 else()
683   OCCT_CHECK_AND_UNSET ("3RDPARTY_FLEX_EXECUTABLE")
684 endif()
685
686 # check all 3rdparty include paths
687 string (REGEX REPLACE ";" " " 3RDPARTY_NOT_INCLUDED "${3RDPARTY_NOT_INCLUDED}")
688 if (3RDPARTY_NOT_INCLUDED)
689   message (FATAL_ERROR "Could not find headers of used third-party products: ${3RDPARTY_NOT_INCLUDED}" )
690 endif()
691
692 if (3RDPARTY_INCLUDE_DIRS)
693   list (REMOVE_DUPLICATES 3RDPARTY_INCLUDE_DIRS)
694   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_INCLUDE_DIRS_WITH_ENDS "${3RDPARTY_INCLUDE_DIRS}")
695   message (STATUS "Info: The directories of 3rdparty headers: \n\t${3RDPARTY_INCLUDE_DIRS_WITH_ENDS}")
696   include_directories (${3RDPARTY_INCLUDE_DIRS})
697 endif()
698
699 # include <cmake binary folder>/inc
700 include_directories (${CMAKE_BINARY_DIR}/${INSTALL_DIR_INCLUDE})
701
702 # check all 3rdparty library paths
703 string (REGEX REPLACE ";" " " 3RDPARTY_NO_LIBS "${3RDPARTY_NO_LIBS}")
704 if (3RDPARTY_NO_LIBS)
705   if (BUILD_SHARED_LIBS)
706     message (SEND_ERROR "Could not find libraries of used third-party products: ${3RDPARTY_NO_LIBS}" )
707   else()
708     message (WARNING "Could not find libraries of used third-party products: ${3RDPARTY_NO_LIBS}" )
709   endif()
710 endif()
711 if (3RDPARTY_LIBRARY_DIRS)
712   list (REMOVE_DUPLICATES 3RDPARTY_LIBRARY_DIRS)
713   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_LIBRARY_DIRS_WITH_ENDS "${3RDPARTY_LIBRARY_DIRS}")
714   message (STATUS "Info: The directories of 3rdparty libraries: \n\t${3RDPARTY_LIBRARY_DIRS_WITH_ENDS}")
715   link_directories (${3RDPARTY_LIBRARY_DIRS})
716 endif()
717
718 # report not found 3rdparty dll paths
719 string (REGEX REPLACE ";" " " 3RDPARTY_NO_DLLS "${3RDPARTY_NO_DLLS}")
720 if (3RDPARTY_NO_DLLS)
721   message (WARNING "Could not find DLLs of used third-party products: ${3RDPARTY_NO_DLLS}" )
722 endif()
723
724 # build directories
725 if (SINGLE_GENERATOR)
726   set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
727   set (CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
728   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
729   if (WIN32)
730     set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
731   endif()
732 endif()
733
734 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
735 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
736 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
737
738 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
739 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
740 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
741
742 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
743 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
744 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
745
746 if (WIN32) 
747   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE        "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
748   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
749   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG          "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
750 endif()
751
752 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
753 message (STATUS "\nInfo: \(${CURRENT_TIME}\) Start collecting all OCCT header files into ${CMAKE_BINARY_DIR}/inc ...")
754
755 # collect all the headers to <binary dir>/inc folder
756 COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}" "${BUILD_TOOLKITS}" "${CMAKE_SOURCE_DIR}/src" "${INSTALL_DIR_INCLUDE}")
757
758 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
759 message (STATUS "Info: \(${CURRENT_TIME}\) End the collecting")
760
761 list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
762 if (${DRAWEXE_INDEX} GREATER -1)
763   OCCT_INSTALL_FILE_OR_DIR ("data/" "${INSTALL_DIR_DATA}")
764   OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR_SAMPLES}")
765 endif()
766
767 if (WIN32)
768   set (SCRIPT_EXT bat)
769 else()
770   set (SCRIPT_EXT sh)
771 endif()
772
773 if (BUILD_Inspector OR BUILD_SAMPLES_QT)
774   # check qt 3rdparty path
775   add_definitions (-DHAVE_QT)
776   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/qt")
777   message (STATUS "Info: Qt is used by OCCT")
778 else()
779   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_QT")
780   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TQTMALLOC")
781   OCCT_CHECK_AND_UNSET ("INSTALL_QT")
782 endif()
783
784 # OCCT tools
785 # include the patched or original list of tools
786 # list <TOOLNAME>_TOOLKITS is created foreach tool and contains its toolkits
787 # list <OCCT_TOOLS> will contain all tools
788 if (BUILD_Inspector)
789   add_definitions (-DHAVE_Inspector)
790
791   OCCT_MODULES_AND_TOOLKITS (TOOLS "TOOL_TOOLKITS" OCCT_TOOLS)
792   foreach (OCCT_TOOL ${OCCT_TOOLS})
793     list (APPEND BUILD_TOOL_TOOLKITS ${${OCCT_TOOL}_TOOL_TOOLKITS})
794   endforeach()
795
796   # collect all the headers to <binary dir>/inc/inspector folder
797   string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
798   message (STATUS "\nInfo: \(${CURRENT_TIME}\) Start collecting all OCCT tool header files into ${CMAKE_BINARY_DIR}/inc/inspector ...")
799   COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}" "${BUILD_TOOL_TOOLKITS}" "${CMAKE_SOURCE_DIR}/tools" "${INSTALL_DIR_INCLUDE}/inspector")
800 endif()
801
802 # OCCT samples
803 # get absolute path from INSTALL_DIR
804 set (INSTALL_DIR_ABSOLUTE "${INSTALL_DIR}")
805 if(NOT IS_ABSOLUTE "${INSTALL_DIR_ABSOLUTE}")
806   get_filename_component(INSTALL_DIR_ABSOLUTE "${CMAKE_BINARY_DIR}/${INSTALL_DIR}" ABSOLUTE)
807 endif()
808
809 if (INSTALL_SAMPLES)
810   OCCT_CONFIGURE ("adm/templates/env.samples.${SCRIPT_EXT}.in" "env.samples.${SCRIPT_EXT}")
811   if (WIN32)
812     OCCT_INSTALL_FILE_OR_DIR ("samples/CSharp" "${INSTALL_DIR_SAMPLES}")
813     OCCT_INSTALL_FILE_OR_DIR ("samples/mfc" "${INSTALL_DIR_SAMPLES}")
814
815     if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
816       OCCT_INSTALL_FILE_OR_DIR ("samples/xaml" "${INSTALL_DIR_SAMPLES}")
817     endif()
818
819     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/CSharp" RENAME "env.${SCRIPT_EXT}")
820     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/mfc/standard" RENAME "env.${SCRIPT_EXT}")
821   endif()
822
823   OCCT_INSTALL_FILE_OR_DIR ("samples/java" "${INSTALL_DIR_SAMPLES}")
824   OCCT_INSTALL_FILE_OR_DIR ("samples/ocafsamples" "${INSTALL_DIR_SAMPLES}")
825   OCCT_INSTALL_FILE_OR_DIR ("samples/qt" "${INSTALL_DIR_SAMPLES}")
826
827   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/FuncDemo" RENAME "env.${SCRIPT_EXT}")
828   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/IESample" RENAME "env.${SCRIPT_EXT}")
829   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/Tutorial" RENAME "env.${SCRIPT_EXT}")
830 endif()
831
832 if (INSTALL_TEST_CASES)
833   OCCT_INSTALL_FILE_OR_DIR ("tests/" "${INSTALL_DIR_TESTS}")
834 endif()
835
836 list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
837 if (${DRAWEXE_INDEX} GREATER -1)
838   # copy data and samples/tcl folders to install script folder
839   OCCT_INSTALL_FILE_OR_DIR ("data/" "${INSTALL_DIR_DATA}")
840   OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR_SAMPLES}")
841
842   # copy draw script to install script folder
843   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}")
844     install (FILES "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
845             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
846   else()
847     install (FILES "${CMAKE_SOURCE_DIR}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
848             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
849   endif()
850
851   # copy draw script to CMake binary folder
852   OCCT_COPY_FILE_OR_DIR ("adm/templates/draw.${SCRIPT_EXT}" "${CMAKE_BINARY_DIR}")
853 endif()
854
855 set (SUB_CUSTOM_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.${SCRIPT_EXT}")
856
857 if (WIN32)
858   set (ADDITIONAL_CUSTOM_CONTENT "\nif exist \"%~dp0${SUB_CUSTOM_NAME}\" (\n  call \"%~dp0${SUB_CUSTOM_NAME}\" %1 %2 %3 \n)")
859 else()
860   set (ADDITIONAL_CUSTOM_CONTENT "\nif [ -e \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" ]; then\n  source \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" \"\$1\" \"\$2\" \nfi")
861 endif()
862
863  # change custom.bat/sh
864 if (EXISTS "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}")
865   file (READ "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" CUSTOM_CONTENT)
866
867   set (CUSTOM_CONTENT "${CUSTOM_CONTENT} ${ADDITIONAL_CUSTOM_CONTENT}")
868
869   file (WRITE "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" "${CUSTOM_CONTENT}")
870 else()
871   OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.${SCRIPT_EXT}.main" "custom.${SCRIPT_EXT}" "custom.${SCRIPT_EXT}" "${INSTALL_DIR_SCRIPT}")
872 endif()
873
874 if (WIN32)
875   set (THIRDPARTY_DIR_REPLACE "%THIRDPARTY_DIR%")
876 else()
877   set (THIRDPARTY_DIR_REPLACE "\${THIRDPARTY_DIR}")
878 endif()
879 get_cmake_property(USED_3RDPARTY_CACHE_VARIABLES VARIABLES)
880 string (REGEX MATCHALL "(^|;)USED_3RDPARTY_[^;]+_DIR[^;]*" USED_3RDPARTY_CACHE_VARIABLES "${USED_3RDPARTY_CACHE_VARIABLES}")
881 file (TO_CMAKE_PATH "${3RDPARTY_DIR}" 3RDPARTY_DIR)
882 foreach (USED_3RDPARTY_CACHE_VARIABLE ${USED_3RDPARTY_CACHE_VARIABLES})
883    file (TO_CMAKE_PATH "${${USED_3RDPARTY_CACHE_VARIABLE}}" ${USED_3RDPARTY_CACHE_VARIABLE})
884    string (REPLACE "${3RDPARTY_DIR}" "${THIRDPARTY_DIR_REPLACE}" ${USED_3RDPARTY_CACHE_VARIABLE} "${${USED_3RDPARTY_CACHE_VARIABLE}}")
885    if (NOT WIN32)
886      string (REGEX REPLACE ";" ":" ${USED_3RDPARTY_CACHE_VARIABLE} "${${USED_3RDPARTY_CACHE_VARIABLE}}")
887    endif()
888 endforeach()
889
890 # write current custom.bat/sh (for install directory)
891 set (SUB_CUSTOM_BUILD_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.install.${SCRIPT_EXT}")
892 OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.install.${SCRIPT_EXT}.in" "${SUB_CUSTOM_BUILD_NAME}" "${SUB_CUSTOM_NAME}" "${INSTALL_DIR_SCRIPT}")
893
894 # write current custom.bat/sh (for build directory)
895 OCCT_CONFIGURE ("adm/templates/custom.build.${SCRIPT_EXT}.in" "${SUB_CUSTOM_NAME}")
896
897 if (BUILD_SAMPLES_MFC OR BUILD_SAMPLES_QT)
898   OCCT_INSTALL_FILE_OR_DIR ("adm/templates/sample.${SCRIPT_EXT}" "${INSTALL_DIR_SCRIPT}")
899   OCCT_COPY_FILE_OR_DIR    ("adm/templates/sample.${SCRIPT_EXT}" "${CMAKE_BINARY_DIR}")
900 endif()
901
902 if (WIN32)
903   # env script for draw in building environment
904   OCCT_CONFIGURE ("adm/templates/env.${SCRIPT_EXT}.in" "env.${SCRIPT_EXT}")
905   # install env script
906   install (FILES "${CMAKE_BINARY_DIR}/env.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SCRIPT}")
907 else()
908   set (SUB_ENV_NAME "env.${SCRIPT_EXT}")
909   set (SUB_ENV_BUILD_NAME "env.install.${SCRIPT_EXT}")
910   # install env script
911   OCCT_CONFIGURE_AND_INSTALL ("adm/templates/env.install.${SCRIPT_EXT}.in" "${SUB_ENV_BUILD_NAME}" "${SUB_ENV_NAME}" "${INSTALL_DIR_SCRIPT}")
912   # env script for draw in building environment
913   OCCT_CONFIGURE ("adm/templates/env.build.${SCRIPT_EXT}.in" "env.${SCRIPT_EXT}")
914 endif()
915
916 # copy DrawAppliInit from OCCT source to build directory
917 if (NOT EXISTS "${CMAKE_BINARY_DIR}/DrawAppliInit")
918   OCCT_COPY_FILE_OR_DIR (DrawAppliInit "${CMAKE_BINARY_DIR}")
919 endif()
920
921 # RESOURCES
922 FILE_TO_LIST ("adm/RESOURCES" RESOURCES)
923 foreach(RESOURCE ${RESOURCES})
924   get_filename_component(RESOURCE_FOLDER ${RESOURCE} DIRECTORY)
925   if(NOT "${RESOURCE_FOLDER}" STREQUAL "")
926     get_filename_component(RESOURCE_FOLDER ${RESOURCE_FOLDER} NAME)
927     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR_RESOURCE}/${RESOURCE_FOLDER}")
928   else()
929     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR_RESOURCE}")
930   endif()
931 endforeach()
932
933 if (BUILD_SAMPLES_QT)
934   FILE_TO_LIST ("adm/SAMPLES_RESOURCES" SAMPLES_RESOURCES)
935   foreach(RESOURCE ${SAMPLES_RESOURCES})
936     OCCT_INSTALL_FILE_OR_DIR ("samples/${RESOURCE}" "${INSTALL_DIR_RESOURCE}/samples")
937     #message("Copy Sample resources: samples/${RESOURCE} into ${INSTALL_DIR_RESOURCE}/samples")
938   endforeach()
939 endif()
940
941
942 # patch installed DrawDefault file if BUILD_SHARED_LIBRARY_NAME_POSTFIX is changed
943 if (NOT "${BUILD_SHARED_LIBRARY_NAME_POSTFIX}" STREQUAL "")
944   OCCT_UPDATE_DRAW_DEFAULT_FILE()
945 endif()
946
947 # include patched toolkit projects or original ones
948 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
949   OCCT_ADD_SUBDIRECTORY ("src/${BUILD_TOOLKIT}")
950 endforeach()
951
952 if (BUILD_DOC_Overview)
953   OCCT_ADD_SUBDIRECTORY (dox)
954 endif()
955
956 # patch DRAWEXE
957 if (MSVC AND 3RDPARTY_DLL_DIRS)
958   list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
959   if (${DRAWEXE_INDEX} GREATER -1)
960     list (REMOVE_DUPLICATES 3RDPARTY_DLL_DIRS)
961     set (3RDPARTY_DLL_DIRS_FOR_PATH "")
962
963     foreach (3RDPARTY_DLL_DIR ${3RDPARTY_DLL_DIRS})
964       set (3RDPARTY_DLL_DIRS_FOR_PATH "${3RDPARTY_DLL_DIRS_FOR_PATH};${3RDPARTY_DLL_DIR}")
965     endforeach()
966
967     OCCT_MAKE_COMPILER_BITNESS()
968     set (X_COMPILER_BITNESS "x64")
969     if ("${COMPILER_BITNESS}" STREQUAL "32")
970       set (X_COMPILER_BITNESS "Win32")
971     endif()
972
973     OCCT_CONFIGURE ("adm/templates/DRAWEXE.vcxproj.user.in" "${CMAKE_BINARY_DIR}/src/DRAWEXE/DRAWEXE.vcxproj.user")
974   endif()
975 endif()
976
977 # include patched toolkit projects or original ones
978 if (BUILD_TOOL_TOOLKITS)
979   foreach (BUILD_TOOL_TOOLKIT ${BUILD_TOOL_TOOLKITS})
980     OCCT_ADD_SUBDIRECTORY ("tools/${BUILD_TOOL_TOOLKIT}")
981   endforeach()
982 endif()
983
984 message (STATUS "Info: \(${CURRENT_TIME}\) OCCT toolkits processed")
985 # samples do not support patch usage
986 if (BUILD_SAMPLES_MFC OR BUILD_SAMPLES_QT)
987   set (OCCT_ROOT ${CMAKE_SOURCE_DIR})
988 endif()
989
990 if (BUILD_SAMPLES_MFC)
991   set (MFC_STANDARD_SAMPLES_DIR ${OCCT_ROOT}/samples/mfc/standard)
992   set (COMMON_WINMAIN_FILE      ${MFC_STANDARD_SAMPLES_DIR}/Common/Winmain.cpp)
993
994   add_subdirectory(samples/mfc/standard/mfcsample)
995   add_subdirectory(samples/mfc/standard/01_Geometry)
996   add_subdirectory(samples/mfc/standard/02_Modeling)
997   add_subdirectory(samples/mfc/standard/03_Viewer2d)
998   add_subdirectory(samples/mfc/standard/04_Viewer3d)
999   add_subdirectory(samples/mfc/standard/05_ImportExport)
1000   add_subdirectory(samples/mfc/standard/06_Ocaf)
1001   add_subdirectory(samples/mfc/standard/07_Triangulation)
1002   add_subdirectory(samples/mfc/standard/08_HLR)
1003   add_subdirectory(samples/mfc/standard/09_Animation)
1004   add_subdirectory(samples/mfc/standard/10_Convert)
1005
1006   message (STATUS "Info: \(${CURRENT_TIME}\) MFC Sample projects added")
1007 endif()
1008
1009 OCCT_MODULES_AND_TOOLKITS (SAMPLES "SAMPLES_TOOLKITS" OCCT_SAMPLES)
1010
1011 if (BUILD_Inspector OR BUILD_SAMPLES_QT)
1012   if (BUILD_SAMPLES_QT)
1013     if (NOT Qt5_FOUND OR "${Qt5Gui_EGL_INCLUDE_DIRS}" STREQUAL "" OR NOT WIN32)
1014       list (REMOVE_ITEM qt_SAMPLES_TOOLKITS AndroidQt)
1015       message (STATUS "Info: AndroidQt sample excluded due to OS is not Windows or Qt is configured without ANGLE")
1016     endif()
1017   else()
1018     list (REMOVE_ITEM OCCT_SAMPLES qt)
1019     message (STATUS "Info: qt samples excluded due to BUILD_SAMPLES_QT is disabled")
1020   endif()
1021
1022   foreach (OCCT_SAMPLE ${OCCT_SAMPLES})
1023     list (APPEND BUILD_SAMPLE_TOOLKITS ${${OCCT_SAMPLE}_SAMPLES_TOOLKITS})
1024
1025     # collect all the headers to <binary dir>/inc/samples folder
1026     string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
1027     message (STATUS "Info: \(${CURRENT_TIME}\) ${OCCT_SAMPLE} Sample projects added")
1028
1029     # include patched toolkit projects or original ones
1030     foreach (BUILD_SAMPLE_TOOLKIT ${${OCCT_SAMPLE}_SAMPLES_TOOLKITS})
1031       OCCT_ADD_SUBDIRECTORY ("samples/${OCCT_SAMPLE}/${BUILD_SAMPLE_TOOLKIT}")
1032     endforeach()
1033   endforeach()
1034 endif()
1035
1036 if (BUILD_MODULE_UwpSample)
1037   add_subdirectory(samples/xaml)
1038 endif()
1039
1040 if (BUILD_TOOL_TOOLKITS)
1041   # copy tinspector script to install script folder
1042   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/adm/templates/inspector.${SCRIPT_EXT}")
1043     install (FILES "${BUILD_PATCH}/adm/templates/inspector.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
1044             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
1045   else()
1046     install (FILES "${CMAKE_SOURCE_DIR}/adm/templates/inspector.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
1047             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
1048   endif()
1049
1050   set (OpenCASCADE_BINARY_DIR "${INSTALL_DIR}/${INSTALL_DIR_BIN}")
1051   # patch TInspectorEXE
1052   OCCT_CONFIGURE ("adm/templates/TInspectorEXE.vcxproj.user.in" "${CMAKE_BINARY_DIR}/tools/TInspectorEXE/TInspectorEXE.vcxproj.user")
1053 endif()
1054
1055 # Prepare variables for configuration of OpenCASCADE cmake config file
1056 set (OCCT_MODULES_ENABLED)
1057 set (OCCT_LIBRARIES)
1058 set (SET_OpenCASCADE_MODULES_TOOLKITS "\n# List of available OpenCASCADE libraries for each module\n")
1059 set (OCCT_COMPILE_DEFINITIONS)
1060
1061 foreach (OCCT_TOOLKIT ${BUILD_TOOLKITS})
1062   if (TARGET ${OCCT_TOOLKIT})
1063
1064     # get all libraries
1065     get_target_property (${OCCT_TOOLKIT}_TYPE ${OCCT_TOOLKIT} "TYPE")
1066     if ("${${OCCT_TOOLKIT}_TYPE}" STREQUAL "STATIC_LIBRARY" OR "${${OCCT_TOOLKIT}_TYPE}" STREQUAL "SHARED_LIBRARY" )
1067       list (APPEND OCCT_LIBRARIES ${OCCT_TOOLKIT})
1068
1069       # get all modules
1070       get_target_property (${OCCT_TOOLKIT}_MODULE ${OCCT_TOOLKIT} "MODULE")
1071       list (APPEND OCCT_MODULES_ENABLED ${${OCCT_TOOLKIT}_MODULE})
1072       list (APPEND OpenCASCADE_${${OCCT_TOOLKIT}_MODULE}_TOOLKITS ${OCCT_TOOLKIT})
1073
1074       # get compile definitions of target directory
1075       get_directory_property (COMPILE_DEFINITIONS DIRECTORY "${${OCCT_TOOLKIT}_SOURCE_DIR}" "COMPILE_DEFINITIONS")
1076       list (APPEND OCCT_COMPILE_DEFINITIONS ${COMPILE_DEFINITIONS})
1077     endif()
1078   endif()
1079 endforeach()
1080 list (REMOVE_DUPLICATES OCCT_MODULES_ENABLED)
1081 list (REMOVE_DUPLICATES OCCT_COMPILE_DEFINITIONS)
1082
1083 # export compile definitions and C/C++ flags for each configuration to OpenCASCADE config files
1084 foreach (OCCT_CONFIGURATION ${CMAKE_CONFIGURATION_TYPES})
1085   set (SET_OpenCASCADE_COMPILE_DEFINITIONS)
1086   string (TOUPPER "${OCCT_CONFIGURATION}" OCCT_CONFIGURATION_UPPER)
1087   string (TOLOWER "${OCCT_CONFIGURATION}" OCCT_CONFIGURATION_LOWER)
1088   foreach(COMPILE_DEFINITION ${OCCT_COMPILE_DEFINITIONS})
1089     string(REPLACE "(" "\\(" COMPILE_DEFINITION "${COMPILE_DEFINITION}")
1090     string(REPLACE ")" "\\)" COMPILE_DEFINITION "${COMPILE_DEFINITION}")
1091     set (SET_OpenCASCADE_COMPILE_DEFINITIONS "${SET_OpenCASCADE_COMPILE_DEFINITIONS}set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:${OCCT_CONFIGURATION}>:${COMPILE_DEFINITION}>)\n")
1092   endforeach()
1093   set (SET_OpenCASCADE_CMAKE_C_FLAGS "${CMAKE_C_FLAGS_${OCCT_CONFIGURATION_UPPER}}")
1094   set (SET_OpenCASCADE_CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS_${OCCT_CONFIGURATION_UPPER}}")
1095   configure_file("${CMAKE_SOURCE_DIR}/adm/templates/OpenCASCADECompileDefinitionsAndFlags.cmake.in" "OpenCASCADECompileDefinitionsAndFlags-${OCCT_CONFIGURATION_LOWER}.cmake" @ONLY)
1096 endforeach()
1097 # install OpenCASCADE config file with compile definitions and C/C++ flags ONLY for current configuration
1098 install (CODE "string (TOLOWER \"\${CMAKE_INSTALL_CONFIG_NAME}\" CMAKE_INSTALL_CONFIG_NAME_LOWER)")
1099 install (CODE "configure_file(\"${CMAKE_BINARY_DIR}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" \"${INSTALL_DIR}/${INSTALL_DIR_CMAKE}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" COPYONLY)")
1100
1101 foreach (OCCT_MODULE ${OCCT_MODULES})
1102   if (BUILD_MODULE_${OCCT_MODULE})
1103     set (SET_OpenCASCADE_MODULES_TOOLKITS "${SET_OpenCASCADE_MODULES_TOOLKITS}set (OpenCASCADE_${OCCT_MODULE}_LIBRARIES ${OpenCASCADE_${OCCT_MODULE}_TOOLKITS})\n")
1104   endif()
1105
1106   # sort enabled modules for correct work of OpenCASCADE config file
1107   list(FIND OCCT_MODULES_ENABLED "${OCCT_MODULE}" OCCT_MODULE_INDEX)
1108   if (NOT ${OCCT_MODULE_INDEX} EQUAL -1)
1109     list (APPEND OCCT_MODULES_ENABLED_SORTED ${OCCT_MODULE})
1110   endif()
1111 endforeach()
1112 set (OCCT_MODULES_ENABLED ${OCCT_MODULES_ENABLED_SORTED})
1113
1114 # Add all targets to the build-tree export set
1115 export (TARGETS ${OCCT_LIBRARIES} FILE "${CMAKE_BINARY_DIR}/OpenCASCADETargets.cmake")
1116
1117 # Export the package for use from the build-tree
1118 # (this registers the build-tree with a global CMake-registry)
1119 export(PACKAGE OpenCASCADE)
1120
1121 if (CMAKE_BUILD_TYPE)
1122   set (SET_OpenCASCADE_BUILD_TYPE "set (OpenCASCADE_BUILD_TYPE        \"${CMAKE_BUILD_TYPE}\")")
1123 endif()
1124
1125 if (BUILD_SHARED_LIBS)
1126   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_SHARED_LINKER_FLAGS}\")")
1127 else()
1128   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_STATIC_LINKER_FLAGS}\")")
1129 endif()
1130
1131 if (WIN32)
1132   set (SET_OpenCASCADE_WITH_D3D "set (OpenCASCADE_WITH_D3D       ${USE_D3D})")
1133 endif()
1134 if (APPLE)
1135   set (SET_OpenCASCADE_WITH_GLX "set (OpenCASCADE_WITH_GLX       ${USE_GLX})")
1136 endif()
1137
1138 # Configure and install cmake config file
1139 configure_file("${CMAKE_SOURCE_DIR}/adm/templates/OpenCASCADEConfig.cmake.in" "OpenCASCADEConfig.cmake" @ONLY)
1140 install(FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfig.cmake" DESTINATION  "${INSTALL_DIR_CMAKE}")
1141
1142 # Configure cmake version file
1143 include(CMakePackageConfigHelpers)
1144 write_basic_package_version_file( ${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake
1145                                   VERSION ${OCC_VERSION_MAJOR}.${OCC_VERSION_MINOR}.${OCC_VERSION_MAINTENANCE}
1146                                   COMPATIBILITY ExactVersion )
1147
1148 # Install cmake version file
1149 install (FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake" DESTINATION "${INSTALL_DIR_CMAKE}")
1150
1151 # Install the export set for use with the install-tree for each configuration
1152 foreach (OCCT_MODULE ${OCCT_MODULES_ENABLED})
1153   install(EXPORT OpenCASCADE${OCCT_MODULE}Targets DESTINATION "${INSTALL_DIR_CMAKE}")
1154 endforeach()
1155
1156 # Update generated OpenCASCADETargets-*.cmake files 
1157 # to have correct paths to libraries depending on the configuration
1158 OCCT_UPDATE_TARGET_FILE ()
1159
1160 message (STATUS "Info: \(${CURRENT_TIME}\) OCCT configuration files prepared")