CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.12 FATAL_ERROR)
   2
   3 set (CMAKE_SUPPRESS_REGENERATION TRUE)
   4
   5 set (CMAKE_CONFIGURATION_TYPES Release Debug RelWithDebInfo CACHE INTERNAL "" FORCE)
   6
   7 # macro: include patched file if it exists
   8 macro (OCCT_INCLUDE_CMAKE_FILE BEING_INCLUDED_FILE)
   9   if (APPLY_OCCT_PATCH_DIR AND EXISTS "${APPLY_OCCT_PATCH_DIR}/${BEING_INCLUDED_FILE}.cmake")
  10     include (${APPLY_OCCT_PATCH_DIR}/${BEING_INCLUDED_FILE}.cmake)
  11   else()
  12     include (${CMAKE_SOURCE_DIR}/${BEING_INCLUDED_FILE}.cmake)
  13   endif()
  14 endmacro()
  15
  16 # include variable description
  17 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vardescr")
  18
  19 # set type of OCCT libraries
  20 if (NOT BUILD_LIBRARY_TYPE)
  21   set (BUILD_LIBRARY_TYPE "Shared" CACHE STRING "${BUILD_LIBRARY_TYPE_DESCR}" FORCE)
  22   SET_PROPERTY(CACHE BUILD_LIBRARY_TYPE PROPERTY STRINGS Shared Static)
  23 endif()
  24
  25 if ("${BUILD_LIBRARY_TYPE}" STREQUAL "Shared")
  26   set (BUILD_SHARED_LIBS ON)
  27 else()
  28   unset (BUILD_SHARED_LIBS)
  29 endif()
  30
  31 # the name of the project
  32 project (OCCT)
  33
  34 # Solution folder property
  35 set_property (GLOBAL PROPERTY USE_FOLDERS ON)
  36
  37 set (INSTALL_OCCT_TEST_CASES OFF CACHE BOOL "${INSTALL_OCCT_TEST_CASES_DESCR}")
  38 # a single-configuration generator like the Makefile generator defines CMAKE_BUILD_TYPE variable
  39 # check this variable and set if it's required
  40 if (DEFINED CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE) # single-configuration generator.
  41   set (CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel." FORCE)
  42 endif()
  43
  44 # enable extended messages of many OCCT algorithms
  45 set (OCCT_ALGO_EXTENDED_OUTPUT OFF CACHE BOOL "${OCCT_ALGO_EXTENDED_OUTPUT_DESCR}")
  46 if (OCCT_ALGO_EXTENDED_OUTPUT)
  47   add_definitions (-DOCCT_DEBUG)
  48 endif()
  49
  50 # copy samples to install directory
  51 set (INSTALL_OCCT_SAMPLES OFF CACHE BOOL "${INSTALL_OCCT_SAMPLES_DESCR}")
  52
  53 # install dir of the built project
  54 set (INSTALL_DIR "" CACHE PATH "${INSTALL_DIR_DESCR}" )
  55 set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE )
  56
  57 set (APPLY_OCCT_PATCH_DIR "" CACHE PATH "${APPLY_OCCT_PATCH_DIR_DESCR}")
  58
  59 # the list of being built toolkits
  60 set (BUILD_ADDITIONAL_TOOLKITS "" CACHE STRING "${BUILD_ADDITIONAL_TOOLKITS_DESCR}")
  61 separate_arguments (BUILD_ADDITIONAL_TOOLKITS)
  62
  63 if (MSVC)
  64   set (BUILD_MODULE_OcctMfcSamples OFF CACHE BOOL "${BUILD_MODULE_OcctMfcSamples_DESCR}")
  65 endif()
  66
  67 # whether use optional 3rdparty or not
  68 if (APPLE)
  69   set (USE_GLX OFF CACHE BOOL "${USE_GLX_DESCR}")
  70 endif()
  71 if (WIN32)
  72   set (USE_D3D OFF CACHE BOOL "${USE_D3D_DESCR}")
  73 endif()
  74
  75 set (USE_VTK OFF CACHE BOOL "${USE_VTK_DESCR}")
  76
  77 # include occt macros
  78 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_macros")
  79
  80 # include the patched or original list of modules
  81 # list <MODULENAME>_TOOLKITS is created foreach module and contains its toolkits
  82 # list <OCCT_MODULES> will contain all modules
  83 OCCT_MODULES_AND_TOOLKITS (OCCT_MODULES)
  84
  85 foreach (OCCT_MODULE ${OCCT_MODULES})
  86   BUILD_MODULE (${OCCT_MODULE})
  87 endforeach()
  88
  89 # Overview
  90 set (BUILD_DOC_OcctOverview OFF CACHE BOOL "${BUILD_DOC_OcctOverview_DESCR}")
  91
  92 if (NOT USE_VTK)
  93   list (REMOVE_ITEM Visualization_TOOLKITS TKIVtk)
  94   list (REMOVE_ITEM Draw_TOOLKITS TKIVtkDraw)
  95 endif()
  96
  97 if (NOT USE_D3D)
  98   list (REMOVE_ITEM Visualization_TOOLKITS TKD3DHost)
  99 endif()
 100
 101 # accumulate used toolkits (first level) in BUILD_TOOLKITS variable
 102 list (APPEND BUILD_TOOLKITS ${BUILD_ADDITIONAL_TOOLKITS})
 103
 104 foreach (OCCT_MODULE ${OCCT_MODULES})
 105   if (BUILD_MODULE_${OCCT_MODULE})
 106     list (APPEND BUILD_TOOLKITS ${${OCCT_MODULE}_TOOLKITS})
 107   endif()
 108 endforeach()
 109
 110 # DRAWEXE excluded when library build is static
 111 if (NOT BUILD_SHARED_LIBS)
 112   list (REMOVE_ITEM BUILD_TOOLKITS DRAWEXE)
 113   message (STATUS "Info: DRAWEXE is not included due to ${BUILD_LIBRARY_TYPE} build library type")
 114 endif()
 115
 116 # accumulate all used toolkits
 117 list (REMOVE_DUPLICATES BUILD_TOOLKITS)
 118 set (RAW_BUILD_TOOLKITS)
 119 foreach(BUILD_TOOLKIT ${BUILD_TOOLKITS})
 120   OCCT_TOOLKIT_FULL_DEP (${BUILD_TOOLKIT} TOOLKIT_FULL_DEPS)
 121   list (APPEND RAW_BUILD_TOOLKITS ${BUILD_TOOLKIT} ${TOOLKIT_FULL_DEPS})
 122 endforeach()
 123
 124 list (REMOVE_DUPLICATES RAW_BUILD_TOOLKITS)
 125 set (BUILD_TOOLKITS ${RAW_BUILD_TOOLKITS})
 126
 127 # include the patched or original list of definitions and flags
 128 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_defs_flags")
 129
 130 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/3rdparty_macro")
 131
 132 # Rebuild *.yacc and *.lex files that are contained by TKMath toolkit
 133 list (FIND BUILD_TOOLKITS TKMath   CAN_REBUILD_PDC_FOR_TKMATH)
 134 list (FIND BUILD_TOOLKITS StepFile CAN_REBUILD_PDC_FOR_STEPFILE)
 135
 136 if (NOT "${CAN_REBUILD_PDC_FOR_TKMATH}" STREQUAL "-1" OR NOT "${CAN_REBUILD_PDC_FOR_STEPFILE}" STREQUAL "-1")
 137   set (REBUILD_PLATFORM_DEPENDENT_CODE OFF CACHE BOOL "${REBUILD_PLATFORM_DEPENDENT_CODE_DESCR}")
 138 else()
 139   OCCT_CHECK_AND_UNSET (REBUILD_PLATFORM_DEPENDENT_CODE)
 140 endif()
 141
 142 if (NOT DEFINED 3RDPARTY_DIR)
 143   set (3RDPARTY_DIR "" CACHE PATH ${3RDPARTY_DIR_DESCR})
 144 endif()
 145
 146 # search for 3rdparty dir
 147 if ("${3RDPARTY_DIR}" STREQUAL "")
 148   if (DEFINED ENV{3RDPARTY_DIR})
 149     set (3RDPARTY_DIR "$ENV{3RDPARTY_DIR}" CACHE PATH ${3RDPARTY_DIR_DESCR} FORCE)
 150   elseif (EXISTS "${CMAKE_SOURCE_DIR}/../")
 151     # in version 6.7.0 and above, occt parent directory contains 3rdparties
 152     get_filename_component (3RDPARTY_DIR "${CMAKE_SOURCE_DIR}/../" ABSOLUTE)
 153     set (3RDPARTY_DIR "${3RDPARTY_DIR}" CACHE PATH ${3RDPARTY_DIR_DESCR} FORCE)
 154   endif()
 155 endif()
 156
 157 # search for CSF_TclLibs variable in EXTERNLIB of each being used toolkit
 158 OCCT_IS_PRODUCT_REQUIRED (CSF_TclLibs USE_TCL)
 159
 160 if ("${USE_TCL}" STREQUAL ON)
 161   message (STATUS "Info: TCL is used by OCCT")
 162   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tcl")
 163 else()
 164   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TCL")
 165   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TK")
 166
 167   OCCT_CHECK_AND_UNSET ("INSTALL_TCL")
 168 endif()
 169
 170 # search for CSF_FREETYPE variable in EXTERNLIB of each being used toolkit
 171 OCCT_IS_PRODUCT_REQUIRED (CSF_FREETYPE USE_FREETYPE)
 172
 173 if ("${USE_FREETYPE}" STREQUAL ON)
 174   message (STATUS "Info: Freetype is used by OCCT")
 175   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freetype")
 176 else()
 177   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREETYPE")
 178   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2")
 179   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build")
 180   OCCT_CHECK_AND_UNSET ("INSTALL_FREETYPE")
 181 endif()
 182
 183 # VTK
 184 if (USE_VTK)
 185   add_definitions (-DHAVE_VTK)
 186   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vtk")
 187 else()
 188   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_VTK")
 189   OCCT_CHECK_AND_UNSET ("INSTALL_VTK")
 190 endif()
 191
 192 # D3D
 193 if (USE_D3D)
 194   add_definitions (-DHAVE_D3D)
 195   #if(MSVC_VERSION LESS 1700)
 196   #OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/d3d")
 197   #endif()
 198 endif()
 199
 200 # GLX
 201 if (USE_GLX)
 202   add_definitions (-DMACOSX_USE_GLX)
 203   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/glx")
 204 endif()
 205
 206 # FREEIMAGE
 207 # search for CSF_FREEIMAGE variable in EXTERNLIB of each being used toolkit
 208 OCCT_IS_PRODUCT_REQUIRED (CSF_FREEIMAGE     CAN_USE_FREEIMAGE)
 209 OCCT_IS_PRODUCT_REQUIRED (CSF_FreeImagePlus CAN_USE_FREEIMAGEPLUS)
 210
 211 if (CAN_USE_FREEIMAGE OR CAN_USE_FREEIMAGEPLUS)
 212   set (USE_FREEIMAGE OFF CACHE BOOL "${USE_FREEIMAGE_DESCR}")
 213
 214   if (USE_FREEIMAGE)
 215     add_definitions (-DHAVE_FREEIMAGE)
 216     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimage")
 217     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimageplus")
 218   else()
 219     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
 220     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGEPLUS")
 221     OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
 222     OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGEPLUS")
 223   endif()
 224 else()
 225   OCCT_CHECK_AND_UNSET ("USE_FREEIMAGE")
 226
 227   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
 228   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGEPLUS")
 229   OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
 230   OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGEPLUS")
 231 endif()
 232
 233 # GL2PS
 234 # search for CSF_GL2PS variable in EXTERNLIB of each being used toolkit
 235 OCCT_IS_PRODUCT_REQUIRED (CSF_GL2PS CAN_USE_GL2PS)
 236
 237 if (NOT DEFINED ANDROID AND CAN_USE_GL2PS)
 238   set (USE_GL2PS OFF CACHE BOOL "${USE_GL2PS_DESCR}")
 239
 240   if (USE_GL2PS)
 241     add_definitions (-DHAVE_GL2PS)
 242     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gl2ps")
 243   else()
 244     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
 245     OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
 246   endif()
 247 else()
 248   OCCT_CHECK_AND_UNSET ("USE_GL2PS")
 249
 250   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
 251   OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
 252 endif()
 253
 254 # TBB
 255 # search for CSF_TBB variable in EXTERNLIB of each being used toolkit
 256 OCCT_IS_PRODUCT_REQUIRED (CSF_TBB CAN_USE_TBB)
 257
 258 if (NOT DEFINED ANDROID AND CAN_USE_TBB)
 259   set (USE_TBB OFF CACHE BOOL "${USE_TBB_DESCR}")
 260
 261   if (USE_TBB)
 262     add_definitions (-DHAVE_TBB)
 263     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tbb")
 264   else()
 265     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
 266     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
 267     OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
 268   endif()
 269 else()
 270   OCCT_CHECK_AND_UNSET ("USE_TBB")
 271
 272   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
 273   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
 274   OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
 275 endif()
 276
 277 # Doxygen
 278 if (BUILD_DOC_OcctOverview)
 279   if (NOT DEFINED INSTALL_DOC_OcctOverview)
 280     set (INSTALL_DOC_OcctOverview OFF CACHE BOOL "${INSTALL_DOC_OcctOverview_DESCR}")
 281   endif()
 282
 283   if (INSTALL_DOC_OcctOverview)
 284     install (DIRECTORY "${CMAKE_BINARY_DIR}/doc/overview" DESTINATION  "${INSTALL_DIR}/doc")
 285
 286     OCCT_INSTALL_FILE_OR_DIR ("dox/resources/overview.html" "${INSTALL_DIR}")
 287   endif()
 288
 289   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
 290 else()
 291   OCCT_CHECK_AND_UNSET ("INSTALL_DOC_OcctOverview")
 292
 293   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOXYGEN_EXECUTABLE")
 294   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOXYGEN_DOT_EXECUTABLE")
 295 endif()
 296
 297 # bison
 298 if (REBUILD_PLATFORM_DEPENDENT_CODE)
 299   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/bison")
 300 else()
 301   OCCT_CHECK_AND_UNSET ("3RDPARTY_BISON_EXECUTABLE")
 302 endif()
 303
 304 # flex
 305 if (REBUILD_PLATFORM_DEPENDENT_CODE)
 306   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/flex")
 307 else()
 308   OCCT_CHECK_AND_UNSET ("3RDPARTY_FLEX_EXECUTABLE")
 309 endif()
 310
 311 string (REGEX REPLACE ";" " " 3RDPARTY_NOT_INCLUDED "${3RDPARTY_NOT_INCLUDED}")
 312
 313 # check all 3rdparty paths
 314 if (3RDPARTY_NOT_INCLUDED)
 315   message (FATAL_ERROR "NOT FOUND: ${3RDPARTY_NOT_INCLUDED}" )
 316 endif()
 317
 318 if (3RDPARTY_INCLUDE_DIRS)
 319   list (REMOVE_DUPLICATES 3RDPARTY_INCLUDE_DIRS)
 320   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_INCLUDE_DIRS_WITH_ENDS "${3RDPARTY_INCLUDE_DIRS}")
 321   message (STATUS "The directories containing 3rdparty headers: ${3RDPARTY_INCLUDE_DIRS_WITH_ENDS}")
 322   include_directories (${3RDPARTY_INCLUDE_DIRS})
 323 endif()
 324
 325 # include <cmake binary folder>/inc
 326 include_directories (${CMAKE_BINARY_DIR}/inc)
 327
 328 if (3RDPARTY_LIBRARY_DIRS)
 329   list (REMOVE_DUPLICATES 3RDPARTY_LIBRARY_DIRS)
 330   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_LIBRARY_DIRS_WITH_ENDS "${3RDPARTY_LIBRARY_DIRS}")
 331   message (STATUS "The directories containing 3rdparty libraries: ${3RDPARTY_LIBRARY_DIRS_WITH_ENDS}")
 332   link_directories (${3RDPARTY_LIBRARY_DIRS})
 333 endif()
 334
 335 # Get all used variables: OS_WITH_BIT, COMPILER
 336 OCCT_MAKE_OS_WITH_BITNESS()
 337 OCCT_MAKE_COMPILER_SHORT_NAME()
 338
 339 # build directories
 340 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
 341 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
 342 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
 343
 344 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
 345 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
 346 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
 347
 348 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
 349 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
 350 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
 351
 352 if (WIN32)
 353   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE        "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
 354   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
 355   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG          "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
 356 endif()
 357
 358 if ("${INSTALL_DIR}" STREQUAL "")
 359   get_filename_component (CMAKE_BINARY_DIR_PARENT ${CMAKE_BINARY_DIR} DIRECTORY)
 360
 361   set (INSTALL_DIR "${CMAKE_BINARY_DIR_PARENT}/install" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
 362   set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE )
 363
 364   message (STATUS "Info: INSTALL_DIR has been set as ${INSTALL_DIR}")
 365 endif()
 366
 367 message (STATUS "\nInfo: Collecting all OCCT header files into ${CMAKE_BINARY_DIR}/inc ...")
 368
 369 # collect all the headers to <binary dir>/inc folder
 370 COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}" "${BUILD_TOOLKITS}")
 371
 372 OCCT_INSTALL_FILE_OR_DIR ("data" "${INSTALL_DIR}")
 373 OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR}/samples")
 374
 375 if (INSTALL_OCCT_SAMPLES)
 376   OCCT_INSTALL_FILE_OR_DIR ("samples" "${INSTALL_DIR}")
 377 endif()
 378
 379 if (INSTALL_OCCT_TEST_CASES)
 380   OCCT_INSTALL_FILE_OR_DIR ("tests" "${INSTALL_DIR}")
 381 endif()
 382
 383 if (WIN32)
 384   set (SCRIPT_EXT bat)
 385 else()
 386   set (SCRIPT_EXT sh)
 387 endif()
 388
 389 # DRAW.BAT or DRAW.SH
 390 if (APPLY_OCCT_PATCH_DIR AND EXISTS "${APPLY_OCCT_PATCH_DIR}/adm/templates/draw.${SCRIPT_EXT}")
 391   install (FILES "${APPLY_OCCT_PATCH_DIR}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR}" PERMISSIONS
 392           OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
 393 else()
 394   install (FILES "${CMAKE_SOURCE_DIR}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR}" PERMISSIONS
 395           OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
 396 endif()
 397 OCCT_COPY_FILE_OR_DIR ("adm/templates/draw.${SCRIPT_EXT}" "${CMAKE_BINARY_DIR}")
 398
 399 set (SUB_CUSTOM_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.${SCRIPT_EXT}")
 400
 401 if (WIN32)
 402   set (ADDITIONAL_CUSTOM_CONTENT "\nif exist \"%~dp0${SUB_CUSTOM_NAME}\" (\n  call \"%~dp0${SUB_CUSTOM_NAME}\" %VCVER% %ARCH% %CASDEB% \n)")
 403 else()
 404   set (ADDITIONAL_CUSTOM_CONTENT "\nif [ -e \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" ]; then\n  source \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" \"\${COMPILER}\" \"\${WOKSTATION}\${ARCH}\" \"\${CASDEB}\" \nfi")
 405 endif()
 406
 407  # change custom.bat/sh
 408 if (EXISTS "${INSTALL_DIR}/custom.${SCRIPT_EXT}")
 409   file (READ "${INSTALL_DIR}/custom.${SCRIPT_EXT}" CUSTOM_CONTENT)
 410
 411   set (CUSTOM_CONTENT "${CUSTOM_CONTENT} ${ADDITIONAL_CUSTOM_CONTENT}")
 412
 413   file (WRITE "${INSTALL_DIR}/custom.${SCRIPT_EXT}" "${CUSTOM_CONTENT}")
 414 else()
 415   OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.${SCRIPT_EXT}.main" "custom.${SCRIPT_EXT}" "custom.${SCRIPT_EXT}" "${INSTALL_DIR}")
 416 endif()
 417
 418 # write current custom.bat/sh (for install directory)
 419 set (SUB_CUSTOM_BUILD_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.install.${SCRIPT_EXT}")
 420 OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.install.${SCRIPT_EXT}.in" "${SUB_CUSTOM_BUILD_NAME}" "${SUB_CUSTOM_NAME}" "${INSTALL_DIR}")
 421
 422 # write current custom.bat/sh (for build directory)
 423 OCCT_CONFIGURE ("adm/templates/custom.build.${SCRIPT_EXT}.in" "${SUB_CUSTOM_NAME}")
 424
 425 if (BUILD_MODULE_OcctMfcSamples)
 426   OCCT_INSTALL_FILE_OR_DIR ("adm/templates/sample.bat" "${INSTALL_DIR}")
 427   OCCT_COPY_FILE_OR_DIR    ("adm/templates/sample.bat" "${CMAKE_BINARY_DIR}")
 428 endif()
 429
 430 # env script for draw in building environment
 431 OCCT_CONFIGURE ("adm/templates/env.build.${SCRIPT_EXT}.in" "env.${SCRIPT_EXT}")
 432
 433 # end script for draw in standalone environment
 434 # release version
 435 set (BUILD_LETTER "")
 436 OCCT_CONFIGURE ("adm/templates/env.install.${SCRIPT_EXT}.in" "env.install.release.${SCRIPT_EXT}")
 437 install (FILES "${CMAKE_BINARY_DIR}/env.install.release.${SCRIPT_EXT}"
 438          CONFIGURATIONS Release
 439          DESTINATION  "${INSTALL_DIR}"
 440          RENAME "env.${SCRIPT_EXT}")
 441
 442 # debug version
 443 set (BUILD_LETTER "d")
 444 OCCT_CONFIGURE ("adm/templates/env.install.${SCRIPT_EXT}.in" "env.install.debug.${SCRIPT_EXT}")
 445 install (FILES "${CMAKE_BINARY_DIR}/env.install.debug.${SCRIPT_EXT}"
 446          CONFIGURATIONS Debug
 447          DESTINATION  "${INSTALL_DIR}"
 448          RENAME "env.${SCRIPT_EXT}")
 449
 450 # release with debug info version
 451 set (BUILD_LETTER "i")
 452 OCCT_CONFIGURE ("adm/templates/env.install.${SCRIPT_EXT}.in" "env.install.relwithdebinfo.${SCRIPT_EXT}")
 453 install (FILES "${CMAKE_BINARY_DIR}/env.install.relwithdebinfo.${SCRIPT_EXT}"
 454          CONFIGURATIONS RelWithDebInfo
 455          DESTINATION  "${INSTALL_DIR}"
 456          RENAME "env.${SCRIPT_EXT}")
 457
 458 # copy DrawAppliInit from OCCT source to build directory
 459 if (NOT EXISTS "${CMAKE_BINARY_DIR}/DrawAppliInit")
 460   OCCT_COPY_FILE_OR_DIR (DrawAppliInit "${CMAKE_BINARY_DIR}")
 461 endif()
 462
 463 # RESOURCES
 464 FILE_TO_LIST ("adm/RESOURCES" RESOURCES)
 465 foreach(RESOURCE ${RESOURCES})
 466   get_filename_component(RESOURCE_FOLDER ${RESOURCE} DIRECTORY)
 467   if(NOT "${RESOURCE_FOLDER}" STREQUAL "")
 468     get_filename_component(RESOURCE_FOLDER ${RESOURCE_FOLDER} NAME)
 469     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR}/src/${RESOURCE_FOLDER}")
 470   else()
 471     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR}/src")
 472   endif()
 473 endforeach()
 474
 475 # include patched toolkit projects or original ones
 476 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
 477   OCCT_ADD_SUBDIRECTORY ("src/${BUILD_TOOLKIT}")
 478 endforeach()
 479
 480 if (BUILD_DOC_OcctOverview)
 481   OCCT_ADD_SUBDIRECTORY (dox)
 482 endif()
 483
 484 # patch DRAWEXE
 485 if (MSVC AND 3RDPARTY_DLL_DIRS)
 486   list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
 487   if (${DRAWEXE_INDEX} GREATER -1)
 488     list (REMOVE_DUPLICATES 3RDPARTY_DLL_DIRS)
 489     set (3RDPARTY_DLL_DIRS_FOR_PATH "")
 490
 491     foreach (3RDPARTY_DLL_DIR ${3RDPARTY_DLL_DIRS})
 492       set (3RDPARTY_DLL_DIRS_FOR_PATH "${3RDPARTY_DLL_DIRS_FOR_PATH};${3RDPARTY_DLL_DIR}")
 493     endforeach()
 494
 495     OCCT_MAKE_COMPILER_BITNESS()
 496     set (X_COMPILER_BITNESS "x64")
 497     if ("${COMPILER_BITNESS}" STREQUAL "32")
 498       set (X_COMPILER_BITNESS "Win32")
 499     endif()
 500
 501     OCCT_CONFIGURE ("adm/templates/DRAWEXE.vcxproj.user.in" "${CMAKE_BINARY_DIR}/src/DRAWEXE/DRAWEXE.vcxproj.user")
 502   endif()
 503 endif()
 504
 505 # samples do not support patch usage
 506 if (BUILD_MODULE_OcctMfcSamples)
 507   set (OCCT_ROOT ${CMAKE_SOURCE_DIR})
 508
 509   set (MFC_STANDARD_SAMPLES_DIR ${OCCT_ROOT}/samples/mfc/standard)
 510   set (COMMON_WINMAIN_FILE      ${MFC_STANDARD_SAMPLES_DIR}/Common/Winmain.cpp)
 511
 512   add_subdirectory(samples/mfc/standard/mfcsample)
 513   add_subdirectory(samples/mfc/standard/01_Geometry)
 514   add_subdirectory(samples/mfc/standard/02_Modeling)
 515   add_subdirectory(samples/mfc/standard/03_Viewer2d)
 516   add_subdirectory(samples/mfc/standard/04_Viewer3d)
 517   add_subdirectory(samples/mfc/standard/05_ImportExport)
 518   add_subdirectory(samples/mfc/standard/06_Ocaf)
 519   add_subdirectory(samples/mfc/standard/07_Triangulation)
 520   add_subdirectory(samples/mfc/standard/08_HLR)
 521   add_subdirectory(samples/mfc/standard/09_Animation)
 522   add_subdirectory(samples/mfc/standard/10_Convert)
 523 endif()