0028110: Configuration - specify Unicode charset instead of multibyte in project...
[occt.git] / CMakeLists.txt
1 cmake_minimum_required (VERSION 2.8.12 FATAL_ERROR)
2
3 set (CMAKE_SUPPRESS_REGENERATION TRUE)
4
5 set (CMAKE_CONFIGURATION_TYPES Release Debug RelWithDebInfo CACHE INTERNAL "" FORCE)
6
7 # macro: include patched file if it exists
8 macro (OCCT_INCLUDE_CMAKE_FILE BEING_INCLUDED_FILE)
9   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake")
10     include (${BUILD_PATCH}/${BEING_INCLUDED_FILE}.cmake)
11   else()
12     include (${CMAKE_SOURCE_DIR}/${BEING_INCLUDED_FILE}.cmake)
13   endif()
14 endmacro()
15
16 # include variable description
17 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vardescr")
18
19 # set type of OCCT libraries
20 if (NOT BUILD_LIBRARY_TYPE)
21   set (BUILD_LIBRARY_TYPE "Shared" CACHE STRING "${BUILD_LIBRARY_TYPE_DESCR}" FORCE)
22   SET_PROPERTY(CACHE BUILD_LIBRARY_TYPE PROPERTY STRINGS Shared Static)
23 endif()
24
25 if ("${BUILD_LIBRARY_TYPE}" STREQUAL "Shared")
26   set (BUILD_SHARED_LIBS ON)
27
28   if (NOT DEFINED BUILD_SHARED_LIBRARY_NAME_POSTFIX)
29     set (BUILD_SHARED_LIBRARY_NAME_POSTFIX "" CACHE STRING "${BUILD_SHARED_LIBRARY_NAME_POSTFIX_DESCR}" FORCE)
30   endif()
31 else()
32   unset (BUILD_SHARED_LIBS)
33   message (STATUS "Info: Only 3rdparty's header files are used for building of static OCCT libraries")
34   unset (BUILD_SHARED_LIBRARY_NAME_POSTFIX)
35 endif()
36
37 # the name of the project
38 project (OCCT)
39
40 if (WIN32)
41   add_definitions(-DUNICODE)
42   add_definitions(-D_UNICODE)
43 endif()
44
45 # include occt macros
46 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_macros")
47
48 # Solution folder property
49 set_property (GLOBAL PROPERTY USE_FOLDERS ON)
50
51 # get current OCCT version
52 OCC_VERSION (OCC_VERSION_MAJOR OCC_VERSION_MINOR OCC_VERSION_MAINTENANCE OCC_VERSION_DEVELOPMENT OCC_VERSION_STRING_EXT)
53
54 set_property (GLOBAL PROPERTY OCC_VERSION_MAJOR ${OCC_VERSION_MAJOR})
55 set_property (GLOBAL PROPERTY OCC_VERSION_MINOR ${OCC_VERSION_MINOR})
56 set_property (GLOBAL PROPERTY OCC_VERSION_MAINTENANCE ${OCC_VERSION_MAINTENANCE})
57
58 set (INSTALL_TEST_CASES OFF CACHE BOOL "${INSTALL_TEST_CASES_DESCR}")
59
60 # Regeneration of OCCT resource files
61 set (BUILD_RESOURCES OFF CACHE BOOL "${BUILD_RESOURCES_DESCR}")
62
63 # single-configuration generator
64 set (SINGLE_GENERATOR OFF)
65 if (CMAKE_BUILD_TYPE)
66   set (SINGLE_GENERATOR ON)
67 endif()
68
69 # a single-configuration generator like the Makefile generator defines CMAKE_BUILD_TYPE variable
70 # check this variable and set if it's required
71 if (DEFINED CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE) # single-configuration generator.
72   set (CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel." FORCE)
73 endif()
74
75 # enable extended messages of many OCCT algorithms
76 if (((SINGLE_GENERATOR AND "${CMAKE_BUILD_TYPE}" STREQUAL "Debug") OR NOT SINGLE_GENERATOR) AND (NOT "${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore"))
77   if (NOT BUILD_WITH_DEBUG)
78     set (BUILD_WITH_DEBUG OFF CACHE BOOL "${BUILD_WITH_DEBUG_DESCR}")
79   endif()
80 else()
81   OCCT_CHECK_AND_UNSET (BUILD_WITH_DEBUG)
82 endif()
83
84 if (BUILD_WITH_DEBUG)
85   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:DEBUG>:OCCT_DEBUG>)
86 endif()
87
88 # copy samples to install directory
89 set (INSTALL_SAMPLES OFF CACHE BOOL "${INSTALL_SAMPLES_DESCR}")
90
91 # install dir of the project
92 if (NOT DEFINED INSTALL_DIR)
93   # set default install directory for Windows
94   if (WIN32 AND NOT DEFINED CMAKE_INSTALL_PREFIX)
95     set (CMAKE_INSTALL_PREFIX "C:/opencascade-${OCC_VERSION_STRING_EXT}")
96   endif()
97   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}")
98 else()
99   file (TO_CMAKE_PATH "${INSTALL_DIR}" INSTALL_DIR)
100   set (INSTALL_DIR "${INSTALL_DIR}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
101 endif()
102
103 # choose a variant of the layout of the install paths
104 if (NOT INSTALL_DIR_LAYOUT)
105   if (WIN32)
106     set (INSTALL_DIR_LAYOUT "Windows" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
107   else()
108     set (INSTALL_DIR_LAYOUT "Unix" CACHE STRING "${INSTALL_DIR_LAYOUT_DESCR}" FORCE)
109   endif()
110   SET_PROPERTY(CACHE INSTALL_DIR_LAYOUT PROPERTY STRINGS Windows Unix)
111 endif()
112
113 # check INSTALL_DIR_LAYOUT changes and update INSTALL_DIR_* paths if necessary
114 if (NOT DEFINED INSTALL_DIR_LAYOUT_PREV)
115   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
116 elseif (NOT "${INSTALL_DIR_LAYOUT_PREV}" STREQUAL "${INSTALL_DIR_LAYOUT}")
117   set (INSTALL_DIR_LAYOUT_PREV "${INSTALL_DIR_LAYOUT}" CACHE INTERNAL "" FORCE)
118   # The structure of install folder should be reset due to changed layout
119   OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
120
121   # Unset INSTALL_DIR_WITH_VERSION on windows
122   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
123     OCCT_CHECK_AND_UNSET (INSTALL_DIR_WITH_VERSION)
124   else()
125     if (NOT DEFINED INSTALL_DIR_WITH_VERSION)
126       set (INSTALL_DIR_WITH_VERSION OFF CACHE BOOL "${INSTALL_DIR_WITH_VERSION_DESCR}")
127     endif()
128   endif()
129 endif()
130
131 # check CMAKE_INSTALL_PREFIX changes and update INSTALL_DIR if necessary
132 if (NOT DEFINED CMAKE_INSTALL_PREFIX_PREV)
133   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
134 elseif (NOT "${CMAKE_INSTALL_PREFIX_PREV}" STREQUAL "${CMAKE_INSTALL_PREFIX}")
135   # CMAKE_INSTALL_PREFIX has been changed at previous step
136   set (CMAKE_INSTALL_PREFIX_PREV "${CMAKE_INSTALL_PREFIX}" CACHE INTERNAL "" FORCE)
137   
138   # INSTALL_DIR is required to be updated
139   set (INSTALL_DIR "${CMAKE_INSTALL_PREFIX}" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE)
140 endif()
141
142 # check INSTALL_DIR changes and update CMAKE_INSTALL_PREFIX if necessary
143 if (NOT DEFINED INSTALL_DIR_PREV)
144   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
145 elseif (NOT "${INSTALL_DIR_PREV}" STREQUAL "${INSTALL_DIR}")
146   # INSTALL_DIR has been changed at previous step
147   set (INSTALL_DIR_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
148
149   # sync CMAKE_INSTALL_PREFIX with INSTALL_DIR 
150   set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
151
152   # set CMAKE_INSTALL_PREFIX_PREV to avoid the reset of structure of the install folder 
153   set (CMAKE_INSTALL_PREFIX_PREV "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
154 endif()
155
156 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
157   if (NOT DEFINED INSTALL_DIR_WITH_VERSION_PREV)
158     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
159   elseif (NOT "${INSTALL_DIR_WITH_VERSION_PREV}" STREQUAL "${INSTALL_DIR_WITH_VERSION}")
160     # INSTALL_DIR_WITH_VERSION has been changed at previous step
161     set (INSTALL_DIR_WITH_VERSION_PREV "${INSTALL_DIR_WITH_VERSION}" CACHE INTERNAL "" FORCE)
162
163     OCCT_CHECK_AND_UNSET_INSTALL_DIR_SUBDIRS ()
164   endif()
165 endif()
166
167 # hide CMAKE_INSTALL_PREFIX from a user
168 set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE)
169
170 set (BIN_LETTER "")
171 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
172   set (BIN_LETTER "d")
173 elseif ("${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo")
174   set (BIN_LETTER "i")
175 endif()
176
177 # Get all used variables: OS_WITH_BIT, COMPILER
178 OCCT_MAKE_OS_WITH_BITNESS()
179 OCCT_MAKE_COMPILER_SHORT_NAME()
180
181 # do not define INSTALL_DIR_BIN for win.
182 # Leave library structure for win: <prefix>/win64/vc10/bin(d)
183 if (NOT DEFINED INSTALL_DIR_BIN)
184   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
185     set (INSTALL_DIR_BIN "bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
186   else()
187     set (INSTALL_DIR_BIN "${OS_WITH_BIT}/${COMPILER}/bin" CACHE PATH "${INSTALL_DIR_BIN_DESCR}")
188   endif()
189 endif()
190
191 # define folder contaning all shell/batch scripts
192 if (NOT DEFINED INSTALL_DIR_SCRIPT)
193   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
194     set (INSTALL_DIR_SCRIPT "${INSTALL_DIR_BIN}" CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
195   else()
196     set (INSTALL_DIR_SCRIPT "." CACHE PATH "${INSTALL_DIR_SCRIPT_DESCR}")
197   endif()
198 endif()
199
200 # place the libraries to <prefix>/lib folder for unix and leave old structure for windows
201 if (NOT DEFINED INSTALL_DIR_LIB)
202   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
203     set (INSTALL_DIR_LIB "lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
204   else()
205     set (INSTALL_DIR_LIB "${OS_WITH_BIT}/${COMPILER}/lib" CACHE PATH "${INSTALL_DIR_LIB_DESCR}")
206   endif()
207 endif()
208
209 # OCCT headers: <prefix>/inc for windows,
210 #               <prefix>/include/opencascade-7.0.0 for unix
211 if (NOT DEFINED INSTALL_DIR_INCLUDE)
212   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
213     set (INSTALL_DIR_INCLUDE "include/opencascade" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
214     if (INSTALL_DIR_WITH_VERSION)
215       set (INSTALL_DIR_INCLUDE "include/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}" FORCE)
216     endif()
217   else()
218     set (INSTALL_DIR_INCLUDE "inc" CACHE PATH "${INSTALL_DIR_INCLUDE_DESCR}")
219   endif()
220 endif()
221
222 # OCCT resources: <prefix>/src for windows,
223 #                 <prefix>/share/opencascade-7.0.0/resources for unix
224 if (NOT DEFINED INSTALL_DIR_RESOURCE)
225   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
226     set (INSTALL_DIR_RESOURCE "share/opencascade/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
227     if (INSTALL_DIR_WITH_VERSION)
228       set (INSTALL_DIR_RESOURCE "share/opencascade-${OCC_VERSION_STRING_EXT}/resources" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}" FORCE)
229     endif()
230   else()
231     set (INSTALL_DIR_RESOURCE "src" CACHE PATH "${INSTALL_DIR_RESOURCE_DESCR}")
232   endif()
233 endif()
234
235 # OCCT data
236 if (NOT DEFINED INSTALL_DIR_DATA)
237   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
238     set (INSTALL_DIR_DATA "share/opencascade/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
239     if (INSTALL_DIR_WITH_VERSION)
240       set (INSTALL_DIR_DATA "share/opencascade-${OCC_VERSION_STRING_EXT}/data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}" FORCE)
241     endif()
242   else()
243     set (INSTALL_DIR_DATA "data" CACHE PATH "${INSTALL_DIR_DATA_DESCR}")
244   endif()
245 endif()
246
247 # OCCT samples
248 if (NOT DEFINED INSTALL_DIR_SAMPLES)
249   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
250     set (INSTALL_DIR_SAMPLES "share/opencascade/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
251     if (INSTALL_DIR_WITH_VERSION)
252       set (INSTALL_DIR_SAMPLES "share/opencascade-${OCC_VERSION_STRING_EXT}/samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}" FORCE)
253     endif()
254   else()
255     set (INSTALL_DIR_SAMPLES "samples" CACHE PATH "${INSTALL_DIR_SAMPLES_DESCR}")
256   endif()
257 endif()
258
259 # OCCT tests
260 if (NOT DEFINED INSTALL_DIR_TESTS)
261   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
262     set (INSTALL_DIR_TESTS "share/opencascade/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
263     if (INSTALL_DIR_WITH_VERSION)
264       set (INSTALL_DIR_TESTS "share/opencascade-${OCC_VERSION_STRING_EXT}/tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}" FORCE)
265     endif()
266   else()
267     set (INSTALL_DIR_TESTS "tests" CACHE PATH "${INSTALL_DIR_TESTS_DESCR}")
268   endif()
269 endif()
270
271 # OCCT doc
272 if (NOT DEFINED INSTALL_DIR_DOC)
273   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
274     set (INSTALL_DIR_DOC "share/doc/opencascade" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
275     if (INSTALL_DIR_WITH_VERSION)
276       set (INSTALL_DIR_DOC "share/doc/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_DOC_DESCR}" FORCE)
277     endif()
278   else()
279     set (INSTALL_DIR_DOC "doc" CACHE PATH "${INSTALL_DIR_DOC_DESCR}")
280   endif()
281 endif()
282
283 # define folder contaning CMake configuration files
284 if (NOT DEFINED INSTALL_DIR_CMAKE)
285   if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
286     if (INSTALL_DIR_WITH_VERSION)
287       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade-${OCC_VERSION_STRING_EXT}" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
288     else()
289       set (INSTALL_DIR_CMAKE "lib/cmake/opencascade" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
290     endif()
291   else()
292     set (INSTALL_DIR_CMAKE "cmake" CACHE PATH "${INSTALL_DIR_CMAKE_DESCR}")
293   endif()
294 endif()
295
296 # include occt macros
297 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_resources")
298
299 # install LICENSE_LGPL_21.txt and OCCT_LGPL_EXCEPTION.txt files
300 if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
301   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" "${INSTALL_DIR_DOC}")
302   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" "${INSTALL_DIR_DOC}")
303 else()
304   OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" ".")
305   OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" ".")
306 endif()
307
308 if(APPLE)
309   set (INSTALL_NAME_DIR "" CACHE STRING "install_name library suffix on OS X (e.g. @executable_path/../Frameworks)")
310 endif()
311
312 # a directory recognized as a 'patch' for OCCT
313 set (BUILD_PATCH "" CACHE PATH "${BUILD_PATCH_DESCR}")
314
315 # the list of being built toolkits
316 set (BUILD_ADDITIONAL_TOOLKITS "" CACHE STRING "${BUILD_ADDITIONAL_TOOLKITS_DESCR}")
317 separate_arguments (BUILD_ADDITIONAL_TOOLKITS)
318
319 if (MSVC)
320   set (BUILD_MODULE_MfcSamples OFF CACHE BOOL "${BUILD_MODULE_MfcSamples_DESCR}")
321 endif()
322
323 # uwp sample
324 if (MSVC)
325   if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
326     set (BUILD_MODULE_UwpSample OFF CACHE BOOL "${BUILD_MODULE_UwpSample_DESCR}")
327   else()
328     unset (BUILD_MODULE_UwpSample)
329   endif()
330 endif()
331
332 # whether use optional 3rdparty or not
333 if (APPLE)
334   set (USE_GLX OFF CACHE BOOL "${USE_GLX_DESCR}")
335 endif()
336
337 if (WIN32)
338   set (USE_D3D OFF CACHE BOOL "${USE_D3D_DESCR}")
339 endif()
340
341 # include the patched or original list of modules
342 # list <MODULENAME>_TOOLKITS is created foreach module and contains its toolkits
343 # list <OCCT_MODULES> will contain all modules
344 OCCT_MODULES_AND_TOOLKITS (OCCT_MODULES)
345
346 foreach (OCCT_MODULE ${OCCT_MODULES})
347   BUILD_MODULE (${OCCT_MODULE})
348 endforeach()
349
350 if (ANDROID AND BUILD_MODULE_Draw)
351   message (STATUS "Info. Draw module is turned off due to it is not supported on Android")
352   set (BUILD_MODULE_Draw OFF CACHE BOOL "${BUILD_MODULE_Draw_DESCR}" FORCE)
353 endif()
354 if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore" AND BUILD_MODULE_Draw)
355   message (STATUS "Info. Draw module is turned off due to it is not supported on UWP")
356   set (BUILD_MODULE_Draw OFF CACHE BOOL "${BUILD_MODULE_Draw_DESCR}" FORCE)
357 endif()
358
359 # Overview
360 if (NOT DEFINED BUILD_DOC_Overview)
361   set (DO_ONLY_CHECK_FOR_DOXYGEN ON)
362   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
363   set (DO_ONLY_CHECK_FOR_DOXYGEN OFF)
364   
365   if (CAN_DOXYGEN_BE_USED)
366     message (STATUS "Info. Overview building is turned on")
367   endif()
368
369   set (BUILD_DOC_Overview ${CAN_DOXYGEN_BE_USED} CACHE BOOL "${BUILD_DOC_Overview_DESCR}")
370 endif()
371
372 if (NOT USE_D3D)
373   list (REMOVE_ITEM Visualization_TOOLKITS TKD3DHost)
374 endif()
375
376 # accumulate used toolkits (first level) in BUILD_TOOLKITS variable
377 list (APPEND BUILD_TOOLKITS ${BUILD_ADDITIONAL_TOOLKITS})
378
379 foreach (OCCT_MODULE ${OCCT_MODULES})
380   if (BUILD_MODULE_${OCCT_MODULE})
381     list (APPEND BUILD_TOOLKITS ${${OCCT_MODULE}_TOOLKITS})
382   endif()
383 endforeach()
384
385 # DRAWEXE excluded when library build is static
386 if (NOT BUILD_SHARED_LIBS)
387   list (REMOVE_ITEM BUILD_TOOLKITS DRAWEXE)
388   message (STATUS "Info: DRAWEXE is not included due to ${BUILD_LIBRARY_TYPE} build library type")
389 endif()
390
391 # accumulate all used toolkits
392 list (REMOVE_DUPLICATES BUILD_TOOLKITS)
393 set (RAW_BUILD_TOOLKITS)
394 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
395   OCCT_TOOLKIT_FULL_DEP (${BUILD_TOOLKIT} TOOLKIT_FULL_DEPS)
396   list (APPEND RAW_BUILD_TOOLKITS ${BUILD_TOOLKIT} ${TOOLKIT_FULL_DEPS})
397 endforeach()
398
399 list (REMOVE_DUPLICATES RAW_BUILD_TOOLKITS)
400 set (BUILD_TOOLKITS ${RAW_BUILD_TOOLKITS})
401
402 # include the patched or original list of definitions and flags
403 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_defs_flags")
404
405 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/3rdparty_macro")
406
407 # search for TKIVtk and TKIVtkDraw in BUILD_TOOLKITS
408 list (FIND BUILD_TOOLKITS TKIVtk CAN_USE_VTK)
409 if (CAN_USE_VTK EQUAL -1)
410   list (FIND BUILD_TOOLKITS TKIVtkDraw CAN_USE_VTK)
411 endif()
412
413 if (NOT CAN_USE_VTK EQUAL -1)
414   if (NOT DEFINED USE_VTK)
415     set (USE_VTK OFF CACHE BOOL "${USE_VTK_DESCR}")
416   endif()
417 else()
418   OCCT_CHECK_AND_UNSET (USE_VTK)
419 endif()
420
421 # Rebuild *.yacc and *.lex files that are contained by TKMath toolkit
422 list (FIND BUILD_TOOLKITS TKMath   CAN_REBUILD_PDC_FOR_TKMATH)
423 list (FIND BUILD_TOOLKITS StepFile CAN_REBUILD_PDC_FOR_STEPFILE)
424
425 if (NOT ${CAN_REBUILD_PDC_FOR_TKMATH} EQUAL -1 OR NOT ${CAN_REBUILD_PDC_FOR_STEPFILE} EQUAL -1)
426   set (BUILD_YACCLEX OFF CACHE BOOL "${BUILD_YACCLEX_DESCR}")
427 else()
428   OCCT_CHECK_AND_UNSET (BUILD_YACCLEX)
429 endif()
430
431 if (NOT DEFINED 3RDPARTY_DIR)
432   set (3RDPARTY_DIR "" CACHE PATH ${3RDPARTY_DIR_DESCR})
433   get_filename_component (3RDPARTY_DIR "${3RDPARTY_DIR}" ABSOLUTE)
434 else()
435   file (TO_CMAKE_PATH "${3RDPARTY_DIR}" 3RDPARTY_DIR)
436   set (3RDPARTY_DIR "${3RDPARTY_DIR}" CACHE PATH "${3RDPARTY_DIR_DESCR}" FORCE)
437 endif()
438
439 # search for CSF_TclLibs variable in EXTERNLIB of each being used toolkit
440 OCCT_IS_PRODUCT_REQUIRED (CSF_TclLibs USE_TCL)
441
442 if (USE_TCL)
443   message (STATUS "Info: TCL is used by OCCT")
444   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tcl")
445   
446   message (STATUS "Info: TK is used by OCCT")
447   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tk")
448 else()
449   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TCL")
450   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TK")
451
452   OCCT_CHECK_AND_UNSET ("INSTALL_TCL")
453   OCCT_CHECK_AND_UNSET ("INSTALL_TK")
454 endif()
455
456 # search for CSF_FREETYPE variable in EXTERNLIB of each being used toolkit
457 OCCT_IS_PRODUCT_REQUIRED (CSF_FREETYPE USE_FREETYPE)
458
459 if (USE_FREETYPE)
460   message (STATUS "Info: Freetype is used by OCCT")
461   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freetype")
462 else()
463   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREETYPE")
464   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2")
465   OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build")
466   OCCT_CHECK_AND_UNSET ("INSTALL_FREETYPE")
467 endif()
468
469 # VTK
470 if (USE_VTK)
471   add_definitions (-DHAVE_VTK)
472   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vtk")
473 else()
474   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_VTK")
475   
476   if (NOT CAN_USE_VTK EQUAL -1)
477     message (STATUS "Info: TKIVtk and TKIVtkDraw toolkits excluded due to VTK usage is disabled")
478
479     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtk)
480     list (REMOVE_ITEM BUILD_TOOLKITS TKIVtkDraw)
481   endif()
482 endif()
483
484 # D3D
485 if (USE_D3D)
486   add_definitions (-DHAVE_D3D)
487   #if(MSVC_VERSION LESS 1700)
488   #OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/d3d")
489   #endif()
490 endif()
491
492 # GLX
493 if (USE_GLX)
494   add_definitions (-DMACOSX_USE_GLX)
495   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/glx")
496 endif()
497
498 # FREEIMAGE
499 # search for CSF_FREEIMAGE variable in EXTERNLIB of each being used toolkit
500 OCCT_IS_PRODUCT_REQUIRED (CSF_FreeImagePlus CAN_USE_FREEIMAGE)
501
502 if (CAN_USE_FREEIMAGE)
503   set (USE_FREEIMAGE OFF CACHE BOOL "${USE_FREEIMAGE_DESCR}")
504
505   if (USE_FREEIMAGE)
506     add_definitions (-DHAVE_FREEIMAGE)
507     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimage")
508   else()
509     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
510     OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
511   endif()
512 else()
513   OCCT_CHECK_AND_UNSET ("USE_FREEIMAGE")
514
515   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE")
516   OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE")
517 endif()
518
519 # OpenGL ES 2.0
520 OCCT_IS_PRODUCT_REQUIRED (CSF_OpenGlLibs CAN_USE_GLES2)
521 if (WIN32 AND CAN_USE_GLES2)
522   if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
523     set (USE_GLES2 ON)
524   else()
525     set (USE_GLES2 OFF CACHE BOOL "${USE_GLES2_DESCR}")
526   endif()
527
528   if (USE_GLES2)
529     add_definitions (-DHAVE_GLES2)
530     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/egl")
531         OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gles2")
532   else()
533     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EGL")
534     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GLES2")
535     OCCT_CHECK_AND_UNSET ("INSTALL_EGL")
536     OCCT_CHECK_AND_UNSET ("INSTALL_GLES2")
537   endif()
538 else()
539   OCCT_CHECK_AND_UNSET ("USE_GLES2")
540
541   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_EGL")
542   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GLES2")
543   OCCT_CHECK_AND_UNSET ("INSTALL_EGL")
544   OCCT_CHECK_AND_UNSET ("INSTALL_GLES2")
545 endif()
546
547 # GL2PS
548 # search for CSF_GL2PS variable in EXTERNLIB of each being used toolkit
549 OCCT_IS_PRODUCT_REQUIRED (CSF_GL2PS CAN_USE_GL2PS)
550
551 if (NOT DEFINED ANDROID AND CAN_USE_GL2PS)
552   set (USE_GL2PS OFF CACHE BOOL "${USE_GL2PS_DESCR}")
553
554   if (USE_GL2PS)
555     add_definitions (-DHAVE_GL2PS)
556     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gl2ps")
557   else()
558     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
559     OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
560   endif()
561 else()
562   OCCT_CHECK_AND_UNSET ("USE_GL2PS")
563
564   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS")
565   OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS")
566 endif()
567
568 # TBB
569 # search for CSF_TBB variable in EXTERNLIB of each being used toolkit
570 OCCT_IS_PRODUCT_REQUIRED (CSF_TBB CAN_USE_TBB)
571
572 if (NOT DEFINED ANDROID AND CAN_USE_TBB)
573   set (USE_TBB OFF CACHE BOOL "${USE_TBB_DESCR}")
574
575   if (USE_TBB)
576     add_definitions (-DHAVE_TBB)
577     OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tbb")
578   else()
579     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
580     OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
581     OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
582   endif()
583 else()
584   OCCT_CHECK_AND_UNSET ("USE_TBB")
585
586   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB")
587   OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC")
588   OCCT_CHECK_AND_UNSET ("INSTALL_TBB")
589 endif()
590
591 # Doxygen
592 if (BUILD_DOC_Overview)
593   if (NOT DEFINED INSTALL_DOC_Overview)
594     set (INSTALL_DOC_Overview OFF CACHE BOOL "${INSTALL_DOC_Overview_DESCR}")
595   endif()
596
597   if (INSTALL_DOC_Overview)
598     install (DIRECTORY "${CMAKE_BINARY_DIR}/doc/overview" DESTINATION  "${INSTALL_DIR_DOC}")
599
600     # create overview.html only for windows
601     if (WIN32 AND "${INSTALL_DIR_LAYOUT}" STREQUAL "Windows")
602       OCCT_INSTALL_FILE_OR_DIR ("dox/resources/overview.html" "${INSTALL_DIR_DOC}/..")
603     endif()
604   endif()
605
606   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen")
607 else()
608   OCCT_CHECK_AND_UNSET ("INSTALL_DOC_Overview")
609
610   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOXYGEN_EXECUTABLE")
611   OCCT_CHECK_AND_UNSET ("3RDPARTY_DOT_EXECUTABLE")
612 endif()
613
614 # bison 
615 if (BUILD_YACCLEX)
616   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/bison")
617 else()
618   OCCT_CHECK_AND_UNSET ("3RDPARTY_BISON_EXECUTABLE")
619 endif()
620
621 # flex 
622 if (BUILD_YACCLEX)
623   OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/flex")
624 else()
625   OCCT_CHECK_AND_UNSET ("3RDPARTY_FLEX_EXECUTABLE")
626 endif()
627
628 string (REGEX REPLACE ";" " " 3RDPARTY_NOT_INCLUDED "${3RDPARTY_NOT_INCLUDED}")
629
630 # check all 3rdparty paths
631 if (3RDPARTY_NOT_INCLUDED)
632   message (FATAL_ERROR "NOT FOUND: ${3RDPARTY_NOT_INCLUDED}" )
633 endif()
634
635 if (3RDPARTY_INCLUDE_DIRS)
636   list (REMOVE_DUPLICATES 3RDPARTY_INCLUDE_DIRS)
637   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_INCLUDE_DIRS_WITH_ENDS "${3RDPARTY_INCLUDE_DIRS}")
638   message (STATUS "Info: The directories of 3rdparty headers: \n\t${3RDPARTY_INCLUDE_DIRS_WITH_ENDS}")
639   include_directories (${3RDPARTY_INCLUDE_DIRS})
640 endif()
641
642 # include <cmake binary folder>/inc
643 include_directories (${CMAKE_BINARY_DIR}/inc)
644
645 if (3RDPARTY_LIBRARY_DIRS AND BUILD_SHARED_LIBS)
646   list (REMOVE_DUPLICATES 3RDPARTY_LIBRARY_DIRS)
647   string (REGEX REPLACE ";" "\n\t" 3RDPARTY_LIBRARY_DIRS_WITH_ENDS "${3RDPARTY_LIBRARY_DIRS}")
648   message (STATUS "Info: The directories of 3rdparty libraries: \n\t${3RDPARTY_LIBRARY_DIRS_WITH_ENDS}")
649   link_directories (${3RDPARTY_LIBRARY_DIRS})
650 endif()
651
652 # build directories
653 if (SINGLE_GENERATOR)
654   set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
655   set (CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
656   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib${BIN_LETTER}")
657   if (WIN32)
658     set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin${BIN_LETTER}")
659   endif()
660 endif()
661
662 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
663 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
664 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib")
665
666 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
667 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
668 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi")
669
670 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
671 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
672 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd")
673
674 if (WIN32) 
675   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE        "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin")
676   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini")
677   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG          "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind")
678 endif()
679
680 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
681 message (STATUS "\nInfo: \(${CURRENT_TIME}\) Start collecting all OCCT header files into ${CMAKE_BINARY_DIR}/inc ...")
682
683 # collect all the headers to <binary dir>/inc folder
684 COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}" "${BUILD_TOOLKITS}")
685
686 string(TIMESTAMP CURRENT_TIME "%H:%M:%S")
687 message (STATUS "Info: \(${CURRENT_TIME}\) End the collecting")
688
689 list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
690 if (${DRAWEXE_INDEX} GREATER -1)
691   OCCT_INSTALL_FILE_OR_DIR ("data/" "${INSTALL_DIR_DATA}")
692   OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR_SAMPLES}")
693 endif()
694
695 if (WIN32)
696   set (SCRIPT_EXT bat)
697 else()
698   set (SCRIPT_EXT sh)
699 endif()
700
701 # OCCT samples
702 # get absolute path from INSTALL_DIR
703 set (INSTALL_DIR_ABSOLUTE "${INSTALL_DIR}")
704 if(NOT IS_ABSOLUTE "${INSTALL_DIR_ABSOLUTE}")
705   get_filename_component(INSTALL_DIR_ABSOLUTE "${CMAKE_BINARY_DIR}/${INSTALL_DIR}" ABSOLUTE)
706 endif()
707
708 if (INSTALL_SAMPLES)
709   OCCT_CONFIGURE ("adm/templates/env.samples.${SCRIPT_EXT}.in" "env.samples.${SCRIPT_EXT}")
710   if (WIN32)
711     OCCT_INSTALL_FILE_OR_DIR ("samples/CSharp" "${INSTALL_DIR_SAMPLES}")
712     OCCT_INSTALL_FILE_OR_DIR ("samples/mfc" "${INSTALL_DIR_SAMPLES}")
713
714     if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsStore")
715       OCCT_INSTALL_FILE_OR_DIR ("samples/xaml" "${INSTALL_DIR_SAMPLES}")
716     endif()
717
718     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/CSharp" RENAME "env.${SCRIPT_EXT}")
719     install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/mfc/standard" RENAME "env.${SCRIPT_EXT}")
720   endif()
721
722   OCCT_INSTALL_FILE_OR_DIR ("samples/java" "${INSTALL_DIR_SAMPLES}")
723   OCCT_INSTALL_FILE_OR_DIR ("samples/ocafsamples" "${INSTALL_DIR_SAMPLES}")
724   OCCT_INSTALL_FILE_OR_DIR ("samples/qt" "${INSTALL_DIR_SAMPLES}")
725
726   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/FuncDemo" RENAME "env.${SCRIPT_EXT}")
727   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/IESample" RENAME "env.${SCRIPT_EXT}")
728   install (FILES "${CMAKE_BINARY_DIR}/env.samples.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SAMPLES}/qt/Tutorial" RENAME "env.${SCRIPT_EXT}")
729 endif()
730
731 if (INSTALL_TEST_CASES)
732   OCCT_INSTALL_FILE_OR_DIR ("tests/" "${INSTALL_DIR_TESTS}")
733 endif()
734
735 list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
736 if (${DRAWEXE_INDEX} GREATER -1)
737   # copy data and samples/tcl folders to install script folder
738   OCCT_INSTALL_FILE_OR_DIR ("data/" "${INSTALL_DIR_DATA}")
739   OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR_SAMPLES}")
740
741   # copy draw script to install script folder
742   if (BUILD_PATCH AND EXISTS "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}")
743     install (FILES "${BUILD_PATCH}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
744             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
745   else()
746     install (FILES "${CMAKE_SOURCE_DIR}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION  "${INSTALL_DIR_SCRIPT}"
747             PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE)
748   endif()
749
750   # copy draw script to CMake binary folder
751   OCCT_COPY_FILE_OR_DIR ("adm/templates/draw.${SCRIPT_EXT}" "${CMAKE_BINARY_DIR}")
752 endif()
753
754 set (SUB_CUSTOM_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.${SCRIPT_EXT}")
755
756 if (WIN32)
757   set (ADDITIONAL_CUSTOM_CONTENT "\nif exist \"%~dp0${SUB_CUSTOM_NAME}\" (\n  call \"%~dp0${SUB_CUSTOM_NAME}\" %1 %2 %3 \n)")
758 else()
759   set (ADDITIONAL_CUSTOM_CONTENT "\nif [ -e \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" ]; then\n  source \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" \"\$1\" \"\$2\" \nfi")
760 endif()
761
762  # change custom.bat/sh
763 if (EXISTS "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}")
764   file (READ "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" CUSTOM_CONTENT)
765
766   set (CUSTOM_CONTENT "${CUSTOM_CONTENT} ${ADDITIONAL_CUSTOM_CONTENT}")
767
768   file (WRITE "${INSTALL_DIR}/${INSTALL_DIR_SCRIPT}/custom.${SCRIPT_EXT}" "${CUSTOM_CONTENT}")
769 else()
770   OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.${SCRIPT_EXT}.main" "custom.${SCRIPT_EXT}" "custom.${SCRIPT_EXT}" "${INSTALL_DIR_SCRIPT}")
771 endif()
772
773 # write current custom.bat/sh (for install directory)
774 set (SUB_CUSTOM_BUILD_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.install.${SCRIPT_EXT}")
775 OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.install.${SCRIPT_EXT}.in" "${SUB_CUSTOM_BUILD_NAME}" "${SUB_CUSTOM_NAME}" "${INSTALL_DIR_SCRIPT}")
776
777 # write current custom.bat/sh (for build directory)
778 OCCT_CONFIGURE ("adm/templates/custom.build.${SCRIPT_EXT}.in" "${SUB_CUSTOM_NAME}")
779
780 if (BUILD_MODULE_MfcSamples)
781   OCCT_INSTALL_FILE_OR_DIR ("adm/templates/sample.bat" "${INSTALL_DIR_SCRIPT}")
782   OCCT_COPY_FILE_OR_DIR    ("adm/templates/sample.bat" "${CMAKE_BINARY_DIR}")
783 endif()
784
785 # env script for draw in building environment
786 OCCT_CONFIGURE ("adm/templates/env.${SCRIPT_EXT}.in" "env.${SCRIPT_EXT}")
787
788 # install env script
789 install (FILES "${CMAKE_BINARY_DIR}/env.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR_SCRIPT}")
790
791 # copy DrawAppliInit from OCCT source to build directory
792 if (NOT EXISTS "${CMAKE_BINARY_DIR}/DrawAppliInit")
793   OCCT_COPY_FILE_OR_DIR (DrawAppliInit "${CMAKE_BINARY_DIR}")
794 endif()
795
796 # RESOURCES
797 FILE_TO_LIST ("adm/RESOURCES" RESOURCES)
798 foreach(RESOURCE ${RESOURCES})
799   get_filename_component(RESOURCE_FOLDER ${RESOURCE} DIRECTORY)
800   if(NOT "${RESOURCE_FOLDER}" STREQUAL "")
801     get_filename_component(RESOURCE_FOLDER ${RESOURCE_FOLDER} NAME)
802     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR_RESOURCE}/${RESOURCE_FOLDER}")
803   else()
804     OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR_RESOURCE}")
805   endif()
806 endforeach()
807
808 # patch installed DrawDefault file if BUILD_SHARED_LIBRARY_NAME_POSTFIX is changed
809 if (NOT "${BUILD_SHARED_LIBRARY_NAME_POSTFIX}" STREQUAL "")
810   OCCT_UPDATE_DRAW_DEFAULT_FILE()
811 endif()
812
813 # define CSF variable
814 OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_csf")
815
816 # include patched toolkit projects or original ones
817 foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS})
818   OCCT_ADD_SUBDIRECTORY ("src/${BUILD_TOOLKIT}")
819 endforeach()
820
821 if (BUILD_DOC_Overview)
822   OCCT_ADD_SUBDIRECTORY (dox)
823 endif()
824
825 # patch DRAWEXE
826 if (MSVC AND 3RDPARTY_DLL_DIRS)
827   list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX)
828   if (${DRAWEXE_INDEX} GREATER -1)
829     list (REMOVE_DUPLICATES 3RDPARTY_DLL_DIRS)
830     set (3RDPARTY_DLL_DIRS_FOR_PATH "")
831
832     foreach (3RDPARTY_DLL_DIR ${3RDPARTY_DLL_DIRS})
833       set (3RDPARTY_DLL_DIRS_FOR_PATH "${3RDPARTY_DLL_DIRS_FOR_PATH};${3RDPARTY_DLL_DIR}")
834     endforeach()
835
836     OCCT_MAKE_COMPILER_BITNESS()
837     set (X_COMPILER_BITNESS "x64")
838     if ("${COMPILER_BITNESS}" STREQUAL "32")
839       set (X_COMPILER_BITNESS "Win32")
840     endif()
841
842     OCCT_CONFIGURE ("adm/templates/DRAWEXE.vcxproj.user.in" "${CMAKE_BINARY_DIR}/src/DRAWEXE/DRAWEXE.vcxproj.user")
843   endif()
844 endif()
845
846 # samples do not support patch usage
847 if (BUILD_MODULE_MfcSamples)
848   set (OCCT_ROOT ${CMAKE_SOURCE_DIR})
849
850   set (MFC_STANDARD_SAMPLES_DIR ${OCCT_ROOT}/samples/mfc/standard)
851   set (COMMON_WINMAIN_FILE      ${MFC_STANDARD_SAMPLES_DIR}/Common/Winmain.cpp)
852
853   add_subdirectory(samples/mfc/standard/mfcsample)
854   add_subdirectory(samples/mfc/standard/01_Geometry)
855   add_subdirectory(samples/mfc/standard/02_Modeling)
856   add_subdirectory(samples/mfc/standard/03_Viewer2d)
857   add_subdirectory(samples/mfc/standard/04_Viewer3d)
858   add_subdirectory(samples/mfc/standard/05_ImportExport)
859   add_subdirectory(samples/mfc/standard/06_Ocaf)
860   add_subdirectory(samples/mfc/standard/07_Triangulation)
861   add_subdirectory(samples/mfc/standard/08_HLR)
862   add_subdirectory(samples/mfc/standard/09_Animation)
863   add_subdirectory(samples/mfc/standard/10_Convert)
864 endif()
865
866 if (BUILD_MODULE_UwpSample)
867   add_subdirectory(samples/xaml)
868 endif()
869
870 # Prepare variables for configuration of OpenCASCADE cmake config file
871 set (OCCT_MODULES_ENABLED)
872 set (OCCT_LIBRARIES)
873 set (SET_OpenCASCADE_MODULES_TOOLKITS "\n# List of available OpenCASCADE libraries for each module\n")
874 set (OCCT_COMPILE_DEFINITIONS)
875
876 foreach (OCCT_TOOLKIT ${BUILD_TOOLKITS})
877   if (TARGET ${OCCT_TOOLKIT})
878
879     # get all libraries
880     get_target_property (${OCCT_TOOLKIT}_TYPE ${OCCT_TOOLKIT} "TYPE")
881     if ("${${OCCT_TOOLKIT}_TYPE}" STREQUAL "STATIC_LIBRARY" OR "${${OCCT_TOOLKIT}_TYPE}" STREQUAL "SHARED_LIBRARY" )
882       list (APPEND OCCT_LIBRARIES ${OCCT_TOOLKIT})
883
884       # get all modules
885       get_target_property (${OCCT_TOOLKIT}_MODULE ${OCCT_TOOLKIT} "MODULE")
886       list (APPEND OCCT_MODULES_ENABLED ${${OCCT_TOOLKIT}_MODULE})
887       list (APPEND OpenCASCADE_${${OCCT_TOOLKIT}_MODULE}_TOOLKITS ${OCCT_TOOLKIT})
888
889       # get compile definitions of target directory
890       get_directory_property (COMPILE_DEFINITIONS DIRECTORY "${${OCCT_TOOLKIT}_SOURCE_DIR}" "COMPILE_DEFINITIONS")
891       list (APPEND OCCT_COMPILE_DEFINITIONS ${COMPILE_DEFINITIONS})
892     endif()
893   endif()
894 endforeach()
895 list (REMOVE_DUPLICATES OCCT_MODULES_ENABLED)
896 list (REMOVE_DUPLICATES OCCT_COMPILE_DEFINITIONS)
897
898 # export compile definitions and C/C++ flags for each configuration to OpenCASCADE config files
899 foreach (OCCT_CONFIGURATION ${CMAKE_CONFIGURATION_TYPES})
900   set (SET_OpenCASCADE_COMPILE_DEFINITIONS)
901   string (TOUPPER "${OCCT_CONFIGURATION}" OCCT_CONFIGURATION_UPPER)
902   string (TOLOWER "${OCCT_CONFIGURATION}" OCCT_CONFIGURATION_LOWER)
903   foreach(COMPILE_DEFINITION ${OCCT_COMPILE_DEFINITIONS})
904     string(REPLACE "(" "\\(" COMPILE_DEFINITION "${COMPILE_DEFINITION}")
905     string(REPLACE ")" "\\)" COMPILE_DEFINITION "${COMPILE_DEFINITION}")
906     set (SET_OpenCASCADE_COMPILE_DEFINITIONS "${SET_OpenCASCADE_COMPILE_DEFINITIONS}set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:${OCCT_CONFIGURATION}>:${COMPILE_DEFINITION}>)\n")
907   endforeach()
908   set (SET_OpenCASCADE_CMAKE_C_FLAGS "${CMAKE_C_FLAGS_${OCCT_CONFIGURATION_UPPER}}")
909   set (SET_OpenCASCADE_CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS_${OCCT_CONFIGURATION_UPPER}}")
910   configure_file("${CMAKE_SOURCE_DIR}/adm/templates/OpenCASCADECompileDefinitionsAndFlags.cmake.in" "OpenCASCADECompileDefinitionsAndFlags-${OCCT_CONFIGURATION_LOWER}.cmake" @ONLY)
911 endforeach()
912 # install OpenCASCADE config file with compile definitions and C/C++ flags ONLY for current configuration
913 install (CODE "string (TOLOWER \"\${CMAKE_INSTALL_CONFIG_NAME}\" CMAKE_INSTALL_CONFIG_NAME_LOWER)")
914 install (CODE "configure_file(\"${CMAKE_BINARY_DIR}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" \"${INSTALL_DIR}/${INSTALL_DIR_CMAKE}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" COPYONLY)")
915
916 foreach (OCCT_MODULE ${OCCT_MODULES})
917   if (BUILD_MODULE_${OCCT_MODULE})
918     set (SET_OpenCASCADE_MODULES_TOOLKITS "${SET_OpenCASCADE_MODULES_TOOLKITS}set (OpenCASCADE_${OCCT_MODULE}_LIBRARIES ${OpenCASCADE_${OCCT_MODULE}_TOOLKITS})\n")
919   endif()
920
921   # sort enabled modules for correct work of OpenCASCADE config file
922   list(FIND OCCT_MODULES_ENABLED "${OCCT_MODULE}" OCCT_MODULE_INDEX)
923   if (NOT ${OCCT_MODULE_INDEX} EQUAL -1)
924     list (APPEND OCCT_MODULES_ENABLED_SORTED ${OCCT_MODULE})
925   endif()
926 endforeach()
927 set (OCCT_MODULES_ENABLED ${OCCT_MODULES_ENABLED_SORTED})
928
929 # Add all targets to the build-tree export set
930 export (TARGETS ${OCCT_LIBRARIES} FILE "${CMAKE_BINARY_DIR}/OpenCASCADETargets.cmake")
931
932 # Export the package for use from the build-tree
933 # (this registers the build-tree with a global CMake-registry)
934 export(PACKAGE OpenCASCADE)
935
936 if (CMAKE_BUILD_TYPE)
937   set (SET_OpenCASCADE_BUILD_TYPE "set (OpenCASCADE_BUILD_TYPE        \"${CMAKE_BUILD_TYPE}\")")
938 endif()
939
940 if (BUILD_SHARED_LIBS)
941   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_SHARED_LINKER_FLAGS}\")")
942 else()
943   set (SET_OpenCASCADE_LINKER_FLAGS "set (OpenCASCADE_LINKER_FLAGS   \"${CMAKE_STATIC_LINKER_FLAGS}\")")
944 endif()
945
946 if (WIN32)
947   set (SET_OpenCASCADE_WITH_D3D "set (OpenCASCADE_WITH_D3D       ${USE_D3D})")
948 endif()
949 if (APPLE)
950   set (SET_OpenCASCADE_WITH_GLX "set (OpenCASCADE_WITH_GLX       ${USE_GLX})")
951 endif()
952
953 if (NOT SINGLE_GENERATOR)
954   OCCT_INSERT_CODE_FOR_TARGET()
955 endif()
956
957 # Configure and install cmake config file
958 configure_file("${CMAKE_SOURCE_DIR}/adm/templates/OpenCASCADEConfig.cmake.in" "OpenCASCADEConfig.cmake" @ONLY)
959 install(FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfig.cmake" DESTINATION  "${INSTALL_DIR_CMAKE}")
960
961 # Configure cmake version file
962 include(CMakePackageConfigHelpers)
963 write_basic_package_version_file( ${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake
964                                   VERSION ${OCC_VERSION_MAJOR}.${OCC_VERSION_MINOR}.${OCC_VERSION_MAINTENANCE}
965                                   COMPATIBILITY ExactVersion )
966
967 # Install cmake version file
968 install (FILES "${CMAKE_BINARY_DIR}/OpenCASCADEConfigVersion.cmake" DESTINATION "${INSTALL_DIR_CMAKE}")
969
970 # Install the export set for use with the install-tree for each configuration
971 foreach (OCCT_MODULE ${OCCT_MODULES_ENABLED})
972   install(EXPORT OpenCASCADE${OCCT_MODULE}Targets DESTINATION "${INSTALL_DIR_CMAKE}")
973 endforeach()
974
975 # Update generated OpenCASCADETargets-*.cmake files 
976 # to have correct paths to libraries depending on the configuration
977 OCCT_UPDATE_TARGET_FILE ()