| 1 | @echo off |
| 2 | |
| 3 | rem Helper script to run generation of VS projects on Windows. |
| 4 | rem Running it requires that Tcl should be in the PATH |
| 5 | rem Optional arguments: IDE OS |
| 6 | rem IDE can be vc10, vc11, vc12, vc14, cbp, or xcd |
| 7 | rem OS can be wnt, mac, or lin |
| 8 | |
| 9 | SET "OLD_PATH=%PATH%" |
| 10 | |
| 11 | rem run GUI configurator if custom.bat is missing |
| 12 | if not exist "%~dp0custom.bat" ( |
| 13 | call %~dp0genconf.bat |
| 14 | ) |
| 15 | |
| 16 | if not exist "%~dp0custom.bat" ( |
| 17 | echo Error: custom.bat is not present. |
| 18 | echo Run the script again to generate custom.bat, or create it manually |
| 19 | goto :eof |
| 20 | ) |
| 21 | |
| 22 | if exist "%~dp0env.bat" ( |
| 23 | call "%~dp0env.bat" %1 |
| 24 | ) |
| 25 | |
| 26 | rem find Tcl |
| 27 | set "TCL_EXEC=tclsh.exe" |
| 28 | for %%X in (%TCL_EXEC%) do (set TCL_FOUND=%%~$PATH:X) |
| 29 | |
| 30 | set "TCL_EXEC2=tclsh86.exe" |
| 31 | if not defined TCL_FOUND ( |
| 32 | for %%X in (%TCL_EXEC2%) do ( |
| 33 | set TCL_FOUND=%%~$PATH:X |
| 34 | set TCL_EXEC=%TCL_EXEC2% |
| 35 | ) |
| 36 | ) |
| 37 | |
| 38 | rem fail if Tcl is not found |
| 39 | if not defined TCL_FOUND ( |
| 40 | echo Error: "%TCL_EXEC%" is not found. Please update PATH variable ^(use custom.bat^) |
| 41 | goto :eof |
| 42 | ) |
| 43 | |
| 44 | cd %~dp0 |
| 45 | %TCL_EXEC% %~dp0adm/start.tcl genproj %VCVER% %2 %3 %4 %5 |
| 46 | SET "PATH=%OLD_PATH%" |