| 1 | cmake_minimum_required (VERSION 2.8.12 FATAL_ERROR) |
| 2 | |
| 3 | set (CMAKE_SUPPRESS_REGENERATION TRUE) |
| 4 | |
| 5 | set (CMAKE_CONFIGURATION_TYPES Release Debug RelWithDebInfo CACHE INTERNAL "" FORCE) |
| 6 | |
| 7 | # macro: include patched file if it exists |
| 8 | macro (OCCT_INCLUDE_CMAKE_FILE BEING_INCLUDED_FILE) |
| 9 | if (APPLY_OCCT_PATCH_DIR AND EXISTS "${APPLY_OCCT_PATCH_DIR}/${BEING_INCLUDED_FILE}.cmake") |
| 10 | include (${APPLY_OCCT_PATCH_DIR}/${BEING_INCLUDED_FILE}.cmake) |
| 11 | else() |
| 12 | include (${CMAKE_SOURCE_DIR}/${BEING_INCLUDED_FILE}.cmake) |
| 13 | endif() |
| 14 | endmacro() |
| 15 | |
| 16 | # include variable description |
| 17 | OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vardescr") |
| 18 | |
| 19 | # set type of OCCT libraries |
| 20 | if (NOT BUILD_LIBRARY_TYPE) |
| 21 | set (BUILD_LIBRARY_TYPE "Shared" CACHE STRING "${BUILD_LIBRARY_TYPE_DESCR}" FORCE) |
| 22 | SET_PROPERTY(CACHE BUILD_LIBRARY_TYPE PROPERTY STRINGS Shared Static) |
| 23 | endif() |
| 24 | |
| 25 | if ("${BUILD_LIBRARY_TYPE}" STREQUAL "Shared") |
| 26 | set (BUILD_SHARED_LIBS ON) |
| 27 | else() |
| 28 | unset (BUILD_SHARED_LIBS) |
| 29 | endif() |
| 30 | |
| 31 | # the name of the project |
| 32 | project (OCCT) |
| 33 | |
| 34 | # Solution folder property |
| 35 | set_property (GLOBAL PROPERTY USE_FOLDERS ON) |
| 36 | |
| 37 | set (INSTALL_OCCT_TEST_CASES OFF CACHE BOOL "${INSTALL_OCCT_TEST_CASES_DESCR}") |
| 38 | # a single-configuration generator like the Makefile generator defines CMAKE_BUILD_TYPE variable |
| 39 | # check this variable and set if it's required |
| 40 | if (DEFINED CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE) # single-configuration generator. |
| 41 | set (CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel." FORCE) |
| 42 | endif() |
| 43 | |
| 44 | # enable extended messages of many OCCT algorithms |
| 45 | set (OCCT_ALGO_EXTENDED_OUTPUT OFF CACHE BOOL "${OCCT_ALGO_EXTENDED_OUTPUT_DESCR}") |
| 46 | if (OCCT_ALGO_EXTENDED_OUTPUT) |
| 47 | add_definitions (-DOCCT_DEBUG) |
| 48 | endif() |
| 49 | |
| 50 | # copy samples to install directory |
| 51 | set (INSTALL_OCCT_SAMPLES OFF CACHE BOOL "${INSTALL_OCCT_SAMPLES_DESCR}") |
| 52 | |
| 53 | # install dir of the built project |
| 54 | set (INSTALL_DIR "" CACHE PATH "${INSTALL_DIR_DESCR}" ) |
| 55 | set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE ) |
| 56 | |
| 57 | set (APPLY_OCCT_PATCH_DIR "" CACHE PATH "${APPLY_OCCT_PATCH_DIR_DESCR}") |
| 58 | |
| 59 | # the list of being built toolkits |
| 60 | set (BUILD_ADDITIONAL_TOOLKITS "" CACHE STRING "${BUILD_ADDITIONAL_TOOLKITS_DESCR}") |
| 61 | separate_arguments (BUILD_ADDITIONAL_TOOLKITS) |
| 62 | |
| 63 | if (MSVC) |
| 64 | set (BUILD_MODULE_OcctMfcSamples OFF CACHE BOOL "${BUILD_MODULE_OcctMfcSamples_DESCR}") |
| 65 | endif() |
| 66 | |
| 67 | # whether use optional 3rdparty or not |
| 68 | if (APPLE) |
| 69 | set (USE_GLX OFF CACHE BOOL "${USE_GLX_DESCR}") |
| 70 | endif() |
| 71 | |
| 72 | set (USE_VTK OFF CACHE BOOL "${USE_VTK_DESCR}") |
| 73 | |
| 74 | # include occt macros |
| 75 | OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_macros") |
| 76 | |
| 77 | # include the patched or original list of modules |
| 78 | # list <MODULENAME>_TOOLKITS is created foreach module and contains its toolkits |
| 79 | # list <OCCT_MODULES> will contain all modules |
| 80 | OCCT_MODULES_AND_TOOLKITS (OCCT_MODULES) |
| 81 | |
| 82 | foreach (OCCT_MODULE ${OCCT_MODULES}) |
| 83 | BUILD_MODULE (${OCCT_MODULE}) |
| 84 | endforeach() |
| 85 | |
| 86 | # Overview |
| 87 | set (BUILD_DOC_OcctOverview OFF CACHE BOOL "${BUILD_DOC_OcctOverview_DESCR}") |
| 88 | |
| 89 | if (NOT USE_VTK) |
| 90 | list (REMOVE_ITEM Visualization_TOOLKITS TKIVtk) |
| 91 | list (REMOVE_ITEM Draw_TOOLKITS TKIVtkDraw) |
| 92 | endif() |
| 93 | |
| 94 | # accumulate used toolkits (first level) in BUILD_TOOLKITS variable |
| 95 | list (APPEND BUILD_TOOLKITS ${BUILD_ADDITIONAL_TOOLKITS}) |
| 96 | |
| 97 | foreach (OCCT_MODULE ${OCCT_MODULES}) |
| 98 | if (BUILD_MODULE_${OCCT_MODULE}) |
| 99 | list (APPEND BUILD_TOOLKITS ${${OCCT_MODULE}_TOOLKITS}) |
| 100 | endif() |
| 101 | endforeach() |
| 102 | |
| 103 | # DRAWEXE excluded when library build is static |
| 104 | if (NOT BUILD_SHARED_LIBS) |
| 105 | list (REMOVE_ITEM BUILD_TOOLKITS DRAWEXE) |
| 106 | message (STATUS "Info: DRAWEXE is not included due to ${BUILD_LIBRARY_TYPE} build library type") |
| 107 | endif() |
| 108 | |
| 109 | # accumulate all used toolkits |
| 110 | list (REMOVE_DUPLICATES BUILD_TOOLKITS) |
| 111 | set (RAW_BUILD_TOOLKITS) |
| 112 | foreach(BUILD_TOOLKIT ${BUILD_TOOLKITS}) |
| 113 | OCCT_TOOLKIT_FULL_DEP (${BUILD_TOOLKIT} TOOLKIT_FULL_DEPS) |
| 114 | list (APPEND RAW_BUILD_TOOLKITS ${BUILD_TOOLKIT} ${TOOLKIT_FULL_DEPS}) |
| 115 | endforeach() |
| 116 | |
| 117 | list (REMOVE_DUPLICATES RAW_BUILD_TOOLKITS) |
| 118 | set (BUILD_TOOLKITS ${RAW_BUILD_TOOLKITS}) |
| 119 | |
| 120 | # include the patched or original list of definitions and flags |
| 121 | OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_defs_flags") |
| 122 | |
| 123 | OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/3rdparty_macro") |
| 124 | |
| 125 | # Rebuild *.yacc and *.lex files that are contained by TKMath toolkit |
| 126 | list (FIND BUILD_TOOLKITS TKMath CAN_REBUILD_PDC_FOR_TKMATH) |
| 127 | list (FIND BUILD_TOOLKITS StepFile CAN_REBUILD_PDC_FOR_STEPFILE) |
| 128 | |
| 129 | if (NOT "${CAN_REBUILD_PDC_FOR_TKMATH}" STREQUAL "-1" OR NOT "${CAN_REBUILD_PDC_FOR_STEPFILE}" STREQUAL "-1") |
| 130 | set (REBUILD_PLATFORM_DEPENDENT_CODE OFF CACHE BOOL "${REBUILD_PLATFORM_DEPENDENT_CODE_DESCR}") |
| 131 | else() |
| 132 | OCCT_CHECK_AND_UNSET (REBUILD_PLATFORM_DEPENDENT_CODE) |
| 133 | endif() |
| 134 | |
| 135 | if (NOT DEFINED 3RDPARTY_DIR) |
| 136 | set (3RDPARTY_DIR "" CACHE PATH ${3RDPARTY_DIR_DESCR}) |
| 137 | endif() |
| 138 | |
| 139 | # search for 3rdparty dir |
| 140 | if ("${3RDPARTY_DIR}" STREQUAL "") |
| 141 | if (DEFINED ENV{3RDPARTY_DIR}) |
| 142 | set (3RDPARTY_DIR "$ENV{3RDPARTY_DIR}" CACHE PATH ${3RDPARTY_DIR_DESCR} FORCE) |
| 143 | elseif (EXISTS "${CMAKE_SOURCE_DIR}/../") |
| 144 | # in version 6.7.0 and above, occt parent directory contains 3rdparties |
| 145 | get_filename_component (3RDPARTY_DIR "${CMAKE_SOURCE_DIR}/../" ABSOLUTE) |
| 146 | set (3RDPARTY_DIR "${3RDPARTY_DIR}" CACHE PATH ${3RDPARTY_DIR_DESCR} FORCE) |
| 147 | endif() |
| 148 | endif() |
| 149 | |
| 150 | # search for CSF_TclLibs variable in EXTERNLIB of each being used toolkit |
| 151 | OCCT_IS_PRODUCT_REQUIRED (CSF_TclLibs USE_TCL) |
| 152 | |
| 153 | if ("${USE_TCL}" STREQUAL ON) |
| 154 | message (STATUS "Info: TCL is used by OCCT") |
| 155 | OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tcl") |
| 156 | else() |
| 157 | OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TCL") |
| 158 | OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TK") |
| 159 | |
| 160 | OCCT_CHECK_AND_UNSET ("INSTALL_TCL") |
| 161 | endif() |
| 162 | |
| 163 | # search for CSF_FREETYPE variable in EXTERNLIB of each being used toolkit |
| 164 | OCCT_IS_PRODUCT_REQUIRED (CSF_FREETYPE USE_FREETYPE) |
| 165 | |
| 166 | if ("${USE_FREETYPE}" STREQUAL ON) |
| 167 | message (STATUS "Info: Freetype is used by OCCT") |
| 168 | OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freetype") |
| 169 | else() |
| 170 | OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREETYPE") |
| 171 | OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_freetype2") |
| 172 | OCCT_CHECK_AND_UNSET ("3RDPARTY_FREETYPE_INCLUDE_DIR_ft2build") |
| 173 | OCCT_CHECK_AND_UNSET ("INSTALL_FREETYPE") |
| 174 | endif() |
| 175 | |
| 176 | # VTK |
| 177 | if (USE_VTK) |
| 178 | add_definitions (-DHAVE_VTK) |
| 179 | OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/vtk") |
| 180 | else() |
| 181 | OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_VTK") |
| 182 | OCCT_CHECK_AND_UNSET ("INSTALL_VTK") |
| 183 | endif() |
| 184 | |
| 185 | # GLX |
| 186 | if (USE_GLX) |
| 187 | add_definitions (-DMACOSX_USE_GLX) |
| 188 | OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/glx") |
| 189 | endif() |
| 190 | |
| 191 | # FREEIMAGE |
| 192 | # search for CSF_FREEIMAGE variable in EXTERNLIB of each being used toolkit |
| 193 | OCCT_IS_PRODUCT_REQUIRED (CSF_FREEIMAGE CAN_USE_FREEIMAGE) |
| 194 | OCCT_IS_PRODUCT_REQUIRED (CSF_FreeImagePlus CAN_USE_FREEIMAGEPLUS) |
| 195 | |
| 196 | if (CAN_USE_FREEIMAGE OR CAN_USE_FREEIMAGEPLUS) |
| 197 | set (USE_FREEIMAGE OFF CACHE BOOL "${USE_FREEIMAGE_DESCR}") |
| 198 | |
| 199 | if (USE_FREEIMAGE) |
| 200 | add_definitions (-DHAVE_FREEIMAGE) |
| 201 | OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimage") |
| 202 | OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/freeimageplus") |
| 203 | else() |
| 204 | OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE") |
| 205 | OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGEPLUS") |
| 206 | OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE") |
| 207 | OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGEPLUS") |
| 208 | endif() |
| 209 | else() |
| 210 | OCCT_CHECK_AND_UNSET ("USE_FREEIMAGE") |
| 211 | |
| 212 | OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGE") |
| 213 | OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_FREEIMAGEPLUS") |
| 214 | OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGE") |
| 215 | OCCT_CHECK_AND_UNSET ("INSTALL_FREEIMAGEPLUS") |
| 216 | endif() |
| 217 | |
| 218 | # GL2PS |
| 219 | # search for CSF_GL2PS variable in EXTERNLIB of each being used toolkit |
| 220 | OCCT_IS_PRODUCT_REQUIRED (CSF_GL2PS CAN_USE_GL2PS) |
| 221 | |
| 222 | if (NOT DEFINED ANDROID AND CAN_USE_GL2PS) |
| 223 | set (USE_GL2PS OFF CACHE BOOL "${USE_GL2PS_DESCR}") |
| 224 | |
| 225 | if (USE_GL2PS) |
| 226 | add_definitions (-DHAVE_GL2PS) |
| 227 | OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/gl2ps") |
| 228 | else() |
| 229 | OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS") |
| 230 | OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS") |
| 231 | endif() |
| 232 | else() |
| 233 | OCCT_CHECK_AND_UNSET ("USE_GL2PS") |
| 234 | |
| 235 | OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_GL2PS") |
| 236 | OCCT_CHECK_AND_UNSET ("INSTALL_GL2PS") |
| 237 | endif() |
| 238 | |
| 239 | # TBB |
| 240 | # search for CSF_TBB variable in EXTERNLIB of each being used toolkit |
| 241 | OCCT_IS_PRODUCT_REQUIRED (CSF_TBB CAN_USE_TBB) |
| 242 | |
| 243 | if (NOT DEFINED ANDROID AND CAN_USE_TBB) |
| 244 | set (USE_TBB OFF CACHE BOOL "${USE_TBB_DESCR}") |
| 245 | |
| 246 | if (USE_TBB) |
| 247 | add_definitions (-DHAVE_TBB) |
| 248 | OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/tbb") |
| 249 | else() |
| 250 | OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB") |
| 251 | OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC") |
| 252 | OCCT_CHECK_AND_UNSET ("INSTALL_TBB") |
| 253 | endif() |
| 254 | else() |
| 255 | OCCT_CHECK_AND_UNSET ("USE_TBB") |
| 256 | |
| 257 | OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBB") |
| 258 | OCCT_CHECK_AND_UNSET_GROUP ("3RDPARTY_TBBMALLOC") |
| 259 | OCCT_CHECK_AND_UNSET ("INSTALL_TBB") |
| 260 | endif() |
| 261 | |
| 262 | # Doxygen |
| 263 | if (BUILD_DOC_OcctOverview) |
| 264 | if (NOT DEFINED INSTALL_DOC_OcctOverview) |
| 265 | set (INSTALL_DOC_OcctOverview OFF CACHE BOOL "${INSTALL_DOC_OcctOverview_DESCR}") |
| 266 | endif() |
| 267 | |
| 268 | if (INSTALL_DOC_OcctOverview) |
| 269 | install (DIRECTORY "${CMAKE_BINARY_DIR}/doc/overview" DESTINATION "${INSTALL_DIR}/doc") |
| 270 | |
| 271 | OCCT_INSTALL_FILE_OR_DIR ("dox/resources/overview.html" "${INSTALL_DIR}") |
| 272 | endif() |
| 273 | |
| 274 | OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/doxygen") |
| 275 | else() |
| 276 | OCCT_CHECK_AND_UNSET ("INSTALL_DOC_OcctOverview") |
| 277 | |
| 278 | OCCT_CHECK_AND_UNSET ("3RDPARTY_DOXYGEN_EXECUTABLE") |
| 279 | OCCT_CHECK_AND_UNSET ("3RDPARTY_DOXYGEN_DOT_EXECUTABLE") |
| 280 | endif() |
| 281 | |
| 282 | # bison |
| 283 | if (REBUILD_PLATFORM_DEPENDENT_CODE) |
| 284 | OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/bison") |
| 285 | else() |
| 286 | OCCT_CHECK_AND_UNSET ("3RDPARTY_BISON_EXECUTABLE") |
| 287 | endif() |
| 288 | |
| 289 | # flex |
| 290 | if (REBUILD_PLATFORM_DEPENDENT_CODE) |
| 291 | OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/flex") |
| 292 | else() |
| 293 | OCCT_CHECK_AND_UNSET ("3RDPARTY_FLEX_EXECUTABLE") |
| 294 | endif() |
| 295 | |
| 296 | string (REGEX REPLACE ";" " " 3RDPARTY_NOT_INCLUDED "${3RDPARTY_NOT_INCLUDED}") |
| 297 | |
| 298 | # check all 3rdparty paths |
| 299 | if (3RDPARTY_NOT_INCLUDED) |
| 300 | message (FATAL_ERROR "NOT FOUND: ${3RDPARTY_NOT_INCLUDED}" ) |
| 301 | endif() |
| 302 | |
| 303 | if (3RDPARTY_INCLUDE_DIRS) |
| 304 | list (REMOVE_DUPLICATES 3RDPARTY_INCLUDE_DIRS) |
| 305 | string (REGEX REPLACE ";" "\n\t" 3RDPARTY_INCLUDE_DIRS_WITH_ENDS "${3RDPARTY_INCLUDE_DIRS}") |
| 306 | message (STATUS "The directories containing 3rdparty headers: ${3RDPARTY_INCLUDE_DIRS_WITH_ENDS}") |
| 307 | include_directories (${3RDPARTY_INCLUDE_DIRS}) |
| 308 | endif() |
| 309 | |
| 310 | # include <cmake binary folder>/inc |
| 311 | include_directories (${CMAKE_BINARY_DIR}/inc) |
| 312 | |
| 313 | if (3RDPARTY_LIBRARY_DIRS) |
| 314 | list (REMOVE_DUPLICATES 3RDPARTY_LIBRARY_DIRS) |
| 315 | string (REGEX REPLACE ";" "\n\t" 3RDPARTY_LIBRARY_DIRS_WITH_ENDS "${3RDPARTY_LIBRARY_DIRS}") |
| 316 | message (STATUS "The directories containing 3rdparty libraries: ${3RDPARTY_LIBRARY_DIRS_WITH_ENDS}") |
| 317 | link_directories (${3RDPARTY_LIBRARY_DIRS}) |
| 318 | endif() |
| 319 | |
| 320 | # Get all used variables: OS_WITH_BIT, COMPILER |
| 321 | OCCT_MAKE_OS_WITH_BITNESS() |
| 322 | OCCT_MAKE_COMPILER_SHORT_NAME() |
| 323 | |
| 324 | # build directories |
| 325 | set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib") |
| 326 | set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin") |
| 327 | set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/lib") |
| 328 | |
| 329 | set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi") |
| 330 | set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini") |
| 331 | set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libi") |
| 332 | |
| 333 | set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd") |
| 334 | set (CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind") |
| 335 | set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/libd") |
| 336 | |
| 337 | if (WIN32) |
| 338 | set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELEASE "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bin") |
| 339 | set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_RELWITHDEBINFO "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bini") |
| 340 | set (CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG "${CMAKE_BINARY_DIR}/${OS_WITH_BIT}/${COMPILER}/bind") |
| 341 | endif() |
| 342 | |
| 343 | if ("${INSTALL_DIR}" STREQUAL "") |
| 344 | get_filename_component (CMAKE_BINARY_DIR_PARENT ${CMAKE_BINARY_DIR} DIRECTORY) |
| 345 | |
| 346 | set (INSTALL_DIR "${CMAKE_BINARY_DIR_PARENT}/install" CACHE PATH "${INSTALL_DIR_DESCR}" FORCE) |
| 347 | set (CMAKE_INSTALL_PREFIX "${INSTALL_DIR}" CACHE INTERNAL "" FORCE ) |
| 348 | |
| 349 | message (STATUS "Info: INSTALL_DIR has been set as ${INSTALL_DIR}") |
| 350 | endif() |
| 351 | |
| 352 | message (STATUS "\nInfo: Collecting all OCCT header files into ${CMAKE_BINARY_DIR}/inc ...") |
| 353 | |
| 354 | # collect all the headers to <binary dir>/inc folder |
| 355 | COLLECT_AND_INSTALL_OCCT_HEADER_FILES ("${CMAKE_BINARY_DIR}" "${BUILD_TOOLKITS}") |
| 356 | |
| 357 | OCCT_INSTALL_FILE_OR_DIR ("data" "${INSTALL_DIR}") |
| 358 | OCCT_INSTALL_FILE_OR_DIR ("samples/tcl" "${INSTALL_DIR}/samples") |
| 359 | |
| 360 | if (INSTALL_OCCT_SAMPLES) |
| 361 | OCCT_INSTALL_FILE_OR_DIR ("samples" "${INSTALL_DIR}") |
| 362 | endif() |
| 363 | |
| 364 | if (INSTALL_OCCT_TEST_CASES) |
| 365 | OCCT_INSTALL_FILE_OR_DIR ("tests" "${INSTALL_DIR}") |
| 366 | endif() |
| 367 | |
| 368 | if (WIN32) |
| 369 | set (SCRIPT_EXT bat) |
| 370 | else() |
| 371 | set (SCRIPT_EXT sh) |
| 372 | endif() |
| 373 | |
| 374 | # DRAW.BAT or DRAW.SH |
| 375 | if (APPLY_OCCT_PATCH_DIR AND EXISTS "${APPLY_OCCT_PATCH_DIR}/adm/templates/draw.${SCRIPT_EXT}") |
| 376 | install (FILES "${APPLY_OCCT_PATCH_DIR}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}" PERMISSIONS |
| 377 | OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE) |
| 378 | else() |
| 379 | install (FILES "${CMAKE_SOURCE_DIR}/adm/templates/draw.${SCRIPT_EXT}" DESTINATION "${INSTALL_DIR}" PERMISSIONS |
| 380 | OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_WRITE GROUP_EXECUTE WORLD_READ WORLD_WRITE WORLD_EXECUTE) |
| 381 | endif() |
| 382 | OCCT_COPY_FILE_OR_DIR ("adm/templates/draw.${SCRIPT_EXT}" "${CMAKE_BINARY_DIR}") |
| 383 | |
| 384 | set (SUB_CUSTOM_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.${SCRIPT_EXT}") |
| 385 | |
| 386 | if (WIN32) |
| 387 | set (ADDITIONAL_CUSTOM_CONTENT "\nif exist \"%~dp0${SUB_CUSTOM_NAME}\" (\n call \"%~dp0${SUB_CUSTOM_NAME}\" %VCVER% %ARCH% %CASDEB% \n)") |
| 388 | else() |
| 389 | set (ADDITIONAL_CUSTOM_CONTENT "\nif [ -e \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" ]; then\n source \"\${aScriptPath}/${SUB_CUSTOM_NAME}\" \"\${COMPILER}\" \"\${WOKSTATION}\${ARCH}\" \"\${CASDEB}\" \nfi") |
| 390 | endif() |
| 391 | |
| 392 | # change custom.bat/sh |
| 393 | if (EXISTS "${INSTALL_DIR}/custom.${SCRIPT_EXT}") |
| 394 | file (READ "${INSTALL_DIR}/custom.${SCRIPT_EXT}" CUSTOM_CONTENT) |
| 395 | |
| 396 | set (CUSTOM_CONTENT "${CUSTOM_CONTENT} ${ADDITIONAL_CUSTOM_CONTENT}") |
| 397 | |
| 398 | file (WRITE "${INSTALL_DIR}/custom.${SCRIPT_EXT}" "${CUSTOM_CONTENT}") |
| 399 | else() |
| 400 | OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.${SCRIPT_EXT}.main" "custom.${SCRIPT_EXT}" "custom.${SCRIPT_EXT}" "${INSTALL_DIR}") |
| 401 | endif() |
| 402 | |
| 403 | # write current custom.bat/sh (for install directory) |
| 404 | set (SUB_CUSTOM_BUILD_NAME "custom_${COMPILER}_${COMPILER_BITNESS}.install.${SCRIPT_EXT}") |
| 405 | OCCT_CONFIGURE_AND_INSTALL ("adm/templates/custom.install.${SCRIPT_EXT}.in" "${SUB_CUSTOM_BUILD_NAME}" "${SUB_CUSTOM_NAME}" "${INSTALL_DIR}") |
| 406 | |
| 407 | # write current custom.bat/sh (for build directory) |
| 408 | OCCT_CONFIGURE ("adm/templates/custom.build.${SCRIPT_EXT}.in" "${SUB_CUSTOM_NAME}") |
| 409 | |
| 410 | if (BUILD_MODULE_OcctMfcSamples) |
| 411 | OCCT_INSTALL_FILE_OR_DIR ("adm/templates/sample.bat" "${INSTALL_DIR}") |
| 412 | OCCT_COPY_FILE_OR_DIR ("adm/templates/sample.bat" "${CMAKE_BINARY_DIR}") |
| 413 | endif() |
| 414 | |
| 415 | # env script for draw in building environment |
| 416 | OCCT_CONFIGURE ("adm/templates/env.build.${SCRIPT_EXT}.in" "env.${SCRIPT_EXT}") |
| 417 | |
| 418 | # end script for draw in standalone environment |
| 419 | # release version |
| 420 | set (BUILD_LETTER "") |
| 421 | OCCT_CONFIGURE ("adm/templates/env.install.${SCRIPT_EXT}.in" "env.install.release.${SCRIPT_EXT}") |
| 422 | install (FILES "${CMAKE_BINARY_DIR}/env.install.release.${SCRIPT_EXT}" |
| 423 | CONFIGURATIONS Release |
| 424 | DESTINATION "${INSTALL_DIR}" |
| 425 | RENAME "env.${SCRIPT_EXT}") |
| 426 | |
| 427 | # debug version |
| 428 | set (BUILD_LETTER "d") |
| 429 | OCCT_CONFIGURE ("adm/templates/env.install.${SCRIPT_EXT}.in" "env.install.debug.${SCRIPT_EXT}") |
| 430 | install (FILES "${CMAKE_BINARY_DIR}/env.install.debug.${SCRIPT_EXT}" |
| 431 | CONFIGURATIONS Debug |
| 432 | DESTINATION "${INSTALL_DIR}" |
| 433 | RENAME "env.${SCRIPT_EXT}") |
| 434 | |
| 435 | # release with debug info version |
| 436 | set (BUILD_LETTER "i") |
| 437 | OCCT_CONFIGURE ("adm/templates/env.install.${SCRIPT_EXT}.in" "env.install.relwithdebinfo.${SCRIPT_EXT}") |
| 438 | install (FILES "${CMAKE_BINARY_DIR}/env.install.relwithdebinfo.${SCRIPT_EXT}" |
| 439 | CONFIGURATIONS RelWithDebInfo |
| 440 | DESTINATION "${INSTALL_DIR}" |
| 441 | RENAME "env.${SCRIPT_EXT}") |
| 442 | |
| 443 | # copy DrawAppliInit from OCCT source to build directory |
| 444 | if (NOT EXISTS "${CMAKE_BINARY_DIR}/DrawAppliInit") |
| 445 | OCCT_COPY_FILE_OR_DIR (DrawAppliInit "${CMAKE_BINARY_DIR}") |
| 446 | endif() |
| 447 | |
| 448 | # RESOURCES |
| 449 | FILE_TO_LIST ("adm/RESOURCES" RESOURCES) |
| 450 | foreach(RESOURCE ${RESOURCES}) |
| 451 | get_filename_component(RESOURCE_FOLDER ${RESOURCE} DIRECTORY) |
| 452 | if(NOT "${RESOURCE_FOLDER}" STREQUAL "") |
| 453 | get_filename_component(RESOURCE_FOLDER ${RESOURCE_FOLDER} NAME) |
| 454 | OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR}/src/${RESOURCE_FOLDER}") |
| 455 | else() |
| 456 | OCCT_INSTALL_FILE_OR_DIR ("src/${RESOURCE}" "${INSTALL_DIR}/src") |
| 457 | endif() |
| 458 | endforeach() |
| 459 | |
| 460 | # include patched toolkit projects or original ones |
| 461 | foreach (BUILD_TOOLKIT ${BUILD_TOOLKITS}) |
| 462 | OCCT_ADD_SUBDIRECTORY ("src/${BUILD_TOOLKIT}") |
| 463 | endforeach() |
| 464 | |
| 465 | if (BUILD_DOC_OcctOverview) |
| 466 | OCCT_ADD_SUBDIRECTORY (dox) |
| 467 | endif() |
| 468 | |
| 469 | # patch DRAWEXE |
| 470 | if (MSVC AND 3RDPARTY_DLL_DIRS) |
| 471 | list (FIND BUILD_TOOLKITS DRAWEXE DRAWEXE_INDEX) |
| 472 | if (${DRAWEXE_INDEX} GREATER -1) |
| 473 | list (REMOVE_DUPLICATES 3RDPARTY_DLL_DIRS) |
| 474 | set (3RDPARTY_DLL_DIRS_FOR_PATH "") |
| 475 | |
| 476 | foreach (3RDPARTY_DLL_DIR ${3RDPARTY_DLL_DIRS}) |
| 477 | set (3RDPARTY_DLL_DIRS_FOR_PATH "${3RDPARTY_DLL_DIRS_FOR_PATH};${3RDPARTY_DLL_DIR}") |
| 478 | endforeach() |
| 479 | |
| 480 | OCCT_MAKE_COMPILER_BITNESS() |
| 481 | set (X_COMPILER_BITNESS "x64") |
| 482 | if ("${COMPILER_BITNESS}" STREQUAL "32") |
| 483 | set (X_COMPILER_BITNESS "Win32") |
| 484 | endif() |
| 485 | |
| 486 | OCCT_CONFIGURE ("adm/templates/DRAWEXE.vcxproj.user.in" "${CMAKE_BINARY_DIR}/src/DRAWEXE/DRAWEXE.vcxproj.user") |
| 487 | endif() |
| 488 | endif() |
| 489 | |
| 490 | # samples do not support patch usage |
| 491 | if (BUILD_MODULE_OcctMfcSamples) |
| 492 | set (OCCT_ROOT ${CMAKE_SOURCE_DIR}) |
| 493 | |
| 494 | set (MFC_STANDARD_SAMPLES_DIR ${OCCT_ROOT}/samples/mfc/standard) |
| 495 | set (COMMON_WINMAIN_FILE ${MFC_STANDARD_SAMPLES_DIR}/Common/Winmain.cpp) |
| 496 | |
| 497 | add_subdirectory(samples/mfc/standard/mfcsample) |
| 498 | add_subdirectory(samples/mfc/standard/01_Geometry) |
| 499 | add_subdirectory(samples/mfc/standard/02_Modeling) |
| 500 | add_subdirectory(samples/mfc/standard/03_Viewer2d) |
| 501 | add_subdirectory(samples/mfc/standard/04_Viewer3d) |
| 502 | add_subdirectory(samples/mfc/standard/05_ImportExport) |
| 503 | add_subdirectory(samples/mfc/standard/06_Ocaf) |
| 504 | add_subdirectory(samples/mfc/standard/07_Triangulation) |
| 505 | add_subdirectory(samples/mfc/standard/08_HLR) |
| 506 | add_subdirectory(samples/mfc/standard/09_Animation) |
| 507 | add_subdirectory(samples/mfc/standard/10_Convert) |
| 508 | endif() |