CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.12 FATAL_ERROR)
   2
   3 set (CMAKE_SUPPRESS_REGENERATION TRUE)
   4
   5 set (CMAKE_CONFIGURATION_TYPES Release Debug RelWithDebInfo CACHE INTERNAL "" FORCE)
   6
   7 # macro: include patched file if it exists
   8 macro (OCCT_INCLUDE_CMAKE_FILE BEING_INCLUDED_FILE)
   9   if (APPLY_OCCT_PATCH_DIR AND EXISTS "${APPLY_OCCT_PATCH_DIR}/${BEING_INCLUDED_FILE}.cmake")
  10     include (${APPLY_OCCT_PATCH_DIR}/${BEING_INCLUDED_FILE}.cmake)
  11   else()
  12     include (${CMAKE_SOURCE_DIR}/${BEING_INCLUDED_FILE}.cmake)
  13   endif()
  14 endmacro()
  15
  16 # include variable description
  17 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vardescr")
  18
  19 # set type of OCCT libraries
  20 if (NOT BUILD_LIBRARY_TYPE)
  21   set (BUILD_LIBRARY_TYPE "Shared" CACHE STRING "${BUILD_LIBRARY_TYPE_DESCR}" FORCE)
  22   SET_PROPERTY(CACHE BUILD_LIBRARY_TYPE PROPERTY STRINGS Shared Static)
  23 endif()
  24
  25 if ("${BUILD_LIBRARY_TYPE}" STREQUAL "Shared")
  26   set (BUILD_SHARED_LIBS ON)
  27 else()
  28   unset (BUILD_SHARED_LIBS)
  29 endif()
  30
  31 # the name of the project
  32 project (OCCT)
  33
  34 # Solution folder property
  35 set_property (GLOBAL PROPERTY USE_FOLDERS ON)
  36
  37 set (INSTALL_OCCT_TEST_CASES OFF CACHE BOOL "${INSTALL_OCCT_TEST_CASES_DESCR}")
  38 # a single-configuration generator like the Makefile generator defines CMAKE_BUILD_TYPE variable
  39 # check this variable and set if it's required
  40 if (DEFINED CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE) # single-configuration generator.
  41   set (CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel." FORCE)
  42 endif()
  43
  44 # enable extended messages of many OCCT algorithms
  45 set (OCCT_ALGO_EXTENDED_OUTPUT OFF CACHE BOOL "${OCCT_ALGO_EXTENDED_OUTPUT_DESCR}")
  46 if (OCCT_ALGO_EXTENDED_OUTPUT)
  47   add_definitions (-DOCCT_DEBUG)
  48 endif()
  49
  50 # copy samples to install directory
  51 set (INSTALL_OCCT_SAMPLES OFF CACHE BOOL "${INSTALL_OCCT_SAMPLES_DESCR}")
  52
  53 # install dir of the built project
  54 set (INSTALL_DIR "" CACHE PATH "${INSTALL_DIR_DESCR}" )
  55 set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE )
  56
  57 set (APPLY_OCCT_PATCH_DIR "" CACHE PATH "${APPLY_OCCT_PATCH_DIR_DESCR}")
  58
  59 # the list of being built toolkits
  60 set (BUILD_ADDITIONAL_TOOLKITS "" CACHE STRING "${BUILD_ADDITIONAL_TOOLKITS_DESCR}")
  61 separate_arguments (BUILD_ADDITIONAL_TOOLKITS)
  62
  63 if (MSVC)
  64   set (BUILD_MODULE_OcctMfcSamples OFF CACHE BOOL "${BUILD_MODULE_OcctMfcSamples_DESCR}")
  65 endif()
  66
  67 # whether use optional 3rdparty or not
  68 if (APPLE)
  69   set (USE_GLX OFF CACHE BOOL "${USE_GLX_DESCR}")
  70 endif()
  71 if (WIN32)
  72   set (USE_D3D OFF CACHE BOOL "${USE_D3D_DESCR}")
  73 endif()
  74
  75 set (USE_VTK OFF CACHE BOOL "${USE_VTK_DESCR}")
  76
  77 # include occt macros
  78 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_macros")
  79
  80 # include the patched or original list of modules
  81 # list <MODULENAME>_TOOLKITS is created foreach module and contains its toolkits
  82 # list <OCCT_MODULES> will contain all modules
  83 OCCT_MODULES_AND_TOOLKITS (OCCT_MODULES)
  84
  85 foreach (OCCT_MODULE ${OCCT_MODULES})
  86   BUILD_MODULE (${OCCT_MODULE})
  87 endforeach()
  88
  89 # Overview
  90 set (BUILD_DOC_OcctOverview OFF CACHE BOOL "${BUILD_DOC_OcctOverview_DESCR}")
  91
  92 if (NOT USE_VTK)
  93   list (REMOVE_ITEM Visualization_TOOLKITS TKIVtk)
  94   list (REMOVE_ITEM Draw_TOOLKITS TKIVtkDraw)
  95 endif()
  96
  97 if (NOT USE_D3D)
  98   list (REMOVE_ITEM Visualization_TOOLKITS TKD3DHost)
  99 endif()
 100
 101 # accumulate used toolkits (first level) in BUILD_TOOLKITS variable
 102 list (APPEND BUILD_TOOLKITS ${BUILD_ADDITIONAL_TOOLKITS})
 103
 104 foreach (OCCT_MODULE ${OCCT_MODULES})
 105   if (BUILD_MODULE_${OCCT_MODULE})
 106     list (APPEND BUILD_TOOLKITS ${${OCCT_MODULE}_TOOLKITS})
 107   endif()
 108 endforeach()
 109
 110 # DRAWEXE excluded when library build is static
 111 if (NOT BUILD_SHARED_LIBS)
 112   list (REMOVE_ITEM BUILD_TOOLKITS DRAWEXE)
 113   message (STATUS "Info: DRAWEXE is not included due to ${BUILD_LIBRARY_TYPE} build library type")
 114 endif()
 115
 116 # accumulate all used toolkits
 117 list (REMOVE_DUPLICATES BUILD_TOOLKITS)
 118 set (RAW_BUILD_TOOLKITS)
 119 foreach(BUILD_TOOLKIT ${BUILD_TOOLKITS})
 120   OCCT_TOOLKIT_FULL_DEP (${BUILD_TOOLKIT} TOOLKIT_FULL_DEPS)
 121   list (APPEND RAW_BUILD_TOOLKITS ${BUILD_TOOLKIT} ${TOOLKIT_FULL_DEPS})
 122 endforeach()
 123
 124 list (REMOVE_DUPLICATES RAW_BUILD_TOOLKITS)
 125 set (BUILD_TOOLKITS ${RAW_BUILD_TOOLKITS})
 126
 127 # include the patched or original list of definitions and flags
 128 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_defs_flags")
 129
 130 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/3rdparty_macro")
 131
 132 # Rebuild *.yacc and *.lex files that are contained by TKMath toolkit
 133 list (FIND BUILD_TOOLKITS TKMath   CAN_REBUILD_PDC_FOR_TKMATH)
 134 list (FIND BUILD_TOOLKITS StepFile CAN_REBUILD_PDC_FOR_STEPFILE)
 135
 136 if (NOT "${CAN_REBUILD_PDC_FOR_TKMATH}" STREQUAL "-1" OR NOT "${CAN_REBUILD_PDC_FOR_STEPFILE}" STREQUAL "-1")
 137   set (REBUILD_PLATFORM_DEPENDENT_CODE OFF CACHE BOOL "${REBUILD_PLATFORM_DEPENDENT_CODE_DESCR}")
 138 else()
 139   OCCT_CHECK_AND_UNSET (REBUILD_PLATFORM_DEPENDENT_CODE)
 140 endif()
 141
 142 if (NOT DEFINED 3RDPARTY_DIR)
 143   set (3RDPARTY_DIR "" CACHE PATH ${3RDPARTY_DIR_DESCR})
 144 endif()
 145
 146 # search for 3rdparty dir
 147 if ("${3RDPARTY_DIR}" STREQUAL "")
 148   if (DEFINED ENV{3RDPARTY_DIR})
 149     set (3RDPARTY_DIR "$ENV{3RDPARTY_DIR}" CACHE PATH ${3RDPARTY_DIR_DESCR} FORCE)
 150   elseif (EXISTS "${CMAKE_SOURCE_DIR}/../")
 151     # in version 6.7.0 and above, occt parent directory contains 3rdparties
 152     get_filename_component (3RDPARTY_DIR "${CMAKE_SOURCE_DIR}/../" ABSOLUTE)
 153     set (3RDPARTY_DIR "${3RDPARTY_DIR}" CACHE PATH ${3RDPARTY_DIR_DESCR} FORCE)
 154   endif()
 155 endif()
 156
 157 # search for CSF_TclLibs variable in EXTERNLIB of each being used toolkit
 158 OCCT_IS_PRODUCT_REQUIRED (CSF_TclLibs USE_TCL)
 159
 160 if ("${USE_TCL}" STREQUAL ON)
 161   message (STATUS "Info: TCL is used by OCCT")
 162   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tcl")
 163
 164   message (STATUS "Info: TK is used by OCCT")
 165   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tk")
 166 else()
 167   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TCL")
 168   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TK")
 169
 170   OCCT_CHECK_AND_UNSET ("INSTALL_TCL")
 171   OCCT_CHECK_AND_UNSET ("INSTALL_TK")
 172 endif()
 173
 174 # search for CSF_FREETYPE variable in EXTERNLIB of each being used toolkit
 175 OCCT_IS_PRODUCT_REQUIRED (CSF_FREETYPE USE_FREETYPE)
 176
 177 if ("${USE_FREETYPE}" STREQUAL ON)
 178   message (STATUS "Info: Freetype is used by OCCT")
 179   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freetype")
 180 else()
 181   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREETYPE")
 182   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2")
 183   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build")
 184   OCCT_CHECK_AND_UNSET ("INSTALL_FREETYPE")
 185 endif()
 186
 187 # VTK
 188 if (USE_VTK)
 189   add_definitions (-DHAVE_VTK)
 190   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vtk")
 191 else()
 192   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_VTK")
 193   OCCT_CHECK_AND_UNSET ("INSTALL_VTK")
 194 endif()
 195
 196 # D3D
 197 if (USE_D3D)
 198   add_definitions (-DHAVE_D3D)
 199   #if(MSVC_VERSION LESS 1700)
 200   #OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/d3d")
 201   #endif()
 202 endif()
 203
 204 # GLX
 205 if (USE_GLX)
 206   add_definitions (-DMACOSX_USE_GLX)
 207   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/glx")
 208 endif()
 209
 210 # FREEIMAGE
 211 # search for CSF_FREEIMAGE variable in EXTERNLIB of each being used toolkit
 212 OCCT_IS_PRODUCT_REQUIRED (CSF_FREEIMAGE     CAN_USE_FREEIMAGE)
 213 OCCT_IS_PRODUCT_REQUIRED (CSF_FreeImagePlus CAN_USE_FREEIMAGEPLUS)
 214
 215 if (CAN_USE_FREEIMAGE OR CAN_USE_FREEIMAGEPLUS)
 216   set (USE_FREEIMAGE OFF CACHE BOOL "${USE_FREEIMAGE_DESCR}")
 217
 218   if (USE_FREEIMAGE)
 219     add_definitions (-DHAVE_FREEIMAGE)
 220     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimage")
 221     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimageplus")
 222   else()
 223     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
 224     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGEPLUS")
 225     OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
 226     OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGEPLUS")
 227   endif()
 228 else()
 229   OCCT_CHECK_AND_UNSET ("USE_FREEIMAGE")
 230
 231   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
 232   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGEPLUS")
 233   OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
 234   OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGEPLUS")
 235 endif()
 236
 237 # GL2PS
 238 # search for CSF_GL2PS variable in EXTERNLIB of each being used toolkit
 239 OCCT_IS_PRODUCT_REQUIRED (CSF_GL2PS CAN_USE_GL2PS)
 240
 241 if (NOT DEFINED ANDROID AND CAN_USE_GL2PS)
 242 message(STATUS "USE_GL2PS = $ENV{USE_GL2PS} or ${USE_GL2PS}")
 243   set (USE_GL2PS OFF CACHE BOOL "${USE_GL2PS_DESCR}")
 244
 245   if (USE_GL2PS)
 246     add_definitions (-DHAVE_GL2PS)
 247     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gl2ps")
 248   else()
 249     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
 250     OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
 251   endif()
 252 else()
 253   OCCT_CHECK_AND_UNSET ("USE_GL2PS")
 254
 255   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
 256   OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
 257 endif()
 258
 259 # TBB
 260 # search for CSF_TBB variable in EXTERNLIB of each being used toolkit
 261 OCCT_IS_PRODUCT_REQUIRED (CSF_TBB CAN_USE_TBB)
 262
 263 if (NOT DEFINED ANDROID AND CAN_USE_TBB)
 264   set (USE_TBB OFF CACHE BOOL "${USE_TBB_DESCR}")
 265
 266   if (USE_TBB)
 267     add_definitions (-DHAVE_TBB)
 268     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tbb")
 269   else()
 270     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
 271     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
 272     OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
 273   endif()
 274 else()
 275   OCCT_CHECK_AND_UNSET ("USE_TBB")
 276
 277   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
 278   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
 279   OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
 280 endif()
 281
 282 # Doxygen
 283 if (BUILD_DOC_OcctOverview)
 284   if (NOT DEFINED INSTALL_DOC_OcctOverview)
 285     set (INSTALL_DOC_OcctOverview OFF CACHE BOOL "${INSTALL_DOC_OcctOverview_DESCR}")
 286   endif()
 287
 288   if (INSTALL_DOC_OcctOverview)
 289     install (DIRECTORY "${CMAKE_BINARY_DIR}/doc/overview" DESTINATION  "${INSTALL_DIR}/doc")
 290
 291     OCCT_INSTALL_FILE_OR_DIR ("dox/resources/overview.html" "${INSTALL_DIR}")
 292   endif()
 293
 294   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
 295 else()
 296   OCCT_CHECK_AND_UNSET ("INSTALL_DOC_OcctOverview")
 297
 298   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOXYGEN_EXECUTABLE")
 299   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOXYGEN_DOT_EXECUTABLE")
 300 endif()
 301
 302 # bison
 303 if (REBUILD_PLATFORM_DEPENDENT_CODE)
 304   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/bison")
 305 else()
 306   OCCT_CHECK_AND_UNSET ("3RDPARTY_BISON_EXECUTABLE")
 307 endif()
 308
 309 # flex
 310 if (REBUILD_PLATFORM_DEPENDENT_CODE)
 311   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/flex")
 312 else()
 313   OCCT_CHECK_AND_UNSET ("3RDPARTY_FLEX_EXECUTABLE")
 314 endif()
 315
 316 string (REGEX REPLACE ";" " " 3RDPARTY_NOT_INCLUDED "${3RDPARTY_NOT_INCLUDED}")
 317
 318 # check all 3rdparty paths
 319 if (3RDPARTY_NOT_INCLUDED)
 320   message (FATAL_ERROR "NOT FOUND: ${3RDPARTY_NOT_INCLUDED}" )
 321 endif()
 322
 323 if (3RDPARTY_INCLUDE_DIRS)
 324   list (REMOVE_DUPLICATES 3RDPARTY_INCLUDE_DIRS)
 325   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_INCLUDE_DIRS_WITH_ENDS "${3RDPARTY_INCLUDE_DIRS}")
 326   message (STATUS "The directories containing 3rdparty headers: ${3RDPARTY_INCLUDE_DIRS_WITH_ENDS}")
 327   include_directories (${3RDPARTY_INCLUDE_DIRS})
 328 endif()
 329
 330 # include <cmake binary folder>/inc
 331 include_directories (${CMAKE_BINARY_DIR}/inc)
 332
 333 if (3RDPARTY_LIBRARY_DIRS)
 334   list (REMOVE_DUPLICATES 3RDPARTY_LIBRARY_DIRS)
 335   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_LIBRARY_DIRS_WITH_ENDS "${3RDPARTY_LIBRARY_DIRS}")
 336   message (STATUS "The directories containing 3rdparty libraries: ${3RDPARTY_LIBRARY_DIRS_WITH_ENDS}")
 337   link_directories (${3RDPARTY_LIBRARY_DIRS})
 338 endif()
 339
 340 # Get all used variables: OS_WITH_BIT, COMPILER
 341 OCCT_MAKE_OS_WITH_BITNESS()
 342 OCCT_MAKE_COMPILER_SHORT_NAME()
 343
 344 # build directories
 345 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
 346 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
 347 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
 348
 349 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
 350 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
 351 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
 352
 353 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
 354 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
 355 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
 356
 357 if (WIN32)
 358   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE        "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
 359   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
 360   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG          "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
 361 endif()
 362
 363 if ("${INSTALL_DIR}" STREQUAL "")
 364   get_filename_component (CMAKE_BINARY_DIR_PARENT ${CMAKE_BINARY_DIR} DIRECTORY)
 365
 366   set (INSTALL_DIR "${CMAKE_BINARY_DIR_PARENT}/install" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
 367   set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE )
 368
 369   message (STATUS "Info: INSTALL_DIR has been set as ${INSTALL_DIR}")
 370 endif()
 371
 372 message (STATUS "\nInfo: Collecting all OCCT header files into ${CMAKE_BINARY_DIR}/inc ...")
 373
 374 # collect all the headers to <binary dir>/inc folder
 375 COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}" "${BUILD_TOOLKITS}")
 376
 377 OCCT_INSTALL_FILE_OR_DIR ("data" "${INSTALL_DIR}")
 378 OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR}/samples")
 379
 380 if (INSTALL_OCCT_SAMPLES)
 381   OCCT_INSTALL_FILE_OR_DIR ("samples" "${INSTALL_DIR}")
 382 endif()
 383
 384 if (INSTALL_OCCT_TEST_CASES)
 385   OCCT_INSTALL_FILE_OR_DIR ("tests" "${INSTALL_DIR}")
 386 endif()
 387
 388 if (WIN32)
 389   set (SCRIPT_EXT bat)
 390 else()
 391   set (SCRIPT_EXT sh)
 392 endif()
 393
 394 # DRAW.BAT or DRAW.SH
 395 if (APPLY_OCCT_PATCH_DIR AND EXISTS "${APPLY_OCCT_PATCH_DIR}/adm/templates/draw.${SCRIPT_EXT}")
 396   install (FILES "${APPLY_OCCT_PATCH_DIR}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR}" PERMISSIONS
 397           OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
 398 else()
 399   install (FILES "${CMAKE_SOURCE_DIR}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR}" PERMISSIONS
 400           OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
 401 endif()
 402 OCCT_COPY_FILE_OR_DIR ("adm/templates/draw.${SCRIPT_EXT}" "${CMAKE_BINARY_DIR}")
 403
 404 set (SUB_CUSTOM_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.${SCRIPT_EXT}")
 405
 406 if (WIN32)
 407   set (ADDITIONAL_CUSTOM_CONTENT "\nif exist \"%~dp0${SUB_CUSTOM_NAME}\" (\n  call \"%~dp0${SUB_CUSTOM_NAME}\" %VCVER% %ARCH% %CASDEB% \n)")
 408 else()
 409   set (ADDITIONAL_CUSTOM_CONTENT "\nif [ -e \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" ]; then\n  source \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" \"\${COMPILER}\" \"\${WOKSTATION}\${ARCH}\" \"\${CASDEB}\" \nfi")
 410 endif()
 411
 412  # change custom.bat/sh
 413 if (EXISTS "${INSTALL_DIR}/custom.${SCRIPT_EXT}")
 414   file (READ "${INSTALL_DIR}/custom.${SCRIPT_EXT}" CUSTOM_CONTENT)
 415
 416   set (CUSTOM_CONTENT "${CUSTOM_CONTENT} ${ADDITIONAL_CUSTOM_CONTENT}")
 417
 418   file (WRITE "${INSTALL_DIR}/custom.${SCRIPT_EXT}" "${CUSTOM_CONTENT}")
 419 else()
 420   OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.${SCRIPT_EXT}.main" "custom.${SCRIPT_EXT}" "custom.${SCRIPT_EXT}" "${INSTALL_DIR}")
 421 endif()
 422
 423 # write current custom.bat/sh (for install directory)
 424 set (SUB_CUSTOM_BUILD_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.install.${SCRIPT_EXT}")
 425 OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.install.${SCRIPT_EXT}.in" "${SUB_CUSTOM_BUILD_NAME}" "${SUB_CUSTOM_NAME}" "${INSTALL_DIR}")
 426
 427 # write current custom.bat/sh (for build directory)
 428 OCCT_CONFIGURE ("adm/templates/custom.build.${SCRIPT_EXT}.in" "${SUB_CUSTOM_NAME}")
 429
 430 if (BUILD_MODULE_OcctMfcSamples)
 431   OCCT_INSTALL_FILE_OR_DIR ("adm/templates/sample.bat" "${INSTALL_DIR}")
 432   OCCT_COPY_FILE_OR_DIR    ("adm/templates/sample.bat" "${CMAKE_BINARY_DIR}")
 433 endif()
 434
 435 # env script for draw in building environment
 436 OCCT_CONFIGURE ("adm/templates/env.build.${SCRIPT_EXT}.in" "env.${SCRIPT_EXT}")
 437
 438 # end script for draw in standalone environment
 439 # release version
 440 set (BUILD_LETTER "")
 441 OCCT_CONFIGURE ("adm/templates/env.install.${SCRIPT_EXT}.in" "env.install.release.${SCRIPT_EXT}")
 442 install (FILES "${CMAKE_BINARY_DIR}/env.install.release.${SCRIPT_EXT}"
 443          CONFIGURATIONS Release
 444          DESTINATION  "${INSTALL_DIR}"
 445          RENAME "env.${SCRIPT_EXT}")
 446
 447 # debug version
 448 set (BUILD_LETTER "d")
 449 OCCT_CONFIGURE ("adm/templates/env.install.${SCRIPT_EXT}.in" "env.install.debug.${SCRIPT_EXT}")
 450 install (FILES "${CMAKE_BINARY_DIR}/env.install.debug.${SCRIPT_EXT}"
 451          CONFIGURATIONS Debug
 452          DESTINATION  "${INSTALL_DIR}"
 453          RENAME "env.${SCRIPT_EXT}")
 454
 455 # release with debug info version
 456 set (BUILD_LETTER "i")
 457 OCCT_CONFIGURE ("adm/templates/env.install.${SCRIPT_EXT}.in" "env.install.relwithdebinfo.${SCRIPT_EXT}")
 458 install (FILES "${CMAKE_BINARY_DIR}/env.install.relwithdebinfo.${SCRIPT_EXT}"
 459          CONFIGURATIONS RelWithDebInfo
 460          DESTINATION  "${INSTALL_DIR}"
 461          RENAME "env.${SCRIPT_EXT}")
 462
 463 # copy DrawAppliInit from OCCT source to build directory
 464 if (NOT EXISTS "${CMAKE_BINARY_DIR}/DrawAppliInit")
 465   OCCT_COPY_FILE_OR_DIR (DrawAppliInit "${CMAKE_BINARY_DIR}")
 466 endif()
 467
 468 # RESOURCES
 469 FILE_TO_LIST ("adm/RESOURCES" RESOURCES)
 470 foreach(RESOURCE ${RESOURCES})
 471   get_filename_component(RESOURCE_FOLDER ${RESOURCE} DIRECTORY)
 472   if(NOT "${RESOURCE_FOLDER}" STREQUAL "")
 473     get_filename_component(RESOURCE_FOLDER ${RESOURCE_FOLDER} NAME)
 474     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR}/src/${RESOURCE_FOLDER}")
 475   else()
 476     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR}/src")
 477   endif()
 478 endforeach()
 479
 480 # include patched toolkit projects or original ones
 481 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
 482   OCCT_ADD_SUBDIRECTORY ("src/${BUILD_TOOLKIT}")
 483 endforeach()
 484
 485 if (BUILD_DOC_OcctOverview)
 486   OCCT_ADD_SUBDIRECTORY (dox)
 487 endif()
 488
 489 # patch DRAWEXE
 490 if (MSVC AND 3RDPARTY_DLL_DIRS)
 491   list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
 492   if (${DRAWEXE_INDEX} GREATER -1)
 493     list (REMOVE_DUPLICATES 3RDPARTY_DLL_DIRS)
 494     set (3RDPARTY_DLL_DIRS_FOR_PATH "")
 495
 496     foreach (3RDPARTY_DLL_DIR ${3RDPARTY_DLL_DIRS})
 497       set (3RDPARTY_DLL_DIRS_FOR_PATH "${3RDPARTY_DLL_DIRS_FOR_PATH};${3RDPARTY_DLL_DIR}")
 498     endforeach()
 499
 500     OCCT_MAKE_COMPILER_BITNESS()
 501     set (X_COMPILER_BITNESS "x64")
 502     if ("${COMPILER_BITNESS}" STREQUAL "32")
 503       set (X_COMPILER_BITNESS "Win32")
 504     endif()
 505
 506     OCCT_CONFIGURE ("adm/templates/DRAWEXE.vcxproj.user.in" "${CMAKE_BINARY_DIR}/src/DRAWEXE/DRAWEXE.vcxproj.user")
 507   endif()
 508 endif()
 509
 510 # samples do not support patch usage
 511 if (BUILD_MODULE_OcctMfcSamples)
 512   set (OCCT_ROOT ${CMAKE_SOURCE_DIR})
 513
 514   set (MFC_STANDARD_SAMPLES_DIR ${OCCT_ROOT}/samples/mfc/standard)
 515   set (COMMON_WINMAIN_FILE      ${MFC_STANDARD_SAMPLES_DIR}/Common/Winmain.cpp)
 516
 517   add_subdirectory(samples/mfc/standard/mfcsample)
 518   add_subdirectory(samples/mfc/standard/01_Geometry)
 519   add_subdirectory(samples/mfc/standard/02_Modeling)
 520   add_subdirectory(samples/mfc/standard/03_Viewer2d)
 521   add_subdirectory(samples/mfc/standard/04_Viewer3d)
 522   add_subdirectory(samples/mfc/standard/05_ImportExport)
 523   add_subdirectory(samples/mfc/standard/06_Ocaf)
 524   add_subdirectory(samples/mfc/standard/07_Triangulation)
 525   add_subdirectory(samples/mfc/standard/08_HLR)
 526   add_subdirectory(samples/mfc/standard/09_Animation)
 527   add_subdirectory(samples/mfc/standard/10_Convert)
 528 endif()